arch/powerpc/platforms/powernv/opal-wrappers.S

   1 /*
   2  * PowerNV OPAL API wrappers
   3  *
   4  * Copyright 2011 IBM Corp.
   5  *
   6  * This program is free software; you can redistribute it and/or
   7  * modify it under the terms of the GNU General Public License
   8  * as published by the Free Software Foundation; either version
   9  * 2 of the License, or (at your option) any later version.
  10  */
  11
  12 #include <linux/jump_label.h>
  13 #include <asm/ppc_asm.h>
  14 #include <asm/hvcall.h>
  15 #include <asm/asm-offsets.h>
  16 #include <asm/opal.h>
  17
  18         .section        ".text"
  19
  20 #ifdef CONFIG_TRACEPOINTS
  21 #ifdef HAVE_JUMP_LABEL
  22 #define OPAL_BRANCH(LABEL)                                      \
  23         ARCH_STATIC_BRANCH(LABEL, opal_tracepoint_key)
  24 #else
  25
  26         .section        ".toc","aw"
  27
  28         .globl opal_tracepoint_refcount
  29 opal_tracepoint_refcount:
  30         .llong  0
  31
  32         .section        ".text"
  33
  34 /*
  35  * We branch around this in early init by using an unconditional cpu
  36  * feature.
  37  */
  38 #define OPAL_BRANCH(LABEL)                                      \
  39 BEGIN_FTR_SECTION;                                              \
  40         b       1f;                                             \
  41 END_FTR_SECTION(0, 1);                                          \
  42         ld      r12,opal_tracepoint_refcount@toc(r2);           \
  43         cmpdi   r12,0;                                          \
  44         bne-    LABEL;                                          \
  45 1:
  46
  47 #endif
  48
  49 #else
  50 #define OPAL_BRANCH(LABEL)
  51 #endif
  52
  53 /* TODO:
  54  *
  55  * - Trace irqs in/off (needs saving/restoring all args, argh...)
  56  * - Get r11 feed up by Dave so I can have better register usage
  57  */
  58
  59 #define OPAL_CALL(name, token)          \
  60  _GLOBAL_TOC(name);                     \
  61         mflr    r0;                     \
  62         std     r0,16(r1);              \
  63         li      r0,token;               \
  64         OPAL_BRANCH(opal_tracepoint_entry) \
  65         mfcr    r12;                    \
  66         stw     r12,8(r1);              \
  67         std     r1,PACAR1(r13);         \
  68         li      r11,0;                  \
  69         mfmsr   r12;                    \
  70         ori     r11,r11,MSR_EE;         \
  71         std     r12,PACASAVEDMSR(r13);  \
  72         andc    r12,r12,r11;            \
  73         mtmsrd  r12,1;                  \
  74         LOAD_REG_ADDR(r11,opal_return); \
  75         mtlr    r11;                    \
  76         li      r11,MSR_DR|MSR_IR|MSR_LE;\
  77         andc    r12,r12,r11;            \
  78         mtspr   SPRN_HSRR1,r12;         \
  79         LOAD_REG_ADDR(r11,opal);        \
  80         ld      r12,8(r11);             \
  81         ld      r2,0(r11);              \
  82         mtspr   SPRN_HSRR0,r12;         \
  83         hrfid
  84
  85 opal_return:
  86         /*
  87          * Fixup endian on OPAL return... we should be able to simplify
  88          * this by instead converting the below trampoline to a set of
  89          * bytes (always BE) since MSR:LE will end up fixed up as a side
  90          * effect of the rfid.
  91          */
  92         FIXUP_ENDIAN
  93         ld      r2,PACATOC(r13);
  94         lwz     r4,8(r1);
  95         ld      r5,16(r1);
  96         ld      r6,PACASAVEDMSR(r13);
  97         mtspr   SPRN_SRR0,r5;
  98         mtspr   SPRN_SRR1,r6;
  99         mtcr    r4;
 100         rfid
 101
 102 #ifdef CONFIG_TRACEPOINTS
 103 opal_tracepoint_entry:
 104         stdu    r1,-STACKFRAMESIZE(r1)
 105         std     r0,STK_REG(R23)(r1)
 106         std     r3,STK_REG(R24)(r1)
 107         std     r4,STK_REG(R25)(r1)
 108         std     r5,STK_REG(R26)(r1)
 109         std     r6,STK_REG(R27)(r1)
 110         std     r7,STK_REG(R28)(r1)
 111         std     r8,STK_REG(R29)(r1)
 112         std     r9,STK_REG(R30)(r1)
 113         std     r10,STK_REG(R31)(r1)
 114         mr      r3,r0
 115         addi    r4,r1,STK_REG(R24)
 116         bl      __trace_opal_entry
 117         ld      r0,STK_REG(R23)(r1)
 118         ld      r3,STK_REG(R24)(r1)
 119         ld      r4,STK_REG(R25)(r1)
 120         ld      r5,STK_REG(R26)(r1)
 121         ld      r6,STK_REG(R27)(r1)
 122         ld      r7,STK_REG(R28)(r1)
 123         ld      r8,STK_REG(R29)(r1)
 124         ld      r9,STK_REG(R30)(r1)
 125         ld      r10,STK_REG(R31)(r1)
 126         LOAD_REG_ADDR(r11,opal_tracepoint_return)
 127         mfcr    r12
 128         std     r11,16(r1)
 129         stw     r12,8(r1)
 130         std     r1,PACAR1(r13)
 131         li      r11,0
 132         mfmsr   r12
 133         ori     r11,r11,MSR_EE
 134         std     r12,PACASAVEDMSR(r13)
 135         andc    r12,r12,r11
 136         mtmsrd  r12,1
 137         LOAD_REG_ADDR(r11,opal_return)
 138         mtlr    r11
 139         li      r11,MSR_DR|MSR_IR|MSR_LE
 140         andc    r12,r12,r11
 141         mtspr   SPRN_HSRR1,r12
 142         LOAD_REG_ADDR(r11,opal)
 143         ld      r12,8(r11)
 144         ld      r2,0(r11)
 145         mtspr   SPRN_HSRR0,r12
 146         hrfid
 147
 148 opal_tracepoint_return:
 149         std     r3,STK_REG(R31)(r1)
 150         mr      r4,r3
 151         ld      r3,STK_REG(R23)(r1)
 152         bl      __trace_opal_exit
 153         ld      r3,STK_REG(R31)(r1)
 154         addi    r1,r1,STACKFRAMESIZE
 155         ld      r0,16(r1)
 156         mtlr    r0
 157         blr
 158 #endif
 159
 160 /*
 161  * Make opal call in realmode. This is a generic function to be called
 162  * from realmode. It handles endianness.
 163  *
 164  * r13 - paca pointer
 165  * r1  - stack pointer
 166  * r0  - opal token
 167  */
 168 _GLOBAL(opal_call_realmode)
 169         mflr    r12
 170         std     r12,PPC_LR_STKOFF(r1)
 171         ld      r2,PACATOC(r13)
 172         /* Set opal return address */
 173         LOAD_REG_ADDR(r12,return_from_opal_call)
 174         mtlr    r12
 175
 176         mfmsr   r12
 177 #ifdef __LITTLE_ENDIAN__
 178         /* Handle endian-ness */
 179         li      r11,MSR_LE
 180         andc    r12,r12,r11
 181 #endif
 182         mtspr   SPRN_HSRR1,r12
 183         LOAD_REG_ADDR(r11,opal)
 184         ld      r12,8(r11)
 185         ld      r2,0(r11)
 186         mtspr   SPRN_HSRR0,r12
 187         hrfid
 188
 189 return_from_opal_call:
 190 #ifdef __LITTLE_ENDIAN__
 191         FIXUP_ENDIAN
 192 #endif
 193         ld      r12,PPC_LR_STKOFF(r1)
 194         mtlr    r12
 195         blr
 196
 197 OPAL_CALL(opal_invalid_call,                    OPAL_INVALID_CALL);
 198 OPAL_CALL(opal_console_write,                   OPAL_CONSOLE_WRITE);
 199 OPAL_CALL(opal_console_read,                    OPAL_CONSOLE_READ);
 200 OPAL_CALL(opal_console_write_buffer_space,      OPAL_CONSOLE_WRITE_BUFFER_SPACE);
 201 OPAL_CALL(opal_rtc_read,                        OPAL_RTC_READ);
 202 OPAL_CALL(opal_rtc_write,                       OPAL_RTC_WRITE);
 203 OPAL_CALL(opal_cec_power_down,                  OPAL_CEC_POWER_DOWN);
 204 OPAL_CALL(opal_cec_reboot,                      OPAL_CEC_REBOOT);
 205 OPAL_CALL(opal_cec_reboot2,                     OPAL_CEC_REBOOT2);
 206 OPAL_CALL(opal_read_nvram,                      OPAL_READ_NVRAM);
 207 OPAL_CALL(opal_write_nvram,                     OPAL_WRITE_NVRAM);
 208 OPAL_CALL(opal_handle_interrupt,                OPAL_HANDLE_INTERRUPT);
 209 OPAL_CALL(opal_poll_events,                     OPAL_POLL_EVENTS);
 210 OPAL_CALL(opal_pci_set_hub_tce_memory,          OPAL_PCI_SET_HUB_TCE_MEMORY);
 211 OPAL_CALL(opal_pci_set_phb_tce_memory,          OPAL_PCI_SET_PHB_TCE_MEMORY);
 212 OPAL_CALL(opal_pci_config_read_byte,            OPAL_PCI_CONFIG_READ_BYTE);
 213 OPAL_CALL(opal_pci_config_read_half_word,       OPAL_PCI_CONFIG_READ_HALF_WORD);
 214 OPAL_CALL(opal_pci_config_read_word,            OPAL_PCI_CONFIG_READ_WORD);
 215 OPAL_CALL(opal_pci_config_write_byte,           OPAL_PCI_CONFIG_WRITE_BYTE);
 216 OPAL_CALL(opal_pci_config_write_half_word,      OPAL_PCI_CONFIG_WRITE_HALF_WORD);
 217 OPAL_CALL(opal_pci_config_write_word,           OPAL_PCI_CONFIG_WRITE_WORD);
 218 OPAL_CALL(opal_set_xive,                        OPAL_SET_XIVE);
 219 OPAL_CALL(opal_get_xive,                        OPAL_GET_XIVE);
 220 OPAL_CALL(opal_register_exception_handler,      OPAL_REGISTER_OPAL_EXCEPTION_HANDLER);
 221 OPAL_CALL(opal_pci_eeh_freeze_status,           OPAL_PCI_EEH_FREEZE_STATUS);
 222 OPAL_CALL(opal_pci_eeh_freeze_clear,            OPAL_PCI_EEH_FREEZE_CLEAR);
 223 OPAL_CALL(opal_pci_eeh_freeze_set,              OPAL_PCI_EEH_FREEZE_SET);
 224 OPAL_CALL(opal_pci_err_inject,                  OPAL_PCI_ERR_INJECT);
 225 OPAL_CALL(opal_pci_shpc,                        OPAL_PCI_SHPC);
 226 OPAL_CALL(opal_pci_phb_mmio_enable,             OPAL_PCI_PHB_MMIO_ENABLE);
 227 OPAL_CALL(opal_pci_set_phb_mem_window,          OPAL_PCI_SET_PHB_MEM_WINDOW);
 228 OPAL_CALL(opal_pci_map_pe_mmio_window,          OPAL_PCI_MAP_PE_MMIO_WINDOW);
 229 OPAL_CALL(opal_pci_set_phb_table_memory,        OPAL_PCI_SET_PHB_TABLE_MEMORY);
 230 OPAL_CALL(opal_pci_set_pe,                      OPAL_PCI_SET_PE);
 231 OPAL_CALL(opal_pci_set_peltv,                   OPAL_PCI_SET_PELTV);
 232 OPAL_CALL(opal_pci_set_mve,                     OPAL_PCI_SET_MVE);
 233 OPAL_CALL(opal_pci_set_mve_enable,              OPAL_PCI_SET_MVE_ENABLE);
 234 OPAL_CALL(opal_pci_get_xive_reissue,            OPAL_PCI_GET_XIVE_REISSUE);
 235 OPAL_CALL(opal_pci_set_xive_reissue,            OPAL_PCI_SET_XIVE_REISSUE);
 236 OPAL_CALL(opal_pci_set_xive_pe,                 OPAL_PCI_SET_XIVE_PE);
 237 OPAL_CALL(opal_get_xive_source,                 OPAL_GET_XIVE_SOURCE);
 238 OPAL_CALL(opal_get_msi_32,                      OPAL_GET_MSI_32);
 239 OPAL_CALL(opal_get_msi_64,                      OPAL_GET_MSI_64);
 240 OPAL_CALL(opal_start_cpu,                       OPAL_START_CPU);
 241 OPAL_CALL(opal_query_cpu_status,                OPAL_QUERY_CPU_STATUS);
 242 OPAL_CALL(opal_write_oppanel,                   OPAL_WRITE_OPPANEL);
 243 OPAL_CALL(opal_pci_map_pe_dma_window,           OPAL_PCI_MAP_PE_DMA_WINDOW);
 244 OPAL_CALL(opal_pci_map_pe_dma_window_real,      OPAL_PCI_MAP_PE_DMA_WINDOW_REAL);
 245 OPAL_CALL(opal_pci_reset,                       OPAL_PCI_RESET);
 246 OPAL_CALL(opal_pci_get_hub_diag_data,           OPAL_PCI_GET_HUB_DIAG_DATA);
 247 OPAL_CALL(opal_pci_get_phb_diag_data,           OPAL_PCI_GET_PHB_DIAG_DATA);
 248 OPAL_CALL(opal_pci_fence_phb,                   OPAL_PCI_FENCE_PHB);
 249 OPAL_CALL(opal_pci_reinit,                      OPAL_PCI_REINIT);
 250 OPAL_CALL(opal_pci_mask_pe_error,               OPAL_PCI_MASK_PE_ERROR);
 251 OPAL_CALL(opal_set_slot_led_status,             OPAL_SET_SLOT_LED_STATUS);
 252 OPAL_CALL(opal_get_epow_status,                 OPAL_GET_EPOW_STATUS);
 253 OPAL_CALL(opal_get_dpo_status,                  OPAL_GET_DPO_STATUS);
 254 OPAL_CALL(opal_set_system_attention_led,        OPAL_SET_SYSTEM_ATTENTION_LED);
 255 OPAL_CALL(opal_pci_next_error,                  OPAL_PCI_NEXT_ERROR);
 256 OPAL_CALL(opal_pci_poll,                        OPAL_PCI_POLL);
 257 OPAL_CALL(opal_pci_msi_eoi,                     OPAL_PCI_MSI_EOI);
 258 OPAL_CALL(opal_pci_get_phb_diag_data2,          OPAL_PCI_GET_PHB_DIAG_DATA2);
 259 OPAL_CALL(opal_xscom_read,                      OPAL_XSCOM_READ);
 260 OPAL_CALL(opal_xscom_write,                     OPAL_XSCOM_WRITE);
 261 OPAL_CALL(opal_lpc_read,                        OPAL_LPC_READ);
 262 OPAL_CALL(opal_lpc_write,                       OPAL_LPC_WRITE);
 263 OPAL_CALL(opal_return_cpu,                      OPAL_RETURN_CPU);
 264 OPAL_CALL(opal_reinit_cpus,                     OPAL_REINIT_CPUS);
 265 OPAL_CALL(opal_read_elog,                       OPAL_ELOG_READ);
 266 OPAL_CALL(opal_send_ack_elog,                   OPAL_ELOG_ACK);
 267 OPAL_CALL(opal_get_elog_size,                   OPAL_ELOG_SIZE);
 268 OPAL_CALL(opal_resend_pending_logs,             OPAL_ELOG_RESEND);
 269 OPAL_CALL(opal_write_elog,                      OPAL_ELOG_WRITE);
 270 OPAL_CALL(opal_validate_flash,                  OPAL_FLASH_VALIDATE);
 271 OPAL_CALL(opal_manage_flash,                    OPAL_FLASH_MANAGE);
 272 OPAL_CALL(opal_update_flash,                    OPAL_FLASH_UPDATE);
 273 OPAL_CALL(opal_resync_timebase,                 OPAL_RESYNC_TIMEBASE);
 274 OPAL_CALL(opal_check_token,                     OPAL_CHECK_TOKEN);
 275 OPAL_CALL(opal_dump_init,                       OPAL_DUMP_INIT);
 276 OPAL_CALL(opal_dump_info,                       OPAL_DUMP_INFO);
 277 OPAL_CALL(opal_dump_info2,                      OPAL_DUMP_INFO2);
 278 OPAL_CALL(opal_dump_read,                       OPAL_DUMP_READ);
 279 OPAL_CALL(opal_dump_ack,                        OPAL_DUMP_ACK);
 280 OPAL_CALL(opal_get_msg,                         OPAL_GET_MSG);
 281 OPAL_CALL(opal_check_completion,                OPAL_CHECK_ASYNC_COMPLETION);
 282 OPAL_CALL(opal_dump_resend_notification,        OPAL_DUMP_RESEND);
 283 OPAL_CALL(opal_sync_host_reboot,                OPAL_SYNC_HOST_REBOOT);
 284 OPAL_CALL(opal_sensor_read,                     OPAL_SENSOR_READ);
 285 OPAL_CALL(opal_get_param,                       OPAL_GET_PARAM);
 286 OPAL_CALL(opal_set_param,                       OPAL_SET_PARAM);
 287 OPAL_CALL(opal_handle_hmi,                      OPAL_HANDLE_HMI);
 288 OPAL_CALL(opal_config_cpu_idle_state,           OPAL_CONFIG_CPU_IDLE_STATE);
 289 OPAL_CALL(opal_slw_set_reg,                     OPAL_SLW_SET_REG);
 290 OPAL_CALL(opal_register_dump_region,            OPAL_REGISTER_DUMP_REGION);
 291 OPAL_CALL(opal_unregister_dump_region,          OPAL_UNREGISTER_DUMP_REGION);
 292 OPAL_CALL(opal_pci_set_phb_cxl_mode,            OPAL_PCI_SET_PHB_CAPI_MODE);
 293 OPAL_CALL(opal_tpo_write,                       OPAL_WRITE_TPO);
 294 OPAL_CALL(opal_tpo_read,                        OPAL_READ_TPO);
 295 OPAL_CALL(opal_ipmi_send,                       OPAL_IPMI_SEND);
 296 OPAL_CALL(opal_ipmi_recv,                       OPAL_IPMI_RECV);
 297 OPAL_CALL(opal_i2c_request,                     OPAL_I2C_REQUEST);
 298 OPAL_CALL(opal_flash_read,                      OPAL_FLASH_READ);
 299 OPAL_CALL(opal_flash_write,                     OPAL_FLASH_WRITE);
 300 OPAL_CALL(opal_flash_erase,                     OPAL_FLASH_ERASE);
 301 OPAL_CALL(opal_prd_msg,                         OPAL_PRD_MSG);
 302 OPAL_CALL(opal_leds_get_ind,                    OPAL_LEDS_GET_INDICATOR);
 303 OPAL_CALL(opal_leds_set_ind,                    OPAL_LEDS_SET_INDICATOR);
 304 OPAL_CALL(opal_console_flush,                   OPAL_CONSOLE_FLUSH);