x86/kernel/ftrace_64.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *  Copyright (C) 2014  Steven Rostedt, Red Hat Inc
   4  */
   5
   6 #include <linux/linkage.h>
   7 #include <linux/cfi_types.h>
   8 #include <asm/ptrace.h>
   9 #include <asm/ftrace.h>
  10 #include <asm/export.h>
  11 #include <asm/nospec-branch.h>
  12 #include <asm/unwind_hints.h>
  13 #include <asm/frame.h>
  14
  15         .code64
  16         .section .text, "ax"
  17
  18 #ifdef CONFIG_FRAME_POINTER
  19 /* Save parent and function stack frames (rip and rbp) */
  20 #  define MCOUNT_FRAME_SIZE     (8+16*2)
  21 #else
  22 /* No need to save a stack frame */
  23 # define MCOUNT_FRAME_SIZE      0
  24 #endif /* CONFIG_FRAME_POINTER */
  25
  26 /* Size of stack used to save mcount regs in save_mcount_regs */
  27 #define MCOUNT_REG_SIZE         (FRAME_SIZE + MCOUNT_FRAME_SIZE)
  28
  29 /*
  30  * gcc -pg option adds a call to 'mcount' in most functions.
  31  * When -mfentry is used, the call is to 'fentry' and not 'mcount'
  32  * and is done before the function's stack frame is set up.
  33  * They both require a set of regs to be saved before calling
  34  * any C code and restored before returning back to the function.
  35  *
  36  * On boot up, all these calls are converted into nops. When tracing
  37  * is enabled, the call can jump to either ftrace_caller or
  38  * ftrace_regs_caller. Callbacks (tracing functions) that require
  39  * ftrace_regs_caller (like kprobes) need to have pt_regs passed to
  40  * it. For this reason, the size of the pt_regs structure will be
  41  * allocated on the stack and the required mcount registers will
  42  * be saved in the locations that pt_regs has them in.
  43  */
  44
  45 /*
  46  * @added: the amount of stack added before calling this
  47  *
  48  * After this is called, the following registers contain:
  49  *
  50  *  %rdi - holds the address that called the trampoline
  51  *  %rsi - holds the parent function (traced function's return address)
  52  *  %rdx - holds the original %rbp
  53  */
  54 .macro save_mcount_regs added=0
  55
  56 #ifdef CONFIG_FRAME_POINTER
  57         /* Save the original rbp */
  58         pushq %rbp
  59
  60         /*
  61          * Stack traces will stop at the ftrace trampoline if the frame pointer
  62          * is not set up properly. If fentry is used, we need to save a frame
  63          * pointer for the parent as well as the function traced, because the
  64          * fentry is called before the stack frame is set up, where as mcount
  65          * is called afterward.
  66          */
  67
  68         /* Save the parent pointer (skip orig rbp and our return address) */
  69         pushq \added+8*2(%rsp)
  70         pushq %rbp
  71         movq %rsp, %rbp
  72         /* Save the return address (now skip orig rbp, rbp and parent) */
  73         pushq \added+8*3(%rsp)
  74         pushq %rbp
  75         movq %rsp, %rbp
  76 #endif /* CONFIG_FRAME_POINTER */
  77
  78         /*
  79          * We add enough stack to save all regs.
  80          */
  81         subq $(FRAME_SIZE), %rsp
  82         movq %rax, RAX(%rsp)
  83         movq %rcx, RCX(%rsp)
  84         movq %rdx, RDX(%rsp)
  85         movq %rsi, RSI(%rsp)
  86         movq %rdi, RDI(%rsp)
  87         movq %r8, R8(%rsp)
  88         movq %r9, R9(%rsp)
  89         movq $0, ORIG_RAX(%rsp)
  90         /*
  91          * Save the original RBP. Even though the mcount ABI does not
  92          * require this, it helps out callers.
  93          */
  94 #ifdef CONFIG_FRAME_POINTER
  95         movq MCOUNT_REG_SIZE-8(%rsp), %rdx
  96 #else
  97         movq %rbp, %rdx
  98 #endif
  99         movq %rdx, RBP(%rsp)
 100
 101         /* Copy the parent address into %rsi (second parameter) */
 102         movq MCOUNT_REG_SIZE+8+\added(%rsp), %rsi
 103
 104          /* Move RIP to its proper location */
 105         movq MCOUNT_REG_SIZE+\added(%rsp), %rdi
 106         movq %rdi, RIP(%rsp)
 107
 108         /*
 109          * Now %rdi (the first parameter) has the return address of
 110          * where ftrace_call returns. But the callbacks expect the
 111          * address of the call itself.
 112          */
 113         subq $MCOUNT_INSN_SIZE, %rdi
 114         .endm
 115
 116 .macro restore_mcount_regs save=0
 117
 118         /* ftrace_regs_caller or frame pointers require this */
 119         movq RBP(%rsp), %rbp
 120
 121         movq R9(%rsp), %r9
 122         movq R8(%rsp), %r8
 123         movq RDI(%rsp), %rdi
 124         movq RSI(%rsp), %rsi
 125         movq RDX(%rsp), %rdx
 126         movq RCX(%rsp), %rcx
 127         movq RAX(%rsp), %rax
 128
 129         addq $MCOUNT_REG_SIZE-\save, %rsp
 130
 131         .endm
 132
 133 SYM_TYPED_FUNC_START(ftrace_stub)
 134         RET
 135 SYM_FUNC_END(ftrace_stub)
 136
 137 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 138 SYM_TYPED_FUNC_START(ftrace_stub_graph)
 139         RET
 140 SYM_FUNC_END(ftrace_stub_graph)
 141 #endif
 142
 143 #ifdef CONFIG_DYNAMIC_FTRACE
 144
 145 SYM_FUNC_START(__fentry__)
 146         RET
 147 SYM_FUNC_END(__fentry__)
 148 EXPORT_SYMBOL(__fentry__)
 149
 150 SYM_FUNC_START(ftrace_caller)
 151         /* save_mcount_regs fills in first two parameters */
 152         save_mcount_regs
 153
 154         /* Stack - skipping return address of ftrace_caller */
 155         leaq MCOUNT_REG_SIZE+8(%rsp), %rcx
 156         movq %rcx, RSP(%rsp)
 157
 158 SYM_INNER_LABEL(ftrace_caller_op_ptr, SYM_L_GLOBAL)
 159         ANNOTATE_NOENDBR
 160         /* Load the ftrace_ops into the 3rd parameter */
 161         movq function_trace_op(%rip), %rdx
 162
 163         /* regs go into 4th parameter */
 164         leaq (%rsp), %rcx
 165
 166         /* Only ops with REGS flag set should have CS register set */
 167         movq $0, CS(%rsp)
 168
 169 SYM_INNER_LABEL(ftrace_call, SYM_L_GLOBAL)
 170         ANNOTATE_NOENDBR
 171         call ftrace_stub
 172
 173         /* Handlers can change the RIP */
 174         movq RIP(%rsp), %rax
 175         movq %rax, MCOUNT_REG_SIZE(%rsp)
 176
 177         restore_mcount_regs
 178
 179         /*
 180          * The code up to this label is copied into trampolines so
 181          * think twice before adding any new code or changing the
 182          * layout here.
 183          */
 184 SYM_INNER_LABEL(ftrace_caller_end, SYM_L_GLOBAL)
 185         ANNOTATE_NOENDBR
 186         RET
 187 SYM_FUNC_END(ftrace_caller);
 188 STACK_FRAME_NON_STANDARD_FP(ftrace_caller)
 189
 190 SYM_FUNC_START(ftrace_regs_caller)
 191         /* Save the current flags before any operations that can change them */
 192         pushfq
 193
 194         /* added 8 bytes to save flags */
 195         save_mcount_regs 8
 196         /* save_mcount_regs fills in first two parameters */
 197
 198 SYM_INNER_LABEL(ftrace_regs_caller_op_ptr, SYM_L_GLOBAL)
 199         ANNOTATE_NOENDBR
 200         /* Load the ftrace_ops into the 3rd parameter */
 201         movq function_trace_op(%rip), %rdx
 202
 203         /* Save the rest of pt_regs */
 204         movq %r15, R15(%rsp)
 205         movq %r14, R14(%rsp)
 206         movq %r13, R13(%rsp)
 207         movq %r12, R12(%rsp)
 208         movq %r11, R11(%rsp)
 209         movq %r10, R10(%rsp)
 210         movq %rbx, RBX(%rsp)
 211         /* Copy saved flags */
 212         movq MCOUNT_REG_SIZE(%rsp), %rcx
 213         movq %rcx, EFLAGS(%rsp)
 214         /* Kernel segments */
 215         movq $__KERNEL_DS, %rcx
 216         movq %rcx, SS(%rsp)
 217         movq $__KERNEL_CS, %rcx
 218         movq %rcx, CS(%rsp)
 219         /* Stack - skipping return address and flags */
 220         leaq MCOUNT_REG_SIZE+8*2(%rsp), %rcx
 221         movq %rcx, RSP(%rsp)
 222
 223         ENCODE_FRAME_POINTER
 224
 225         /* regs go into 4th parameter */
 226         leaq (%rsp), %rcx
 227
 228 SYM_INNER_LABEL(ftrace_regs_call, SYM_L_GLOBAL)
 229         ANNOTATE_NOENDBR
 230         call ftrace_stub
 231
 232         /* Copy flags back to SS, to restore them */
 233         movq EFLAGS(%rsp), %rax
 234         movq %rax, MCOUNT_REG_SIZE(%rsp)
 235
 236         /* Handlers can change the RIP */
 237         movq RIP(%rsp), %rax
 238         movq %rax, MCOUNT_REG_SIZE+8(%rsp)
 239
 240         /* restore the rest of pt_regs */
 241         movq R15(%rsp), %r15
 242         movq R14(%rsp), %r14
 243         movq R13(%rsp), %r13
 244         movq R12(%rsp), %r12
 245         movq R10(%rsp), %r10
 246         movq RBX(%rsp), %rbx
 247
 248         movq ORIG_RAX(%rsp), %rax
 249         movq %rax, MCOUNT_REG_SIZE-8(%rsp)
 250
 251         /*
 252          * If ORIG_RAX is anything but zero, make this a call to that.
 253          * See arch_ftrace_set_direct_caller().
 254          */
 255         testq   %rax, %rax
 256 SYM_INNER_LABEL(ftrace_regs_caller_jmp, SYM_L_GLOBAL)
 257         ANNOTATE_NOENDBR
 258         jnz     1f
 259
 260         restore_mcount_regs
 261         /* Restore flags */
 262         popfq
 263
 264         /*
 265          * The trampoline will add the return.
 266          */
 267 SYM_INNER_LABEL(ftrace_regs_caller_end, SYM_L_GLOBAL)
 268         ANNOTATE_NOENDBR
 269         RET
 270
 271         /* Swap the flags with orig_rax */
 272 1:      movq MCOUNT_REG_SIZE(%rsp), %rdi
 273         movq %rdi, MCOUNT_REG_SIZE-8(%rsp)
 274         movq %rax, MCOUNT_REG_SIZE(%rsp)
 275
 276         restore_mcount_regs 8
 277         /* Restore flags */
 278         popfq
 279         UNWIND_HINT_FUNC
 280         RET
 281
 282 SYM_FUNC_END(ftrace_regs_caller)
 283 STACK_FRAME_NON_STANDARD_FP(ftrace_regs_caller)
 284
 285
 286 #else /* ! CONFIG_DYNAMIC_FTRACE */
 287
 288 SYM_FUNC_START(__fentry__)
 289         cmpq $ftrace_stub, ftrace_trace_function
 290         jnz trace
 291         RET
 292
 293 trace:
 294         /* save_mcount_regs fills in first two parameters */
 295         save_mcount_regs
 296
 297         /*
 298          * When DYNAMIC_FTRACE is not defined, ARCH_SUPPORTS_FTRACE_OPS is not
 299          * set (see include/asm/ftrace.h and include/linux/ftrace.h).  Only the
 300          * ip and parent ip are used and the list function is called when
 301          * function tracing is enabled.
 302          */
 303         movq ftrace_trace_function, %r8
 304         CALL_NOSPEC r8
 305         restore_mcount_regs
 306
 307         jmp ftrace_stub
 308 SYM_FUNC_END(__fentry__)
 309 EXPORT_SYMBOL(__fentry__)
 310 STACK_FRAME_NON_STANDARD_FP(__fentry__)
 311
 312 #endif /* CONFIG_DYNAMIC_FTRACE */
 313
 314 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 315 SYM_CODE_START(return_to_handler)
 316         UNWIND_HINT_EMPTY
 317         ANNOTATE_NOENDBR
 318         subq  $16, %rsp
 319
 320         /* Save the return values */
 321         movq %rax, (%rsp)
 322         movq %rdx, 8(%rsp)
 323         movq %rbp, %rdi
 324
 325         call ftrace_return_to_handler
 326
 327         movq %rax, %rdi
 328         movq 8(%rsp), %rdx
 329         movq (%rsp), %rax
 330
 331         addq $16, %rsp
 332         /*
 333          * Jump back to the old return address. This cannot be JMP_NOSPEC rdi
 334          * since IBT would demand that contain ENDBR, which simply isn't so for
 335          * return addresses. Use a retpoline here to keep the RSB balanced.
 336          */
 337         ANNOTATE_INTRA_FUNCTION_CALL
 338         call .Ldo_rop
 339         int3
 340 .Ldo_rop:
 341         mov %rdi, (%rsp)
 342         RET
 343 SYM_CODE_END(return_to_handler)
 344 #endif