scripts/module.lds.S

   1 /*
   2  * Common module linker script, always used when linking a module.
   3  * Archs are free to supply their own linker scripts.  ld will
   4  * combine them automatically.
   5  */
   6 SECTIONS {
   7         /DISCARD/ : {
   8                 *(.discard)
   9                 *(.discard.*)
  10         }
  11
  12         __ksymtab               0 : { *(SORT(___ksymtab+*)) }
  13         __ksymtab_gpl           0 : { *(SORT(___ksymtab_gpl+*)) }
  14         __ksymtab_unused        0 : { *(SORT(___ksymtab_unused+*)) }
  15         __ksymtab_unused_gpl    0 : { *(SORT(___ksymtab_unused_gpl+*)) }
  16         __ksymtab_gpl_future    0 : { *(SORT(___ksymtab_gpl_future+*)) }
  17         __kcrctab               0 : { *(SORT(___kcrctab+*)) }
  18         __kcrctab_gpl           0 : { *(SORT(___kcrctab_gpl+*)) }
  19         __kcrctab_unused        0 : { *(SORT(___kcrctab_unused+*)) }
  20         __kcrctab_unused_gpl    0 : { *(SORT(___kcrctab_unused_gpl+*)) }
  21         __kcrctab_gpl_future    0 : { *(SORT(___kcrctab_gpl_future+*)) }
  22
  23         .init_array             0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) }
  24
  25         .altinstructions        0 : ALIGN(8) { KEEP(*(.altinstructions)) }
  26         __bug_table             0 : ALIGN(8) { KEEP(*(__bug_table)) }
  27         __jump_table            0 : ALIGN(8) { KEEP(*(__jump_table)) }
  28
  29         __patchable_function_entries : { *(__patchable_function_entries) }
  30
  31 #ifdef CONFIG_LTO_CLANG
  32         /*
  33          * With CONFIG_LTO_CLANG, LLD always enables -fdata-sections and
  34          * -ffunction-sections, which increases the size of the final module.
  35          * Merge the split sections in the final binary.
  36          */
  37         .bss : {
  38                 *(.bss .bss.[0-9a-zA-Z_]*)
  39                 *(.bss..L*)
  40         }
  41
  42         .data : {
  43                 *(.data .data.[0-9a-zA-Z_]*)
  44                 *(.data..L*)
  45         }
  46
  47         .rodata : {
  48                 *(.rodata .rodata.[0-9a-zA-Z_]*)
  49                 *(.rodata..L*)
  50         }
  51
  52         .text : { *(.text .text.[0-9a-zA-Z_]*) }
  53 #endif
  54 }
  55
  56 /* bring in arch-specific sections */
  57 #include <asm/module.lds.h>