config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34
  35 %union
  36 {
  37         char *string;
  38         struct file *file;
  39         struct symbol *symbol;
  40         struct expr *expr;
  41         struct menu *menu;
  42         const struct kconf_id *id;
  43         enum symbol_type type;
  44         enum variable_flavor flavor;
  45 }
  46
  47 %token <id>T_MAINMENU
  48 %token <id>T_MENU
  49 %token <id>T_ENDMENU
  50 %token <id>T_SOURCE
  51 %token <id>T_CHOICE
  52 %token <id>T_ENDCHOICE
  53 %token <id>T_COMMENT
  54 %token <id>T_CONFIG
  55 %token <id>T_MENUCONFIG
  56 %token <id>T_HELP
  57 %token <string> T_HELPTEXT
  58 %token <id>T_IF
  59 %token <id>T_ENDIF
  60 %token <id>T_DEPENDS
  61 %token <id>T_OPTIONAL
  62 %token <id>T_PROMPT
  63 %token <id>T_SELECT
  64 %token <id>T_IMPLY
  65 %token <id>T_RANGE
  66 %token <id>T_VISIBLE
  67 %token <id>T_OPTION
  68 %token <id>T_ON
  69 %token <string> T_WORD
  70 %token <string> T_WORD_QUOTE
  71 %token T_BOOL
  72 %token T_CLOSE_PAREN
  73 %token T_DEFAULT
  74 %token T_DEF_BOOL
  75 %token T_DEF_TRISTATE
  76 %token T_HEX
  77 %token T_INT
  78 %token T_OPEN_PAREN
  79 %token T_STRING
  80 %token T_TRISTATE
  81 %token T_EOL
  82 %token <string> T_VARIABLE
  83 %token <flavor> T_ASSIGN
  84 %token <string> T_ASSIGN_VAL
  85
  86 %left T_OR
  87 %left T_AND
  88 %left T_EQUAL T_UNEQUAL
  89 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  90 %nonassoc T_NOT
  91
  92 %type <string> prompt
  93 %type <symbol> nonconst_symbol
  94 %type <symbol> symbol
  95 %type <type> type logic_type default
  96 %type <expr> expr
  97 %type <expr> if_expr
  98 %type <id> end
  99 %type <menu> if_entry menu_entry choice_entry
 100 %type <string> symbol_option_arg word_opt assign_val
 101
 102 %destructor {
 103         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
 104                 $$->file->name, $$->lineno);
 105         if (current_menu == $$)
 106                 menu_end_menu();
 107 } if_entry menu_entry choice_entry
 108
 109 %{
 110 /* Include kconf_id.c here so it can see the token constants. */
 111 #include "kconf_id.c"
 112 %}
 113
 114 %%
 115 input: mainmenu_stmt stmt_list | stmt_list;
 116
 117 /* mainmenu entry */
 118
 119 mainmenu_stmt: T_MAINMENU prompt T_EOL
 120 {
 121         menu_add_prompt(P_MENU, $2, NULL);
 122 };
 123
 124 stmt_list:
 125           /* empty */
 126         | stmt_list common_stmt
 127         | stmt_list choice_stmt
 128         | stmt_list menu_stmt
 129         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 130         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 131 ;
 132
 133 common_stmt:
 134           if_stmt
 135         | comment_stmt
 136         | config_stmt
 137         | menuconfig_stmt
 138         | source_stmt
 139         | assignment_stmt
 140 ;
 141
 142 /* config/menuconfig entry */
 143
 144 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 145 {
 146         $2->flags |= SYMBOL_OPTIONAL;
 147         menu_add_entry($2);
 148         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 149 };
 150
 151 config_stmt: config_entry_start config_option_list
 152 {
 153         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 154 };
 155
 156 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 157 {
 158         $2->flags |= SYMBOL_OPTIONAL;
 159         menu_add_entry($2);
 160         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 161 };
 162
 163 menuconfig_stmt: menuconfig_entry_start config_option_list
 164 {
 165         if (current_entry->prompt)
 166                 current_entry->prompt->type = P_MENU;
 167         else
 168                 zconfprint("warning: menuconfig statement without prompt");
 169         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 170 };
 171
 172 config_option_list:
 173           /* empty */
 174         | config_option_list config_option
 175         | config_option_list symbol_option
 176         | config_option_list depends
 177         | config_option_list help
 178 ;
 179
 180 config_option: type prompt_stmt_opt T_EOL
 181 {
 182         menu_set_type($1);
 183         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 184                 zconf_curname(), zconf_lineno(),
 185                 $1);
 186 };
 187
 188 config_option: T_PROMPT prompt if_expr T_EOL
 189 {
 190         menu_add_prompt(P_PROMPT, $2, $3);
 191         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 192 };
 193
 194 config_option: default expr if_expr T_EOL
 195 {
 196         menu_add_expr(P_DEFAULT, $2, $3);
 197         if ($1 != S_UNKNOWN)
 198                 menu_set_type($1);
 199         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 200                 zconf_curname(), zconf_lineno(),
 201                 $1);
 202 };
 203
 204 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 205 {
 206         menu_add_symbol(P_SELECT, $2, $3);
 207         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 208 };
 209
 210 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 211 {
 212         menu_add_symbol(P_IMPLY, $2, $3);
 213         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 214 };
 215
 216 config_option: T_RANGE symbol symbol if_expr T_EOL
 217 {
 218         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 219         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 220 };
 221
 222 symbol_option: T_OPTION symbol_option_list T_EOL
 223 ;
 224
 225 symbol_option_list:
 226           /* empty */
 227         | symbol_option_list T_WORD symbol_option_arg
 228 {
 229         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 230         if (id && id->flags & TF_OPTION) {
 231                 menu_add_option(id->token, $3);
 232                 free($3);
 233         }
 234         else
 235                 zconfprint("warning: ignoring unknown option %s", $2);
 236         free($2);
 237 };
 238
 239 symbol_option_arg:
 240           /* empty */           { $$ = NULL; }
 241         | T_EQUAL prompt        { $$ = $2; }
 242 ;
 243
 244 /* choice entry */
 245
 246 choice: T_CHOICE word_opt T_EOL
 247 {
 248         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 249         sym->flags |= SYMBOL_NO_WRITE;
 250         menu_add_entry(sym);
 251         menu_add_expr(P_CHOICE, NULL, NULL);
 252         free($2);
 253         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 254 };
 255
 256 choice_entry: choice choice_option_list
 257 {
 258         $$ = menu_add_menu();
 259 };
 260
 261 choice_end: end
 262 {
 263         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 264                 menu_end_menu();
 265                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 266         }
 267 };
 268
 269 choice_stmt: choice_entry choice_block choice_end
 270 ;
 271
 272 choice_option_list:
 273           /* empty */
 274         | choice_option_list choice_option
 275         | choice_option_list depends
 276         | choice_option_list help
 277 ;
 278
 279 choice_option: T_PROMPT prompt if_expr T_EOL
 280 {
 281         menu_add_prompt(P_PROMPT, $2, $3);
 282         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 283 };
 284
 285 choice_option: logic_type prompt_stmt_opt T_EOL
 286 {
 287         menu_set_type($1);
 288         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 289                zconf_curname(), zconf_lineno(), $1);
 290 };
 291
 292 choice_option: T_OPTIONAL T_EOL
 293 {
 294         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 295         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 296 };
 297
 298 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 299 {
 300         menu_add_symbol(P_DEFAULT, $2, $3);
 301         printd(DEBUG_PARSE, "%s:%d:default\n",
 302                zconf_curname(), zconf_lineno());
 303 };
 304
 305 type:
 306           logic_type
 307         | T_INT                 { $$ = S_INT; }
 308         | T_HEX                 { $$ = S_HEX; }
 309         | T_STRING              { $$ = S_STRING; }
 310
 311 logic_type:
 312           T_BOOL                { $$ = S_BOOLEAN; }
 313         | T_TRISTATE            { $$ = S_TRISTATE; }
 314
 315 default:
 316           T_DEFAULT             { $$ = S_UNKNOWN; }
 317         | T_DEF_BOOL            { $$ = S_BOOLEAN; }
 318         | T_DEF_TRISTATE        { $$ = S_TRISTATE; }
 319
 320 choice_block:
 321           /* empty */
 322         | choice_block common_stmt
 323 ;
 324
 325 /* if entry */
 326
 327 if_entry: T_IF expr T_EOL
 328 {
 329         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 330         menu_add_entry(NULL);
 331         menu_add_dep($2);
 332         $$ = menu_add_menu();
 333 };
 334
 335 if_end: end
 336 {
 337         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 338                 menu_end_menu();
 339                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 340         }
 341 };
 342
 343 if_stmt: if_entry stmt_list if_end
 344 ;
 345
 346 /* menu entry */
 347
 348 menu: T_MENU prompt T_EOL
 349 {
 350         menu_add_entry(NULL);
 351         menu_add_prompt(P_MENU, $2, NULL);
 352         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 353 };
 354
 355 menu_entry: menu menu_option_list
 356 {
 357         $$ = menu_add_menu();
 358 };
 359
 360 menu_end: end
 361 {
 362         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 363                 menu_end_menu();
 364                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 365         }
 366 };
 367
 368 menu_stmt: menu_entry stmt_list menu_end
 369 ;
 370
 371 menu_option_list:
 372           /* empty */
 373         | menu_option_list visible
 374         | menu_option_list depends
 375 ;
 376
 377 source_stmt: T_SOURCE prompt T_EOL
 378 {
 379         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 380         zconf_nextfile($2);
 381         free($2);
 382 };
 383
 384 /* comment entry */
 385
 386 comment: T_COMMENT prompt T_EOL
 387 {
 388         menu_add_entry(NULL);
 389         menu_add_prompt(P_COMMENT, $2, NULL);
 390         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 391 };
 392
 393 comment_stmt: comment comment_option_list
 394 ;
 395
 396 comment_option_list:
 397           /* empty */
 398         | comment_option_list depends
 399 ;
 400
 401 /* help option */
 402
 403 help_start: T_HELP T_EOL
 404 {
 405         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 406         zconf_starthelp();
 407 };
 408
 409 help: help_start T_HELPTEXT
 410 {
 411         if (current_entry->help) {
 412                 free(current_entry->help);
 413                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 414                            current_entry->sym->name ?: "<choice>");
 415         }
 416
 417         /* Is the help text empty or all whitespace? */
 418         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 419                 zconfprint("warning: '%s' defined with blank help text",
 420                            current_entry->sym->name ?: "<choice>");
 421
 422         current_entry->help = $2;
 423 };
 424
 425 /* depends option */
 426
 427 depends: T_DEPENDS T_ON expr T_EOL
 428 {
 429         menu_add_dep($3);
 430         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 431 };
 432
 433 /* visibility option */
 434 visible: T_VISIBLE if_expr T_EOL
 435 {
 436         menu_add_visibility($2);
 437 };
 438
 439 /* prompt statement */
 440
 441 prompt_stmt_opt:
 442           /* empty */
 443         | prompt if_expr
 444 {
 445         menu_add_prompt(P_PROMPT, $1, $2);
 446 };
 447
 448 prompt:   T_WORD
 449         | T_WORD_QUOTE
 450 ;
 451
 452 end:      T_ENDMENU T_EOL       { $$ = $1; }
 453         | T_ENDCHOICE T_EOL     { $$ = $1; }
 454         | T_ENDIF T_EOL         { $$ = $1; }
 455 ;
 456
 457 if_expr:  /* empty */                   { $$ = NULL; }
 458         | T_IF expr                     { $$ = $2; }
 459 ;
 460
 461 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 462         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 463         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 464         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 465         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 466         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 467         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 468         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 469         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 470         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 471         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 472 ;
 473
 474 /* For symbol definitions, selects, etc., where quotes are not accepted */
 475 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 476
 477 symbol:   nonconst_symbol
 478         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 479 ;
 480
 481 word_opt: /* empty */                   { $$ = NULL; }
 482         | T_WORD
 483
 484 /* assignment statement */
 485
 486 assignment_stmt:  T_VARIABLE T_ASSIGN assign_val T_EOL  { variable_add($1, $3, $2); free($1); free($3); }
 487
 488 assign_val:
 489         /* empty */             { $$ = xstrdup(""); };
 490         | T_ASSIGN_VAL
 491 ;
 492
 493 %%
 494
 495 void conf_parse(const char *name)
 496 {
 497         struct symbol *sym;
 498         int i;
 499
 500         zconf_initscan(name);
 501
 502         _menu_init();
 503         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 504
 505         if (getenv("ZCONF_DEBUG"))
 506                 yydebug = 1;
 507         yyparse();
 508
 509         /* Variables are expanded in the parse phase. We can free them here. */
 510         variable_all_del();
 511
 512         if (yynerrs)
 513                 exit(1);
 514         if (!modules_sym)
 515                 modules_sym = sym_find( "n" );
 516
 517         if (!menu_has_prompt(&rootmenu)) {
 518                 current_entry = &rootmenu;
 519                 menu_add_prompt(P_MENU, "Main menu", NULL);
 520         }
 521
 522         menu_finalize(&rootmenu);
 523         for_all_symbols(i, sym) {
 524                 if (sym_check_deps(sym))
 525                         yynerrs++;
 526         }
 527         if (yynerrs)
 528                 exit(1);
 529         sym_set_change_count(1);
 530 }
 531
 532 static const char *zconf_tokenname(int token)
 533 {
 534         switch (token) {
 535         case T_MENU:            return "menu";
 536         case T_ENDMENU:         return "endmenu";
 537         case T_CHOICE:          return "choice";
 538         case T_ENDCHOICE:       return "endchoice";
 539         case T_IF:              return "if";
 540         case T_ENDIF:           return "endif";
 541         case T_DEPENDS:         return "depends";
 542         case T_VISIBLE:         return "visible";
 543         }
 544         return "<token>";
 545 }
 546
 547 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 548 {
 549         if (id->token != endtoken) {
 550                 zconf_error("unexpected '%s' within %s block",
 551                         id->name, zconf_tokenname(starttoken));
 552                 yynerrs++;
 553                 return false;
 554         }
 555         if (current_menu->file != current_file) {
 556                 zconf_error("'%s' in different file than '%s'",
 557                         id->name, zconf_tokenname(starttoken));
 558                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 559                         current_menu->file->name, current_menu->lineno,
 560                         zconf_tokenname(starttoken));
 561                 yynerrs++;
 562                 return false;
 563         }
 564         return true;
 565 }
 566
 567 static void zconfprint(const char *err, ...)
 568 {
 569         va_list ap;
 570
 571         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 572         va_start(ap, err);
 573         vfprintf(stderr, err, ap);
 574         va_end(ap);
 575         fprintf(stderr, "\n");
 576 }
 577
 578 static void zconf_error(const char *err, ...)
 579 {
 580         va_list ap;
 581
 582         yynerrs++;
 583         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 584         va_start(ap, err);
 585         vfprintf(stderr, err, ap);
 586         va_end(ap);
 587         fprintf(stderr, "\n");
 588 }
 589
 590 static void yyerror(const char *err)
 591 {
 592         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 593 }
 594
 595 static void print_quoted_string(FILE *out, const char *str)
 596 {
 597         const char *p;
 598         int len;
 599
 600         putc('"', out);
 601         while ((p = strchr(str, '"'))) {
 602                 len = p - str;
 603                 if (len)
 604                         fprintf(out, "%.*s", len, str);
 605                 fputs("\\\"", out);
 606                 str = p + 1;
 607         }
 608         fputs(str, out);
 609         putc('"', out);
 610 }
 611
 612 static void print_symbol(FILE *out, struct menu *menu)
 613 {
 614         struct symbol *sym = menu->sym;
 615         struct property *prop;
 616
 617         if (sym_is_choice(sym))
 618                 fprintf(out, "\nchoice\n");
 619         else
 620                 fprintf(out, "\nconfig %s\n", sym->name);
 621         switch (sym->type) {
 622         case S_BOOLEAN:
 623                 fputs("  bool\n", out);
 624                 break;
 625         case S_TRISTATE:
 626                 fputs("  tristate\n", out);
 627                 break;
 628         case S_STRING:
 629                 fputs("  string\n", out);
 630                 break;
 631         case S_INT:
 632                 fputs("  integer\n", out);
 633                 break;
 634         case S_HEX:
 635                 fputs("  hex\n", out);
 636                 break;
 637         default:
 638                 fputs("  ???\n", out);
 639                 break;
 640         }
 641         for (prop = sym->prop; prop; prop = prop->next) {
 642                 if (prop->menu != menu)
 643                         continue;
 644                 switch (prop->type) {
 645                 case P_PROMPT:
 646                         fputs("  prompt ", out);
 647                         print_quoted_string(out, prop->text);
 648                         if (!expr_is_yes(prop->visible.expr)) {
 649                                 fputs(" if ", out);
 650                                 expr_fprint(prop->visible.expr, out);
 651                         }
 652                         fputc('\n', out);
 653                         break;
 654                 case P_DEFAULT:
 655                         fputs( "  default ", out);
 656                         expr_fprint(prop->expr, out);
 657                         if (!expr_is_yes(prop->visible.expr)) {
 658                                 fputs(" if ", out);
 659                                 expr_fprint(prop->visible.expr, out);
 660                         }
 661                         fputc('\n', out);
 662                         break;
 663                 case P_CHOICE:
 664                         fputs("  #choice value\n", out);
 665                         break;
 666                 case P_SELECT:
 667                         fputs( "  select ", out);
 668                         expr_fprint(prop->expr, out);
 669                         fputc('\n', out);
 670                         break;
 671                 case P_IMPLY:
 672                         fputs( "  imply ", out);
 673                         expr_fprint(prop->expr, out);
 674                         fputc('\n', out);
 675                         break;
 676                 case P_RANGE:
 677                         fputs( "  range ", out);
 678                         expr_fprint(prop->expr, out);
 679                         fputc('\n', out);
 680                         break;
 681                 case P_MENU:
 682                         fputs( "  menu ", out);
 683                         print_quoted_string(out, prop->text);
 684                         fputc('\n', out);
 685                         break;
 686                 case P_SYMBOL:
 687                         fputs( "  symbol ", out);
 688                         fprintf(out, "%s\n", prop->sym->name);
 689                         break;
 690                 default:
 691                         fprintf(out, "  unknown prop %d!\n", prop->type);
 692                         break;
 693                 }
 694         }
 695         if (menu->help) {
 696                 int len = strlen(menu->help);
 697                 while (menu->help[--len] == '\n')
 698                         menu->help[len] = 0;
 699                 fprintf(out, "  help\n%s\n", menu->help);
 700         }
 701 }
 702
 703 void zconfdump(FILE *out)
 704 {
 705         struct property *prop;
 706         struct symbol *sym;
 707         struct menu *menu;
 708
 709         menu = rootmenu.list;
 710         while (menu) {
 711                 if ((sym = menu->sym))
 712                         print_symbol(out, menu);
 713                 else if ((prop = menu->prompt)) {
 714                         switch (prop->type) {
 715                         case P_COMMENT:
 716                                 fputs("\ncomment ", out);
 717                                 print_quoted_string(out, prop->text);
 718                                 fputs("\n", out);
 719                                 break;
 720                         case P_MENU:
 721                                 fputs("\nmenu ", out);
 722                                 print_quoted_string(out, prop->text);
 723                                 fputs("\n", out);
 724                                 break;
 725                         default:
 726                                 ;
 727                         }
 728                         if (!expr_is_yes(prop->visible.expr)) {
 729                                 fputs("  depends ", out);
 730                                 expr_fprint(prop->visible.expr, out);
 731                                 fputc('\n', out);
 732                         }
 733                 }
 734
 735                 if (menu->list)
 736                         menu = menu->list;
 737                 else if (menu->next)
 738                         menu = menu->next;
 739                 else while ((menu = menu->parent)) {
 740                         if (menu->prompt && menu->prompt->type == P_MENU)
 741                                 fputs("\nendmenu\n", out);
 742                         if (menu->next) {
 743                                 menu = menu->next;
 744                                 break;
 745                         }
 746                 }
 747         }
 748 }
 749
 750 #include "zconf.lex.c"
 751 #include "util.c"
 752 #include "confdata.c"
 753 #include "expr.c"
 754 #include "symbol.c"
 755 #include "menu.c"
 756 #include "preprocess.c"