arch/s390/kernel/mcount.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Copyright IBM Corp. 2008, 2009
   4  *
   5  *   Author(s): Heiko Carstens <heiko.carstens@de.ibm.com>,
   6  *
   7  */
   8
   9 #include <linux/linkage.h>
  10 #include <asm/asm-offsets.h>
  11 #include <asm/ftrace.h>
  12 #include <asm/nospec-insn.h>
  13 #include <asm/ptrace.h>
  14 #include <asm/export.h>
  15
  16         GEN_BR_THUNK %r1
  17         GEN_BR_THUNK %r14
  18
  19         .section .kprobes.text, "ax"
  20
  21 ENTRY(ftrace_stub)
  22         BR_EX   %r14
  23
  24 #define STACK_FRAME_SIZE  (STACK_FRAME_OVERHEAD + __PT_SIZE)
  25 #define STACK_PTREGS      (STACK_FRAME_OVERHEAD)
  26 #define STACK_PTREGS_GPRS (STACK_PTREGS + __PT_GPRS)
  27 #define STACK_PTREGS_PSW  (STACK_PTREGS + __PT_PSW)
  28 #ifdef __PACK_STACK
  29 /* allocate just enough for r14, r15 and backchain */
  30 #define TRACED_FUNC_FRAME_SIZE  24
  31 #else
  32 #define TRACED_FUNC_FRAME_SIZE  STACK_FRAME_OVERHEAD
  33 #endif
  34
  35 ENTRY(_mcount)
  36         BR_EX   %r14
  37
  38 EXPORT_SYMBOL(_mcount)
  39
  40 ENTRY(ftrace_caller)
  41         .globl  ftrace_regs_caller
  42         .set    ftrace_regs_caller,ftrace_caller
  43         stg     %r14,(__SF_GPRS+8*8)(%r15)      # save traced function caller
  44         lgr     %r1,%r15
  45 #ifndef CC_USING_HOTPATCH
  46         aghi    %r0,MCOUNT_RETURN_FIXUP
  47 #endif
  48         # allocate stack frame for ftrace_caller to contain traced function
  49         aghi    %r15,-TRACED_FUNC_FRAME_SIZE
  50         stg     %r1,__SF_BACKCHAIN(%r15)
  51         stg     %r0,(__SF_GPRS+8*8)(%r15)
  52         stg     %r15,(__SF_GPRS+9*8)(%r15)
  53         # allocate pt_regs and stack frame for ftrace_trace_function
  54         aghi    %r15,-STACK_FRAME_SIZE
  55         stg     %r1,(STACK_PTREGS_GPRS+15*8)(%r15)
  56         aghi    %r1,-TRACED_FUNC_FRAME_SIZE
  57         stg     %r1,__SF_BACKCHAIN(%r15)
  58         stg     %r0,(STACK_PTREGS_PSW+8)(%r15)
  59         stmg    %r2,%r14,(STACK_PTREGS_GPRS+2*8)(%r15)
  60 #ifdef CONFIG_HAVE_MARCH_Z196_FEATURES
  61         aghik   %r2,%r0,-MCOUNT_INSN_SIZE
  62         lgrl    %r4,function_trace_op
  63         lgrl    %r1,ftrace_func
  64 #else
  65         lgr     %r2,%r0
  66         aghi    %r2,-MCOUNT_INSN_SIZE
  67         larl    %r4,function_trace_op
  68         lg      %r4,0(%r4)
  69         larl    %r1,ftrace_func
  70         lg      %r1,0(%r1)
  71 #endif
  72         lgr     %r3,%r14
  73         la      %r5,STACK_PTREGS(%r15)
  74         BASR_EX %r14,%r1
  75 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  76 # The j instruction gets runtime patched to a nop instruction.
  77 # See ftrace_enable_ftrace_graph_caller.
  78 ENTRY(ftrace_graph_caller)
  79         j       ftrace_graph_caller_end
  80         lg      %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
  81         lg      %r3,(STACK_PTREGS_PSW+8)(%r15)
  82         brasl   %r14,prepare_ftrace_return
  83         stg     %r2,(STACK_PTREGS_GPRS+14*8)(%r15)
  84 ftrace_graph_caller_end:
  85         .globl  ftrace_graph_caller_end
  86 #endif
  87         lg      %r1,(STACK_PTREGS_PSW+8)(%r15)
  88         lmg     %r2,%r15,(STACK_PTREGS_GPRS+2*8)(%r15)
  89         BR_EX   %r1
  90
  91 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  92
  93 ENTRY(return_to_handler)
  94         stmg    %r2,%r5,32(%r15)
  95         lgr     %r1,%r15
  96         aghi    %r15,-STACK_FRAME_OVERHEAD
  97         stg     %r1,__SF_BACKCHAIN(%r15)
  98         brasl   %r14,ftrace_return_to_handler
  99         aghi    %r15,STACK_FRAME_OVERHEAD
 100         lgr     %r14,%r2
 101         lmg     %r2,%r5,32(%r15)
 102         BR_EX   %r14
 103
 104 #endif