arch/s390/crypto/crc32be-vx.S

   1 /*
   2  * Hardware-accelerated CRC-32 variants for Linux on z Systems
   3  *
   4  * Use the z/Architecture Vector Extension Facility to accelerate the
   5  * computing of CRC-32 checksums.
   6  *
   7  * This CRC-32 implementation algorithm processes the most-significant
   8  * bit first (BE).
   9  *
  10  * Copyright IBM Corp. 2015
  11  * Author(s): Hendrik Brueckner <brueckner@linux.vnet.ibm.com>
  12  */
  13
  14 #include <linux/linkage.h>
  15 #include <asm/nospec-insn.h>
  16 #include <asm/vx-insn.h>
  17
  18 /* Vector register range containing CRC-32 constants */
  19 #define CONST_R1R2              %v9
  20 #define CONST_R3R4              %v10
  21 #define CONST_R5                %v11
  22 #define CONST_R6                %v12
  23 #define CONST_RU_POLY           %v13
  24 #define CONST_CRC_POLY          %v14
  25
  26 .data
  27 .align 8
  28
  29 /*
  30  * The CRC-32 constant block contains reduction constants to fold and
  31  * process particular chunks of the input data stream in parallel.
  32  *
  33  * For the CRC-32 variants, the constants are precomputed according to
  34  * these defintions:
  35  *
  36  *      R1 = x4*128+64 mod P(x)
  37  *      R2 = x4*128    mod P(x)
  38  *      R3 = x128+64   mod P(x)
  39  *      R4 = x128      mod P(x)
  40  *      R5 = x96       mod P(x)
  41  *      R6 = x64       mod P(x)
  42  *
  43  *      Barret reduction constant, u, is defined as floor(x**64 / P(x)).
  44  *
  45  *      where P(x) is the polynomial in the normal domain and the P'(x) is the
  46  *      polynomial in the reversed (bitreflected) domain.
  47  *
  48  * Note that the constant definitions below are extended in order to compute
  49  * intermediate results with a single VECTOR GALOIS FIELD MULTIPLY instruction.
  50  * The righmost doubleword can be 0 to prevent contribution to the result or
  51  * can be multiplied by 1 to perform an XOR without the need for a separate
  52  * VECTOR EXCLUSIVE OR instruction.
  53  *
  54  * CRC-32 (IEEE 802.3 Ethernet, ...) polynomials:
  55  *
  56  *      P(x)  = 0x04C11DB7
  57  *      P'(x) = 0xEDB88320
  58  */
  59
  60 .Lconstants_CRC_32_BE:
  61         .quad           0x08833794c, 0x0e6228b11        # R1, R2
  62         .quad           0x0c5b9cd4c, 0x0e8a45605        # R3, R4
  63         .quad           0x0f200aa66, 1 << 32            # R5, x32
  64         .quad           0x0490d678d, 1                  # R6, 1
  65         .quad           0x104d101df, 0                  # u
  66         .quad           0x104C11DB7, 0                  # P(x)
  67
  68 .previous
  69
  70         GEN_BR_THUNK %r14
  71
  72 .text
  73 /*
  74  * The CRC-32 function(s) use these calling conventions:
  75  *
  76  * Parameters:
  77  *
  78  *      %r2:    Initial CRC value, typically ~0; and final CRC (return) value.
  79  *      %r3:    Input buffer pointer, performance might be improved if the
  80  *              buffer is on a doubleword boundary.
  81  *      %r4:    Length of the buffer, must be 64 bytes or greater.
  82  *
  83  * Register usage:
  84  *
  85  *      %r5:    CRC-32 constant pool base pointer.
  86  *      V0:     Initial CRC value and intermediate constants and results.
  87  *      V1..V4: Data for CRC computation.
  88  *      V5..V8: Next data chunks that are fetched from the input buffer.
  89  *
  90  *      V9..V14: CRC-32 constants.
  91  */
  92 ENTRY(crc32_be_vgfm_16)
  93         /* Load CRC-32 constants */
  94         larl    %r5,.Lconstants_CRC_32_BE
  95         VLM     CONST_R1R2,CONST_CRC_POLY,0,%r5
  96
  97         /* Load the initial CRC value into the leftmost word of V0. */
  98         VZERO   %v0
  99         VLVGF   %v0,%r2,0
 100
 101         /* Load a 64-byte data chunk and XOR with CRC */
 102         VLM     %v1,%v4,0,%r3           /* 64-bytes into V1..V4 */
 103         VX      %v1,%v0,%v1             /* V1 ^= CRC */
 104         aghi    %r3,64                  /* BUF = BUF + 64 */
 105         aghi    %r4,-64                 /* LEN = LEN - 64 */
 106
 107         /* Check remaining buffer size and jump to proper folding method */
 108         cghi    %r4,64
 109         jl      .Lless_than_64bytes
 110
 111 .Lfold_64bytes_loop:
 112         /* Load the next 64-byte data chunk into V5 to V8 */
 113         VLM     %v5,%v8,0,%r3
 114
 115         /*
 116          * Perform a GF(2) multiplication of the doublewords in V1 with
 117          * the reduction constants in V0.  The intermediate result is
 118          * then folded (accumulated) with the next data chunk in V5 and
 119          * stored in V1.  Repeat this step for the register contents
 120          * in V2, V3, and V4 respectively.
 121          */
 122         VGFMAG  %v1,CONST_R1R2,%v1,%v5
 123         VGFMAG  %v2,CONST_R1R2,%v2,%v6
 124         VGFMAG  %v3,CONST_R1R2,%v3,%v7
 125         VGFMAG  %v4,CONST_R1R2,%v4,%v8
 126
 127         /* Adjust buffer pointer and length for next loop */
 128         aghi    %r3,64                  /* BUF = BUF + 64 */
 129         aghi    %r4,-64                 /* LEN = LEN - 64 */
 130
 131         cghi    %r4,64
 132         jnl     .Lfold_64bytes_loop
 133
 134 .Lless_than_64bytes:
 135         /* Fold V1 to V4 into a single 128-bit value in V1 */
 136         VGFMAG  %v1,CONST_R3R4,%v1,%v2
 137         VGFMAG  %v1,CONST_R3R4,%v1,%v3
 138         VGFMAG  %v1,CONST_R3R4,%v1,%v4
 139
 140         /* Check whether to continue with 64-bit folding */
 141         cghi    %r4,16
 142         jl      .Lfinal_fold
 143
 144 .Lfold_16bytes_loop:
 145
 146         VL      %v2,0,,%r3              /* Load next data chunk */
 147         VGFMAG  %v1,CONST_R3R4,%v1,%v2  /* Fold next data chunk */
 148
 149         /* Adjust buffer pointer and size for folding next data chunk */
 150         aghi    %r3,16
 151         aghi    %r4,-16
 152
 153         /* Process remaining data chunks */
 154         cghi    %r4,16
 155         jnl     .Lfold_16bytes_loop
 156
 157 .Lfinal_fold:
 158         /*
 159          * The R5 constant is used to fold a 128-bit value into an 96-bit value
 160          * that is XORed with the next 96-bit input data chunk.  To use a single
 161          * VGFMG instruction, multiply the rightmost 64-bit with x^32 (1<<32) to
 162          * form an intermediate 96-bit value (with appended zeros) which is then
 163          * XORed with the intermediate reduction result.
 164          */
 165         VGFMG   %v1,CONST_R5,%v1
 166
 167         /*
 168          * Further reduce the remaining 96-bit value to a 64-bit value using a
 169          * single VGFMG, the rightmost doubleword is multiplied with 0x1. The
 170          * intermediate result is then XORed with the product of the leftmost
 171          * doubleword with R6.  The result is a 64-bit value and is subject to
 172          * the Barret reduction.
 173          */
 174         VGFMG   %v1,CONST_R6,%v1
 175
 176         /*
 177          * The input values to the Barret reduction are the degree-63 polynomial
 178          * in V1 (R(x)), degree-32 generator polynomial, and the reduction
 179          * constant u.  The Barret reduction result is the CRC value of R(x) mod
 180          * P(x).
 181          *
 182          * The Barret reduction algorithm is defined as:
 183          *
 184          *    1. T1(x) = floor( R(x) / x^32 ) GF2MUL u
 185          *    2. T2(x) = floor( T1(x) / x^32 ) GF2MUL P(x)
 186          *    3. C(x)  = R(x) XOR T2(x) mod x^32
 187          *
 188          * Note: To compensate the division by x^32, use the vector unpack
 189          * instruction to move the leftmost word into the leftmost doubleword
 190          * of the vector register.  The rightmost doubleword is multiplied
 191          * with zero to not contribute to the intermedate results.
 192          */
 193
 194         /* T1(x) = floor( R(x) / x^32 ) GF2MUL u */
 195         VUPLLF  %v2,%v1
 196         VGFMG   %v2,CONST_RU_POLY,%v2
 197
 198         /*
 199          * Compute the GF(2) product of the CRC polynomial in VO with T1(x) in
 200          * V2 and XOR the intermediate result, T2(x),  with the value in V1.
 201          * The final result is in the rightmost word of V2.
 202          */
 203         VUPLLF  %v2,%v2
 204         VGFMAG  %v2,CONST_CRC_POLY,%v2,%v1
 205
 206 .Ldone:
 207         VLGVF   %r2,%v2,3
 208         BR_EX   %r14
 209
 210 .previous