arch/x86/kernel/ftrace_64.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *  Copyright (C) 2014  Steven Rostedt, Red Hat Inc
   4  */
   5
   6 #include <linux/linkage.h>
   7 #include <asm/ptrace.h>
   8 #include <asm/ftrace.h>
   9 #include <asm/export.h>
  10 #include <asm/nospec-branch.h>
  11 #include <asm/unwind_hints.h>
  12 #include <asm/frame.h>
  13
  14         .code64
  15         .section .text, "ax"
  16
  17 #ifdef CONFIG_FRAME_POINTER
  18 /* Save parent and function stack frames (rip and rbp) */
  19 #  define MCOUNT_FRAME_SIZE     (8+16*2)
  20 #else
  21 /* No need to save a stack frame */
  22 # define MCOUNT_FRAME_SIZE      0
  23 #endif /* CONFIG_FRAME_POINTER */
  24
  25 /* Size of stack used to save mcount regs in save_mcount_regs */
  26 #define MCOUNT_REG_SIZE         (FRAME_SIZE + MCOUNT_FRAME_SIZE)
  27
  28 /*
  29  * gcc -pg option adds a call to 'mcount' in most functions.
  30  * When -mfentry is used, the call is to 'fentry' and not 'mcount'
  31  * and is done before the function's stack frame is set up.
  32  * They both require a set of regs to be saved before calling
  33  * any C code and restored before returning back to the function.
  34  *
  35  * On boot up, all these calls are converted into nops. When tracing
  36  * is enabled, the call can jump to either ftrace_caller or
  37  * ftrace_regs_caller. Callbacks (tracing functions) that require
  38  * ftrace_regs_caller (like kprobes) need to have pt_regs passed to
  39  * it. For this reason, the size of the pt_regs structure will be
  40  * allocated on the stack and the required mcount registers will
  41  * be saved in the locations that pt_regs has them in.
  42  */
  43
  44 /*
  45  * @added: the amount of stack added before calling this
  46  *
  47  * After this is called, the following registers contain:
  48  *
  49  *  %rdi - holds the address that called the trampoline
  50  *  %rsi - holds the parent function (traced function's return address)
  51  *  %rdx - holds the original %rbp
  52  */
  53 .macro save_mcount_regs added=0
  54
  55 #ifdef CONFIG_FRAME_POINTER
  56         /* Save the original rbp */
  57         pushq %rbp
  58
  59         /*
  60          * Stack traces will stop at the ftrace trampoline if the frame pointer
  61          * is not set up properly. If fentry is used, we need to save a frame
  62          * pointer for the parent as well as the function traced, because the
  63          * fentry is called before the stack frame is set up, where as mcount
  64          * is called afterward.
  65          */
  66
  67         /* Save the parent pointer (skip orig rbp and our return address) */
  68         pushq \added+8*2(%rsp)
  69         pushq %rbp
  70         movq %rsp, %rbp
  71         /* Save the return address (now skip orig rbp, rbp and parent) */
  72         pushq \added+8*3(%rsp)
  73         pushq %rbp
  74         movq %rsp, %rbp
  75 #endif /* CONFIG_FRAME_POINTER */
  76
  77         /*
  78          * We add enough stack to save all regs.
  79          */
  80         subq $(FRAME_SIZE), %rsp
  81         movq %rax, RAX(%rsp)
  82         movq %rcx, RCX(%rsp)
  83         movq %rdx, RDX(%rsp)
  84         movq %rsi, RSI(%rsp)
  85         movq %rdi, RDI(%rsp)
  86         movq %r8, R8(%rsp)
  87         movq %r9, R9(%rsp)
  88         movq $0, ORIG_RAX(%rsp)
  89         /*
  90          * Save the original RBP. Even though the mcount ABI does not
  91          * require this, it helps out callers.
  92          */
  93 #ifdef CONFIG_FRAME_POINTER
  94         movq MCOUNT_REG_SIZE-8(%rsp), %rdx
  95 #else
  96         movq %rbp, %rdx
  97 #endif
  98         movq %rdx, RBP(%rsp)
  99
 100         /* Copy the parent address into %rsi (second parameter) */
 101         movq MCOUNT_REG_SIZE+8+\added(%rsp), %rsi
 102
 103          /* Move RIP to its proper location */
 104         movq MCOUNT_REG_SIZE+\added(%rsp), %rdi
 105         movq %rdi, RIP(%rsp)
 106
 107         /*
 108          * Now %rdi (the first parameter) has the return address of
 109          * where ftrace_call returns. But the callbacks expect the
 110          * address of the call itself.
 111          */
 112         subq $MCOUNT_INSN_SIZE, %rdi
 113         .endm
 114
 115 .macro restore_mcount_regs save=0
 116
 117         /* ftrace_regs_caller or frame pointers require this */
 118         movq RBP(%rsp), %rbp
 119
 120         movq R9(%rsp), %r9
 121         movq R8(%rsp), %r8
 122         movq RDI(%rsp), %rdi
 123         movq RSI(%rsp), %rsi
 124         movq RDX(%rsp), %rdx
 125         movq RCX(%rsp), %rcx
 126         movq RAX(%rsp), %rax
 127
 128         addq $MCOUNT_REG_SIZE-\save, %rsp
 129
 130         .endm
 131
 132 #ifdef CONFIG_DYNAMIC_FTRACE
 133
 134 SYM_FUNC_START(__fentry__)
 135         RET
 136 SYM_FUNC_END(__fentry__)
 137 EXPORT_SYMBOL(__fentry__)
 138
 139 SYM_FUNC_START(ftrace_caller)
 140         /* save_mcount_regs fills in first two parameters */
 141         save_mcount_regs
 142
 143         /* Stack - skipping return address of ftrace_caller */
 144         leaq MCOUNT_REG_SIZE+8(%rsp), %rcx
 145         movq %rcx, RSP(%rsp)
 146
 147 SYM_INNER_LABEL(ftrace_caller_op_ptr, SYM_L_GLOBAL)
 148         /* Load the ftrace_ops into the 3rd parameter */
 149         movq function_trace_op(%rip), %rdx
 150
 151         /* regs go into 4th parameter */
 152         leaq (%rsp), %rcx
 153
 154         /* Only ops with REGS flag set should have CS register set */
 155         movq $0, CS(%rsp)
 156
 157 SYM_INNER_LABEL(ftrace_call, SYM_L_GLOBAL)
 158         call ftrace_stub
 159
 160         /* Handlers can change the RIP */
 161         movq RIP(%rsp), %rax
 162         movq %rax, MCOUNT_REG_SIZE(%rsp)
 163
 164         restore_mcount_regs
 165
 166         /*
 167          * The code up to this label is copied into trampolines so
 168          * think twice before adding any new code or changing the
 169          * layout here.
 170          */
 171 SYM_INNER_LABEL(ftrace_caller_end, SYM_L_GLOBAL)
 172
 173         jmp ftrace_epilogue
 174 SYM_FUNC_END(ftrace_caller);
 175
 176 SYM_FUNC_START(ftrace_epilogue)
 177 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 178 SYM_INNER_LABEL(ftrace_graph_call, SYM_L_GLOBAL)
 179         jmp ftrace_stub
 180 #endif
 181
 182 /*
 183  * This is weak to keep gas from relaxing the jumps.
 184  */
 185 SYM_INNER_LABEL_ALIGN(ftrace_stub, SYM_L_WEAK)
 186         UNWIND_HINT_FUNC
 187         RET
 188 SYM_FUNC_END(ftrace_epilogue)
 189
 190 SYM_FUNC_START(ftrace_regs_caller)
 191         /* Save the current flags before any operations that can change them */
 192         pushfq
 193
 194         /* added 8 bytes to save flags */
 195         save_mcount_regs 8
 196         /* save_mcount_regs fills in first two parameters */
 197
 198 SYM_INNER_LABEL(ftrace_regs_caller_op_ptr, SYM_L_GLOBAL)
 199         /* Load the ftrace_ops into the 3rd parameter */
 200         movq function_trace_op(%rip), %rdx
 201
 202         /* Save the rest of pt_regs */
 203         movq %r15, R15(%rsp)
 204         movq %r14, R14(%rsp)
 205         movq %r13, R13(%rsp)
 206         movq %r12, R12(%rsp)
 207         movq %r11, R11(%rsp)
 208         movq %r10, R10(%rsp)
 209         movq %rbx, RBX(%rsp)
 210         /* Copy saved flags */
 211         movq MCOUNT_REG_SIZE(%rsp), %rcx
 212         movq %rcx, EFLAGS(%rsp)
 213         /* Kernel segments */
 214         movq $__KERNEL_DS, %rcx
 215         movq %rcx, SS(%rsp)
 216         movq $__KERNEL_CS, %rcx
 217         movq %rcx, CS(%rsp)
 218         /* Stack - skipping return address and flags */
 219         leaq MCOUNT_REG_SIZE+8*2(%rsp), %rcx
 220         movq %rcx, RSP(%rsp)
 221
 222         ENCODE_FRAME_POINTER
 223
 224         /* regs go into 4th parameter */
 225         leaq (%rsp), %rcx
 226
 227 SYM_INNER_LABEL(ftrace_regs_call, SYM_L_GLOBAL)
 228         call ftrace_stub
 229
 230         /* Copy flags back to SS, to restore them */
 231         movq EFLAGS(%rsp), %rax
 232         movq %rax, MCOUNT_REG_SIZE(%rsp)
 233
 234         /* Handlers can change the RIP */
 235         movq RIP(%rsp), %rax
 236         movq %rax, MCOUNT_REG_SIZE+8(%rsp)
 237
 238         /* restore the rest of pt_regs */
 239         movq R15(%rsp), %r15
 240         movq R14(%rsp), %r14
 241         movq R13(%rsp), %r13
 242         movq R12(%rsp), %r12
 243         movq R10(%rsp), %r10
 244         movq RBX(%rsp), %rbx
 245
 246         movq ORIG_RAX(%rsp), %rax
 247         movq %rax, MCOUNT_REG_SIZE-8(%rsp)
 248
 249         /*
 250          * If ORIG_RAX is anything but zero, make this a call to that.
 251          * See arch_ftrace_set_direct_caller().
 252          */
 253         movq ORIG_RAX(%rsp), %rax
 254         testq   %rax, %rax
 255 SYM_INNER_LABEL(ftrace_regs_caller_jmp, SYM_L_GLOBAL)
 256         jnz     1f
 257
 258         restore_mcount_regs
 259         /* Restore flags */
 260         popfq
 261
 262         /*
 263          * As this jmp to ftrace_epilogue can be a short jump
 264          * it must not be copied into the trampoline.
 265          * The trampoline will add the code to jump
 266          * to the return.
 267          */
 268 SYM_INNER_LABEL(ftrace_regs_caller_end, SYM_L_GLOBAL)
 269         jmp ftrace_epilogue
 270
 271         /* Swap the flags with orig_rax */
 272 1:      movq MCOUNT_REG_SIZE(%rsp), %rdi
 273         movq %rdi, MCOUNT_REG_SIZE-8(%rsp)
 274         movq %rax, MCOUNT_REG_SIZE(%rsp)
 275
 276         restore_mcount_regs 8
 277         /* Restore flags */
 278         popfq
 279         UNWIND_HINT_FUNC
 280         jmp     ftrace_epilogue
 281
 282 SYM_FUNC_END(ftrace_regs_caller)
 283
 284
 285 #else /* ! CONFIG_DYNAMIC_FTRACE */
 286
 287 SYM_FUNC_START(__fentry__)
 288         cmpq $ftrace_stub, ftrace_trace_function
 289         jnz trace
 290
 291 fgraph_trace:
 292 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 293         cmpq $ftrace_stub, ftrace_graph_return
 294         jnz ftrace_graph_caller
 295
 296         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 297         jnz ftrace_graph_caller
 298 #endif
 299
 300 SYM_INNER_LABEL(ftrace_stub, SYM_L_GLOBAL)
 301         RET
 302
 303 trace:
 304         /* save_mcount_regs fills in first two parameters */
 305         save_mcount_regs
 306
 307         /*
 308          * When DYNAMIC_FTRACE is not defined, ARCH_SUPPORTS_FTRACE_OPS is not
 309          * set (see include/asm/ftrace.h and include/linux/ftrace.h).  Only the
 310          * ip and parent ip are used and the list function is called when
 311          * function tracing is enabled.
 312          */
 313         movq ftrace_trace_function, %r8
 314         CALL_NOSPEC r8
 315         restore_mcount_regs
 316
 317         jmp fgraph_trace
 318 SYM_FUNC_END(__fentry__)
 319 EXPORT_SYMBOL(__fentry__)
 320 #endif /* CONFIG_DYNAMIC_FTRACE */
 321
 322 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 323 SYM_FUNC_START(ftrace_graph_caller)
 324         /* Saves rbp into %rdx and fills first parameter  */
 325         save_mcount_regs
 326
 327         leaq MCOUNT_REG_SIZE+8(%rsp), %rsi
 328         movq $0, %rdx   /* No framepointers needed */
 329         call    prepare_ftrace_return
 330
 331         restore_mcount_regs
 332
 333         RET
 334 SYM_FUNC_END(ftrace_graph_caller)
 335
 336 SYM_FUNC_START(return_to_handler)
 337         subq  $16, %rsp
 338
 339         /* Save the return values */
 340         movq %rax, (%rsp)
 341         movq %rdx, 8(%rsp)
 342         movq %rbp, %rdi
 343
 344         call ftrace_return_to_handler
 345
 346         movq %rax, %rdi
 347         movq 8(%rsp), %rdx
 348         movq (%rsp), %rax
 349
 350         addq $16, %rsp
 351         /*
 352          * Jump back to the old return address. This cannot be JMP_NOSPEC rdi
 353          * since IBT would demand that contain ENDBR, which simply isn't so for
 354          * return addresses. Use a retpoline here to keep the RSB balanced.
 355          */
 356         ANNOTATE_INTRA_FUNCTION_CALL
 357         call .Ldo_rop
 358         int3
 359 .Ldo_rop:
 360         mov %rdi, (%rsp)
 361         UNWIND_HINT_FUNC
 362         RET
 363 SYM_FUNC_END(return_to_handler)
 364 #endif