8sync/actors.scm

   1 ;;; 8sync --- Asynchronous programming for Guile
   2 ;;; Copyright © 2016, 2017 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of 8sync.
   5 ;;;
   6 ;;; 8sync is free software: you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU Lesser General Public License as
   8 ;;; published by the Free Software Foundation, either version 3 of the
   9 ;;; License, or (at your option) any later version.
  10 ;;;
  11 ;;; 8sync is distributed in the hope that it will be useful,
  12 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU Lesser General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU Lesser General Public
  17 ;;; License along with 8sync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (8sync actors)
  20   #:use-module (oop goops)
  21   #:use-module (srfi srfi-9)
  22   #:use-module (ice-9 control)
  23   #:use-module (ice-9 format)
  24   #:use-module (ice-9 match)
  25   #:use-module (ice-9 atomic)
  26   #:use-module ((ice-9 ports internal)
  27                 #:select (port-read-wait-fd port-write-wait-fd))
  28   #:use-module (ice-9 pretty-print)
  29   #:use-module (ice-9 receive)
  30   #:use-module (ice-9 suspendable-ports)
  31   #:use-module (fibers)
  32   #:use-module (fibers channels)
  33   #:use-module (fibers conditions)
  34   #:use-module (fibers operations)
  35   #:use-module (8sync inbox)
  36   #:use-module (8sync rmeta-slot)
  37
  38   #:export (;; utilities... ought to go in their own module
  39             big-random-number
  40             big-random-number-string
  41
  42             <actor>
  43             actor-id
  44             actor-message-handler
  45
  46             *current-actor*
  47
  48             ;;; Commenting out the <address> type for now;
  49             ;;; it may be back when we have better serializers
  50             ;; <address>
  51             make-address
  52             address-actor-id address-hive-id
  53
  54             address->string
  55             actor-id-actor
  56             actor-id-hive
  57             actor-id-string
  58
  59             actor-init! actor-cleanup!
  60
  61             build-actions
  62
  63             define-actor
  64
  65             actor-spawn-fiber
  66             with-actor-nonblocking-ports
  67
  68             ;; <hive>
  69             ;; make-hive
  70             ;; ;; There are more methods for the hive, but there's
  71             ;; ;; no reason for the outside world to look at them maybe?
  72             ;; hive-id
  73             create-actor create-actor*
  74             self-destruct
  75
  76             <message>
  77             make-message message?
  78             message-to message-action message-from
  79             message-id message-body message-in-reply-to
  80             message-wants-reply
  81
  82             <- <-wait
  83
  84             spawn-hive run-hive
  85
  86             ;; Maybe the wrong place for this, or for it to be exported.
  87             ;; But it's used in websockets' server implementation at least...
  88             live-wrap))
  89
  90 ;; For ids
  91 (set! *random-state* (random-state-from-platform))
  92
  93 ;; Same size as a uuid4 I think...
  94 (define random-number-size (expt 2 128))
  95
  96 (define (big-random-number)
  97   (random random-number-size))
  98
  99 ;; Would be great to get this base64 encoded instead.
 100 (define (big-random-number-string)
 101   ;; @@: This is slow.  Using format here is wasteful.
 102   (format #f "~x" (big-random-number)))
 103
 104 ;; @@: This is slow-ish.  A mere ~275k / second on my (old) machine.
 105 ;;   The main cost seems to be in number->string.
 106 (define (simple-message-id-generator)
 107   ;; Prepending this cookie makes message ids unique per hive
 108   (let ((prefix (format #f "~x:" (big-random-number)))
 109         (counter 0))
 110     (lambda ()
 111       (set! counter (1+ counter))
 112       (string-append prefix (number->string counter)))))
 113
 114
 115 \f
 116 ;;; Messages
 117 ;;; ========
 118
 119 (define-record-type <message>
 120   (make-message-intern id to from action
 121                        body in-reply-to wants-reply)
 122   message?
 123   ;; @@: message-ids are removed.  They could be re-enabled
 124   ;;   if we had thread-safe promises...
 125   (id message-id)                    ; id of this message
 126   (to message-to)                    ; actor id this is going to
 127   (from message-from)                ; actor id of sender
 128   (action message-action)            ; action (a symbol) to be handled
 129   (body message-body)                ; argument list "body" of message
 130   (in-reply-to message-in-reply-to)  ; message id this is in reply to, if any
 131   (wants-reply message-wants-reply)) ; whether caller is waiting for reply
 132
 133
 134 (define* (make-message id to from action body
 135                        #:key in-reply-to wants-reply)
 136   (make-message-intern id to from action body
 137                        in-reply-to wants-reply))
 138
 139 (define (kwarg-list-to-alist args)
 140   (let loop ((remaining args)
 141              (result '()))
 142     (match remaining
 143       (((? keyword? key) val rest ...)
 144        (loop rest
 145              (cons (cons (keyword->symbol key) val)
 146                    result)))
 147       (() result)
 148       (_ (throw 'invalid-kwarg-list
 149                 "Invalid keyword argument list"
 150                 args)))))
 151
 152
 153 ;;; See: https://web.archive.org/web/20081223021934/http://mumble.net/~jar/articles/oo-moon-weinreb.html
 154 ;;;   (also worth seeing: http://mumble.net/~jar/articles/oo.html )
 155
 156 ;; This is the internal, generalized message sending method.
 157 ;; Users shouldn't use it!  Use the <-foo forms instead.
 158
 159 (define (%<- wants-reply from-actor to action args message-id in-reply-to)
 160   ;; Okay, we need to deal with message ids.
 161   ;; Could we get rid of them? :\
 162   ;; It seems if we can use eq? and have messages be immutable then
 163   ;; it should be possible to identify follow-up replies.
 164   ;; If we need to track replies across hive boundaries we could
 165   ;; register unique ids across the ambassador barrier.
 166   (match to
 167     (#(_ _ (? channel? channel) dead?)
 168      (let ((message (make-message message-id to
 169                                   (and from-actor (actor-id from-actor))
 170                                   action args
 171                                   #:wants-reply wants-reply
 172                                   #:in-reply-to in-reply-to)))
 173        (perform-operation
 174         (choice-operation
 175          (put-operation channel message)
 176          (wait-operation dead?)))))
 177     ;; TODO: put remote addresses here.
 178     (#(actor-id hive-id #f #f)
 179      ;; Here we'd make a call to our hive...
 180      'TODO)
 181     ;; A message sent to nobody goes nowhere.
 182     ;; TODO: Should we display a warning here, probably?
 183     (#f #f)
 184     ;; We shouldn't technically be passing in actors but rather their
 185     ;; addresses, but often actors want to message themselves and
 186     ;; this makes that slightly easier.
 187     ((? (lambda (x) (is-a? x <actor>)) actor)
 188      (%<- wants-reply from-actor (actor-id actor) action
 189           args message-id in-reply-to))))
 190
 191 (define (<- to action . args)
 192   (define from-actor (*current-actor*))
 193   (%<- #f from-actor to action args
 194        (or (and from-actor
 195                 ((actor-msg-id-generator from-actor)))
 196            (big-random-number-string))
 197        #f))
 198
 199 (define (<-wait to action . args)
 200   (define prompt (*actor-prompt*))
 201   (when (not prompt)
 202     (error "Tried to <-wait without being in an actor's context..."))
 203
 204   (let ((reply (abort-to-prompt prompt '<-wait to action args)))
 205     (cond ((eq? (message-action reply) '*error*)
 206            (throw 'hive-unresumable-coroutine
 207                   "Won't resume coroutine; got an *error* as a reply"
 208                   #:message reply))
 209           (else (apply values (message-body reply))))))
 210
 211 \f
 212 ;;; Main actor implementation
 213 ;;; =========================
 214
 215 (define (actor-inheritable-message-handler actor message)
 216   (define action (message-action message))
 217   (define method
 218     (class-rmeta-ref (class-of actor) 'actions action
 219                      #:equals? eq? #:cache-set! hashq-set!
 220                      #:cache-ref hashq-ref))
 221   (unless method
 222     (throw 'action-not-found
 223            "No appropriate action handler found for actor"
 224            #:action action
 225            #:actor actor
 226            #:message message))
 227   (apply method actor message (message-body message)))
 228
 229 (define-syntax-rule (live-wrap body)
 230   "Wrap possibly multi-value function in a procedure, applies all arguments"
 231   (lambda args
 232     (apply body args)))
 233
 234 (define-syntax-rule (build-actions (symbol method) ...)
 235   "Construct an alist of (symbol . method), where the method is wrapped
 236 with `live-wrap' to facilitate live hacking and allow the method definition
 237 to come after class definition."
 238   (build-rmeta-slot
 239    (list (cons (quote symbol)
 240                (live-wrap method)) ...)))
 241
 242 (define-class <actor> ()
 243   ;; An address object... a vector of #(actor-id hive-id inbox-channel dead?)
 244   ;;  - inbox-channel is the receiving channel (as opposed to actor-inbox-deq)
 245   ;;  - dead? is a fibers condition variable which is set once this actor
 246   ;;    kicks the bucket
 247   (id #:init-keyword #:address
 248       #:getter actor-id)
 249
 250   ;; Our queue to send/receive messages on
 251   (inbox-deq #:init-thunk make-channel
 252              #:accessor actor-inbox-deq)
 253
 254   (msg-id-generator #:init-thunk simple-message-id-generator
 255                     #:getter actor-msg-id-generator)
 256
 257   ;; How we receive and process new messages
 258   (message-handler #:init-value actor-inheritable-message-handler
 259                    ;; @@: There's no reason not to use #:class instead of
 260                    ;;   #:each-subclass anywhere in this file, except for
 261                    ;;   Guile bug #25211 (#:class is broken in Guile 2.2)
 262                    #:allocation #:each-subclass
 263                    #:getter actor-message-handler)
 264
 265   ;; valid values are:
 266   ;;  - #t as in, send the init message, but don't wait (default)
 267   ;;  - 'wait, as in wait on the init message
 268   ;;  - #f as in don't bother to init
 269   (should-init #:init-value #t
 270                #:getter actor-should-init
 271                #:allocation #:each-subclass)
 272
 273   ;; This is the default, "simple" way to inherit and process messages.
 274   (actions #:init-thunk (build-actions)
 275            #:allocation #:each-subclass))
 276
 277 ;;; Actors may specify an "init" action that occurs before the actor
 278 ;;; actually begins to run.
 279 ;;; During actor-init!, an actor may send a message to itself or others
 280 ;;; via <- but *may not* use <-wait.
 281 (define-method (actor-init! (actor <actor>))
 282   'no-op)
 283
 284 (define-method (actor-cleanup! (actor <actor>))
 285   'no-op)
 286
 287 ;;; Addresses are vectors where the first part is the actor-id and
 288 ;;; the second part is the hive-id.  This works well enough... they
 289 ;;; look decent being pretty-printed.
 290
 291 (define (make-address actor-id hive-id channel dead?)
 292   (vector actor-id hive-id channel dead?))
 293
 294 (define (address-actor-id address)
 295   (vector-ref address 0))
 296
 297 (define (address-hive-id address)
 298   (vector-ref address 1))
 299
 300 (define (address-channel address)
 301   (vector-ref address 2))
 302
 303 (define (address-dead? address)
 304   (vector-ref address 3))
 305
 306 (define (address->string address)
 307   (string-append (address-actor-id address) "@"
 308                  (address-hive-id address)))
 309
 310 (define (address-equal? address1 address2)
 311   "Check whether or not the two addresses are equal.
 312
 313 This compares the actor-id and hive-id but ignores the channel and
 314 dead? condition."
 315   (match address1
 316     (#(actor-id-1 hive-id-1 _ _)
 317      (match address2
 318        (#(actor-id-2 hive-id-2)
 319         (and (equal? actor-id-1 actor-id-2)
 320              (and (equal? hive-id-1 hive-id-2))))
 321        (_ #f)))
 322     (_ #f)))
 323
 324 (define (actor-id-actor actor)
 325   "Get the actor id component of the actor-id"
 326   (address-actor-id (actor-id actor)))
 327
 328 (define (actor-id-hive actor)
 329   "Get the hive id component of the actor-id"
 330   (address-hive-id (actor-id actor)))
 331
 332 (define (actor-id-string actor)
 333   "Render the full actor id as a human-readable string"
 334   (address->string (actor-id actor)))
 335
 336 (define (actor-inbox-enq actor)
 337   (address-channel (actor-id actor)))
 338
 339 (define *current-actor*
 340   (make-parameter #f))
 341
 342 (define *actor-prompt*
 343   (make-parameter #f))
 344
 345 (define *resume-io-channel*
 346   (make-parameter #f))
 347
 348 (define (actor-main-loop actor)
 349   "Main loop of the actor.  Loops around, pulling messages off its queue
 350 and handling them."
 351   ;; @@: Maybe establish some sort of garbage collection routine for these...
 352   (define waiting
 353     (make-hash-table))
 354   (define message-handler
 355     (actor-message-handler actor))
 356   (define dead?
 357     (address-dead? (actor-id actor)))
 358   (define prompt (make-prompt-tag (actor-id-actor actor)))
 359   ;; Not always used, only if with-actor-nonblocking-ports is used
 360   (define resume-io-channel
 361     (make-channel))
 362
 363   (define (handle-message message)
 364     (catch #t
 365       (lambda ()
 366         (call-with-values
 367             (lambda ()
 368               (message-handler actor message))
 369           (lambda vals
 370             ;; Return reply if necessary
 371             (when (message-wants-reply message)
 372               (%<- #f actor (message-from message) '*reply*
 373                    vals ((actor-msg-id-generator actor))
 374                    (message-id message))))))
 375       (const #t)
 376       (let ((err (current-error-port)))
 377         (lambda (key . args)
 378           (false-if-exception
 379            (let ((stack (make-stack #t 4)))
 380              (format err "Uncaught exception when handling message ~a:\n"
 381                      message)
 382              (display-backtrace stack err)
 383              (print-exception err (stack-ref stack 0)
 384                               key args)
 385              (newline err)
 386              ;; If the other actor is waiting on a reply, let's let them
 387              ;; know there was an error...
 388              (when (message-wants-reply message)
 389                (%<- #f actor (message-from message) '*error*
 390                     (list key) ((actor-msg-id-generator actor))
 391                     (message-id message)))))))))
 392
 393   (define (resume-handler message)
 394     (define in-reply-to (message-in-reply-to message))
 395     (cond
 396      ((hash-ref waiting in-reply-to) =>
 397       (lambda (kont)
 398         (hash-remove! waiting in-reply-to)
 399         (kont message)))
 400      (else
 401       (format (current-error-port)
 402               "Tried to resume nonexistant message: ~a\n"
 403               (message-id message)))))
 404
 405   (define (call-with-actor-prompt thunk)
 406     (call-with-prompt prompt
 407       thunk
 408       ;; Here's where we abort to if we're doing <-wait
 409       ;; @@: maybe use match-lambda if we're going to end up
 410       ;;   handling multiple ~commands
 411       (match-lambda*
 412         ((kont '<-wait to action message-args)
 413          (define message-id
 414            ((actor-msg-id-generator actor)))
 415          (hash-set! waiting message-id kont)
 416          (%<- #t actor to action message-args message-id #f))
 417         ((kont 'run-me proc)
 418          (proc kont)))))
 419
 420   (define halt-or-handle-message
 421     ;; It would be nice if we could give priorities to certain operations.
 422     ;; halt should always win over getting a message...
 423     (choice-operation
 424      (wrap-operation (wait-operation dead?)
 425                      (const #f))  ; halt and return
 426      (wrap-operation (get-operation (actor-inbox-deq actor))
 427                      (lambda (message)
 428                        (call-with-actor-prompt
 429                         (lambda ()
 430                           (if (message-in-reply-to message)
 431                               ;; resume a continuation which was waiting on a reply
 432                               (resume-handler message)
 433                               ;; start handling a new message
 434                               (handle-message message))))
 435                        #t))   ; loop again
 436      (wrap-operation (get-operation resume-io-channel)
 437                      (lambda (thunk)
 438                        (call-with-actor-prompt
 439                         (lambda ()
 440                           (thunk)))
 441                        #t))))
 442
 443   ;; Mutate the parameter; this should be fine since each fiber
 444   ;; runs in its own dynamic state with with-dynamic-state.
 445   ;; See with-dynamic-state discussion in
 446   ;;   https://wingolog.org/archives/2017/06/27/growing-fibers
 447   (*current-actor* actor)
 448   (*resume-io-channel* resume-io-channel)
 449
 450   ;; We temporarily set the *actor-prompt* to #f to make sure that
 451   ;; actor-init! doesn't try to do a <-wait message (and not accidentally use
 452   ;; the parent fiber's *actor-prompt* either.)
 453   (*actor-prompt* #f)
 454   (actor-init! actor)
 455   (*actor-prompt* prompt)
 456
 457   (let loop ()
 458     (and (perform-operation halt-or-handle-message)
 459          (loop))))
 460
 461
 462 ;; @@: So in order for this to work, we're going to have to add
 463 ;; another channel to actors, which is resumable i/o.  We'll have to
 464 ;; spawn a fiber that wakes up a thunk on the actor when its port is
 465 ;; available.  Funky...
 466
 467 (define (%suspend-io-to-actor wait-for-read/write)
 468   (lambda (port)
 469     (define prompt (*actor-prompt*))
 470     (define resume-channel (*resume-io-channel*))
 471     (define (run-at-prompt k)
 472       (spawn-fiber
 473        (lambda ()
 474          (wait-for-read/write port)
 475          ;; okay, we're awake again, tell the actor to resume this
 476          ;; continuation
 477          (put-message resume-channel k))
 478        #:parallel? #f))
 479     (when (not prompt)
 480       (error "Attempt to abort to actor prompt outside of actor"))
 481     (abort-to-prompt (*actor-prompt*)
 482                      'run-me run-at-prompt)))
 483
 484 (define suspend-read-to-actor
 485   (%suspend-io-to-actor (@@ (fibers) wait-for-readable)))
 486
 487 (define suspend-write-to-actor
 488   (%suspend-io-to-actor (@@ (fibers) wait-for-writable)))
 489
 490 (define (with-actor-nonblocking-ports thunk)
 491   "Runs THUNK in dynamic context in which attempting to read/write
 492 from a port that would otherwise block an actor's correspondence with
 493 other actors (note that reading from a nonblocking port should never
 494 block other fibers) will instead permit reading other messages while
 495 I/O is waiting to complete.
 496
 497 Note that currently "
 498   (parameterize ((current-read-waiter suspend-read-to-actor)
 499                  (current-write-waiter suspend-write-to-actor))
 500     (thunk)))
 501
 502 (define (actor-spawn-fiber thunk . args)
 503   "Spawn a fiber from an actor but unset actor-machinery-specific
 504 dynamic context."
 505   (apply spawn-fiber
 506          (lambda ()
 507            (*current-actor* #f)
 508            (*resume-io-channel* #f)
 509            (*actor-prompt* #f)
 510            (thunk))
 511          args))
 512
 513
 514 \f
 515 ;;; Actor utilities
 516 ;;; ===============
 517
 518 (define-syntax-rule (define-actor class inherits
 519                       (action ...)
 520                       slots ...)
 521   (define-class class inherits
 522     (actions #:init-thunk (build-actions action ...)
 523              #:allocation #:each-subclass)
 524     slots ...))
 525
 526 \f
 527 ;;; The Hive
 528 ;;; ========
 529 ;;;   Every actor has a hive, which keeps track of other actors, manages
 530 ;;;   cleanup, and performs inter-hive communication.
 531
 532 ;; TODO: Make this a srfi-9 record type
 533 (define-class <hive> ()
 534   (id #:init-keyword #:id
 535       #:getter hive-id)
 536   (actor-registry #:init-thunk make-hash-table
 537                   #:getter hive-actor-registry)
 538   ;; TODO: Rename "ambassadors" to "relays"
 539   ;; Ambassadors are used (or will be) for inter-hive communication.
 540   ;; These are special actors that know how to route messages to other
 541   ;; hives.
 542   (ambassadors #:init-thunk make-weak-key-hash-table
 543                #:getter hive-ambassadors)
 544   (channel #:init-thunk make-channel
 545            #:getter hive-channel)
 546   (halt? #:init-thunk make-condition
 547          #:getter hive-halt?))
 548
 549 (define* (make-hive #:key hive-id)
 550   (make <hive> #:id (or hive-id
 551                         (big-random-number-string))))
 552
 553 (define (gen-actor-id cookie)
 554   (if cookie
 555       (string-append cookie ":" (big-random-number-string))
 556       (big-random-number-string)))
 557
 558 (define (hive-main-loop hive)
 559   "The main loop of the hive.  This listens for messages on the hive-channel
 560 for certain actions to perform.
 561
 562 `messages' here is not the same as a <message> object; these are a list of
 563 values, the first value being a symbol"
 564   (define channel (hive-channel hive))
 565   (define halt? (hive-halt? hive))
 566   (define registry (hive-actor-registry hive))
 567
 568   ;; not the same as a <message> ;P
 569   (define handle-message
 570     (match-lambda
 571       (('register-actor actor-id address actor)
 572        (hash-set! registry actor-id (vector address actor)))
 573       ;; Remove the actor from hive
 574       (('remove-actor actor-id)
 575        (hash-remove! (hive-actor-registry hive) actor-id))
 576       (('register-ambassador hive-id ambassador-actor-id)
 577        'TODO)
 578       (('unregister-ambassador hive-id ambassador-actor-id)
 579        'TODO)
 580       (('forward-message from-actor-id message)
 581        'TODO)))
 582
 583   (define halt-or-handle
 584     (choice-operation
 585      (wrap-operation (get-operation channel)
 586                      (lambda (msg)
 587                        (handle-message msg)
 588                        #t))
 589      (wrap-operation (wait-operation halt?)
 590                      (const #f))))
 591
 592   (let lp ()
 593     (and (perform-operation halt-or-handle)
 594          (lp))))
 595
 596 (define *hive-id* (make-parameter #f))
 597 (define *hive-channel* (make-parameter #f))
 598
 599 ;; @@: Should we halt the hive either at the end of spawn-hive or run-hive?
 600 (define* (spawn-hive proc #:key (hive (make-hive)))
 601   "Spawn a hive and run PROC, passing it the fresh hive and establishing
 602 a dynamic context surrounding the hive."
 603   (spawn-fiber (lambda () (hive-main-loop hive)))
 604   (parameterize ((*hive-id* (hive-id hive))
 605                  (*hive-channel* (hive-channel hive)))
 606     (proc hive)))
 607
 608 (define (run-hive proc . args)
 609   "Spawn a hive and run it in run-fibers.  Takes a PROC as would be passed
 610 to spawn-hive... all remaining arguments passed to run-fibers."
 611   (apply run-fibers
 612          (lambda ()
 613            (spawn-hive proc))
 614          args))
 615
 616 (define (%create-actor actor-class init-args id-cookie send-init?)
 617   (let* ((hive-channel (*hive-channel*))
 618          (hive-id (*hive-id*))
 619          (actor-id (gen-actor-id id-cookie))
 620          (dead? (make-condition))
 621          (inbox-enq (make-channel))
 622          (address (make-address actor-id hive-id
 623                                 inbox-enq dead?))
 624          (actor (apply make actor-class
 625                        #:address address
 626                        init-args))
 627          (should-init (actor-should-init actor)))
 628
 629     ;; start the main loop
 630     (spawn-fiber (lambda ()
 631                    ;; start the inbox loop
 632                    (spawn-fiber
 633                     (lambda ()
 634                       (delivery-agent inbox-enq (actor-inbox-deq actor)
 635                                       dead?))
 636                     ;; this one is decidedly non-parallel, because we want
 637                     ;; the delivery agent to be in the same thread as its actor
 638                     #:parallel? #f)
 639
 640                    (actor-main-loop actor))
 641                  #:parallel? #t)
 642
 643     (put-message hive-channel (list 'register-actor actor-id address actor))
 644
 645     ;; return the address
 646     address))
 647
 648 (define* (create-actor actor-class #:rest init-args)
 649   "Create an instance of actor-class.  Return the new actor's id.
 650
 651 This is the method actors should call directly (unless they want
 652 to supply an id-cookie, in which case they should use
 653 create-actor*)."
 654   (%create-actor actor-class init-args #f #t))
 655
 656
 657 (define* (create-actor* actor-class id-cookie #:rest init-args)
 658   "Create an instance of actor-class.  Return the new actor's id.
 659
 660 Like create-actor, but permits supplying an id-cookie."
 661   (%create-actor actor-class init-args id-cookie #t))
 662
 663 (define* (self-destruct actor #:key (cleanup #t))
 664   "Remove an actor from the hive.
 665
 666 Unless #:cleanup is set to #f, this will first have the actor handle
 667 its '*cleanup* action handler."
 668   (signal-condition! (address-dead? (actor-id actor)))
 669   (put-message (*hive-channel*) (list 'remove-actor (actor-id-actor actor)))
 670   ;; Set *actor-prompt* to nothing to prevent actor-cleanup! from sending
 671   ;; a message with <-wait
 672   (*actor-prompt* #f)
 673   (actor-cleanup! actor))
 674