arch/s390/kernel/mcount.S

   1 /*
   2  * Copyright IBM Corp. 2008, 2009
   3  *
   4  *   Author(s): Heiko Carstens <heiko.carstens@de.ibm.com>,
   5  *
   6  */
   7
   8 #include <linux/linkage.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/ftrace.h>
  11 #include <asm/nospec-insn.h>
  12 #include <asm/ptrace.h>
  13
  14         GEN_BR_THUNK %r1
  15         GEN_BR_THUNK %r14
  16
  17         .section .kprobes.text, "ax"
  18
  19 ENTRY(ftrace_stub)
  20         BR_EX   %r14
  21
  22 #define STACK_FRAME_SIZE  (STACK_FRAME_OVERHEAD + __PT_SIZE)
  23 #define STACK_PTREGS      (STACK_FRAME_OVERHEAD)
  24 #define STACK_PTREGS_GPRS (STACK_PTREGS + __PT_GPRS)
  25 #define STACK_PTREGS_PSW  (STACK_PTREGS + __PT_PSW)
  26 #ifdef __PACK_STACK
  27 /* allocate just enough for r14, r15 and backchain */
  28 #define TRACED_FUNC_FRAME_SIZE  24
  29 #else
  30 #define TRACED_FUNC_FRAME_SIZE  STACK_FRAME_OVERHEAD
  31 #endif
  32
  33 ENTRY(_mcount)
  34         BR_EX   %r14
  35
  36 ENTRY(ftrace_caller)
  37         .globl  ftrace_regs_caller
  38         .set    ftrace_regs_caller,ftrace_caller
  39         stg     %r14,(__SF_GPRS+8*8)(%r15)      # save traced function caller
  40         lgr     %r1,%r15
  41 #ifndef CC_USING_HOTPATCH
  42         aghi    %r0,MCOUNT_RETURN_FIXUP
  43 #endif
  44         # allocate stack frame for ftrace_caller to contain traced function
  45         aghi    %r15,-TRACED_FUNC_FRAME_SIZE
  46         stg     %r1,__SF_BACKCHAIN(%r15)
  47         stg     %r0,(__SF_GPRS+8*8)(%r15)
  48         stg     %r15,(__SF_GPRS+9*8)(%r15)
  49         # allocate pt_regs and stack frame for ftrace_trace_function
  50         aghi    %r15,-STACK_FRAME_SIZE
  51         stg     %r1,(STACK_PTREGS_GPRS+15*8)(%r15)
  52         aghi    %r1,-TRACED_FUNC_FRAME_SIZE
  53         stg     %r1,__SF_BACKCHAIN(%r15)
  54         stg     %r0,(STACK_PTREGS_PSW+8)(%r15)
  55         stmg    %r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
  56 #ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
  57         aghik   %r2,%r0,-MCOUNT_INSN_SIZE
  58         lgrl    %r4,function_trace_op
  59         lgrl    %r1,ftrace_func
  60 #else
  61         lgr     %r2,%r0
  62         aghi    %r2,-MCOUNT_INSN_SIZE
  63         larl    %r4,function_trace_op
  64         lg      %r4,0(%r4)
  65         larl    %r1,ftrace_func
  66         lg      %r1,0(%r1)
  67 #endif
  68         lgr     %r3,%r14
  69         la      %r5,STACK_PTREGS(%r15)
  70         BASR_EX %r14,%r1
  71 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  72 # The j instruction gets runtime patched to a nop instruction.
  73 # See ftrace_enable_ftrace_graph_caller.
  74 ENTRY(ftrace_graph_caller)
  75         j       ftrace_graph_caller_end
  76         lg      %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
  77         lg      %r3,(STACK_PTREGS_PSW+8)(%r15)
  78         brasl   %r14,prepare_ftrace_return
  79         stg     %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
  80 ftrace_graph_caller_end:
  81         .globl  ftrace_graph_caller_end
  82 #endif
  83         lg      %r1,(STACK_PTREGS_PSW+8)(%r15)
  84         lmg     %r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
  85         BR_EX   %r1
  86
  87 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  88
  89 ENTRY(return_to_handler)
  90         stmg    %r2,%r5,32(%r15)
  91         lgr     %r1,%r15
  92         aghi    %r15,-STACK_FRAME_OVERHEAD
  93         stg     %r1,__SF_BACKCHAIN(%r15)
  94         brasl   %r14,ftrace_return_to_handler
  95         aghi    %r15,STACK_FRAME_OVERHEAD
  96         lgr     %r14,%r2
  97         lmg     %r2,%r5,32(%r15)
  98         BR_EX   %r14
  99
 100 #endif