arch/s390/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /* ld script to make s390 Linux kernel
   3  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   4  */
   5
   6 #include <asm/thread_info.h>
   7 #include <asm/page.h>
   8
   9 /*
  10  * Put .bss..swapper_pg_dir as the first thing in .bss. This will
  11  * make sure it has 16k alignment.
  12  */
  13 #define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
  14
  15 /* Handle ro_after_init data on our own. */
  16 #define RO_AFTER_INIT_DATA
  17
  18 #include <asm-generic/vmlinux.lds.h>
  19
  20 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  21 OUTPUT_ARCH(s390:64-bit)
  22 ENTRY(startup_continue)
  23 jiffies = jiffies_64;
  24
  25 PHDRS {
  26         text PT_LOAD FLAGS(5);  /* R_E */
  27         data PT_LOAD FLAGS(7);  /* RWE */
  28         note PT_NOTE FLAGS(0);  /* ___ */
  29 }
  30
  31 SECTIONS
  32 {
  33         . = 0x100000;
  34         .text : {
  35                 _stext = .;             /* Start of text section */
  36                 _text = .;              /* Text and read-only data */
  37                 HEAD_TEXT
  38                 TEXT_TEXT
  39                 SCHED_TEXT
  40                 CPUIDLE_TEXT
  41                 LOCK_TEXT
  42                 KPROBES_TEXT
  43                 IRQENTRY_TEXT
  44                 SOFTIRQENTRY_TEXT
  45                 *(.text.*_indirect_*)
  46                 *(.fixup)
  47                 *(.gnu.warning)
  48                 . = ALIGN(PAGE_SIZE);
  49                 _etext = .;             /* End of text section */
  50         } :text = 0x0700
  51
  52         NOTES :text :note
  53
  54         .dummy : { *(.dummy) } :data
  55
  56         RO_DATA_SECTION(PAGE_SIZE)
  57
  58         . = ALIGN(PAGE_SIZE);
  59         _sdata = .;             /* Start of data section */
  60
  61         . = ALIGN(PAGE_SIZE);
  62         __start_ro_after_init = .;
  63         .data..ro_after_init : {
  64                  *(.data..ro_after_init)
  65         }
  66         EXCEPTION_TABLE(16)
  67         . = ALIGN(PAGE_SIZE);
  68         __end_ro_after_init = .;
  69
  70         RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
  71
  72         _edata = .;             /* End of data section */
  73
  74         /* will be freed after init */
  75         . = ALIGN(PAGE_SIZE);   /* Init code and data */
  76         __init_begin = .;
  77
  78         . = ALIGN(PAGE_SIZE);
  79         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  80                 _sinittext = .;
  81                 INIT_TEXT
  82                 . = ALIGN(PAGE_SIZE);
  83                 _einittext = .;
  84         }
  85
  86         /*
  87          * .exit.text is discarded at runtime, not link time,
  88          * to deal with references from __bug_table
  89         */
  90         .exit.text : {
  91                 EXIT_TEXT
  92         }
  93
  94         .exit.data : {
  95                 EXIT_DATA
  96         }
  97
  98         /*
  99          * struct alt_inst entries. From the header (alternative.h):
 100          * "Alternative instructions for different CPU types or capabilities"
 101          * Think locking instructions on spinlocks.
 102          * Note, that it is a part of __init region.
 103          */
 104         . = ALIGN(8);
 105         .altinstructions : {
 106                 __alt_instructions = .;
 107                 *(.altinstructions)
 108                 __alt_instructions_end = .;
 109         }
 110
 111         /*
 112          * And here are the replacement instructions. The linker sticks
 113          * them as binary blobs. The .altinstructions has enough data to
 114          * get the address and the length of them to patch the kernel safely.
 115          * Note, that it is a part of __init region.
 116          */
 117         .altinstr_replacement : {
 118                 *(.altinstr_replacement)
 119         }
 120
 121         /*
 122          * Table with the patch locations to undo expolines
 123         */
 124         .nospec_call_table : {
 125                 __nospec_call_start = . ;
 126                 *(.s390_indirect*)
 127                 __nospec_call_end = . ;
 128         }
 129         .nospec_return_table : {
 130                 __nospec_return_start = . ;
 131                 *(.s390_return*)
 132                 __nospec_return_end = . ;
 133         }
 134
 135         /* early.c uses stsi, which requires page aligned data. */
 136         . = ALIGN(PAGE_SIZE);
 137         INIT_DATA_SECTION(0x100)
 138
 139         PERCPU_SECTION(0x100)
 140         . = ALIGN(PAGE_SIZE);
 141         __init_end = .;         /* freed after init ends here */
 142
 143         BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
 144
 145         _end = . ;
 146
 147         /* Debugging sections.  */
 148         STABS_DEBUG
 149         DWARF_DEBUG
 150
 151         /* Sections to be discarded */
 152         DISCARDS
 153         /DISCARD/ : {
 154                 *(.eh_frame)
 155         }
 156 }