target_firmware/CMakeLists.txt

   1 ##
   2  # Copyright (c) 2013 Qualcomm Atheros, Inc.
   3  #
   4  # All rights reserved.
   5  #
   6  # Redistribution and use in source and binary forms, with or without
   7  # modification, are permitted (subject to the limitations in the
   8  # disclaimer below) provided that the following conditions are met:
   9  #
  10  #  * Redistributions of source code must retain the above copyright
  11  #    notice, this list of conditions and the following disclaimer.
  12  #
  13  #  * Redistributions in binary form must reproduce the above copyright
  14  #    notice, this list of conditions and the following disclaimer in the
  15  #    documentation and/or other materials provided with the
  16  #    distribution.
  17  #
  18  #  * Neither the name of Qualcomm Atheros nor the names of its
  19  #    contributors may be used to endorse or promote products derived
  20  #    from this software without specific prior written permission.
  21  #
  22  # NO EXPRESS OR IMPLIED LICENSES TO ANY PARTY'S PATENT RIGHTS ARE
  23  # GRANTED BY THIS LICENSE.  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT
  24  # HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED
  25  # WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  26  # MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  27  # DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
  28  # LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  29  # CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  30  # SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR
  31  # BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  32  # WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE
  33  # OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN
  34  # IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35  ##
  36
  37 SET(CMAKE_C_COMPILER_WORKS 1)
  38
  39 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  40 PROJECT(ath9k_firmware NONE)
  41 ENABLE_LANGUAGE(C)
  42
  43 ADD_DEFINITIONS(
  44         -g -Os
  45         -Wunused-label
  46         -Wunused-variable
  47         -Wunused-value
  48         -Wpointer-arith
  49         -nostdlib
  50         -Wundef
  51         -Wunused-but-set-variable
  52 )
  53 ADD_DEFINITIONS(
  54         -D_RAM_
  55         -DBIG_ENDIAN -D_BYTE_ORDER=_BIG_ENDIAN
  56         -D__XTENSA__
  57         -DFUSION_USB_FW -DRX_SCATTER
  58         -DFUSION_USB_ENABLE_TX_STREAM -DFUSION_USB_ENABLE_RX_STREAM
  59         -DATH_ENABLE_CABQ
  60 )
  61
  62 SET(SOURCES
  63         magpie_fw_dev/target/init/app_start.c
  64         magpie_fw_dev/target/init/init.c
  65         magpie_fw_dev/target/init/magpie.c
  66         magpie_fw_dev/target/adf/adf_nbuf.c
  67         magpie_fw_dev/target/adf/adf_net.c
  68         magpie_fw_dev/target/adf/adf_os_defer_pvt.c
  69         magpie_fw_dev/target/adf/adf_os_dma.c
  70         magpie_fw_dev/target/adf/adf_os_irq_pvt.c
  71         magpie_fw_dev/target/adf/adf_os_timer.c
  72         magpie_fw_dev/target/buf_pool/buf_pool_static.c
  73         magpie_fw_dev/target/cmnos/dbg_api.c
  74         magpie_fw_dev/target/cmnos/cmnos_sflash.c
  75         magpie_fw_dev/target/hif/usb_api_main_patch.c
  76         wlan/ah.c
  77         wlan/ah_osdep.c
  78         wlan/ar5416Phy.c
  79         wlan/ar5416_hw.c
  80         wlan/ar5416_phy.c
  81         wlan/ratectrl_11n_ln.c
  82         wlan/if_owl.c
  83         wlan/if_ath.c
  84         wlan/if_ath_pci.c
  85         magpie_fw_dev/target/wlan/wlan_pci.c
  86         wlan/ieee80211_output.c
  87         magpie_fw_dev/target/htc/htc.c
  88         magpie_fw_dev/target/wmi/wmi_svc.c
  89 )
  90
  91 IF(TARGET_K2)
  92         SET(SOURCES ${SOURCES}
  93                 magpie_fw_dev/target/hif/k2_HIF_usb_patch.c
  94                 magpie_fw_dev/target/hif/usb_api_k2_patch.c
  95         )
  96         SET(LIBS ${LIBS} hif)
  97         ADD_DEFINITIONS(-DPROJECT_K2)
  98         SET(PLATFORM_NAME k2)
  99         SET(SOURCES ${SOURCES}
 100                 magpie_fw_dev/target/cmnos/k2_cmnos_clock_patch.c
 101                 magpie_fw_dev/target/cmnos/k2_fw_cmnos_printf.c
 102         )
 103         SET(FIRMWARE_NAME htc_9271.fw)
 104 ELSEIF(TARGET_MAGPIE)
 105         ADD_DEFINITIONS(
 106                 -DROM_VER_1_1 -D_ROM_1_1_
 107                 -DPROJECT_MAGPIE
 108                 -DMAGPIE_MERLIN
 109         )
 110         SET(SOURCES ${SOURCES}
 111                 magpie_fw_dev/target/hif/usb_api_magpie_patch.c
 112                 magpie_fw_dev/target/rompatch/cmnos_clock_patch.c
 113                 magpie_fw_dev/target/rompatch/HIF_usb_patch.c
 114         )
 115         INCLUDE_DIRECTORIES(
 116                 ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/adf
 117         )
 118         SET(PLATFORM_NAME magpie)
 119         SET(FIRMWARE_NAME htc_7010.fw)
 120 ELSE()
 121         MESSAGE(FATAL_ERROR "Unknown target name")
 122 ENDIF()
 123
 124 INCLUDE_DIRECTORIES(
 125         ${CMAKE_SOURCE_DIR}/include
 126         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/
 127         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/inc
 128         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/inc/xtensa-elf
 129         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/inc/${PLATFORM_NAME}
 130         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/inc/${PLATFORM_NAME}/${PLATFORM_NAME}
 131         ${CMAKE_SOURCE_DIR}/wlan
 132         ${CMAKE_SOURCE_DIR}/wlan/include
 133         ${CMAKE_SOURCE_DIR}/wlan/include/${PLATFORM_NAME}
 134         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/wlan
 135         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/cmnos
 136         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/wmi
 137         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/adf
 138         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/buf_pool
 139         ${CMAKE_SOURCE_DIR}/magpie_fw_dev/target/htc
 140 )
 141
 142 ADD_LIBRARY(firmware ${SOURCES})
 143
 144 ADD_CUSTOM_COMMAND(
 145         OUTPUT fw.elf
 146         DEPENDS firmware
 147         COMMAND ${CMAKE_C_COMPILER}
 148                 -nostdlib
 149                 -fno-lto
 150                 -Wl,--start-group
 151                 ${CMAKE_BINARY_DIR}/libfirmware.a
 152                 -Wl,--end-group
 153                 -Wl,-T,${CMAKE_SOURCE_DIR}/ram-${PLATFORM_NAME}.ld
 154                 -Wl,-T,${CMAKE_SOURCE_DIR}/rom-addrs-${PLATFORM_NAME}.ld
 155                 -o fw.elf
 156 )
 157 ADD_CUSTOM_COMMAND(
 158         OUTPUT fw.bin
 159         DEPENDS fw.elf
 160         COMMAND ${CMAKE_OBJCOPY}
 161                 --change-section-lma .boot-0x400000
 162                 --change-section-vma .boot-0x400000
 163                 --change-section-lma .text-0x400000
 164                 --change-section-vma .text-0x400000
 165                 -O binary fw.elf fw.bin
 166 )
 167 ADD_CUSTOM_COMMAND(
 168         OUTPUT ${FIRMWARE_NAME}
 169         DEPENDS fw.bin
 170         COMMAND ${CMAKE_SOURCE_DIR}/firmware-crc.pl < fw.bin > ${FIRMWARE_NAME}
 171 )
 172 ADD_CUSTOM_TARGET(gen-firmware ALL DEPENDS ${FIRMWARE_NAME})