config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34
  35 %union
  36 {
  37         char *string;
  38         struct file *file;
  39         struct symbol *symbol;
  40         struct expr *expr;
  41         struct menu *menu;
  42         const struct kconf_id *id;
  43         enum symbol_type type;
  44         enum variable_flavor flavor;
  45 }
  46
  47 %token <id>T_MAINMENU
  48 %token <id>T_MENU
  49 %token <id>T_ENDMENU
  50 %token <id>T_SOURCE
  51 %token <id>T_CHOICE
  52 %token <id>T_ENDCHOICE
  53 %token <id>T_COMMENT
  54 %token <id>T_CONFIG
  55 %token <id>T_MENUCONFIG
  56 %token <id>T_HELP
  57 %token <string> T_HELPTEXT
  58 %token <id>T_IF
  59 %token <id>T_ENDIF
  60 %token <id>T_DEPENDS
  61 %token <id>T_OPTIONAL
  62 %token <id>T_PROMPT
  63 %token <id>T_SELECT
  64 %token <id>T_IMPLY
  65 %token <id>T_RANGE
  66 %token <id>T_VISIBLE
  67 %token <id>T_ON
  68 %token <string> T_WORD
  69 %token <string> T_WORD_QUOTE
  70 %token T_ALLNOCONFIG_Y
  71 %token T_BOOL
  72 %token T_CLOSE_PAREN
  73 %token T_DEFAULT
  74 %token T_DEFCONFIG_LIST
  75 %token T_DEF_BOOL
  76 %token T_DEF_TRISTATE
  77 %token T_HEX
  78 %token T_INT
  79 %token T_MODULES
  80 %token T_OPEN_PAREN
  81 %token T_OPTION
  82 %token T_STRING
  83 %token T_TRISTATE
  84 %token T_EOL
  85 %token <string> T_VARIABLE
  86 %token <flavor> T_ASSIGN
  87 %token <string> T_ASSIGN_VAL
  88
  89 %left T_OR
  90 %left T_AND
  91 %left T_EQUAL T_UNEQUAL
  92 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  93 %nonassoc T_NOT
  94
  95 %type <string> prompt
  96 %type <symbol> nonconst_symbol
  97 %type <symbol> symbol
  98 %type <type> type logic_type default
  99 %type <expr> expr
 100 %type <expr> if_expr
 101 %type <id> end
 102 %type <menu> if_entry menu_entry choice_entry
 103 %type <string> word_opt assign_val
 104
 105 %destructor {
 106         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
 107                 $$->file->name, $$->lineno);
 108         if (current_menu == $$)
 109                 menu_end_menu();
 110 } if_entry menu_entry choice_entry
 111
 112 %{
 113 /* Include kconf_id.c here so it can see the token constants. */
 114 #include "kconf_id.c"
 115 %}
 116
 117 %%
 118 input: mainmenu_stmt stmt_list | stmt_list;
 119
 120 /* mainmenu entry */
 121
 122 mainmenu_stmt: T_MAINMENU prompt T_EOL
 123 {
 124         menu_add_prompt(P_MENU, $2, NULL);
 125 };
 126
 127 stmt_list:
 128           /* empty */
 129         | stmt_list common_stmt
 130         | stmt_list choice_stmt
 131         | stmt_list menu_stmt
 132         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 133         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 134 ;
 135
 136 common_stmt:
 137           if_stmt
 138         | comment_stmt
 139         | config_stmt
 140         | menuconfig_stmt
 141         | source_stmt
 142         | assignment_stmt
 143 ;
 144
 145 /* config/menuconfig entry */
 146
 147 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 148 {
 149         $2->flags |= SYMBOL_OPTIONAL;
 150         menu_add_entry($2);
 151         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 152 };
 153
 154 config_stmt: config_entry_start config_option_list
 155 {
 156         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 157 };
 158
 159 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 160 {
 161         $2->flags |= SYMBOL_OPTIONAL;
 162         menu_add_entry($2);
 163         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 164 };
 165
 166 menuconfig_stmt: menuconfig_entry_start config_option_list
 167 {
 168         if (current_entry->prompt)
 169                 current_entry->prompt->type = P_MENU;
 170         else
 171                 zconfprint("warning: menuconfig statement without prompt");
 172         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 173 };
 174
 175 config_option_list:
 176           /* empty */
 177         | config_option_list config_option
 178         | config_option_list depends
 179         | config_option_list help
 180 ;
 181
 182 config_option: type prompt_stmt_opt T_EOL
 183 {
 184         menu_set_type($1);
 185         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 186                 zconf_curname(), zconf_lineno(),
 187                 $1);
 188 };
 189
 190 config_option: T_PROMPT prompt if_expr T_EOL
 191 {
 192         menu_add_prompt(P_PROMPT, $2, $3);
 193         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 194 };
 195
 196 config_option: default expr if_expr T_EOL
 197 {
 198         menu_add_expr(P_DEFAULT, $2, $3);
 199         if ($1 != S_UNKNOWN)
 200                 menu_set_type($1);
 201         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 202                 zconf_curname(), zconf_lineno(),
 203                 $1);
 204 };
 205
 206 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 207 {
 208         menu_add_symbol(P_SELECT, $2, $3);
 209         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 210 };
 211
 212 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 213 {
 214         menu_add_symbol(P_IMPLY, $2, $3);
 215         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 216 };
 217
 218 config_option: T_RANGE symbol symbol if_expr T_EOL
 219 {
 220         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 221         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 222 };
 223
 224 config_option: T_OPTION T_MODULES T_EOL
 225 {
 226         menu_add_option_modules();
 227 };
 228
 229 config_option: T_OPTION T_DEFCONFIG_LIST T_EOL
 230 {
 231         menu_add_option_defconfig_list();
 232 };
 233
 234 config_option: T_OPTION T_ALLNOCONFIG_Y T_EOL
 235 {
 236         menu_add_option_allnoconfig_y();
 237 };
 238
 239 /* choice entry */
 240
 241 choice: T_CHOICE word_opt T_EOL
 242 {
 243         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 244         sym->flags |= SYMBOL_NO_WRITE;
 245         menu_add_entry(sym);
 246         menu_add_expr(P_CHOICE, NULL, NULL);
 247         free($2);
 248         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 249 };
 250
 251 choice_entry: choice choice_option_list
 252 {
 253         $$ = menu_add_menu();
 254 };
 255
 256 choice_end: end
 257 {
 258         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 259                 menu_end_menu();
 260                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 261         }
 262 };
 263
 264 choice_stmt: choice_entry choice_block choice_end
 265 ;
 266
 267 choice_option_list:
 268           /* empty */
 269         | choice_option_list choice_option
 270         | choice_option_list depends
 271         | choice_option_list help
 272 ;
 273
 274 choice_option: T_PROMPT prompt if_expr T_EOL
 275 {
 276         menu_add_prompt(P_PROMPT, $2, $3);
 277         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 278 };
 279
 280 choice_option: logic_type prompt_stmt_opt T_EOL
 281 {
 282         menu_set_type($1);
 283         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 284                zconf_curname(), zconf_lineno(), $1);
 285 };
 286
 287 choice_option: T_OPTIONAL T_EOL
 288 {
 289         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 290         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 291 };
 292
 293 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 294 {
 295         menu_add_symbol(P_DEFAULT, $2, $3);
 296         printd(DEBUG_PARSE, "%s:%d:default\n",
 297                zconf_curname(), zconf_lineno());
 298 };
 299
 300 type:
 301           logic_type
 302         | T_INT                 { $$ = S_INT; }
 303         | T_HEX                 { $$ = S_HEX; }
 304         | T_STRING              { $$ = S_STRING; }
 305
 306 logic_type:
 307           T_BOOL                { $$ = S_BOOLEAN; }
 308         | T_TRISTATE            { $$ = S_TRISTATE; }
 309
 310 default:
 311           T_DEFAULT             { $$ = S_UNKNOWN; }
 312         | T_DEF_BOOL            { $$ = S_BOOLEAN; }
 313         | T_DEF_TRISTATE        { $$ = S_TRISTATE; }
 314
 315 choice_block:
 316           /* empty */
 317         | choice_block common_stmt
 318 ;
 319
 320 /* if entry */
 321
 322 if_entry: T_IF expr T_EOL
 323 {
 324         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 325         menu_add_entry(NULL);
 326         menu_add_dep($2);
 327         $$ = menu_add_menu();
 328 };
 329
 330 if_end: end
 331 {
 332         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 333                 menu_end_menu();
 334                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 335         }
 336 };
 337
 338 if_stmt: if_entry stmt_list if_end
 339 ;
 340
 341 /* menu entry */
 342
 343 menu: T_MENU prompt T_EOL
 344 {
 345         menu_add_entry(NULL);
 346         menu_add_prompt(P_MENU, $2, NULL);
 347         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 348 };
 349
 350 menu_entry: menu menu_option_list
 351 {
 352         $$ = menu_add_menu();
 353 };
 354
 355 menu_end: end
 356 {
 357         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 358                 menu_end_menu();
 359                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 360         }
 361 };
 362
 363 menu_stmt: menu_entry stmt_list menu_end
 364 ;
 365
 366 menu_option_list:
 367           /* empty */
 368         | menu_option_list visible
 369         | menu_option_list depends
 370 ;
 371
 372 source_stmt: T_SOURCE prompt T_EOL
 373 {
 374         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 375         zconf_nextfile($2);
 376         free($2);
 377 };
 378
 379 /* comment entry */
 380
 381 comment: T_COMMENT prompt T_EOL
 382 {
 383         menu_add_entry(NULL);
 384         menu_add_prompt(P_COMMENT, $2, NULL);
 385         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 386 };
 387
 388 comment_stmt: comment comment_option_list
 389 ;
 390
 391 comment_option_list:
 392           /* empty */
 393         | comment_option_list depends
 394 ;
 395
 396 /* help option */
 397
 398 help_start: T_HELP T_EOL
 399 {
 400         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 401         zconf_starthelp();
 402 };
 403
 404 help: help_start T_HELPTEXT
 405 {
 406         if (current_entry->help) {
 407                 free(current_entry->help);
 408                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 409                            current_entry->sym->name ?: "<choice>");
 410         }
 411
 412         /* Is the help text empty or all whitespace? */
 413         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 414                 zconfprint("warning: '%s' defined with blank help text",
 415                            current_entry->sym->name ?: "<choice>");
 416
 417         current_entry->help = $2;
 418 };
 419
 420 /* depends option */
 421
 422 depends: T_DEPENDS T_ON expr T_EOL
 423 {
 424         menu_add_dep($3);
 425         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 426 };
 427
 428 /* visibility option */
 429 visible: T_VISIBLE if_expr T_EOL
 430 {
 431         menu_add_visibility($2);
 432 };
 433
 434 /* prompt statement */
 435
 436 prompt_stmt_opt:
 437           /* empty */
 438         | prompt if_expr
 439 {
 440         menu_add_prompt(P_PROMPT, $1, $2);
 441 };
 442
 443 prompt:   T_WORD
 444         | T_WORD_QUOTE
 445 ;
 446
 447 end:      T_ENDMENU T_EOL       { $$ = $1; }
 448         | T_ENDCHOICE T_EOL     { $$ = $1; }
 449         | T_ENDIF T_EOL         { $$ = $1; }
 450 ;
 451
 452 if_expr:  /* empty */                   { $$ = NULL; }
 453         | T_IF expr                     { $$ = $2; }
 454 ;
 455
 456 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 457         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 458         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 459         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 460         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 461         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 462         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 463         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 464         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 465         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 466         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 467 ;
 468
 469 /* For symbol definitions, selects, etc., where quotes are not accepted */
 470 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 471
 472 symbol:   nonconst_symbol
 473         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 474 ;
 475
 476 word_opt: /* empty */                   { $$ = NULL; }
 477         | T_WORD
 478
 479 /* assignment statement */
 480
 481 assignment_stmt:  T_VARIABLE T_ASSIGN assign_val T_EOL  { variable_add($1, $3, $2); free($1); free($3); }
 482
 483 assign_val:
 484         /* empty */             { $$ = xstrdup(""); };
 485         | T_ASSIGN_VAL
 486 ;
 487
 488 %%
 489
 490 void conf_parse(const char *name)
 491 {
 492         struct symbol *sym;
 493         int i;
 494
 495         zconf_initscan(name);
 496
 497         _menu_init();
 498         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 499
 500         if (getenv("ZCONF_DEBUG"))
 501                 yydebug = 1;
 502         yyparse();
 503
 504         /* Variables are expanded in the parse phase. We can free them here. */
 505         variable_all_del();
 506
 507         if (yynerrs)
 508                 exit(1);
 509         if (!modules_sym)
 510                 modules_sym = sym_find( "n" );
 511
 512         if (!menu_has_prompt(&rootmenu)) {
 513                 current_entry = &rootmenu;
 514                 menu_add_prompt(P_MENU, "Main menu", NULL);
 515         }
 516
 517         menu_finalize(&rootmenu);
 518         for_all_symbols(i, sym) {
 519                 if (sym_check_deps(sym))
 520                         yynerrs++;
 521         }
 522         if (yynerrs)
 523                 exit(1);
 524         sym_set_change_count(1);
 525 }
 526
 527 static const char *zconf_tokenname(int token)
 528 {
 529         switch (token) {
 530         case T_MENU:            return "menu";
 531         case T_ENDMENU:         return "endmenu";
 532         case T_CHOICE:          return "choice";
 533         case T_ENDCHOICE:       return "endchoice";
 534         case T_IF:              return "if";
 535         case T_ENDIF:           return "endif";
 536         case T_DEPENDS:         return "depends";
 537         case T_VISIBLE:         return "visible";
 538         }
 539         return "<token>";
 540 }
 541
 542 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 543 {
 544         if (id->token != endtoken) {
 545                 zconf_error("unexpected '%s' within %s block",
 546                         id->name, zconf_tokenname(starttoken));
 547                 yynerrs++;
 548                 return false;
 549         }
 550         if (current_menu->file != current_file) {
 551                 zconf_error("'%s' in different file than '%s'",
 552                         id->name, zconf_tokenname(starttoken));
 553                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 554                         current_menu->file->name, current_menu->lineno,
 555                         zconf_tokenname(starttoken));
 556                 yynerrs++;
 557                 return false;
 558         }
 559         return true;
 560 }
 561
 562 static void zconfprint(const char *err, ...)
 563 {
 564         va_list ap;
 565
 566         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 567         va_start(ap, err);
 568         vfprintf(stderr, err, ap);
 569         va_end(ap);
 570         fprintf(stderr, "\n");
 571 }
 572
 573 static void zconf_error(const char *err, ...)
 574 {
 575         va_list ap;
 576
 577         yynerrs++;
 578         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 579         va_start(ap, err);
 580         vfprintf(stderr, err, ap);
 581         va_end(ap);
 582         fprintf(stderr, "\n");
 583 }
 584
 585 static void yyerror(const char *err)
 586 {
 587         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 588 }
 589
 590 static void print_quoted_string(FILE *out, const char *str)
 591 {
 592         const char *p;
 593         int len;
 594
 595         putc('"', out);
 596         while ((p = strchr(str, '"'))) {
 597                 len = p - str;
 598                 if (len)
 599                         fprintf(out, "%.*s", len, str);
 600                 fputs("\\\"", out);
 601                 str = p + 1;
 602         }
 603         fputs(str, out);
 604         putc('"', out);
 605 }
 606
 607 static void print_symbol(FILE *out, struct menu *menu)
 608 {
 609         struct symbol *sym = menu->sym;
 610         struct property *prop;
 611
 612         if (sym_is_choice(sym))
 613                 fprintf(out, "\nchoice\n");
 614         else
 615                 fprintf(out, "\nconfig %s\n", sym->name);
 616         switch (sym->type) {
 617         case S_BOOLEAN:
 618                 fputs("  bool\n", out);
 619                 break;
 620         case S_TRISTATE:
 621                 fputs("  tristate\n", out);
 622                 break;
 623         case S_STRING:
 624                 fputs("  string\n", out);
 625                 break;
 626         case S_INT:
 627                 fputs("  integer\n", out);
 628                 break;
 629         case S_HEX:
 630                 fputs("  hex\n", out);
 631                 break;
 632         default:
 633                 fputs("  ???\n", out);
 634                 break;
 635         }
 636         for (prop = sym->prop; prop; prop = prop->next) {
 637                 if (prop->menu != menu)
 638                         continue;
 639                 switch (prop->type) {
 640                 case P_PROMPT:
 641                         fputs("  prompt ", out);
 642                         print_quoted_string(out, prop->text);
 643                         if (!expr_is_yes(prop->visible.expr)) {
 644                                 fputs(" if ", out);
 645                                 expr_fprint(prop->visible.expr, out);
 646                         }
 647                         fputc('\n', out);
 648                         break;
 649                 case P_DEFAULT:
 650                         fputs( "  default ", out);
 651                         expr_fprint(prop->expr, out);
 652                         if (!expr_is_yes(prop->visible.expr)) {
 653                                 fputs(" if ", out);
 654                                 expr_fprint(prop->visible.expr, out);
 655                         }
 656                         fputc('\n', out);
 657                         break;
 658                 case P_CHOICE:
 659                         fputs("  #choice value\n", out);
 660                         break;
 661                 case P_SELECT:
 662                         fputs( "  select ", out);
 663                         expr_fprint(prop->expr, out);
 664                         fputc('\n', out);
 665                         break;
 666                 case P_IMPLY:
 667                         fputs( "  imply ", out);
 668                         expr_fprint(prop->expr, out);
 669                         fputc('\n', out);
 670                         break;
 671                 case P_RANGE:
 672                         fputs( "  range ", out);
 673                         expr_fprint(prop->expr, out);
 674                         fputc('\n', out);
 675                         break;
 676                 case P_MENU:
 677                         fputs( "  menu ", out);
 678                         print_quoted_string(out, prop->text);
 679                         fputc('\n', out);
 680                         break;
 681                 case P_SYMBOL:
 682                         fputs( "  symbol ", out);
 683                         fprintf(out, "%s\n", prop->sym->name);
 684                         break;
 685                 default:
 686                         fprintf(out, "  unknown prop %d!\n", prop->type);
 687                         break;
 688                 }
 689         }
 690         if (menu->help) {
 691                 int len = strlen(menu->help);
 692                 while (menu->help[--len] == '\n')
 693                         menu->help[len] = 0;
 694                 fprintf(out, "  help\n%s\n", menu->help);
 695         }
 696 }
 697
 698 void zconfdump(FILE *out)
 699 {
 700         struct property *prop;
 701         struct symbol *sym;
 702         struct menu *menu;
 703
 704         menu = rootmenu.list;
 705         while (menu) {
 706                 if ((sym = menu->sym))
 707                         print_symbol(out, menu);
 708                 else if ((prop = menu->prompt)) {
 709                         switch (prop->type) {
 710                         case P_COMMENT:
 711                                 fputs("\ncomment ", out);
 712                                 print_quoted_string(out, prop->text);
 713                                 fputs("\n", out);
 714                                 break;
 715                         case P_MENU:
 716                                 fputs("\nmenu ", out);
 717                                 print_quoted_string(out, prop->text);
 718                                 fputs("\n", out);
 719                                 break;
 720                         default:
 721                                 ;
 722                         }
 723                         if (!expr_is_yes(prop->visible.expr)) {
 724                                 fputs("  depends ", out);
 725                                 expr_fprint(prop->visible.expr, out);
 726                                 fputc('\n', out);
 727                         }
 728                 }
 729
 730                 if (menu->list)
 731                         menu = menu->list;
 732                 else if (menu->next)
 733                         menu = menu->next;
 734                 else while ((menu = menu->parent)) {
 735                         if (menu->prompt && menu->prompt->type == P_MENU)
 736                                 fputs("\nendmenu\n", out);
 737                         if (menu->next) {
 738                                 menu = menu->next;
 739                                 break;
 740                         }
 741                 }
 742         }
 743 }
 744
 745 #include "zconf.lex.c"
 746 #include "util.c"
 747 #include "confdata.c"
 748 #include "expr.c"
 749 #include "symbol.c"
 750 #include "menu.c"
 751 #include "preprocess.c"