mudsync/room.scm

   1 ;;; Mudsync --- Live hackable MUD
   2 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of Mudsync.
   5 ;;;
   6 ;;; Mudsync is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or
   9 ;;; (at your option) any later version.
  10 ;;;
  11 ;;; Mudsync is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;;; General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with Mudsync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (mudsync room)
  20   #:use-module (mudsync command)
  21   #:use-module (mudsync gameobj)
  22   #:use-module (8sync systems actors)
  23   #:use-module (8sync agenda)
  24   #:use-module (oop goops)
  25   #:use-module (srfi srfi-1)
  26   #:use-module (ice-9 control)
  27   #:export (<room>
  28             room-actions
  29             room-actions*
  30
  31             <exit>))
  32
  33 \f
  34 ;;; Exits
  35 ;;; =====
  36
  37 (define-class <exit> ()
  38   (to #:init-keyword #:to)
  39   ;; Name of the room (@@: Should this be names?)
  40   (name #:getter exit-name
  41         #:init-keyword #:name)
  42   (desc #:init-keyword #:desc
  43         #:init-value #f)
  44
  45   ;; *Note*: These two methods have an extra layer of indirection, but
  46   ;;   it's for a good reason.
  47   (visible-check #:init-value (const #t)
  48                  #:init-keyword #:visible-check)
  49   ;; By default all exits can be traversed
  50   (traverse-check #:init-value (const #t)
  51                   #:init-keyword #:traverse-check))
  52
  53 (define* (exit-can-traverse? exit actor
  54                              #:optional (target-actor (actor-id actor)))
  55   ((slot-ref exit 'traverse-check) exit actor target-actor))
  56
  57 (define* (exit-is-visible? exit actor
  58                            #:optional (target-actor (actor-id actor)))
  59   ((slot-ref exit 'traverse-check) exit actor target-actor))
  60
  61
  62 \f
  63 ;;; Rooms
  64 ;;; =====
  65
  66 (define %room-contain-commands
  67   (list
  68    (loose-direct-command "look" 'cmd-look-at)
  69    (empty-command "look" 'cmd-look-room)
  70    (empty-command "go" 'cmd-go-where)
  71    (loose-direct-command "go" 'cmd-go)
  72    (greedy-command "say" 'cmd-say)
  73    (greedy-command "emote" 'cmd-emote)))
  74
  75 (define room-actions
  76   (build-actions
  77    (cmd-go (wrap-apply room-cmd-go))
  78    (cmd-go-where (wrap-apply room-cmd-go-where))
  79    (announce-entrance (wrap-apply room-announce-entrance))
  80    (look-room (wrap-apply room-look-room))
  81    (tell-room (wrap-apply room-act-tell-room))
  82    ;; in this case the command is the same version as the normal
  83    ;; look-room version
  84    (cmd-look-room (wrap-apply room-look-room))
  85    (cmd-look-at (wrap-apply room-look-at))
  86    (cmd-say (wrap-apply room-cmd-say))
  87    (cmd-emote (wrap-apply room-cmd-emote))))
  88
  89 (define room-actions*
  90   (append room-actions gameobj-actions))
  91
  92 (define room-action-dispatch
  93   (simple-dispatcher room-actions*))
  94
  95 ;; TODO: Subclass from container?
  96 (define-class <room> (<gameobj>)
  97   ;; A list of <exit>
  98   (exits #:init-value '()
  99          #:init-keyword #:exits
 100          #:getter room-exits)
 101
 102   (container-commands
 103    #:init-value (wrap %room-contain-commands))
 104
 105   (message-handler
 106    #:allocation #:each-subclass
 107    ;; @@: Can remove this indirection once things settle
 108    #:init-value (wrap-apply room-action-dispatch)))
 109
 110 (define* (room-cmd-go room message #:key direct-obj)
 111   (define exit
 112     (find
 113      (lambda (exit)
 114        (equal? (exit-name exit) direct-obj))
 115      (room-exits room)))
 116   (define to-address (if exit
 117                          ;; Get the exit, but resolve it dynamically
 118                          ;; in case it's a special
 119                          (dyn-ref room (slot-ref exit 'to))
 120                          #f))
 121   (define player-name
 122     (msg-val (<-wait room (message-from message) 'get-name)))
 123   (cond
 124    (exit
 125     ;; Set the player's new location
 126     (<-wait room (message-from message) 'set-loc!
 127             #:loc to-address)
 128     ;; Tell everyone else the person walked away
 129     (room-tell-room
 130      room
 131      (format #f "~a wanders ~a.\n"
 132              player-name direct-obj))
 133     (<- room to-address 'announce-entrance
 134         #:who-entered (message-from message))
 135     ;; Have the new room update the player to the new location
 136     (<- room to-address 'look-room
 137         #:to-id (message-from message)))
 138    (else
 139     (<- room (message-from message) 'tell
 140         #:text "You don't see any way to go there.\n"))))
 141
 142 (define (room-cmd-go-where room message)
 143   (<- room (message-from message) 'tell
 144       #:text "Go where?\n"))
 145
 146 ;;; look commands
 147
 148 (define (list-words-as-string words)
 149   "A little utility for listing a bunch of words in an English-style list"
 150   ;; TODO: This could be made faster by traversing the O(n)
 151   ;;   list once, not twice
 152   (let ((word-length (length words)))
 153     (cond
 154      ((eqv? word-length 0) "")
 155      ((eqv? word-length 1) (car words))
 156      (else
 157       ;; TODO: and this is NOT efficient
 158       (string-append
 159        (string-join
 160         (drop-right words 1)
 161         ", ")
 162        " and "
 163        (last words))))))
 164
 165 (define (room-player-looks-around room player-id)
 166   "Handle looking around the room"
 167   ;; Get the room text
 168   (define room-text
 169     (format #f "**~a**\n~a\n"
 170             (slot-ref room 'name)
 171             (slot-ref room 'desc)))
 172
 173   ;; Get a list of other things the player would see in the room
 174   (define occupant-names-all
 175     (map
 176      (lambda (occupant)
 177        (call-with-message (<-wait room occupant 'visible-name
 178                                   #:whos-looking player-id)
 179                           (lambda* (_ #:key text)
 180                             text)))
 181      (remove
 182       (lambda (x) (equal? x player-id))
 183       (hash-map->list (lambda (x _) x)
 184                       (slot-ref room 'occupants)))))
 185
 186   ;; Strip out the #f responses (these aren't listed because they lack a name
 187   ;; or they aren't "obviously visible" to the player)
 188   (define occupant-names-filtered
 189     (filter identity occupant-names-all))
 190
 191   (define occupant-names-string
 192     (if (eq? occupant-names-filtered '())
 193         #f
 194         (format #f "You see here: ~a.\n"
 195                 (list-words-as-string occupant-names-filtered))))
 196
 197   (define final-text
 198     (if occupant-names-string
 199         (string-append room-text occupant-names-string)
 200         room-text))
 201
 202   (<- room player-id 'tell
 203       #:text final-text))
 204
 205
 206 (define* (room-look-room room message
 207                             ;; Either send it to the #:to-id of the message,
 208                             ;; or to the sender of the message
 209                             #:key (to-id (message-from message)))
 210   "Command: Player asks to look around the room"
 211   (room-player-looks-around room to-id))
 212
 213 (define (room-find-thing-called room called-this)
 214   "Find something called CALLED-THIS in the room, if any."
 215   (call/ec
 216    (lambda (return)
 217      (for-each
 218       (lambda (occupant)
 219         (msg-receive (_ #:key goes-by)
 220             (<-wait room occupant 'goes-by)
 221           (if (member called-this goes-by)
 222               (return occupant))))
 223       (hash-map->list (lambda (key val) key)
 224                       (slot-ref room 'occupants)))
 225      #f)))
 226
 227 (define %formless-desc
 228   "You don't see anything special.")
 229
 230 (define* (room-look-at room message #:key direct-obj)
 231   "Look at a specific object in the room."
 232   (define matching-object
 233     (room-find-thing-called room direct-obj))
 234
 235   (cond
 236    (matching-object
 237     (let ((obj-desc
 238            (msg-val (<-wait room matching-object 'get-desc
 239                             #:whos-looking (message-from message)))))
 240       (if obj-desc
 241           (<- room (message-from message) 'tell
 242               #:text (string-append obj-desc "\n"))
 243           (<- room (message-from message) 'tell
 244               #:text (string-append %formless-desc "\n")))))
 245    (else
 246     (<- room (message-from message) 'tell
 247         #:text "You don't see that here, so you can't look at it.\n"))))
 248
 249
 250 (define* (room-tell-room room text #:key exclude wait)
 251   (define who-to-tell (gameobj-occupants room #:exclude exclude))
 252   (for-each
 253    (lambda (tell-me)
 254      ;; @@: Does anything really care?
 255      (define deliver-method
 256        (if wait
 257            <-wait
 258            <-))
 259      (deliver-method room tell-me 'tell
 260                      #:text text))
 261    who-to-tell))
 262
 263 (define* (room-act-tell-room room message #:key text exclude wait)
 264   "Tell the room some messages."
 265   (room-tell-room room text
 266                   #:exclude exclude
 267                   #:wait wait))
 268
 269 (define* (room-cmd-say room message #:key phrase)
 270   "Command: Say something to room participants."
 271   (define player-name
 272     (msg-val (<-wait room (message-from message)
 273                      'get-name)))
 274   (define message-to-send
 275     (format #f "~a says: ~a\n" player-name phrase))
 276   (room-tell-room room message-to-send))
 277
 278 (define* (room-cmd-emote room message #:key phrase)
 279   "Command: Say something to room participants."
 280   (define player-name
 281     (msg-val (<-wait room (message-from message)
 282                      'get-name)))
 283   (define message-to-send
 284     (format #f "* ~a ~a\n" player-name phrase))
 285   (room-tell-room room message-to-send))
 286
 287 (define* (room-announce-entrance room message #:key who-entered)
 288   (define player-name
 289     (msg-val (<-wait room who-entered 'get-name)))
 290   (define message-to-send
 291     (format #f "~a enters the room.\n" player-name))
 292   (room-tell-room room message-to-send
 293                   #:exclude who-entered))