scripts/kconfig/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 extern int zconflex(void);
  24 static void zconfprint(const char *err, ...);
  25 static void zconf_error(const char *err, ...);
  26 static void zconferror(const char *err);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 30
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80
  81 %left T_OR
  82 %left T_AND
  83 %left T_EQUAL T_UNEQUAL
  84 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  85 %nonassoc T_NOT
  86
  87 %type <string> prompt
  88 %type <symbol> symbol
  89 %type <expr> expr
  90 %type <expr> if_expr
  91 %type <id> end
  92 %type <id> option_name
  93 %type <menu> if_entry menu_entry choice_entry
  94 %type <string> symbol_option_arg word_opt
  95
  96 %destructor {
  97         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  98                 $$->file->name, $$->lineno);
  99         if (current_menu == $$)
 100                 menu_end_menu();
 101 } if_entry menu_entry choice_entry
 102
 103 %{
 104 /* Include zconf_id.c here so it can see the token constants. */
 105 #include "kconf_id.c"
 106 %}
 107
 108 %%
 109 input: nl start | start;
 110
 111 start: mainmenu_stmt stmt_list | no_mainmenu_stmt stmt_list;
 112
 113 /* mainmenu entry */
 114
 115 mainmenu_stmt: T_MAINMENU prompt T_EOL
 116 {
 117         menu_add_prompt(P_MENU, $2, NULL);
 118 };
 119
 120 /* Default main menu, if there's no mainmenu entry */
 121
 122 no_mainmenu_stmt: /* empty */
 123 {
 124         /*
 125          * Hack: Keep the main menu title on the heap so we can safely free it
 126          * later regardless of whether it comes from the 'prompt' in
 127          * mainmenu_stmt or here
 128          */
 129         menu_add_prompt(P_MENU, strdup("Linux Kernel Configuration"), NULL);
 130 };
 131
 132
 133 stmt_list:
 134           /* empty */
 135         | stmt_list common_stmt
 136         | stmt_list choice_stmt
 137         | stmt_list menu_stmt
 138         | stmt_list end                 { zconf_error("unexpected end statement"); }
 139         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 140         | stmt_list option_name error T_EOL
 141 {
 142         zconf_error("unexpected option \"%s\"", $2->name);
 143 }
 144         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 145 ;
 146
 147 option_name:
 148         T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
 149 ;
 150
 151 common_stmt:
 152           T_EOL
 153         | if_stmt
 154         | comment_stmt
 155         | config_stmt
 156         | menuconfig_stmt
 157         | source_stmt
 158 ;
 159
 160 option_error:
 161           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 162         | error T_EOL                   { zconf_error("invalid option"); }
 163 ;
 164
 165
 166 /* config/menuconfig entry */
 167
 168 config_entry_start: T_CONFIG T_WORD T_EOL
 169 {
 170         struct symbol *sym = sym_lookup($2, 0);
 171         sym->flags |= SYMBOL_OPTIONAL;
 172         menu_add_entry(sym);
 173         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2);
 174 };
 175
 176 config_stmt: config_entry_start config_option_list
 177 {
 178         menu_end_entry();
 179         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 180 };
 181
 182 menuconfig_entry_start: T_MENUCONFIG T_WORD T_EOL
 183 {
 184         struct symbol *sym = sym_lookup($2, 0);
 185         sym->flags |= SYMBOL_OPTIONAL;
 186         menu_add_entry(sym);
 187         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2);
 188 };
 189
 190 menuconfig_stmt: menuconfig_entry_start config_option_list
 191 {
 192         if (current_entry->prompt)
 193                 current_entry->prompt->type = P_MENU;
 194         else
 195                 zconfprint("warning: menuconfig statement without prompt");
 196         menu_end_entry();
 197         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 198 };
 199
 200 config_option_list:
 201           /* empty */
 202         | config_option_list config_option
 203         | config_option_list symbol_option
 204         | config_option_list depends
 205         | config_option_list help
 206         | config_option_list option_error
 207         | config_option_list T_EOL
 208 ;
 209
 210 config_option: T_TYPE prompt_stmt_opt T_EOL
 211 {
 212         menu_set_type($1->stype);
 213         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 214                 zconf_curname(), zconf_lineno(),
 215                 $1->stype);
 216 };
 217
 218 config_option: T_PROMPT prompt if_expr T_EOL
 219 {
 220         menu_add_prompt(P_PROMPT, $2, $3);
 221         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 222 };
 223
 224 config_option: T_DEFAULT expr if_expr T_EOL
 225 {
 226         menu_add_expr(P_DEFAULT, $2, $3);
 227         if ($1->stype != S_UNKNOWN)
 228                 menu_set_type($1->stype);
 229         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 230                 zconf_curname(), zconf_lineno(),
 231                 $1->stype);
 232 };
 233
 234 config_option: T_SELECT T_WORD if_expr T_EOL
 235 {
 236         menu_add_symbol(P_SELECT, sym_lookup($2, 0), $3);
 237         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 238 };
 239
 240 config_option: T_IMPLY T_WORD if_expr T_EOL
 241 {
 242         menu_add_symbol(P_IMPLY, sym_lookup($2, 0), $3);
 243         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 244 };
 245
 246 config_option: T_RANGE symbol symbol if_expr T_EOL
 247 {
 248         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 249         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 250 };
 251
 252 symbol_option: T_OPTION symbol_option_list T_EOL
 253 ;
 254
 255 symbol_option_list:
 256           /* empty */
 257         | symbol_option_list T_WORD symbol_option_arg
 258 {
 259         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 260         if (id && id->flags & TF_OPTION)
 261                 menu_add_option(id->token, $3);
 262         else
 263                 zconfprint("warning: ignoring unknown option %s", $2);
 264         free($2);
 265 };
 266
 267 symbol_option_arg:
 268           /* empty */           { $$ = NULL; }
 269         | T_EQUAL prompt        { $$ = $2; }
 270 ;
 271
 272 /* choice entry */
 273
 274 choice: T_CHOICE word_opt T_EOL
 275 {
 276         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 277         sym->flags |= SYMBOL_AUTO;
 278         menu_add_entry(sym);
 279         menu_add_expr(P_CHOICE, NULL, NULL);
 280         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 281 };
 282
 283 choice_entry: choice choice_option_list
 284 {
 285         $$ = menu_add_menu();
 286 };
 287
 288 choice_end: end
 289 {
 290         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 291                 menu_end_menu();
 292                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 293         }
 294 };
 295
 296 choice_stmt: choice_entry choice_block choice_end
 297 ;
 298
 299 choice_option_list:
 300           /* empty */
 301         | choice_option_list choice_option
 302         | choice_option_list depends
 303         | choice_option_list help
 304         | choice_option_list T_EOL
 305         | choice_option_list option_error
 306 ;
 307
 308 choice_option: T_PROMPT prompt if_expr T_EOL
 309 {
 310         menu_add_prompt(P_PROMPT, $2, $3);
 311         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 312 };
 313
 314 choice_option: T_TYPE prompt_stmt_opt T_EOL
 315 {
 316         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 317                 menu_set_type($1->stype);
 318                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 319                         zconf_curname(), zconf_lineno(),
 320                         $1->stype);
 321         } else
 322                 YYERROR;
 323 };
 324
 325 choice_option: T_OPTIONAL T_EOL
 326 {
 327         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 328         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 329 };
 330
 331 choice_option: T_DEFAULT T_WORD if_expr T_EOL
 332 {
 333         if ($1->stype == S_UNKNOWN) {
 334                 menu_add_symbol(P_DEFAULT, sym_lookup($2, 0), $3);
 335                 printd(DEBUG_PARSE, "%s:%d:default\n",
 336                         zconf_curname(), zconf_lineno());
 337         } else
 338                 YYERROR;
 339 };
 340
 341 choice_block:
 342           /* empty */
 343         | choice_block common_stmt
 344 ;
 345
 346 /* if entry */
 347
 348 if_entry: T_IF expr T_EOL
 349 {
 350         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 351         menu_add_entry(NULL);
 352         menu_add_dep($2);
 353         $$ = menu_add_menu();
 354 };
 355
 356 if_end: end
 357 {
 358         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 359                 menu_end_menu();
 360                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 361         }
 362 };
 363
 364 if_stmt: if_entry if_block if_end
 365 ;
 366
 367 if_block:
 368           /* empty */
 369         | if_block common_stmt
 370         | if_block menu_stmt
 371         | if_block choice_stmt
 372 ;
 373
 374 /* menu entry */
 375
 376 menu: T_MENU prompt T_EOL
 377 {
 378         menu_add_entry(NULL);
 379         menu_add_prompt(P_MENU, $2, NULL);
 380         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 381 };
 382
 383 menu_entry: menu visibility_list depends_list
 384 {
 385         $$ = menu_add_menu();
 386 };
 387
 388 menu_end: end
 389 {
 390         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 391                 menu_end_menu();
 392                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 393         }
 394 };
 395
 396 menu_stmt: menu_entry menu_block menu_end
 397 ;
 398
 399 menu_block:
 400           /* empty */
 401         | menu_block common_stmt
 402         | menu_block menu_stmt
 403         | menu_block choice_stmt
 404 ;
 405
 406 source_stmt: T_SOURCE prompt T_EOL
 407 {
 408         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 409         zconf_nextfile($2);
 410 };
 411
 412 /* comment entry */
 413
 414 comment: T_COMMENT prompt T_EOL
 415 {
 416         menu_add_entry(NULL);
 417         menu_add_prompt(P_COMMENT, $2, NULL);
 418         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 419 };
 420
 421 comment_stmt: comment depends_list
 422 {
 423         menu_end_entry();
 424 };
 425
 426 /* help option */
 427
 428 help_start: T_HELP T_EOL
 429 {
 430         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 431         zconf_starthelp();
 432 };
 433
 434 help: help_start T_HELPTEXT
 435 {
 436         current_entry->help = $2;
 437 };
 438
 439 /* depends option */
 440
 441 depends_list:
 442           /* empty */
 443         | depends_list depends
 444         | depends_list T_EOL
 445         | depends_list option_error
 446 ;
 447
 448 depends: T_DEPENDS T_ON expr T_EOL
 449 {
 450         menu_add_dep($3);
 451         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 452 };
 453
 454 /* visibility option */
 455
 456 visibility_list:
 457           /* empty */
 458         | visibility_list visible
 459         | visibility_list T_EOL
 460 ;
 461
 462 visible: T_VISIBLE if_expr
 463 {
 464         menu_add_visibility($2);
 465 };
 466
 467 /* prompt statement */
 468
 469 prompt_stmt_opt:
 470           /* empty */
 471         | prompt if_expr
 472 {
 473         menu_add_prompt(P_PROMPT, $1, $2);
 474 };
 475
 476 prompt:   T_WORD
 477         | T_WORD_QUOTE
 478 ;
 479
 480 end:      T_ENDMENU T_EOL       { $$ = $1; }
 481         | T_ENDCHOICE T_EOL     { $$ = $1; }
 482         | T_ENDIF T_EOL         { $$ = $1; }
 483 ;
 484
 485 nl:
 486           T_EOL
 487         | nl T_EOL
 488 ;
 489
 490 if_expr:  /* empty */                   { $$ = NULL; }
 491         | T_IF expr                     { $$ = $2; }
 492 ;
 493
 494 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 495         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 496         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 497         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 498         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 499         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 500         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 501         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 502         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 503         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 504         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 505 ;
 506
 507 symbol:   T_WORD        { $$ = sym_lookup($1, 0); free($1); }
 508         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 509 ;
 510
 511 word_opt: /* empty */                   { $$ = NULL; }
 512         | T_WORD
 513
 514 %%
 515
 516 void conf_parse(const char *name)
 517 {
 518         const char *tmp;
 519         struct symbol *sym;
 520         int i;
 521
 522         zconf_initscan(name);
 523
 524         sym_init();
 525         _menu_init();
 526
 527         if (getenv("ZCONF_DEBUG"))
 528                 zconfdebug = 1;
 529         zconfparse();
 530         if (zconfnerrs)
 531                 exit(1);
 532         if (!modules_sym)
 533                 modules_sym = sym_find( "n" );
 534
 535         tmp = rootmenu.prompt->text;
 536         rootmenu.prompt->text = _(rootmenu.prompt->text);
 537         rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
 538         free((char*)tmp);
 539
 540         menu_finalize(&rootmenu);
 541         for_all_symbols(i, sym) {
 542                 if (sym_check_deps(sym))
 543                         zconfnerrs++;
 544         }
 545         if (zconfnerrs)
 546                 exit(1);
 547         sym_set_change_count(1);
 548 }
 549
 550 static const char *zconf_tokenname(int token)
 551 {
 552         switch (token) {
 553         case T_MENU:            return "menu";
 554         case T_ENDMENU:         return "endmenu";
 555         case T_CHOICE:          return "choice";
 556         case T_ENDCHOICE:       return "endchoice";
 557         case T_IF:              return "if";
 558         case T_ENDIF:           return "endif";
 559         case T_DEPENDS:         return "depends";
 560         case T_VISIBLE:         return "visible";
 561         }
 562         return "<token>";
 563 }
 564
 565 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 566 {
 567         if (id->token != endtoken) {
 568                 zconf_error("unexpected '%s' within %s block",
 569                         id->name, zconf_tokenname(starttoken));
 570                 zconfnerrs++;
 571                 return false;
 572         }
 573         if (current_menu->file != current_file) {
 574                 zconf_error("'%s' in different file than '%s'",
 575                         id->name, zconf_tokenname(starttoken));
 576                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 577                         current_menu->file->name, current_menu->lineno,
 578                         zconf_tokenname(starttoken));
 579                 zconfnerrs++;
 580                 return false;
 581         }
 582         return true;
 583 }
 584
 585 static void zconfprint(const char *err, ...)
 586 {
 587         va_list ap;
 588
 589         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 590         va_start(ap, err);
 591         vfprintf(stderr, err, ap);
 592         va_end(ap);
 593         fprintf(stderr, "\n");
 594 }
 595
 596 static void zconf_error(const char *err, ...)
 597 {
 598         va_list ap;
 599
 600         zconfnerrs++;
 601         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 602         va_start(ap, err);
 603         vfprintf(stderr, err, ap);
 604         va_end(ap);
 605         fprintf(stderr, "\n");
 606 }
 607
 608 static void zconferror(const char *err)
 609 {
 610         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 611 }
 612
 613 static void print_quoted_string(FILE *out, const char *str)
 614 {
 615         const char *p;
 616         int len;
 617
 618         putc('"', out);
 619         while ((p = strchr(str, '"'))) {
 620                 len = p - str;
 621                 if (len)
 622                         fprintf(out, "%.*s", len, str);
 623                 fputs("\\\"", out);
 624                 str = p + 1;
 625         }
 626         fputs(str, out);
 627         putc('"', out);
 628 }
 629
 630 static void print_symbol(FILE *out, struct menu *menu)
 631 {
 632         struct symbol *sym = menu->sym;
 633         struct property *prop;
 634
 635         if (sym_is_choice(sym))
 636                 fprintf(out, "\nchoice\n");
 637         else
 638                 fprintf(out, "\nconfig %s\n", sym->name);
 639         switch (sym->type) {
 640         case S_BOOLEAN:
 641                 fputs("  boolean\n", out);
 642                 break;
 643         case S_TRISTATE:
 644                 fputs("  tristate\n", out);
 645                 break;
 646         case S_STRING:
 647                 fputs("  string\n", out);
 648                 break;
 649         case S_INT:
 650                 fputs("  integer\n", out);
 651                 break;
 652         case S_HEX:
 653                 fputs("  hex\n", out);
 654                 break;
 655         default:
 656                 fputs("  ???\n", out);
 657                 break;
 658         }
 659         for (prop = sym->prop; prop; prop = prop->next) {
 660                 if (prop->menu != menu)
 661                         continue;
 662                 switch (prop->type) {
 663                 case P_PROMPT:
 664                         fputs("  prompt ", out);
 665                         print_quoted_string(out, prop->text);
 666                         if (!expr_is_yes(prop->visible.expr)) {
 667                                 fputs(" if ", out);
 668                                 expr_fprint(prop->visible.expr, out);
 669                         }
 670                         fputc('\n', out);
 671                         break;
 672                 case P_DEFAULT:
 673                         fputs( "  default ", out);
 674                         expr_fprint(prop->expr, out);
 675                         if (!expr_is_yes(prop->visible.expr)) {
 676                                 fputs(" if ", out);
 677                                 expr_fprint(prop->visible.expr, out);
 678                         }
 679                         fputc('\n', out);
 680                         break;
 681                 case P_CHOICE:
 682                         fputs("  #choice value\n", out);
 683                         break;
 684                 case P_SELECT:
 685                         fputs( "  select ", out);
 686                         expr_fprint(prop->expr, out);
 687                         fputc('\n', out);
 688                         break;
 689                 case P_IMPLY:
 690                         fputs( "  imply ", out);
 691                         expr_fprint(prop->expr, out);
 692                         fputc('\n', out);
 693                         break;
 694                 case P_RANGE:
 695                         fputs( "  range ", out);
 696                         expr_fprint(prop->expr, out);
 697                         fputc('\n', out);
 698                         break;
 699                 case P_MENU:
 700                         fputs( "  menu ", out);
 701                         print_quoted_string(out, prop->text);
 702                         fputc('\n', out);
 703                         break;
 704                 default:
 705                         fprintf(out, "  unknown prop %d!\n", prop->type);
 706                         break;
 707                 }
 708         }
 709         if (menu->help) {
 710                 int len = strlen(menu->help);
 711                 while (menu->help[--len] == '\n')
 712                         menu->help[len] = 0;
 713                 fprintf(out, "  help\n%s\n", menu->help);
 714         }
 715 }
 716
 717 void zconfdump(FILE *out)
 718 {
 719         struct property *prop;
 720         struct symbol *sym;
 721         struct menu *menu;
 722
 723         menu = rootmenu.list;
 724         while (menu) {
 725                 if ((sym = menu->sym))
 726                         print_symbol(out, menu);
 727                 else if ((prop = menu->prompt)) {
 728                         switch (prop->type) {
 729                         case P_COMMENT:
 730                                 fputs("\ncomment ", out);
 731                                 print_quoted_string(out, prop->text);
 732                                 fputs("\n", out);
 733                                 break;
 734                         case P_MENU:
 735                                 fputs("\nmenu ", out);
 736                                 print_quoted_string(out, prop->text);
 737                                 fputs("\n", out);
 738                                 break;
 739                         default:
 740                                 ;
 741                         }
 742                         if (!expr_is_yes(prop->visible.expr)) {
 743                                 fputs("  depends ", out);
 744                                 expr_fprint(prop->visible.expr, out);
 745                                 fputc('\n', out);
 746                         }
 747                 }
 748
 749                 if (menu->list)
 750                         menu = menu->list;
 751                 else if (menu->next)
 752                         menu = menu->next;
 753                 else while ((menu = menu->parent)) {
 754                         if (menu->prompt && menu->prompt->type == P_MENU)
 755                                 fputs("\nendmenu\n", out);
 756                         if (menu->next) {
 757                                 menu = menu->next;
 758                                 break;
 759                         }
 760                 }
 761         }
 762 }
 763
 764 #include "zconf.lex.c"
 765 #include "util.c"
 766 #include "confdata.c"
 767 #include "expr.c"
 768 #include "symbol.c"
 769 #include "menu.c"