arch/x86/entry/calling.h

   1 #include <linux/jump_label.h>
   2 #include <asm/cpufeatures.h>
   3
   4 /*
   5
   6  x86 function call convention, 64-bit:
   7  -------------------------------------
   8   arguments           |  callee-saved      | extra caller-saved | return
   9  [callee-clobbered]   |                    | [callee-clobbered] |
  10  ---------------------------------------------------------------------------
  11  rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]
  12
  13  ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
  14    functions when it sees tail-call optimization possibilities) rflags is
  15    clobbered. Leftover arguments are passed over the stack frame.)
  16
  17  [*]  In the frame-pointers case rbp is fixed to the stack frame.
  18
  19  [**] for struct return values wider than 64 bits the return convention is a
  20       bit more complex: up to 128 bits width we return small structures
  21       straight in rax, rdx. For structures larger than that (3 words or
  22       larger) the caller puts a pointer to an on-stack return struct
  23       [allocated in the caller's stack frame] into the first argument - i.e.
  24       into rdi. All other arguments shift up by one in this case.
  25       Fortunately this case is rare in the kernel.
  26
  27 For 32-bit we have the following conventions - kernel is built with
  28 -mregparm=3 and -freg-struct-return:
  29
  30  x86 function calling convention, 32-bit:
  31  ----------------------------------------
  32   arguments         | callee-saved        | extra caller-saved | return
  33  [callee-clobbered] |                     | [callee-clobbered] |
  34  -------------------------------------------------------------------------
  35  eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]
  36
  37  ( here too esp is obviously invariant across normal function calls. eflags
  38    is clobbered. Leftover arguments are passed over the stack frame. )
  39
  40  [*]  In the frame-pointers case ebp is fixed to the stack frame.
  41
  42  [**] We build with -freg-struct-return, which on 32-bit means similar
  43       semantics as on 64-bit: edx can be used for a second return value
  44       (i.e. covering integer and structure sizes up to 64 bits) - after that
  45       it gets more complex and more expensive: 3-word or larger struct returns
  46       get done in the caller's frame and the pointer to the return struct goes
  47       into regparm0, i.e. eax - the other arguments shift up and the
  48       function's register parameters degenerate to regparm=2 in essence.
  49
  50 */
  51
  52 #ifdef CONFIG_X86_64
  53
  54 /*
  55  * 64-bit system call stack frame layout defines and helpers,
  56  * for assembly code:
  57  */
  58
  59 /* The layout forms the "struct pt_regs" on the stack: */
  60 /*
  61  * C ABI says these regs are callee-preserved. They aren't saved on kernel entry
  62  * unless syscall needs a complete, fully filled "struct pt_regs".
  63  */
  64 #define R15             0*8
  65 #define R14             1*8
  66 #define R13             2*8
  67 #define R12             3*8
  68 #define RBP             4*8
  69 #define RBX             5*8
  70 /* These regs are callee-clobbered. Always saved on kernel entry. */
  71 #define R11             6*8
  72 #define R10             7*8
  73 #define R9              8*8
  74 #define R8              9*8
  75 #define RAX             10*8
  76 #define RCX             11*8
  77 #define RDX             12*8
  78 #define RSI             13*8
  79 #define RDI             14*8
  80 /*
  81  * On syscall entry, this is syscall#. On CPU exception, this is error code.
  82  * On hw interrupt, it's IRQ number:
  83  */
  84 #define ORIG_RAX        15*8
  85 /* Return frame for iretq */
  86 #define RIP             16*8
  87 #define CS              17*8
  88 #define EFLAGS          18*8
  89 #define RSP             19*8
  90 #define SS              20*8
  91
  92 #define SIZEOF_PTREGS   21*8
  93
  94         .macro ALLOC_PT_GPREGS_ON_STACK addskip=0
  95         addq    $-(15*8+\addskip), %rsp
  96         .endm
  97
  98         .macro SAVE_C_REGS_HELPER offset=0 rax=1 rcx=1 r8910=1 r11=1
  99         .if \r11
 100         movq %r11, 6*8+\offset(%rsp)
 101         .endif
 102         .if \r8910
 103         movq %r10, 7*8+\offset(%rsp)
 104         movq %r9,  8*8+\offset(%rsp)
 105         movq %r8,  9*8+\offset(%rsp)
 106         .endif
 107         .if \rax
 108         movq %rax, 10*8+\offset(%rsp)
 109         .endif
 110         .if \rcx
 111         movq %rcx, 11*8+\offset(%rsp)
 112         .endif
 113         movq %rdx, 12*8+\offset(%rsp)
 114         movq %rsi, 13*8+\offset(%rsp)
 115         movq %rdi, 14*8+\offset(%rsp)
 116         .endm
 117         .macro SAVE_C_REGS offset=0
 118         SAVE_C_REGS_HELPER \offset, 1, 1, 1, 1
 119         .endm
 120         .macro SAVE_C_REGS_EXCEPT_RAX_RCX offset=0
 121         SAVE_C_REGS_HELPER \offset, 0, 0, 1, 1
 122         .endm
 123         .macro SAVE_C_REGS_EXCEPT_R891011
 124         SAVE_C_REGS_HELPER 0, 1, 1, 0, 0
 125         .endm
 126         .macro SAVE_C_REGS_EXCEPT_RCX_R891011
 127         SAVE_C_REGS_HELPER 0, 1, 0, 0, 0
 128         .endm
 129         .macro SAVE_C_REGS_EXCEPT_RAX_RCX_R11
 130         SAVE_C_REGS_HELPER 0, 0, 0, 1, 0
 131         .endm
 132
 133         .macro SAVE_EXTRA_REGS offset=0
 134         movq %r15, 0*8+\offset(%rsp)
 135         movq %r14, 1*8+\offset(%rsp)
 136         movq %r13, 2*8+\offset(%rsp)
 137         movq %r12, 3*8+\offset(%rsp)
 138         movq %rbp, 4*8+\offset(%rsp)
 139         movq %rbx, 5*8+\offset(%rsp)
 140         .endm
 141
 142         .macro RESTORE_EXTRA_REGS offset=0
 143         movq 0*8+\offset(%rsp), %r15
 144         movq 1*8+\offset(%rsp), %r14
 145         movq 2*8+\offset(%rsp), %r13
 146         movq 3*8+\offset(%rsp), %r12
 147         movq 4*8+\offset(%rsp), %rbp
 148         movq 5*8+\offset(%rsp), %rbx
 149         .endm
 150
 151         .macro ZERO_EXTRA_REGS
 152         xorl    %r15d, %r15d
 153         xorl    %r14d, %r14d
 154         xorl    %r13d, %r13d
 155         xorl    %r12d, %r12d
 156         xorl    %ebp, %ebp
 157         xorl    %ebx, %ebx
 158         .endm
 159
 160         .macro RESTORE_C_REGS_HELPER rstor_rax=1, rstor_rcx=1, rstor_r11=1, rstor_r8910=1, rstor_rdx=1
 161         .if \rstor_r11
 162         movq 6*8(%rsp), %r11
 163         .endif
 164         .if \rstor_r8910
 165         movq 7*8(%rsp), %r10
 166         movq 8*8(%rsp), %r9
 167         movq 9*8(%rsp), %r8
 168         .endif
 169         .if \rstor_rax
 170         movq 10*8(%rsp), %rax
 171         .endif
 172         .if \rstor_rcx
 173         movq 11*8(%rsp), %rcx
 174         .endif
 175         .if \rstor_rdx
 176         movq 12*8(%rsp), %rdx
 177         .endif
 178         movq 13*8(%rsp), %rsi
 179         movq 14*8(%rsp), %rdi
 180         .endm
 181         .macro RESTORE_C_REGS
 182         RESTORE_C_REGS_HELPER 1,1,1,1,1
 183         .endm
 184         .macro RESTORE_C_REGS_EXCEPT_RAX
 185         RESTORE_C_REGS_HELPER 0,1,1,1,1
 186         .endm
 187         .macro RESTORE_C_REGS_EXCEPT_RCX
 188         RESTORE_C_REGS_HELPER 1,0,1,1,1
 189         .endm
 190         .macro RESTORE_C_REGS_EXCEPT_R11
 191         RESTORE_C_REGS_HELPER 1,1,0,1,1
 192         .endm
 193         .macro RESTORE_C_REGS_EXCEPT_RCX_R11
 194         RESTORE_C_REGS_HELPER 1,0,0,1,1
 195         .endm
 196
 197         .macro REMOVE_PT_GPREGS_FROM_STACK addskip=0
 198         subq $-(15*8+\addskip), %rsp
 199         .endm
 200
 201         .macro icebp
 202         .byte 0xf1
 203         .endm
 204
 205 /*
 206  * Mitigate Spectre v1 for conditional swapgs code paths.
 207  *
 208  * FENCE_SWAPGS_USER_ENTRY is used in the user entry swapgs code path, to
 209  * prevent a speculative swapgs when coming from kernel space.
 210  *
 211  * FENCE_SWAPGS_KERNEL_ENTRY is used in the kernel entry non-swapgs code path,
 212  * to prevent the swapgs from getting speculatively skipped when coming from
 213  * user space.
 214  */
 215 .macro FENCE_SWAPGS_USER_ENTRY
 216         ALTERNATIVE "", "lfence", X86_FEATURE_FENCE_SWAPGS_USER
 217 .endm
 218 .macro FENCE_SWAPGS_KERNEL_ENTRY
 219         ALTERNATIVE "", "lfence", X86_FEATURE_FENCE_SWAPGS_KERNEL
 220 .endm
 221
 222 #endif /* CONFIG_X86_64 */
 223
 224 /*
 225  * This does 'call enter_from_user_mode' unless we can avoid it based on
 226  * kernel config or using the static jump infrastructure.
 227  */
 228 .macro CALL_enter_from_user_mode
 229 #ifdef CONFIG_CONTEXT_TRACKING
 230 #ifdef HAVE_JUMP_LABEL
 231         STATIC_JUMP_IF_FALSE .Lafter_call_\@, context_tracking_enabled, def=0
 232 #endif
 233         call enter_from_user_mode
 234 .Lafter_call_\@:
 235 #endif
 236 .endm