arch/s390/kernel/mcount.S

   1 /*
   2  * Copyright IBM Corp. 2008, 2009
   3  *
   4  *   Author(s): Heiko Carstens <heiko.carstens@de.ibm.com>,
   5  *
   6  */
   7
   8 #include <linux/linkage.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/ftrace.h>
  11 #include <asm/nospec-insn.h>
  12 #include <asm/ptrace.h>
  13 #include <asm/export.h>
  14
  15         GEN_BR_THUNK %r1
  16         GEN_BR_THUNK %r14
  17
  18         .section .kprobes.text, "ax"
  19
  20 ENTRY(ftrace_stub)
  21         BR_EX   %r14
  22
  23 #define STACK_FRAME_SIZE  (STACK_FRAME_OVERHEAD + __PT_SIZE)
  24 #define STACK_PTREGS      (STACK_FRAME_OVERHEAD)
  25 #define STACK_PTREGS_GPRS (STACK_PTREGS + __PT_GPRS)
  26 #define STACK_PTREGS_PSW  (STACK_PTREGS + __PT_PSW)
  27 #ifdef __PACK_STACK
  28 /* allocate just enough for r14, r15 and backchain */
  29 #define TRACED_FUNC_FRAME_SIZE  24
  30 #else
  31 #define TRACED_FUNC_FRAME_SIZE  STACK_FRAME_OVERHEAD
  32 #endif
  33
  34 ENTRY(_mcount)
  35         BR_EX   %r14
  36
  37 EXPORT_SYMBOL(_mcount)
  38
  39 ENTRY(ftrace_caller)
  40         .globl  ftrace_regs_caller
  41         .set    ftrace_regs_caller,ftrace_caller
  42         stg     %r14,(__SF_GPRS+8*8)(%r15)      # save traced function caller
  43         lgr     %r1,%r15
  44 #ifndef CC_USING_HOTPATCH
  45         aghi    %r0,MCOUNT_RETURN_FIXUP
  46 #endif
  47         # allocate stack frame for ftrace_caller to contain traced function
  48         aghi    %r15,-TRACED_FUNC_FRAME_SIZE
  49         stg     %r1,__SF_BACKCHAIN(%r15)
  50         stg     %r0,(__SF_GPRS+8*8)(%r15)
  51         stg     %r15,(__SF_GPRS+9*8)(%r15)
  52         # allocate pt_regs and stack frame for ftrace_trace_function
  53         aghi    %r15,-STACK_FRAME_SIZE
  54         stg     %r1,(STACK_PTREGS_GPRS+15*8)(%r15)
  55         aghi    %r1,-TRACED_FUNC_FRAME_SIZE
  56         stg     %r1,__SF_BACKCHAIN(%r15)
  57         stg     %r0,(STACK_PTREGS_PSW+8)(%r15)
  58         stmg    %r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
  59 #ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
  60         aghik   %r2,%r0,-MCOUNT_INSN_SIZE
  61         lgrl    %r4,function_trace_op
  62         lgrl    %r1,ftrace_func
  63 #else
  64         lgr     %r2,%r0
  65         aghi    %r2,-MCOUNT_INSN_SIZE
  66         larl    %r4,function_trace_op
  67         lg      %r4,0(%r4)
  68         larl    %r1,ftrace_func
  69         lg      %r1,0(%r1)
  70 #endif
  71         lgr     %r3,%r14
  72         la      %r5,STACK_PTREGS(%r15)
  73         BASR_EX %r14,%r1
  74 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  75 # The j instruction gets runtime patched to a nop instruction.
  76 # See ftrace_enable_ftrace_graph_caller.
  77 ENTRY(ftrace_graph_caller)
  78         j       ftrace_graph_caller_end
  79         lg      %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
  80         lg      %r3,(STACK_PTREGS_PSW+8)(%r15)
  81         brasl   %r14,prepare_ftrace_return
  82         stg     %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
  83 ftrace_graph_caller_end:
  84         .globl  ftrace_graph_caller_end
  85 #endif
  86         lg      %r1,(STACK_PTREGS_PSW+8)(%r15)
  87         lmg     %r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
  88         BR_EX   %r1
  89
  90 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  91
  92 ENTRY(return_to_handler)
  93         stmg    %r2,%r5,32(%r15)
  94         lgr     %r1,%r15
  95         aghi    %r15,-STACK_FRAME_OVERHEAD
  96         stg     %r1,__SF_BACKCHAIN(%r15)
  97         brasl   %r14,ftrace_return_to_handler
  98         aghi    %r15,STACK_FRAME_OVERHEAD
  99         lgr     %r14,%r2
 100         lmg     %r2,%r5,32(%r15)
 101         BR_EX   %r14
 102
 103 #endif