scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use strict;
 110
 111 my $P = $0;
 112 $P =~ s@.*/@@g;
 113
 114 my $V = '0.1';
 115
 116 if ($#ARGV != 11) {
 117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118         print "version: $V\n";
 119         exit(1);
 120 }
 121
 122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127     exit(0);
 128 }
 129
 130 # Acceptable sections to record.
 131 my %text_sections = (
 132      ".text" => 1,
 133      ".ref.text" => 1,
 134      ".sched.text" => 1,
 135      ".spinlock.text" => 1,
 136      ".irqentry.text" => 1,
 137      ".kprobes.text" => 1,
 138      ".text.unlikely" => 1,
 139 );
 140
 141 # Acceptable section-prefixes to record.
 142 my %text_section_prefixes = (
 143      ".text." => 1,
 144 );
 145
 146 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 147 $objdump = 'objdump' if (!$objdump);
 148 $objcopy = 'objcopy' if (!$objcopy);
 149 $cc = 'gcc' if (!$cc);
 150 $ld = 'ld' if (!$ld);
 151 $nm = 'nm' if (!$nm);
 152 $rm = 'rm' if (!$rm);
 153 $mv = 'mv' if (!$mv);
 154
 155 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 156 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 157
 158 my %locals;             # List of local (static) functions
 159 my %weak;               # List of weak functions
 160 my %convert;            # List of local functions used that needs conversion
 161
 162 my $type;
 163 my $local_regex;        # Match a local function (return function)
 164 my $weak_regex;         # Match a weak function (return function)
 165 my $section_regex;      # Find the start of a section
 166 my $function_regex;     # Find the name of a function
 167                         #    (return offset and func name)
 168 my $mcount_regex;       # Find the call site to mcount (return offset)
 169 my $mcount_adjust;      # Address adjustment to mcount offset
 170 my $alignment;          # The .align value to use for $mcount_section
 171 my $section_type;       # Section header plus possible alignment command
 172 my $can_use_local = 0;  # If we can use local function references
 173
 174 # Shut up recordmcount if user has older objcopy
 175 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 176 my $print_warning = 1;
 177 $print_warning = 0 if ( -f $quiet_recordmcount);
 178
 179 ##
 180 # check_objcopy - whether objcopy supports --globalize-symbols
 181 #
 182 #  --globalize-symbols came out in 2.17, we must test the version
 183 #  of objcopy, and if it is less than 2.17, then we can not
 184 #  record local functions.
 185 sub check_objcopy
 186 {
 187     open (IN, "$objcopy --version |") or die "error running $objcopy";
 188     while (<IN>) {
 189         if (/objcopy.*\s(\d+)\.(\d+)/) {
 190             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 191             last;
 192         }
 193     }
 194     close (IN);
 195
 196     if (!$can_use_local && $print_warning) {
 197         print STDERR "WARNING: could not find objcopy version or version " .
 198             "is less than 2.17.\n" .
 199             "\tLocal function references are disabled.\n";
 200         open (QUIET, ">$quiet_recordmcount");
 201         printf QUIET "Disables the warning from recordmcount.pl\n";
 202         close QUIET;
 203     }
 204 }
 205
 206 if ($arch =~ /(x86(_64)?)|(i386)/) {
 207     if ($bits == 64) {
 208         $arch = "x86_64";
 209     } else {
 210         $arch = "i386";
 211     }
 212 }
 213
 214 #
 215 # We base the defaults off of i386, the other archs may
 216 # feel free to change them in the below if statements.
 217 #
 218 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 219 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 220 $section_regex = "Disassembly of section\\s+(\\S+):";
 221 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 222 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 223 $section_type = '@progbits';
 224 $mcount_adjust = 0;
 225 $type = ".long";
 226
 227 if ($arch eq "x86_64") {
 228     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 229     $type = ".quad";
 230     $alignment = 8;
 231     $mcount_adjust = -1;
 232
 233     # force flags for this arch
 234     $ld .= " -m elf_x86_64";
 235     $objdump .= " -M x86-64";
 236     $objcopy .= " -O elf64-x86-64";
 237     $cc .= " -m64";
 238
 239 } elsif ($arch eq "i386") {
 240     $alignment = 4;
 241     $mcount_adjust = -1;
 242
 243     # force flags for this arch
 244     $ld .= " -m elf_i386";
 245     $objdump .= " -M i386";
 246     $objcopy .= " -O elf32-i386";
 247     $cc .= " -m32";
 248
 249 } elsif ($arch eq "s390" && $bits == 64) {
 250     if ($cc =~ /-DCC_USING_HOTPATCH/) {
 251         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$";
 252         $mcount_adjust = 0;
 253     } else {
 254         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 255         $mcount_adjust = -14;
 256     }
 257     $alignment = 8;
 258     $type = ".quad";
 259     $ld .= " -m elf64_s390";
 260     $cc .= " -m64";
 261
 262 } elsif ($arch eq "sh") {
 263     $alignment = 2;
 264
 265     # force flags for this arch
 266     $ld .= " -m shlelf_linux";
 267     if ($endian eq "big") {
 268         $objcopy .= " -O elf32-shbig-linux";
 269     } else {
 270         $objcopy .= " -O elf32-sh-linux";
 271     }
 272
 273 } elsif ($arch eq "powerpc") {
 274     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 275     # See comment in the sparc64 section for why we use '\w'.
 276     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
 277     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 278
 279     if ($bits == 64) {
 280         $type = ".quad";
 281     }
 282
 283 } elsif ($arch eq "arm") {
 284     $alignment = 2;
 285     $section_type = '%progbits';
 286     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 287                         "\\s+(__gnu_mcount_nc|mcount)\$";
 288
 289 } elsif ($arch eq "arm64") {
 290     $alignment = 3;
 291     $section_type = '%progbits';
 292     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 293     $type = ".quad";
 294 } elsif ($arch eq "ia64") {
 295     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 296     $type = "data8";
 297
 298     if ($is_module eq "0") {
 299         $cc .= " -mconstant-gp";
 300     }
 301 } elsif ($arch eq "sparc64") {
 302     # In the objdump output there are giblets like:
 303     # 0000000000000000 <igmp_net_exit-0x18>:
 304     # As there's some data blobs that get emitted into the
 305     # text section before the first instructions and the first
 306     # real symbols.  We don't want to match that, so to combat
 307     # this we use '\w' so we'll match just plain symbol names,
 308     # and not those that also include hex offsets inside of the
 309     # '<>' brackets.  Actually the generic function_regex setting
 310     # could safely use this too.
 311     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 312
 313     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 314     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 315
 316     $alignment = 8;
 317     $type = ".xword";
 318     $ld .= " -m elf64_sparc";
 319     $cc .= " -m64";
 320     $objcopy .= " -O elf64-sparc";
 321 } elsif ($arch eq "mips") {
 322     # To enable module support, we need to enable the -mlong-calls option
 323     # of gcc for module, after using this option, we can not get the real
 324     # offset of the calling to _mcount, but the offset of the lui
 325     # instruction or the addiu one. herein, we record the address of the
 326     # first one, and then we can replace this instruction by a branch
 327     # instruction to jump over the profiling function to filter the
 328     # indicated functions, or swith back to the lui instruction to trace
 329     # them, which means dynamic tracing.
 330     #
 331     #       c:  3c030000        lui     v1,0x0
 332     #                   c: R_MIPS_HI16  _mcount
 333     #                   c: R_MIPS_NONE  *ABS*
 334     #                   c: R_MIPS_NONE  *ABS*
 335     #      10:  64630000        daddiu  v1,v1,0
 336     #                   10: R_MIPS_LO16 _mcount
 337     #                   10: R_MIPS_NONE *ABS*
 338     #                   10: R_MIPS_NONE *ABS*
 339     #      14:  03e0082d        move    at,ra
 340     #      18:  0060f809        jalr    v1
 341     #
 342     # for the kernel:
 343     #
 344     #     10:   03e0082d        move    at,ra
 345     #     14:   0c000000        jal     0 <loongson_halt>
 346     #                    14: R_MIPS_26   _mcount
 347     #                    14: R_MIPS_NONE *ABS*
 348     #                    14: R_MIPS_NONE *ABS*
 349     #    18:   00020021        nop
 350     if ($is_module eq "0") {
 351             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 352     } else {
 353             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 354     }
 355     $objdump .= " -Melf-trad".$endian."mips ";
 356
 357     if ($endian eq "big") {
 358             $endian = " -EB ";
 359             $ld .= " -melf".$bits."btsmip";
 360     } else {
 361             $endian = " -EL ";
 362             $ld .= " -melf".$bits."ltsmip";
 363     }
 364
 365     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 366     $ld .= $endian;
 367
 368     if ($bits == 64) {
 369             $function_regex =
 370                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 371             $type = ".dword";
 372     }
 373 } elsif ($arch eq "microblaze") {
 374     # Microblaze calls '_mcount' instead of plain 'mcount'.
 375     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 376 } elsif ($arch eq "blackfin") {
 377     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 378     $mcount_adjust = -4;
 379 } elsif ($arch eq "tilegx" || $arch eq "tile") {
 380     # Default to the newer TILE-Gx architecture if only "tile" is given.
 381     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 382     $type = ".quad";
 383     $alignment = 8;
 384 } else {
 385     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 386 }
 387
 388 my $text_found = 0;
 389 my $read_function = 0;
 390 my $opened = 0;
 391 my $mcount_section = "__mcount_loc";
 392
 393 my $dirname;
 394 my $filename;
 395 my $prefix;
 396 my $ext;
 397
 398 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 399     $dirname = $1;
 400     $filename = $2;
 401 } else {
 402     $dirname = ".";
 403     $filename = $inputfile;
 404 }
 405
 406 if ($filename =~ m,^(.*)(\.\S),) {
 407     $prefix = $1;
 408     $ext = $2;
 409 } else {
 410     $prefix = $filename;
 411     $ext = "";
 412 }
 413
 414 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 415 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 416
 417 check_objcopy();
 418
 419 #
 420 # Step 1: find all the local (static functions) and weak symbols.
 421 #         't' is local, 'w/W' is weak
 422 #
 423 open (IN, "$nm $inputfile|") || die "error running $nm";
 424 while (<IN>) {
 425     if (/$local_regex/) {
 426         $locals{$1} = 1;
 427     } elsif (/$weak_regex/) {
 428         $weak{$2} = $1;
 429     }
 430 }
 431 close(IN);
 432
 433 my @offsets;            # Array of offsets of mcount callers
 434 my $ref_func;           # reference function to use for offsets
 435 my $offset = 0;         # offset of ref_func to section beginning
 436
 437 ##
 438 # update_funcs - print out the current mcount callers
 439 #
 440 #  Go through the list of offsets to callers and write them to
 441 #  the output file in a format that can be read by an assembler.
 442 #
 443 sub update_funcs
 444 {
 445     return unless ($ref_func and @offsets);
 446
 447     # Sanity check on weak function. A weak function may be overwritten by
 448     # another function of the same name, making all these offsets incorrect.
 449     if (defined $weak{$ref_func}) {
 450         die "$inputfile: ERROR: referencing weak function" .
 451             " $ref_func for mcount\n";
 452     }
 453
 454     # is this function static? If so, note this fact.
 455     if (defined $locals{$ref_func}) {
 456
 457         # only use locals if objcopy supports globalize-symbols
 458         if (!$can_use_local) {
 459             return;
 460         }
 461         $convert{$ref_func} = 1;
 462     }
 463
 464     # Loop through all the mcount caller offsets and print a reference
 465     # to the caller based from the ref_func.
 466     if (!$opened) {
 467         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 468         $opened = 1;
 469         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 470         print FILE "\t.align $alignment\n" if (defined($alignment));
 471     }
 472     foreach my $cur_offset (@offsets) {
 473         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 474     }
 475 }
 476
 477 #
 478 # Step 2: find the sections and mcount call sites
 479 #
 480 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 481
 482 my $text;
 483
 484
 485 # read headers first
 486 my $read_headers = 1;
 487
 488 while (<IN>) {
 489
 490     if ($read_headers && /$mcount_section/) {
 491         #
 492         # Somehow the make process can execute this script on an
 493         # object twice. If it does, we would duplicate the mcount
 494         # section and it will cause the function tracer self test
 495         # to fail. Check if the mcount section exists, and if it does,
 496         # warn and exit.
 497         #
 498         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 499             "\tThis may be an indication that your build is corrupted.\n" .
 500             "\tDelete $inputfile and try again. If the same object file\n" .
 501             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 502         exit(-1);
 503     }
 504
 505     # is it a section?
 506     if (/$section_regex/) {
 507         $read_headers = 0;
 508
 509         # Only record text sections that we know are safe
 510         $read_function = defined($text_sections{$1});
 511         if (!$read_function) {
 512             foreach my $prefix (keys %text_section_prefixes) {
 513                 if (substr($1, 0, length $prefix) eq $prefix) {
 514                     $read_function = 1;
 515                     last;
 516                 }
 517             }
 518         }
 519         # print out any recorded offsets
 520         update_funcs();
 521
 522         # reset all markers and arrays
 523         $text_found = 0;
 524         undef($ref_func);
 525         undef(@offsets);
 526
 527     # section found, now is this a start of a function?
 528     } elsif ($read_function && /$function_regex/) {
 529         $text_found = 1;
 530         $text = $2;
 531
 532         # if this is either a local function or a weak function
 533         # keep looking for functions that are global that
 534         # we can use safely.
 535         if (!defined($locals{$text}) && !defined($weak{$text})) {
 536             $ref_func = $text;
 537             $read_function = 0;
 538             $offset = hex $1;
 539         } else {
 540             # if we already have a function, and this is weak, skip it
 541             if (!defined($ref_func) && !defined($weak{$text}) &&
 542                  # PPC64 can have symbols that start with .L and
 543                  # gcc considers these special. Don't use them!
 544                  $text !~ /^\.L/) {
 545                 $ref_func = $text;
 546                 $offset = hex $1;
 547             }
 548         }
 549     }
 550     # is this a call site to mcount? If so, record it to print later
 551     if ($text_found && /$mcount_regex/) {
 552         push(@offsets, (hex $1) + $mcount_adjust);
 553     }
 554 }
 555
 556 # dump out anymore offsets that may have been found
 557 update_funcs();
 558
 559 # If we did not find any mcount callers, we are done (do nothing).
 560 if (!$opened) {
 561     exit(0);
 562 }
 563
 564 close(FILE);
 565
 566 #
 567 # Step 3: Compile the file that holds the list of call sites to mcount.
 568 #
 569 `$cc -o $mcount_o -c $mcount_s`;
 570
 571 my @converts = keys %convert;
 572
 573 #
 574 # Step 4: Do we have sections that started with local functions?
 575 #
 576 if ($#converts >= 0) {
 577     my $globallist = "";
 578     my $locallist = "";
 579
 580     foreach my $con (@converts) {
 581         $globallist .= " --globalize-symbol $con";
 582         $locallist .= " --localize-symbol $con";
 583     }
 584
 585     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 586     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 587
 588     #
 589     # Step 5: set up each local function as a global
 590     #
 591     `$objcopy $globallist $inputfile $globalobj`;
 592
 593     #
 594     # Step 6: Link the global version to our list.
 595     #
 596     `$ld -r $globalobj $mcount_o -o $globalmix`;
 597
 598     #
 599     # Step 7: Convert the local functions back into local symbols
 600     #
 601     `$objcopy $locallist $globalmix $inputfile`;
 602
 603     # Remove the temp files
 604     `$rm $globalobj $globalmix`;
 605
 606 } else {
 607
 608     my $mix = $dirname . "/.tmp_mx_" . $filename;
 609
 610     #
 611     # Step 8: Link the object with our list of call sites object.
 612     #
 613     `$ld -r $inputfile $mcount_o -o $mix`;
 614
 615     #
 616     # Step 9: Move the result back to the original object.
 617     #
 618     `$mv $mix $inputfile`;
 619 }
 620
 621 # Clean up the temp files
 622 `$rm $mcount_o $mcount_s`;
 623
 624 exit(0);