8sync/systems/websocket/client.scm

   1 ;;; guile-websocket --- WebSocket client/server
   2 ;;; Copyright © 2016 David Thompson <davet@gnu.org>
   3 ;;; Copyright © 2017 Christopher Allan Webber <cwebber@dustycloud.org>
   4 ;;; Copyright © 2019, 2020 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
   5 ;;;
   6 ;;; This file is part of guile-websocket.
   7 ;;;
   8 ;;; Guile-websocket is free software; you can redistribute it and/or modify
   9 ;;; it under the terms of the GNU Lesser General Public License as
  10 ;;; published by the Free Software Foundation; either version 3 of the
  11 ;;; License, or (at your option) any later version.
  12 ;;;
  13 ;;; Guile-websocket is distributed in the hope that it will be useful,
  14 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;;; Lesser General Public License for more details.
  17 ;;;
  18 ;;; You should have received a copy of the GNU Lesser General Public
  19 ;;; License along with guile-websocket.  If not, see
  20 ;;; <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23 ;;
  24 ;; WebSocket client.
  25 ;;
  26 ;;; Code:
  27
  28 (define-module (8sync systems websocket client)
  29   #:use-module (ice-9 match)
  30   #:use-module (srfi srfi-26)
  31   #:use-module (rnrs bytevectors)
  32   #:use-module (rnrs io ports)
  33   #:use-module (web request)
  34   #:use-module (web response)
  35   #:use-module (web uri)
  36   #:use-module (oop goops)
  37   #:use-module (8sync)
  38   #:use-module (8sync ports)
  39   #:use-module (8sync contrib base64)
  40   #:use-module (8sync systems websocket frame)
  41   #:use-module (8sync systems websocket utils)
  42   #:export (<websocket>
  43             .on-close
  44             .on-error
  45             .on-message
  46             .on-open
  47             .socket
  48             .state
  49             .url
  50
  51             websocket-closed?
  52             websocket-closing?
  53             websocket-connect
  54             websocket-connecting?
  55             websocket-open?
  56
  57             websocket-close
  58             websocket-loop
  59             websocket-send))
  60
  61 (define no-op (const #f))
  62
  63 (define-actor <websocket> (<actor>)
  64   ((*init* websocket-init)
  65    (close websocket-close)
  66    (open websocket-open)
  67    (send websocket-send))
  68
  69   (state #:accessor .state #:init-value 'closed #:init-keyword #:state)
  70   (socket #:accessor .socket #:init-value #f #:init-keyword #:socket)
  71   (url #:getter .url #:init-value #f #:init-keyword #:url)
  72   (uri #:accessor .uri #:init-value #f #:init-keyword #:uri)
  73   (entropy-port #:accessor .entropy-port #:init-form (open-entropy-port))
  74
  75   (on-close #:init-keyword #:on-close
  76                  #:init-value no-op
  77                  #:accessor .on-close)
  78   (on-error #:init-keyword #:on-error
  79             #:init-value no-op
  80             #:accessor .on-error)
  81   (on-message #:init-keyword #:on-message
  82               #:accessor .on-message)
  83   (on-open #:init-keyword #:on-open
  84                 #:init-value no-op
  85                 #:accessor .on-open))
  86
  87 (define-method (websocket-close (websocket <websocket>) message)
  88   (when (websocket-open? websocket)
  89     (false-if-exception (close-port (.socket websocket)))
  90     (set! (.state websocket) 'closed)
  91     (false-if-exception ((.on-close websocket) websocket))
  92     (set! (.socket websocket) #f)))
  93
  94 (define-method (websocket-open (websocket <websocket>) message uri-or-string)
  95   (if (websocket-closed? websocket)
  96       (let ((uri (match uri-or-string
  97                    ((? uri? uri) uri)
  98                    ((? string? str) (string->uri str)))))
  99         (if (websocket-uri? uri)
 100             (catch 'system-error
 101               (lambda _
 102                 (set! (.uri websocket) uri)
 103                 (let ((sock (make-client-socket uri)))
 104                   (set! (.socket websocket) sock)
 105                   (handshake websocket)
 106                   (websocket-loop websocket message)))
 107               (lambda (key . args)
 108                 ((.on-error websocket) websocket (format #f "open failed: ~s: ~s" uri-or-string args))))
 109             ((.on-error websocket) websocket (format #f "not a websocket uri: ~s" uri-or-string))))
 110       ((.on-error websocket) websocket (format #f "cannot open websocket in state: ~s" (.state websocket)))))
 111
 112 (define-method (websocket-send (websocket <websocket>) message data)
 113   (catch #t           ; expect: wrong-type-arg (open port), system-error
 114     (lambda _
 115       (write-frame
 116        (cond ((string? data)
 117               (make-text-frame data))
 118              ((bytevector? data)
 119               (make-binary-frame data)))
 120        (.socket websocket)))
 121     (lambda (key . args)
 122       (let ((message (format #f "~a: ~s" key args)))
 123         ((.on-error websocket) websocket (format #f "send failed: ~s ~a\n" websocket message))
 124         (websocket-close websocket message)))))
 125
 126 (define-method (websocket-init (websocket <websocket>) message)
 127   (and=> (.url websocket) (cut websocket-open websocket message <>)))
 128
 129 (define-method (websocket-loop (websocket <websocket>) message)
 130
 131   (define (handle-data-frame type data)
 132     ((.on-message websocket)
 133      websocket
 134      (match type
 135        ('text   (utf8->string data))
 136        ('binary data))))
 137
 138   (define (read-frame-maybe)
 139     (and (not (eof-object? (lookahead-u8 (.socket websocket))))
 140          (read-frame (.socket websocket))))
 141
 142   (define (close-down)
 143     (websocket-close websocket message))
 144
 145   ((.on-open websocket) websocket)
 146
 147   (let loop ((fragments '())
 148              (type #f))
 149     (let* ((socket (.socket websocket))
 150            (frame (and (websocket-open? websocket)
 151                        (read-frame-maybe))))
 152       (cond
 153        ;; EOF - port is closed.
 154        ;; @@: Sometimes the eof object appears here as opposed to
 155        ;;   at lookahead, but I'm not sure why
 156        ((or (not frame) (eof-object? frame))
 157         (close-down))
 158        ;; Per section 5.4, control frames may appear interspersed
 159        ;; along with a fragmented message.
 160        ((close-frame? frame)
 161         ;; Per section 5.5.1, echo the close frame back to the
 162         ;; socket before closing the socket.  The socket may no
 163         ;; longer be listening.
 164         (false-if-exception
 165          (write-frame (make-close-frame (frame-data frame)) socket))
 166         (close-down))
 167        ((ping-frame? frame)
 168         ;; Per section 5.5.3, a pong frame must include the exact
 169         ;; same data as the ping frame.
 170         (write-frame (make-pong-frame (frame-data frame)) socket)
 171         (loop fragments type))
 172        ((pong-frame? frame)           ; silently ignore pongs
 173         (loop fragments type))
 174        ((first-fragment-frame? frame) ; begin accumulating fragments
 175         (loop (list frame) (frame-type frame)))
 176        ((final-fragment-frame? frame) ; concatenate all fragments
 177         (handle-data-frame type (frame-concatenate
 178                                  (reverse (cons frame fragments))))
 179         (loop '() #f))
 180        ((fragment-frame? frame)       ; add a fragment
 181         (loop (cons frame fragments) type))
 182        ((data-frame? frame)           ; unfragmented data frame
 183         (handle-data-frame (frame-type frame) (frame-data frame))
 184         (loop '() #f))))))
 185
 186 ;; See Section 3 - WebSocket URIs
 187 (define (encrypted-websocket-scheme? uri)
 188   "Return #t if the scheme for URI is 'wss', the secure WebSocket
 189 scheme."
 190   (eq? (uri-scheme uri) 'wss))
 191
 192 (define (unencrypted-websocket-scheme? uri)
 193   "Return #t if the scheme for URI is 'ws', the insecure WebSocket
 194 scheme."
 195   (eq? (uri-scheme uri) 'ws))
 196
 197 (define (websocket-uri? uri)
 198   "Return #t if URI is a valid WebSocket URI."
 199   (and (or (encrypted-websocket-scheme? uri)
 200            (unencrypted-websocket-scheme? uri))
 201        (not (uri-fragment uri))))
 202
 203 (define (set-nonblocking! port)
 204   (fcntl port F_SETFL (logior O_NONBLOCK (fcntl port F_GETFL)))
 205   (setvbuf port 'block 1024))
 206
 207 (define (make-client-socket uri)
 208   "Connect a socket to the remote resource described by URI."
 209   (let* ((port (uri-port uri))
 210          (info (car (getaddrinfo (uri-host uri)
 211                                  (if port
 212                                      (number->string port)
 213                                      (symbol->string (uri-scheme uri)))
 214                                  (if port
 215                                      AI_NUMERICSERV
 216                                      0))))
 217          (sock (with-fluids ((%default-port-encoding #f))
 218                  (socket (addrinfo:fam info) SOCK_STREAM IPPROTO_IP))))
 219
 220     (set-nonblocking! sock)
 221     ;; Disable buffering for websockets
 222     (setvbuf sock 'none)
 223
 224     ;; TODO: Configure I/O buffering?
 225     (connect sock (addrinfo:addr info))
 226     sock))
 227
 228 (define-method (write (o <websocket>) port)
 229    (format port "#<websocket ~a ~a>"
 230            (.url o)
 231            (.state o)))
 232
 233 (define-method (websocket-connecting? (websocket <websocket>))
 234   "Return #t if WEBSOCKET is in the connecting state."
 235   (eq? (.state websocket) 'connecting))
 236
 237 (define-method (websocket-open? (websocket <websocket>))
 238   "Return #t if WEBSOCKET is in the open state."
 239   (eq? (.state websocket) 'open))
 240
 241 (define-method (websocket-closing? (websocket <websocket>))
 242   "Return #t if WEBSOCKET is in the closing state."
 243   (eq? (.state websocket) 'closing))
 244
 245 (define-method (websocket-closed? (websocket <websocket>))
 246   "Return #t if WEBSOCKET is in the closed state."
 247   (eq? (.state websocket) 'closed))
 248
 249 (define-method (generate-client-key (websocket <websocket>))
 250   "Return a random, base64 encoded nonce using the entropy source of
 251 WEBSOCKET."
 252   (base64-encode
 253    (get-bytevector-n (.entropy-port websocket) 16)))
 254
 255 ;; See Section 4.1 - Client Requirements
 256 (define (make-handshake-request uri key)
 257   "Create an HTTP request for initiating a WebSocket connection with
 258 the remote resource described by URI, using a randomly generated nonce
 259 KEY."
 260   (let ((headers `((host . (,(uri-host uri) . #f))
 261                    (upgrade . ("WebSocket"))
 262                    (connection . (upgrade))
 263                    (sec-websocket-key . ,key)
 264                    (sec-websocket-version . "13"))))
 265     (build-request uri #:method 'GET #:headers headers)))
 266
 267 (define-method (handshake (websocket <websocket>))
 268   "Perform the WebSocket handshake for the client WEBSOCKET."
 269   (let ((key (generate-client-key websocket)))
 270     (write-request (make-handshake-request (.uri websocket) key)
 271                    (.socket websocket))
 272     (let* ((response (read-response (.socket websocket)))
 273            (headers (response-headers response))
 274            (upgrade (assoc-ref headers 'upgrade))
 275            (connection (assoc-ref headers 'connection))
 276            (accept (assoc-ref headers 'sec-websocket-accept)))
 277       ;; Validate the handshake.
 278       (if (and (= (response-code response) 101)
 279                (string-ci=? (car upgrade) "websocket")
 280                (equal? connection '(upgrade))
 281                (string=? (string-trim-both accept) (make-accept-key key)))
 282           (set! (.state websocket) 'open)
 283           (begin
 284             (websocket-close websocket)
 285             ((.on-error websocket) websocket
 286              (format #f "websocket handshake failed: ~s"
 287                      (uri->string (.uri websocket)))))))))
 288
 289 (define (open-entropy-port)
 290   "Return an open input port to a reliable source of entropy for the
 291 current system."
 292   ;; XXX: This works on GNU/Linux and OS X systems, but this isn't
 293   ;; exactly portable.
 294   (open-input-file "/dev/urandom"))
 295
 296 (define-method (websocket-close (websocket <websocket>))
 297   "Close the WebSocket connection for the client WEBSOCKET."
 298   (let ((socket (.socket websocket)))
 299     (set! (.state websocket) 'closing)
 300     (write-frame (make-close-frame (make-bytevector 0)) socket)
 301     ;; Per section 5.5.1 , wait for the server to close the connection
 302     ;; for a reasonable amount of time.
 303     (let loop ()
 304       (match (select #() (vector socket) #() 1) ; 1 second timeout
 305         ((#() #(socket) #()) ; there is output to read
 306          (unless (port-eof? socket)
 307            (read-frame socket) ; throw it away
 308            (loop)))))
 309     (close-port socket)
 310     (close-port (.entropy-port websocket))
 311     (set! (.state websocket) 'closed)))