arch/s390/kernel/vmlinux.lds.S

   1 /* ld script to make s390 Linux kernel
   2  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   3  */
   4
   5 #include <asm/thread_info.h>
   6 #include <asm/page.h>
   7
   8 /*
   9  * Put .bss..swapper_pg_dir as the first thing in .bss. This will
  10  * make sure it has 16k alignment.
  11  */
  12 #define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
  13
  14 /* Handle ro_after_init data on our own. */
  15 #define RO_AFTER_INIT_DATA
  16
  17 #include <asm-generic/vmlinux.lds.h>
  18
  19 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  20 OUTPUT_ARCH(s390:64-bit)
  21 ENTRY(startup)
  22 jiffies = jiffies_64;
  23
  24 PHDRS {
  25         text PT_LOAD FLAGS(5);  /* R_E */
  26         data PT_LOAD FLAGS(7);  /* RWE */
  27         note PT_NOTE FLAGS(0);  /* ___ */
  28 }
  29
  30 SECTIONS
  31 {
  32         . = 0x00000000;
  33         .text : {
  34                 /* Text and read-only data */
  35                 HEAD_TEXT
  36                 /*
  37                  * E.g. perf doesn't like symbols starting at address zero,
  38                  * therefore skip the initial PSW and channel program located
  39                  * at address zero and let _text start at 0x200.
  40                  */
  41         _text = 0x200;
  42                 TEXT_TEXT
  43                 SCHED_TEXT
  44                 CPUIDLE_TEXT
  45                 LOCK_TEXT
  46                 KPROBES_TEXT
  47                 IRQENTRY_TEXT
  48                 SOFTIRQENTRY_TEXT
  49                 *(.fixup)
  50                 *(.gnu.warning)
  51         } :text = 0x0700
  52
  53         _etext = .;             /* End of text section */
  54
  55         NOTES :text :note
  56
  57         .dummy : { *(.dummy) } :data
  58
  59         RO_DATA_SECTION(PAGE_SIZE)
  60
  61 #ifdef CONFIG_SHARED_KERNEL
  62         . = ALIGN(0x100000);    /* VM shared segments are 1MB aligned */
  63 #endif
  64
  65         . = ALIGN(PAGE_SIZE);
  66         _eshared = .;           /* End of shareable data */
  67         _sdata = .;             /* Start of data section */
  68
  69         . = ALIGN(PAGE_SIZE);
  70         __start_ro_after_init = .;
  71         __start_data_ro_after_init = .;
  72         .data..ro_after_init : {
  73                  *(.data..ro_after_init)
  74         }
  75         __end_data_ro_after_init = .;
  76         EXCEPTION_TABLE(16)
  77         . = ALIGN(PAGE_SIZE);
  78         __end_ro_after_init = .;
  79
  80         RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
  81
  82         _edata = .;             /* End of data section */
  83
  84         /* will be freed after init */
  85         . = ALIGN(PAGE_SIZE);   /* Init code and data */
  86         __init_begin = .;
  87
  88         INIT_TEXT_SECTION(PAGE_SIZE)
  89
  90         /*
  91          * .exit.text is discarded at runtime, not link time,
  92          * to deal with references from __bug_table
  93         */
  94         .exit.text : {
  95                 EXIT_TEXT
  96         }
  97
  98         .exit.data : {
  99                 EXIT_DATA
 100         }
 101
 102         /*
 103          * struct alt_inst entries. From the header (alternative.h):
 104          * "Alternative instructions for different CPU types or capabilities"
 105          * Think locking instructions on spinlocks.
 106          * Note, that it is a part of __init region.
 107          */
 108         . = ALIGN(8);
 109         .altinstructions : {
 110                 __alt_instructions = .;
 111                 *(.altinstructions)
 112                 __alt_instructions_end = .;
 113         }
 114
 115         /*
 116          * And here are the replacement instructions. The linker sticks
 117          * them as binary blobs. The .altinstructions has enough data to
 118          * get the address and the length of them to patch the kernel safely.
 119          * Note, that it is a part of __init region.
 120          */
 121         .altinstr_replacement : {
 122                 *(.altinstr_replacement)
 123         }
 124
 125         /*
 126          * Table with the patch locations to undo expolines
 127         */
 128         .nospec_call_table : {
 129                 __nospec_call_start = . ;
 130                 *(.s390_indirect*)
 131                 __nospec_call_end = . ;
 132         }
 133         .nospec_return_table : {
 134                 __nospec_return_start = . ;
 135                 *(.s390_return*)
 136                 __nospec_return_end = . ;
 137         }
 138
 139         /* early.c uses stsi, which requires page aligned data. */
 140         . = ALIGN(PAGE_SIZE);
 141         INIT_DATA_SECTION(0x100)
 142
 143         PERCPU_SECTION(0x100)
 144         . = ALIGN(PAGE_SIZE);
 145         __init_end = .;         /* freed after init ends here */
 146
 147         BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
 148
 149         _end = . ;
 150
 151         /* Debugging sections.  */
 152         STABS_DEBUG
 153         DWARF_DEBUG
 154
 155         /* Sections to be discarded */
 156         DISCARDS
 157 }