+ (prompt (make-prompt-tag))
+ (read-port-map (make-hash-table))
+ (write-port-map (make-hash-table))
+ (except-port-map (make-hash-table))
+ (schedule (make-schedule))
+ (time (gettimeofday)))
+ ;; TODO: document arguments
+ "Make a fresh agenda."
+ (make-agenda-intern queue prompt
+ read-port-map write-port-map except-port-map
+ schedule time))
+
+(define (current-agenda-prompt)
+ "Get the prompt for the current agenda; signal an error if there isn't one."
+ (let ((current-agenda (%current-agenda)))
+ (if (not current-agenda)
+ (throw
+ 'no-current-agenda
+ "Can't get current agenda prompt if there's no current agenda!")
+ (agenda-prompt-tag current-agenda))))
+
+
+\f
+;;; Schedule
+;;; ========
+
+;;; This is where we handle timed events for the future
+
+;; This section totally borrows from the ideas in SICP
+;; <3 <3 <3
+
+;; NOTE: time is a cons of (seconds . microseconds)
+
+(define-record-type <time-segment>
+ (make-time-segment-intern time queue)
+ time-segment?
+ (time time-segment-time)
+ (queue time-segment-queue))
+
+(define (time-segment-right-format time)
+ "Ensure TIME is in the right format.
+
+The right format means (second . microsecond).
+If an integer, will convert appropriately."
+ ;; TODO: add floating point / rational number support.
+ (match time
+ ;; time is already a cons of second and microsecnd
+ (((? integer? s) . (? integer? u)) time)
+ ;; time was just an integer (just the second)
+ ((? integer? _) (cons time 0))
+ (_ (throw 'invalid-time "Invalid time" time))))
+
+(define* (make-time-segment time #:optional (queue (make-q)))
+ "Make a time segment of TIME and QUEUE
+
+No automatic conversion is done, so you might have to
+run (time-segment-right-format) first."
+ (make-time-segment-intern time queue))
+
+(define (time< time1 time2)
+ "Check if TIME1 is less than TIME2"
+ (cond ((< (car time1)
+ (car time2))
+ #t)
+ ((and (= (car time1)
+ (car time2))
+ (< (cdr time1)
+ (cdr time2)))
+ #t)
+ (else #f)))
+
+(define (time= time1 time2)
+ "Check whether TIME1 and TIME2 are equivalent"
+ (and (= (car time1) (car time2))
+ (= (cdr time1) (cdr time2))))
+
+(define (time<= time1 time2)
+ "Check if TIME1 is less than or equal to TIME2"
+ (or (time< time1 time2)
+ (time= time1 time2)))
+
+
+(define-record-type <time-delta>
+ (make-time-delta-intern sec usec)
+ time-delta?
+ (sec time-delta-sec)
+ (usec time-delta-usec))
+
+(define* (make-time-delta sec #:optional (usec 0))
+ "Make a <time-delta> of SEC seconds and USEC microseconds.
+
+This is used primarily so the agenda can recognize RUN-REQUEST objects
+which are meant "
+ (make-time-delta-intern sec usec))
+
+(define tdelta make-time-delta)
+
+(define (time-carry-correct time)
+ "Corrects/handles time microsecond carry.
+Will produce (0 . 0) instead of a negative number, if needed."
+ (cond ((>= (cdr time) 1000000)
+ (cons
+ (+ (car time) 1)
+ (- (cdr time) 1000000)))
+ ((< (cdr time) 0)
+ (if (= (car time) 0)
+ '(0 0)
+ (cons
+ (- (car time) 1)
+ (+ (cdr time) 1000000))))
+ (else time)))
+
+(define (time-delta+ time time-delta)
+ "Increment a TIME by the value of TIME-DELTA"
+ (time-carry-correct
+ (cons (+ (car time) (time-delta-sec time-delta))
+ (+ (cdr time) (time-delta-usec time-delta)))))
+
+(define (time-minus time1 time2)
+ "Subtract TIME2 from TIME1"
+ (time-carry-correct
+ (cons (- (car time1) (car time2))
+ (- (cdr time2) (cdr time2)))))
+
+(define (time-plus time1 time2)
+ "Add TIME1 and TIME2"
+ (time-carry-correct
+ (cons (+ (car time1) (car time2))
+ (+ (cdr time2) (cdr time2)))))
+
+
+(define-record-type <schedule>
+ (make-schedule-intern segments)
+ schedule?
+ (segments schedule-segments set-schedule-segments!))
+
+(define* (make-schedule #:optional segments)
+ "Make a schedule, optionally pre-composed of SEGMENTS"
+ (make-schedule-intern (or segments '())))
+
+(define (schedule-soonest-time schedule)
+ "Return a cons of (sec . usec) for next time segement, or #f if none"
+ (let ((segments (schedule-segments schedule)))
+ (if (eq? segments '())
+ #f
+ (time-segment-time (car segments)))))
+
+;; TODO: This code is reasonably easy to read but it
+;; mutates AND is worst case of O(n) in both space and time :(
+;; but at least it'll be reasonably easy to refactor to
+;; a more functional setup?
+(define (schedule-add! schedule time proc)
+ "Mutate SCHEDULE, adding PROC at an appropriate time segment for TIME"
+ (let ((time (time-segment-right-format time)))
+ (define (new-time-segment)
+ (let ((new-segment
+ (make-time-segment time)))
+ (enq! (time-segment-queue new-segment) proc)
+ new-segment))
+ (define (loop segments)
+ (define (segment-equals-time? segment)
+ (time= time (time-segment-time segment)))
+
+ (define (segment-more-than-time? segment)
+ (time< time (time-segment-time segment)))
+
+ ;; We could switch this out to be more mutate'y
+ ;; and avoid the O(n) of space... is that over-optimizing?
+ (match segments
+ ;; If we're at the end of the list, time to make a new
+ ;; segment...
+ ('() (cons (new-time-segment) '()))
+ ;; If the segment's time is exactly our time, good news
+ ;; everyone! Let's append our stuff to its queue
+ (((? segment-equals-time? first) rest ...)
+ (enq! (time-segment-queue first) proc)
+ segments)
+ ;; If the first segment is more than our time,
+ ;; ours belongs before this one, so add it and
+ ;; start consing our way back
+ (((? segment-more-than-time? first) rest ...)
+ (cons (new-time-segment) segments))
+ ;; Otherwise, build up recursive result
+ ((first rest ... )
+ (cons first (loop rest)))))
+ (set-schedule-segments!
+ schedule
+ (loop (schedule-segments schedule)))))
+
+(define (schedule-empty? schedule)
+ "Check if the SCHEDULE is currently empty"
+ (eq? (schedule-segments schedule) '()))
+
+(define (schedule-segments-split schedule time)
+ "Does a multiple value return of time segments before/at and after TIME"
+ (let ((time (time-segment-right-format time)))
+ (define (segment-is-now? segment)
+ (time= (time-segment-time segment) time))
+ (define (segment-is-before-now? segment)
+ (time< (time-segment-time segment) time))
+
+ (let loop ((segments-before '())
+ (segments-left (schedule-segments schedule)))
+ (match segments-left
+ ;; end of the line, return
+ ('()
+ (values (reverse segments-before) '()))
+
+ ;; It's right now, so time to stop, but include this one in before
+ ;; but otherwise return
+ (((? segment-is-now? first) rest ...)
+ (values (reverse (cons first segments-before)) rest))
+
+ ;; This is prior or at now, so add it and keep going
+ (((? segment-is-before-now? first) rest ...)
+ (loop (cons first segments-before) rest))
+
+ ;; Otherwise it's past now, just return what we have
+ (segments-after
+ (values segments-before segments-after))))))
+
+(define (schedule-extract-until! schedule time)
+ "Extract all segments until TIME from SCHEDULE, and pop old segments off"
+ (receive (segments-before segments-after)
+ (schedule-segments-split schedule time)
+ (set-schedule-segments! schedule segments-after)
+ segments-before))
+
+(define (add-segments-contents-to-queue! segments queue)
+ (for-each
+ (lambda (segment)
+ (let ((seg-queue (time-segment-queue segment)))
+ (while (not (q-empty? seg-queue))
+ (enq! queue (deq! seg-queue)))))
+ segments))
+
+
+\f
+;;; Request to run stuff
+;;; ====================
+
+(define-record-type <run-request>
+ (make-run-request proc when)
+ run-request?
+ (proc run-request-proc)
+ (when run-request-when))
+
+(define* (run-it proc #:optional when)
+ "Make a request to run PROC (possibly at WHEN)"
+ (make-run-request proc when))
+
+(define-syntax-rule (wrap body ...)
+ "Wrap contents in a procedure"
+ (lambda ()
+ body ...))
+
+;; @@: Do we really want `body ...' here?
+;; what about just `body'?
+(define-syntax-rule (run body ...)
+ "Run everything in BODY but wrap in a convenient procedure"
+ (make-run-request (wrap body ...) #f))
+
+(define-syntax-rule (run-at body ... when)
+ "Run BODY at WHEN"
+ (make-run-request (wrap body ...) when))
+
+;; @@: Is it okay to overload the term "delay" like this?
+;; Would `run-in' be better?
+(define-syntax-rule (run-delay body ... delay-time)
+ "Run BODY at DELAY-TIME time from now"
+ (make-run-request (wrap body ...) (tdelta delay-time)))
+
+
+;; A request to set up a port with at least one of read, write, except
+;; handling processes
+
+(define-record-type <port-request>
+ (make-port-request-intern port read write except)
+ port-request?
+ (port port-request-port)
+ (read port-request-read)
+ (write port-request-write)
+ (except port-request-except))
+
+(define* (make-port-request port #:key read write except)
+ (if (not (or read write except))
+ (throw 'no-port-handler-given "No port handler given.\n"))
+ (make-port-request-intern port read write except))
+
+(define port-request make-port-request)
+
+
+\f
+;;; Asynchronous escape to run things
+;;; =================================
+
+;; The future's in futures
+
+(define (make-future call-first on-success on-fail on-error)
+ ;; TODO: add error stuff here
+ (lambda ()
+ (let ((call-result (call-first)))
+ ;; queue up calling the
+ (run (on-success call-result)))))
+
+(define (agenda-on-error agenda)
+ (const #f))
+
+(define (agenda-on-fail agenda)
+ (const #f))
+
+(define* (request-future call-first on-success
+ #:key
+ (agenda (%current-agenda))
+ (on-fail (agenda-on-fail agenda))
+ (on-error (agenda-on-error agenda))
+ (when #f))
+ ;; TODO: error handling
+ ;; do we need some distinction between expected, catchable errors,
+ ;; and unexpected, uncatchable ones? Probably...?
+ (make-run-request
+ (make-future call-first on-success on-fail on-error)
+ when))
+
+(define-syntax-rule (%sync async-request)
+ "Run BODY asynchronously at a prompt, passing args to make-future.
+
+Pronounced `eight-sync' despite the spelling.
+
+%sync was chosen because (async) was already taken and could lead to
+errors, and this version of asynchronous code uses a prompt, so the `a'
+character becomes a `%' prompt! :)
+
+The % and 8 characters kind of look similar... hence this library's
+name! (That, and the pun 'eight-synchronous' programming.)
+There are 8sync aliases if you prefer that name."
+ (abort-to-prompt (current-agenda-prompt)
+ async-request))
+
+(define-syntax-rule (8sync args ...)
+ "Alias for %sync"
+ (%sync args ...))
+
+;; Async port request and run-request meta-requests
+(define (make-async-request proc)
+ "Wrap PROC in an async-request
+
+The purpose of this is to make sure that users don't accidentally
+return the wrong thing via (8sync) and trip themselves up."
+ (cons '*async-request* proc))
+
+(define (setup-async-request resume-kont async-request)
+ "Complete an async request for agenda-run-once's continuation handling"
+ (match async-request
+ (('*async-request* . async-setup-proc)
+ (async-setup-proc resume-kont))
+ ;; TODO: deliver more helpful errors depending on what the user
+ ;; returned
+ (_ (throw 'invalid-async-request
+ "Invalid request passed back via an (%sync) procedure."
+ async-request))))
+
+(define-syntax-rule (%run body ...)
+ (%run-at body ... #f))
+
+(define-syntax-rule (%run-at body ... when)
+ (make-async-request
+ (lambda (kont)
+ (make-run-request
+ (wrap
+ (kont
+ (begin body ...)))
+ when))))
+
+(define-syntax-rule (%run-delay body ... delay-time)
+ (%run-at body ... (tdelta delay-time)))
+
+(define-syntax-rule (%port-request add-this-port port-request-args ...)
+ (make-async-request
+ (lambda (kont)
+ (list (make-port-request port-request-args ...)
+ (make-run-request kont)))))
+
+;; TODO
+(define-syntax-rule (%run-with-return return body ...)
+ (make-async-request
+ (lambda (kont)
+ (let ((return kont))
+ (lambda ()
+ body ...)))))
+
+;; Aliases
+(define-syntax-rule (8run args ...) (%run args ...))
+(define-syntax-rule (8run-at args ...) (%run-at args ...))
+(define-syntax-rule (8run-delay args ...) (%run-delay args ...))
+(define-syntax-rule (8port-request args ...) (%port-request args ...))
+
+
+\f
+;;; Execution of agenda, and current agenda
+;;; =======================================