arch/s390/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /* ld script to make s390 Linux kernel
   3  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   4  */
   5
   6 #include <asm/thread_info.h>
   7 #include <asm/page.h>
   8
   9 /*
  10  * Put .bss..swapper_pg_dir as the first thing in .bss. This will
  11  * make sure it has 16k alignment.
  12  */
  13 #define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
  14
  15 /* Handle ro_after_init data on our own. */
  16 #define RO_AFTER_INIT_DATA
  17
  18 #define RUNTIME_DISCARD_EXIT
  19
  20 #include <asm-generic/vmlinux.lds.h>
  21 #include <asm/vmlinux.lds.h>
  22
  23 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  24 OUTPUT_ARCH(s390:64-bit)
  25 ENTRY(startup_continue)
  26 jiffies = jiffies_64;
  27
  28 PHDRS {
  29         text PT_LOAD FLAGS(5);  /* R_E */
  30         data PT_LOAD FLAGS(7);  /* RWE */
  31         note PT_NOTE FLAGS(0);  /* ___ */
  32 }
  33
  34 SECTIONS
  35 {
  36         . = 0x100000;
  37         .text : {
  38                 _stext = .;             /* Start of text section */
  39                 _text = .;              /* Text and read-only data */
  40                 HEAD_TEXT
  41                 TEXT_TEXT
  42                 SCHED_TEXT
  43                 CPUIDLE_TEXT
  44                 LOCK_TEXT
  45                 KPROBES_TEXT
  46                 IRQENTRY_TEXT
  47                 SOFTIRQENTRY_TEXT
  48                 *(.text.*_indirect_*)
  49                 *(.fixup)
  50                 *(.gnu.warning)
  51                 . = ALIGN(PAGE_SIZE);
  52                 _etext = .;             /* End of text section */
  53         } :text = 0x0700
  54
  55         NOTES :text :note
  56
  57         .dummy : { *(.dummy) } :data
  58
  59         RO_DATA_SECTION(PAGE_SIZE)
  60
  61         . = ALIGN(PAGE_SIZE);
  62         _sdata = .;             /* Start of data section */
  63
  64         . = ALIGN(PAGE_SIZE);
  65         __start_ro_after_init = .;
  66         .data..ro_after_init : {
  67                  *(.data..ro_after_init)
  68                 JUMP_TABLE_DATA
  69         }
  70         EXCEPTION_TABLE(16)
  71         . = ALIGN(PAGE_SIZE);
  72         __end_ro_after_init = .;
  73
  74         RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
  75         BOOT_DATA_PRESERVED
  76
  77         _edata = .;             /* End of data section */
  78
  79         /* will be freed after init */
  80         . = ALIGN(PAGE_SIZE);   /* Init code and data */
  81         __init_begin = .;
  82
  83         . = ALIGN(PAGE_SIZE);
  84         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  85                 _sinittext = .;
  86                 INIT_TEXT
  87                 . = ALIGN(PAGE_SIZE);
  88                 _einittext = .;
  89         }
  90
  91         /*
  92          * .exit.text is discarded at runtime, not link time,
  93          * to deal with references from __bug_table
  94         */
  95         .exit.text : {
  96                 EXIT_TEXT
  97         }
  98
  99         .exit.data : {
 100                 EXIT_DATA
 101         }
 102
 103         /*
 104          * struct alt_inst entries. From the header (alternative.h):
 105          * "Alternative instructions for different CPU types or capabilities"
 106          * Think locking instructions on spinlocks.
 107          * Note, that it is a part of __init region.
 108          */
 109         . = ALIGN(8);
 110         .altinstructions : {
 111                 __alt_instructions = .;
 112                 *(.altinstructions)
 113                 __alt_instructions_end = .;
 114         }
 115
 116         /*
 117          * And here are the replacement instructions. The linker sticks
 118          * them as binary blobs. The .altinstructions has enough data to
 119          * get the address and the length of them to patch the kernel safely.
 120          * Note, that it is a part of __init region.
 121          */
 122         .altinstr_replacement : {
 123                 *(.altinstr_replacement)
 124         }
 125
 126         /*
 127          * Table with the patch locations to undo expolines
 128         */
 129         . = ALIGN(4);
 130         .nospec_call_table : {
 131                 __nospec_call_start = . ;
 132                 *(.s390_indirect*)
 133                 __nospec_call_end = . ;
 134         }
 135         .nospec_return_table : {
 136                 __nospec_return_start = . ;
 137                 *(.s390_return*)
 138                 __nospec_return_end = . ;
 139         }
 140
 141         BOOT_DATA
 142
 143         /* early.c uses stsi, which requires page aligned data. */
 144         . = ALIGN(PAGE_SIZE);
 145         INIT_DATA_SECTION(0x100)
 146
 147         PERCPU_SECTION(0x100)
 148
 149         .dynsym ALIGN(8) : {
 150                 __dynsym_start = .;
 151                 *(.dynsym)
 152                 __dynsym_end = .;
 153         }
 154         .rela.dyn ALIGN(8) : {
 155                 __rela_dyn_start = .;
 156                 *(.rela*)
 157                 __rela_dyn_end = .;
 158         }
 159
 160         . = ALIGN(PAGE_SIZE);
 161         __init_end = .;         /* freed after init ends here */
 162
 163         BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
 164
 165         _end = . ;
 166
 167         /*
 168          * uncompressed image info used by the decompressor
 169          * it should match struct vmlinux_info
 170          */
 171         .vmlinux.info 0 (INFO) : {
 172                 QUAD(_stext)                                    /* default_lma */
 173                 QUAD(startup_continue)                          /* entry */
 174                 QUAD(__bss_start - _stext)                      /* image_size */
 175                 QUAD(__bss_stop - __bss_start)                  /* bss_size */
 176                 QUAD(__boot_data_start)                         /* bootdata_off */
 177                 QUAD(__boot_data_end - __boot_data_start)       /* bootdata_size */
 178                 QUAD(__boot_data_preserved_start)               /* bootdata_preserved_off */
 179                 QUAD(__boot_data_preserved_end -
 180                      __boot_data_preserved_start)               /* bootdata_preserved_size */
 181                 QUAD(__dynsym_start)                            /* dynsym_start */
 182                 QUAD(__rela_dyn_start)                          /* rela_dyn_start */
 183                 QUAD(__rela_dyn_end)                            /* rela_dyn_end */
 184         } :NONE
 185
 186         /* Debugging sections.  */
 187         STABS_DEBUG
 188         DWARF_DEBUG
 189
 190         /* Sections to be discarded */
 191         DISCARDS
 192         /DISCARD/ : {
 193                 *(.eh_frame)
 194                 *(.interp)
 195         }
 196 }