arch/powerpc/lib/copypage_64.S

   1 /*
   2  * Copyright (C) 2008 Mark Nelson, IBM Corp.
   3  *
   4  * This program is free software; you can redistribute it and/or
   5  * modify it under the terms of the GNU General Public License
   6  * as published by the Free Software Foundation; either version
   7  * 2 of the License, or (at your option) any later version.
   8  */
   9 #include <asm/page.h>
  10 #include <asm/processor.h>
  11 #include <asm/ppc_asm.h>
  12 #include <asm/asm-offsets.h>
  13 #include <asm/export.h>
  14 #include <asm/feature-fixups.h>
  15
  16         .section        ".toc","aw"
  17 PPC64_CACHES:
  18         .tc             ppc64_caches[TC],ppc64_caches
  19         .section        ".text"
  20
  21 _GLOBAL_TOC(copy_page)
  22 BEGIN_FTR_SECTION
  23         lis     r5,PAGE_SIZE@h
  24 FTR_SECTION_ELSE
  25 #ifdef CONFIG_PPC_BOOK3S_64
  26         b       copypage_power7
  27 #endif
  28 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_VMX_COPY)
  29         ori     r5,r5,PAGE_SIZE@l
  30 BEGIN_FTR_SECTION
  31         ld      r10,PPC64_CACHES@toc(r2)
  32         lwz     r11,DCACHEL1LOGBLOCKSIZE(r10)   /* log2 of cache block size */
  33         lwz     r12,DCACHEL1BLOCKSIZE(r10)      /* get cache block size */
  34         li      r9,0
  35         srd     r8,r5,r11
  36
  37         mtctr   r8
  38 .Lsetup:
  39         dcbt    r9,r4
  40         dcbz    r9,r3
  41         add     r9,r9,r12
  42         bdnz    .Lsetup
  43 END_FTR_SECTION_IFSET(CPU_FTR_CP_USE_DCBTZ)
  44         addi    r3,r3,-8
  45         srdi    r8,r5,7         /* page is copied in 128 byte strides */
  46         addi    r8,r8,-1        /* one stride copied outside loop */
  47
  48         mtctr   r8
  49
  50         ld      r5,0(r4)
  51         ld      r6,8(r4)
  52         ld      r7,16(r4)
  53         ldu     r8,24(r4)
  54 1:      std     r5,8(r3)
  55         std     r6,16(r3)
  56         ld      r9,8(r4)
  57         ld      r10,16(r4)
  58         std     r7,24(r3)
  59         std     r8,32(r3)
  60         ld      r11,24(r4)
  61         ld      r12,32(r4)
  62         std     r9,40(r3)
  63         std     r10,48(r3)
  64         ld      r5,40(r4)
  65         ld      r6,48(r4)
  66         std     r11,56(r3)
  67         std     r12,64(r3)
  68         ld      r7,56(r4)
  69         ld      r8,64(r4)
  70         std     r5,72(r3)
  71         std     r6,80(r3)
  72         ld      r9,72(r4)
  73         ld      r10,80(r4)
  74         std     r7,88(r3)
  75         std     r8,96(r3)
  76         ld      r11,88(r4)
  77         ld      r12,96(r4)
  78         std     r9,104(r3)
  79         std     r10,112(r3)
  80         ld      r5,104(r4)
  81         ld      r6,112(r4)
  82         std     r11,120(r3)
  83         stdu    r12,128(r3)
  84         ld      r7,120(r4)
  85         ldu     r8,128(r4)
  86         bdnz    1b
  87
  88         std     r5,8(r3)
  89         std     r6,16(r3)
  90         ld      r9,8(r4)
  91         ld      r10,16(r4)
  92         std     r7,24(r3)
  93         std     r8,32(r3)
  94         ld      r11,24(r4)
  95         ld      r12,32(r4)
  96         std     r9,40(r3)
  97         std     r10,48(r3)
  98         ld      r5,40(r4)
  99         ld      r6,48(r4)
 100         std     r11,56(r3)
 101         std     r12,64(r3)
 102         ld      r7,56(r4)
 103         ld      r8,64(r4)
 104         std     r5,72(r3)
 105         std     r6,80(r3)
 106         ld      r9,72(r4)
 107         ld      r10,80(r4)
 108         std     r7,88(r3)
 109         std     r8,96(r3)
 110         ld      r11,88(r4)
 111         ld      r12,96(r4)
 112         std     r9,104(r3)
 113         std     r10,112(r3)
 114         std     r11,120(r3)
 115         std     r12,128(r3)
 116         blr
 117 EXPORT_SYMBOL(copy_page)