scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use strict;
 110
 111 my $P = $0;
 112 $P =~ s@.*/@@g;
 113
 114 my $V = '0.1';
 115
 116 if ($#ARGV != 11) {
 117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118         print "version: $V\n";
 119         exit(1);
 120 }
 121
 122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127     exit(0);
 128 }
 129
 130 # Acceptable sections to record.
 131 my %text_sections = (
 132      ".text" => 1,
 133      ".ref.text" => 1,
 134      ".sched.text" => 1,
 135      ".spinlock.text" => 1,
 136      ".irqentry.text" => 1,
 137      ".softirqentry.text" => 1,
 138      ".kprobes.text" => 1,
 139      ".cpuidle.text" => 1,
 140      ".text.unlikely" => 1,
 141 );
 142
 143 # Acceptable section-prefixes to record.
 144 my %text_section_prefixes = (
 145      ".text." => 1,
 146 );
 147
 148 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 149 $objdump = 'objdump' if (!$objdump);
 150 $objcopy = 'objcopy' if (!$objcopy);
 151 $cc = 'gcc' if (!$cc);
 152 $ld = 'ld' if (!$ld);
 153 $nm = 'nm' if (!$nm);
 154 $rm = 'rm' if (!$rm);
 155 $mv = 'mv' if (!$mv);
 156
 157 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 158 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 159
 160 my %locals;             # List of local (static) functions
 161 my %weak;               # List of weak functions
 162 my %convert;            # List of local functions used that needs conversion
 163
 164 my $type;
 165 my $local_regex;        # Match a local function (return function)
 166 my $weak_regex;         # Match a weak function (return function)
 167 my $section_regex;      # Find the start of a section
 168 my $function_regex;     # Find the name of a function
 169                         #    (return offset and func name)
 170 my $mcount_regex;       # Find the call site to mcount (return offset)
 171 my $mcount_adjust;      # Address adjustment to mcount offset
 172 my $alignment;          # The .align value to use for $mcount_section
 173 my $section_type;       # Section header plus possible alignment command
 174 my $can_use_local = 0;  # If we can use local function references
 175
 176 # Shut up recordmcount if user has older objcopy
 177 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 178 my $print_warning = 1;
 179 $print_warning = 0 if ( -f $quiet_recordmcount);
 180
 181 ##
 182 # check_objcopy - whether objcopy supports --globalize-symbols
 183 #
 184 #  --globalize-symbols came out in 2.17, we must test the version
 185 #  of objcopy, and if it is less than 2.17, then we can not
 186 #  record local functions.
 187 sub check_objcopy
 188 {
 189     open (IN, "$objcopy --version |") or die "error running $objcopy";
 190     while (<IN>) {
 191         if (/objcopy.*\s(\d+)\.(\d+)/) {
 192             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 193             last;
 194         }
 195     }
 196     close (IN);
 197
 198     if (!$can_use_local && $print_warning) {
 199         print STDERR "WARNING: could not find objcopy version or version " .
 200             "is less than 2.17.\n" .
 201             "\tLocal function references are disabled.\n";
 202         open (QUIET, ">$quiet_recordmcount");
 203         printf QUIET "Disables the warning from recordmcount.pl\n";
 204         close QUIET;
 205     }
 206 }
 207
 208 if ($arch =~ /(x86(_64)?)|(i386)/) {
 209     if ($bits == 64) {
 210         $arch = "x86_64";
 211     } else {
 212         $arch = "i386";
 213     }
 214 }
 215
 216 #
 217 # We base the defaults off of i386, the other archs may
 218 # feel free to change them in the below if statements.
 219 #
 220 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 221 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 222 $section_regex = "Disassembly of section\\s+(\\S+):";
 223 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 224 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 225 $section_type = '@progbits';
 226 $mcount_adjust = 0;
 227 $type = ".long";
 228
 229 if ($arch eq "x86_64") {
 230     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 231     $type = ".quad";
 232     $alignment = 8;
 233     $mcount_adjust = -1;
 234
 235     # force flags for this arch
 236     $ld .= " -m elf_x86_64";
 237     $objdump .= " -M x86-64";
 238     $objcopy .= " -O elf64-x86-64";
 239     $cc .= " -m64";
 240
 241 } elsif ($arch eq "i386") {
 242     $alignment = 4;
 243     $mcount_adjust = -1;
 244
 245     # force flags for this arch
 246     $ld .= " -m elf_i386";
 247     $objdump .= " -M i386";
 248     $objcopy .= " -O elf32-i386";
 249     $cc .= " -m32";
 250
 251 } elsif ($arch eq "s390" && $bits == 64) {
 252     if ($cc =~ /-DCC_USING_HOTPATCH/) {
 253         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*(brcl\\s*0,|jgnop\\s*)[0-9a-f]+ <([^\+]*)>\$";
 254         $mcount_adjust = 0;
 255     } else {
 256         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 257         $mcount_adjust = -14;
 258     }
 259     $alignment = 8;
 260     $type = ".quad";
 261     $ld .= " -m elf64_s390";
 262     $cc .= " -m64";
 263
 264 } elsif ($arch eq "sh") {
 265     $alignment = 2;
 266
 267     # force flags for this arch
 268     $ld .= " -m shlelf_linux";
 269     if ($endian eq "big") {
 270         $objcopy .= " -O elf32-shbig-linux";
 271     } else {
 272         $objcopy .= " -O elf32-sh-linux";
 273     }
 274
 275 } elsif ($arch eq "powerpc") {
 276     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 277     # See comment in the sparc64 section for why we use '\w'.
 278     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
 279     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 280
 281     if ($bits == 64) {
 282         $type = ".quad";
 283     }
 284
 285 } elsif ($arch eq "arm") {
 286     $alignment = 2;
 287     $section_type = '%progbits';
 288     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 289                         "\\s+(__gnu_mcount_nc|mcount)\$";
 290
 291 } elsif ($arch eq "arm64") {
 292     $alignment = 3;
 293     $section_type = '%progbits';
 294     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 295     $type = ".quad";
 296 } elsif ($arch eq "ia64") {
 297     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 298     $type = "data8";
 299
 300     if ($is_module eq "0") {
 301         $cc .= " -mconstant-gp";
 302     }
 303 } elsif ($arch eq "sparc64") {
 304     # In the objdump output there are giblets like:
 305     # 0000000000000000 <igmp_net_exit-0x18>:
 306     # As there's some data blobs that get emitted into the
 307     # text section before the first instructions and the first
 308     # real symbols.  We don't want to match that, so to combat
 309     # this we use '\w' so we'll match just plain symbol names,
 310     # and not those that also include hex offsets inside of the
 311     # '<>' brackets.  Actually the generic function_regex setting
 312     # could safely use this too.
 313     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 314
 315     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 316     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 317
 318     $alignment = 8;
 319     $type = ".xword";
 320     $ld .= " -m elf64_sparc";
 321     $cc .= " -m64";
 322     $objcopy .= " -O elf64-sparc";
 323 } elsif ($arch eq "mips") {
 324     # To enable module support, we need to enable the -mlong-calls option
 325     # of gcc for module, after using this option, we can not get the real
 326     # offset of the calling to _mcount, but the offset of the lui
 327     # instruction or the addiu one. herein, we record the address of the
 328     # first one, and then we can replace this instruction by a branch
 329     # instruction to jump over the profiling function to filter the
 330     # indicated functions, or swith back to the lui instruction to trace
 331     # them, which means dynamic tracing.
 332     #
 333     #       c:  3c030000        lui     v1,0x0
 334     #                   c: R_MIPS_HI16  _mcount
 335     #                   c: R_MIPS_NONE  *ABS*
 336     #                   c: R_MIPS_NONE  *ABS*
 337     #      10:  64630000        daddiu  v1,v1,0
 338     #                   10: R_MIPS_LO16 _mcount
 339     #                   10: R_MIPS_NONE *ABS*
 340     #                   10: R_MIPS_NONE *ABS*
 341     #      14:  03e0082d        move    at,ra
 342     #      18:  0060f809        jalr    v1
 343     #
 344     # for the kernel:
 345     #
 346     #     10:   03e0082d        move    at,ra
 347     #     14:   0c000000        jal     0 <loongson_halt>
 348     #                    14: R_MIPS_26   _mcount
 349     #                    14: R_MIPS_NONE *ABS*
 350     #                    14: R_MIPS_NONE *ABS*
 351     #    18:   00020021        nop
 352     if ($is_module eq "0") {
 353             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 354     } else {
 355             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 356     }
 357     $objdump .= " -Melf-trad".$endian."mips ";
 358
 359     if ($endian eq "big") {
 360             $endian = " -EB ";
 361             $ld .= " -melf".$bits."btsmip";
 362     } else {
 363             $endian = " -EL ";
 364             $ld .= " -melf".$bits."ltsmip";
 365     }
 366
 367     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 368     $ld .= $endian;
 369
 370     if ($bits == 64) {
 371             $function_regex =
 372                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 373             $type = ".dword";
 374     }
 375 } elsif ($arch eq "microblaze") {
 376     # Microblaze calls '_mcount' instead of plain 'mcount'.
 377     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 378 } elsif ($arch eq "blackfin") {
 379     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 380     $mcount_adjust = -4;
 381 } elsif ($arch eq "tilegx" || $arch eq "tile") {
 382     # Default to the newer TILE-Gx architecture if only "tile" is given.
 383     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 384     $type = ".quad";
 385     $alignment = 8;
 386 } else {
 387     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 388 }
 389
 390 my $text_found = 0;
 391 my $read_function = 0;
 392 my $opened = 0;
 393 my $mcount_section = "__mcount_loc";
 394
 395 my $dirname;
 396 my $filename;
 397 my $prefix;
 398 my $ext;
 399
 400 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 401     $dirname = $1;
 402     $filename = $2;
 403 } else {
 404     $dirname = ".";
 405     $filename = $inputfile;
 406 }
 407
 408 if ($filename =~ m,^(.*)(\.\S),) {
 409     $prefix = $1;
 410     $ext = $2;
 411 } else {
 412     $prefix = $filename;
 413     $ext = "";
 414 }
 415
 416 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 417 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 418
 419 check_objcopy();
 420
 421 #
 422 # Step 1: find all the local (static functions) and weak symbols.
 423 #         't' is local, 'w/W' is weak
 424 #
 425 open (IN, "$nm $inputfile|") || die "error running $nm";
 426 while (<IN>) {
 427     if (/$local_regex/) {
 428         $locals{$1} = 1;
 429     } elsif (/$weak_regex/) {
 430         $weak{$2} = $1;
 431     }
 432 }
 433 close(IN);
 434
 435 my @offsets;            # Array of offsets of mcount callers
 436 my $ref_func;           # reference function to use for offsets
 437 my $offset = 0;         # offset of ref_func to section beginning
 438
 439 ##
 440 # update_funcs - print out the current mcount callers
 441 #
 442 #  Go through the list of offsets to callers and write them to
 443 #  the output file in a format that can be read by an assembler.
 444 #
 445 sub update_funcs
 446 {
 447     return unless ($ref_func and @offsets);
 448
 449     # Sanity check on weak function. A weak function may be overwritten by
 450     # another function of the same name, making all these offsets incorrect.
 451     if (defined $weak{$ref_func}) {
 452         die "$inputfile: ERROR: referencing weak function" .
 453             " $ref_func for mcount\n";
 454     }
 455
 456     # is this function static? If so, note this fact.
 457     if (defined $locals{$ref_func}) {
 458
 459         # only use locals if objcopy supports globalize-symbols
 460         if (!$can_use_local) {
 461             return;
 462         }
 463         $convert{$ref_func} = 1;
 464     }
 465
 466     # Loop through all the mcount caller offsets and print a reference
 467     # to the caller based from the ref_func.
 468     if (!$opened) {
 469         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 470         $opened = 1;
 471         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 472         print FILE "\t.align $alignment\n" if (defined($alignment));
 473     }
 474     foreach my $cur_offset (@offsets) {
 475         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 476     }
 477 }
 478
 479 #
 480 # Step 2: find the sections and mcount call sites
 481 #
 482 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 483
 484 my $text;
 485
 486
 487 # read headers first
 488 my $read_headers = 1;
 489
 490 while (<IN>) {
 491
 492     if ($read_headers && /$mcount_section/) {
 493         #
 494         # Somehow the make process can execute this script on an
 495         # object twice. If it does, we would duplicate the mcount
 496         # section and it will cause the function tracer self test
 497         # to fail. Check if the mcount section exists, and if it does,
 498         # warn and exit.
 499         #
 500         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 501             "\tThis may be an indication that your build is corrupted.\n" .
 502             "\tDelete $inputfile and try again. If the same object file\n" .
 503             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 504         exit(-1);
 505     }
 506
 507     # is it a section?
 508     if (/$section_regex/) {
 509         $read_headers = 0;
 510
 511         # Only record text sections that we know are safe
 512         $read_function = defined($text_sections{$1});
 513         if (!$read_function) {
 514             foreach my $prefix (keys %text_section_prefixes) {
 515                 if (substr($1, 0, length $prefix) eq $prefix) {
 516                     $read_function = 1;
 517                     last;
 518                 }
 519             }
 520         }
 521         # print out any recorded offsets
 522         update_funcs();
 523
 524         # reset all markers and arrays
 525         $text_found = 0;
 526         undef($ref_func);
 527         undef(@offsets);
 528
 529     # section found, now is this a start of a function?
 530     } elsif ($read_function && /$function_regex/) {
 531         $text_found = 1;
 532         $text = $2;
 533
 534         # if this is either a local function or a weak function
 535         # keep looking for functions that are global that
 536         # we can use safely.
 537         if (!defined($locals{$text}) && !defined($weak{$text})) {
 538             $ref_func = $text;
 539             $read_function = 0;
 540             $offset = hex $1;
 541         } else {
 542             # if we already have a function, and this is weak, skip it
 543             if (!defined($ref_func) && !defined($weak{$text}) &&
 544                  # PPC64 can have symbols that start with .L and
 545                  # gcc considers these special. Don't use them!
 546                  $text !~ /^\.L/) {
 547                 $ref_func = $text;
 548                 $offset = hex $1;
 549             }
 550         }
 551     }
 552     # is this a call site to mcount? If so, record it to print later
 553     if ($text_found && /$mcount_regex/) {
 554         push(@offsets, (hex $1) + $mcount_adjust);
 555     }
 556 }
 557
 558 # dump out anymore offsets that may have been found
 559 update_funcs();
 560
 561 # If we did not find any mcount callers, we are done (do nothing).
 562 if (!$opened) {
 563     exit(0);
 564 }
 565
 566 close(FILE);
 567
 568 #
 569 # Step 3: Compile the file that holds the list of call sites to mcount.
 570 #
 571 `$cc -o $mcount_o -c $mcount_s`;
 572
 573 my @converts = keys %convert;
 574
 575 #
 576 # Step 4: Do we have sections that started with local functions?
 577 #
 578 if ($#converts >= 0) {
 579     my $globallist = "";
 580     my $locallist = "";
 581
 582     foreach my $con (@converts) {
 583         $globallist .= " --globalize-symbol $con";
 584         $locallist .= " --localize-symbol $con";
 585     }
 586
 587     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 588     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 589
 590     #
 591     # Step 5: set up each local function as a global
 592     #
 593     `$objcopy $globallist $inputfile $globalobj`;
 594
 595     #
 596     # Step 6: Link the global version to our list.
 597     #
 598     `$ld -r $globalobj $mcount_o -o $globalmix`;
 599
 600     #
 601     # Step 7: Convert the local functions back into local symbols
 602     #
 603     `$objcopy $locallist $globalmix $inputfile`;
 604
 605     # Remove the temp files
 606     `$rm $globalobj $globalmix`;
 607
 608 } else {
 609
 610     my $mix = $dirname . "/.tmp_mx_" . $filename;
 611
 612     #
 613     # Step 8: Link the object with our list of call sites object.
 614     #
 615     `$ld -r $inputfile $mcount_o -o $mix`;
 616
 617     #
 618     # Step 9: Move the result back to the original object.
 619     #
 620     `$mv $mix $inputfile`;
 621 }
 622
 623 # Clean up the temp files
 624 `$rm $mcount_o $mcount_s`;
 625
 626 exit(0);