arch/s390/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /* ld script to make s390 Linux kernel
   3  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   4  */
   5
   6 #include <asm/thread_info.h>
   7 #include <asm/page.h>
   8
   9 /*
  10  * Put .bss..swapper_pg_dir as the first thing in .bss. This will
  11  * make sure it has 16k alignment.
  12  */
  13 #define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
  14
  15 /* Handle ro_after_init data on our own. */
  16 #define RO_AFTER_INIT_DATA
  17
  18 #include <asm-generic/vmlinux.lds.h>
  19
  20 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  21 OUTPUT_ARCH(s390:64-bit)
  22 ENTRY(startup)
  23 jiffies = jiffies_64;
  24
  25 PHDRS {
  26         text PT_LOAD FLAGS(5);  /* R_E */
  27         data PT_LOAD FLAGS(7);  /* RWE */
  28         note PT_NOTE FLAGS(0);  /* ___ */
  29 }
  30
  31 SECTIONS
  32 {
  33         . = 0x00000000;
  34         .text : {
  35                 /* Text and read-only data */
  36                 HEAD_TEXT
  37                 /*
  38                  * E.g. perf doesn't like symbols starting at address zero,
  39                  * therefore skip the initial PSW and channel program located
  40                  * at address zero and let _text start at 0x200.
  41                  */
  42         _text = 0x200;
  43                 TEXT_TEXT
  44                 SCHED_TEXT
  45                 CPUIDLE_TEXT
  46                 LOCK_TEXT
  47                 KPROBES_TEXT
  48                 IRQENTRY_TEXT
  49                 SOFTIRQENTRY_TEXT
  50                 *(.fixup)
  51                 *(.gnu.warning)
  52         } :text = 0x0700
  53
  54         . = ALIGN(PAGE_SIZE);
  55         _etext = .;             /* End of text section */
  56
  57         NOTES :text :note
  58
  59         .dummy : { *(.dummy) } :data
  60
  61         RO_DATA_SECTION(PAGE_SIZE)
  62
  63 #ifdef CONFIG_SHARED_KERNEL
  64         . = ALIGN(0x100000);    /* VM shared segments are 1MB aligned */
  65 #endif
  66
  67         . = ALIGN(PAGE_SIZE);
  68         _eshared = .;           /* End of shareable data */
  69         _sdata = .;             /* Start of data section */
  70
  71         . = ALIGN(PAGE_SIZE);
  72         __start_ro_after_init = .;
  73         .data..ro_after_init : {
  74                  *(.data..ro_after_init)
  75         }
  76         EXCEPTION_TABLE(16)
  77         . = ALIGN(PAGE_SIZE);
  78         __end_ro_after_init = .;
  79
  80         RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
  81
  82         _edata = .;             /* End of data section */
  83
  84         /* will be freed after init */
  85         . = ALIGN(PAGE_SIZE);   /* Init code and data */
  86         __init_begin = .;
  87
  88         . = ALIGN(PAGE_SIZE);
  89         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  90                 VMLINUX_SYMBOL(_sinittext) = . ;
  91                 INIT_TEXT
  92                 . = ALIGN(PAGE_SIZE);
  93                 VMLINUX_SYMBOL(_einittext) = . ;
  94         }
  95
  96         /*
  97          * .exit.text is discarded at runtime, not link time,
  98          * to deal with references from __bug_table
  99         */
 100         .exit.text : {
 101                 EXIT_TEXT
 102         }
 103
 104         .exit.data : {
 105                 EXIT_DATA
 106         }
 107
 108         /*
 109          * struct alt_inst entries. From the header (alternative.h):
 110          * "Alternative instructions for different CPU types or capabilities"
 111          * Think locking instructions on spinlocks.
 112          * Note, that it is a part of __init region.
 113          */
 114         . = ALIGN(8);
 115         .altinstructions : {
 116                 __alt_instructions = .;
 117                 *(.altinstructions)
 118                 __alt_instructions_end = .;
 119         }
 120
 121         /*
 122          * And here are the replacement instructions. The linker sticks
 123          * them as binary blobs. The .altinstructions has enough data to
 124          * get the address and the length of them to patch the kernel safely.
 125          * Note, that it is a part of __init region.
 126          */
 127         .altinstr_replacement : {
 128                 *(.altinstr_replacement)
 129         }
 130
 131         /*
 132          * Table with the patch locations to undo expolines
 133         */
 134         .nospec_call_table : {
 135                 __nospec_call_start = . ;
 136                 *(.s390_indirect*)
 137                 __nospec_call_end = . ;
 138         }
 139         .nospec_return_table : {
 140                 __nospec_return_start = . ;
 141                 *(.s390_return*)
 142                 __nospec_return_end = . ;
 143         }
 144
 145         /* early.c uses stsi, which requires page aligned data. */
 146         . = ALIGN(PAGE_SIZE);
 147         INIT_DATA_SECTION(0x100)
 148
 149         PERCPU_SECTION(0x100)
 150         . = ALIGN(PAGE_SIZE);
 151         __init_end = .;         /* freed after init ends here */
 152
 153         BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
 154
 155         _end = . ;
 156
 157         /* Debugging sections.  */
 158         STABS_DEBUG
 159         DWARF_DEBUG
 160
 161         /* Sections to be discarded */
 162         DISCARDS
 163 }