s390/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /* ld script to make s390 Linux kernel
   3  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   4  */
   5
   6 #include <asm/thread_info.h>
   7 #include <asm/page.h>
   8 #include <asm/ftrace.lds.h>
   9
  10 /*
  11  * Put .bss..swapper_pg_dir as the first thing in .bss. This will
  12  * make sure it has 16k alignment.
  13  */
  14 #define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir) \
  15                            *(.bss..invalid_pg_dir)
  16
  17 /* Handle ro_after_init data on our own. */
  18 #define RO_AFTER_INIT_DATA
  19
  20 #define RUNTIME_DISCARD_EXIT
  21
  22 #define EMITS_PT_NOTE
  23
  24 #include <asm-generic/vmlinux.lds.h>
  25 #include <asm/vmlinux.lds.h>
  26
  27 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  28 OUTPUT_ARCH(s390:64-bit)
  29 ENTRY(startup_continue)
  30 jiffies = jiffies_64;
  31
  32 PHDRS {
  33         text PT_LOAD FLAGS(5);  /* R_E */
  34         data PT_LOAD FLAGS(7);  /* RWE */
  35         note PT_NOTE FLAGS(0);  /* ___ */
  36 }
  37
  38 SECTIONS
  39 {
  40         . = 0x100000;
  41         .text : {
  42                 _stext = .;             /* Start of text section */
  43                 _text = .;              /* Text and read-only data */
  44                 HEAD_TEXT
  45                 TEXT_TEXT
  46                 SCHED_TEXT
  47                 CPUIDLE_TEXT
  48                 LOCK_TEXT
  49                 KPROBES_TEXT
  50                 IRQENTRY_TEXT
  51                 SOFTIRQENTRY_TEXT
  52                 FTRACE_HOTPATCH_TRAMPOLINES_TEXT
  53                 *(.text.*_indirect_*)
  54                 *(.gnu.warning)
  55                 . = ALIGN(PAGE_SIZE);
  56                 _etext = .;             /* End of text section */
  57         } :text = 0x0700
  58
  59         RO_DATA(PAGE_SIZE)
  60
  61         . = ALIGN(PAGE_SIZE);
  62         _sdata = .;             /* Start of data section */
  63
  64         . = ALIGN(PAGE_SIZE);
  65         __start_ro_after_init = .;
  66         .data..ro_after_init : {
  67                  *(.data..ro_after_init)
  68                 JUMP_TABLE_DATA
  69         } :data
  70         EXCEPTION_TABLE(16)
  71         . = ALIGN(PAGE_SIZE);
  72         __end_ro_after_init = .;
  73
  74         RW_DATA(0x100, PAGE_SIZE, THREAD_SIZE)
  75         BOOT_DATA_PRESERVED
  76
  77         . = ALIGN(8);
  78         .amode31.refs : {
  79                 _start_amode31_refs = .;
  80                 *(.amode31.refs)
  81                 _end_amode31_refs = .;
  82         }
  83
  84         . = ALIGN(PAGE_SIZE);
  85         _edata = .;             /* End of data section */
  86
  87         /* will be freed after init */
  88         . = ALIGN(PAGE_SIZE);   /* Init code and data */
  89         __init_begin = .;
  90
  91         . = ALIGN(PAGE_SIZE);
  92         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  93                 _sinittext = .;
  94                 INIT_TEXT
  95                 . = ALIGN(PAGE_SIZE);
  96                 _einittext = .;
  97         }
  98
  99         /*
 100          * .exit.text is discarded at runtime, not link time,
 101          * to deal with references from __bug_table
 102         */
 103         .exit.text : {
 104                 EXIT_TEXT
 105         }
 106
 107         .exit.data : {
 108                 EXIT_DATA
 109         }
 110
 111         /*
 112          * struct alt_inst entries. From the header (alternative.h):
 113          * "Alternative instructions for different CPU types or capabilities"
 114          * Think locking instructions on spinlocks.
 115          * Note, that it is a part of __init region.
 116          */
 117         . = ALIGN(8);
 118         .altinstructions : {
 119                 __alt_instructions = .;
 120                 *(.altinstructions)
 121                 __alt_instructions_end = .;
 122         }
 123
 124         /*
 125          * And here are the replacement instructions. The linker sticks
 126          * them as binary blobs. The .altinstructions has enough data to
 127          * get the address and the length of them to patch the kernel safely.
 128          * Note, that it is a part of __init region.
 129          */
 130         .altinstr_replacement : {
 131                 *(.altinstr_replacement)
 132         }
 133
 134         /*
 135          * Table with the patch locations to undo expolines
 136         */
 137         . = ALIGN(4);
 138         .nospec_call_table : {
 139                 __nospec_call_start = . ;
 140                 *(.s390_indirect*)
 141                 __nospec_call_end = . ;
 142         }
 143         .nospec_return_table : {
 144                 __nospec_return_start = . ;
 145                 *(.s390_return*)
 146                 __nospec_return_end = . ;
 147         }
 148
 149         BOOT_DATA
 150
 151         /*
 152          * .amode31 section for code, data, ex_table that need to stay
 153          * below 2 GB, even when the kernel is relocated above 2 GB.
 154          */
 155         . = ALIGN(PAGE_SIZE);
 156         _samode31 = .;
 157         .amode31.text : {
 158                 _stext_amode31 = .;
 159                 *(.amode31.text)
 160                 *(.amode31.text.*_indirect_*)
 161                 . = ALIGN(PAGE_SIZE);
 162                 _etext_amode31 = .;
 163         }
 164         . = ALIGN(16);
 165         .amode31.ex_table : {
 166                 _start_amode31_ex_table = .;
 167                 KEEP(*(.amode31.ex_table))
 168                 _stop_amode31_ex_table = .;
 169         }
 170         . = ALIGN(PAGE_SIZE);
 171         .amode31.data : {
 172                 *(.amode31.data)
 173         }
 174         . = ALIGN(PAGE_SIZE);
 175         _eamode31 = .;
 176
 177         /* early.c uses stsi, which requires page aligned data. */
 178         . = ALIGN(PAGE_SIZE);
 179         INIT_DATA_SECTION(0x100)
 180
 181         PERCPU_SECTION(0x100)
 182
 183         .dynsym ALIGN(8) : {
 184                 __dynsym_start = .;
 185                 *(.dynsym)
 186                 __dynsym_end = .;
 187         }
 188         .rela.dyn ALIGN(8) : {
 189                 __rela_dyn_start = .;
 190                 *(.rela*)
 191                 __rela_dyn_end = .;
 192         }
 193
 194         . = ALIGN(PAGE_SIZE);
 195         __init_end = .;         /* freed after init ends here */
 196
 197         BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
 198
 199         . = ALIGN(PAGE_SIZE);
 200         _end = . ;
 201
 202         /*
 203          * uncompressed image info used by the decompressor
 204          * it should match struct vmlinux_info
 205          */
 206         .vmlinux.info 0 (INFO) : {
 207                 QUAD(_stext)                                    /* default_lma */
 208                 QUAD(startup_continue)                          /* entry */
 209                 QUAD(__bss_start - _stext)                      /* image_size */
 210                 QUAD(__bss_stop - __bss_start)                  /* bss_size */
 211                 QUAD(__boot_data_start)                         /* bootdata_off */
 212                 QUAD(__boot_data_end - __boot_data_start)       /* bootdata_size */
 213                 QUAD(__boot_data_preserved_start)               /* bootdata_preserved_off */
 214                 QUAD(__boot_data_preserved_end -
 215                      __boot_data_preserved_start)               /* bootdata_preserved_size */
 216                 QUAD(__dynsym_start)                            /* dynsym_start */
 217                 QUAD(__rela_dyn_start)                          /* rela_dyn_start */
 218                 QUAD(__rela_dyn_end)                            /* rela_dyn_end */
 219                 QUAD(_eamode31 - _samode31)                     /* amode31_size */
 220         } :NONE
 221
 222         /* Debugging sections.  */
 223         STABS_DEBUG
 224         DWARF_DEBUG
 225         ELF_DETAILS
 226
 227         /* Sections to be discarded */
 228         DISCARDS
 229         /DISCARD/ : {
 230                 *(.eh_frame)
 231                 *(.interp)
 232         }
 233 }