arch/powerpc/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 #ifdef CONFIG_PPC64
   3 #define PROVIDE32(x)    PROVIDE(__unused__##x)
   4 #else
   5 #define PROVIDE32(x)    PROVIDE(x)
   6 #endif
   7 #include <asm/page.h>
   8 #include <asm-generic/vmlinux.lds.h>
   9 #include <asm/cache.h>
  10 #include <asm/thread_info.h>
  11
  12 #if defined(CONFIG_STRICT_KERNEL_RWX) && !defined(CONFIG_PPC32)
  13 #define STRICT_ALIGN_SIZE       (1 << 24)
  14 #else
  15 #define STRICT_ALIGN_SIZE       PAGE_SIZE
  16 #endif
  17
  18 ENTRY(_stext)
  19
  20 PHDRS {
  21         kernel PT_LOAD FLAGS(7); /* RWX */
  22         notes PT_NOTE FLAGS(0);
  23         dummy PT_NOTE FLAGS(0);
  24
  25         /* binutils < 2.18 has a bug that makes it misbehave when taking an
  26            ELF file with all segments at load address 0 as input.  This
  27            happens when running "strip" on vmlinux, because of the AT() magic
  28            in this linker script.  People using GCC >= 4.2 won't run into
  29            this problem, because the "build-id" support will put some data
  30            into the "notes" segment (at a non-zero load address).
  31
  32            To work around this, we force some data into both the "dummy"
  33            segment and the kernel segment, so the dummy segment will get a
  34            non-zero load address.  It's not enough to always create the
  35            "notes" segment, since if nothing gets assigned to it, its load
  36            address will be zero.  */
  37 }
  38
  39 #ifdef CONFIG_PPC64
  40 OUTPUT_ARCH(powerpc:common64)
  41 jiffies = jiffies_64;
  42 #else
  43 OUTPUT_ARCH(powerpc:common)
  44 jiffies = jiffies_64 + 4;
  45 #endif
  46 SECTIONS
  47 {
  48         . = KERNELBASE;
  49
  50 /*
  51  * Text, read only data and other permanent read-only sections
  52  */
  53
  54         _text = .;
  55         _stext = .;
  56
  57         /*
  58          * Head text.
  59          * This needs to be in its own output section to avoid ld placing
  60          * branch trampoline stubs randomly throughout the fixed sections,
  61          * which it will do (even if the branch comes from another section)
  62          * in order to optimize stub generation.
  63          */
  64         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
  65 #ifdef CONFIG_PPC64
  66                 KEEP(*(.head.text.first_256B));
  67 #ifdef CONFIG_PPC_BOOK3E
  68 #else
  69                 KEEP(*(.head.text.real_vectors));
  70                 *(.head.text.real_trampolines);
  71                 KEEP(*(.head.text.virt_vectors));
  72                 *(.head.text.virt_trampolines);
  73 # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
  74                 KEEP(*(.head.data.fwnmi_page));
  75 # endif
  76 #endif
  77 #else /* !CONFIG_PPC64 */
  78                 HEAD_TEXT
  79 #endif
  80         } :kernel
  81
  82         __head_end = .;
  83
  84 #ifdef CONFIG_PPC64
  85         /*
  86          * BLOCK(0) overrides the default output section alignment because
  87          * this needs to start right after .head.text in order for fixed
  88          * section placement to work.
  89          */
  90         .text BLOCK(0) : AT(ADDR(.text) - LOAD_OFFSET) {
  91 #ifdef CONFIG_LD_HEAD_STUB_CATCH
  92                 KEEP(*(.linker_stub_catch));
  93                 . = . ;
  94 #endif
  95
  96 #else
  97         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  98                 ALIGN_FUNCTION();
  99 #endif
 100                 /* careful! __ftr_alt_* sections need to be close to .text */
 101                 *(.text.hot TEXT_MAIN .text.fixup .text.unlikely .fixup __ftr_alt_* .ref.text);
 102                 NOINSTR_TEXT
 103                 SCHED_TEXT
 104                 CPUIDLE_TEXT
 105                 LOCK_TEXT
 106                 KPROBES_TEXT
 107                 IRQENTRY_TEXT
 108                 SOFTIRQENTRY_TEXT
 109                 /*
 110                  * -Os builds call FP save/restore functions. The powerpc64
 111                  * linker generates those on demand in the .sfpr section.
 112                  * .sfpr gets placed at the beginning of a group of input
 113                  * sections, which can break start-of-text offset if it is
 114                  * included with the main text sections, so put it by itself.
 115                  */
 116                 *(.sfpr);
 117                 MEM_KEEP(init.text)
 118                 MEM_KEEP(exit.text)
 119
 120 #ifdef CONFIG_PPC32
 121                 *(.got1)
 122                 __got2_start = .;
 123                 *(.got2)
 124                 __got2_end = .;
 125 #endif /* CONFIG_PPC32 */
 126
 127         } :kernel
 128
 129         . = ALIGN(PAGE_SIZE);
 130         _etext = .;
 131         PROVIDE32 (etext = .);
 132
 133         /* Read-only data */
 134         RO_DATA(PAGE_SIZE)
 135
 136 #ifdef CONFIG_PPC64
 137         . = ALIGN(8);
 138         __stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
 139                 __start___stf_entry_barrier_fixup = .;
 140                 *(__stf_entry_barrier_fixup)
 141                 __stop___stf_entry_barrier_fixup = .;
 142         }
 143
 144         . = ALIGN(8);
 145         __uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) {
 146                 __start___uaccess_flush_fixup = .;
 147                 *(__uaccess_flush_fixup)
 148                 __stop___uaccess_flush_fixup = .;
 149         }
 150
 151         . = ALIGN(8);
 152         __entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) {
 153                 __start___entry_flush_fixup = .;
 154                 *(__entry_flush_fixup)
 155                 __stop___entry_flush_fixup = .;
 156         }
 157
 158         . = ALIGN(8);
 159         __stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
 160                 __start___stf_exit_barrier_fixup = .;
 161                 *(__stf_exit_barrier_fixup)
 162                 __stop___stf_exit_barrier_fixup = .;
 163         }
 164
 165         . = ALIGN(8);
 166         __rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
 167                 __start___rfi_flush_fixup = .;
 168                 *(__rfi_flush_fixup)
 169                 __stop___rfi_flush_fixup = .;
 170         }
 171 #endif /* CONFIG_PPC64 */
 172
 173 #ifdef CONFIG_PPC_BARRIER_NOSPEC
 174         . = ALIGN(8);
 175         __spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
 176                 __start___barrier_nospec_fixup = .;
 177                 *(__barrier_nospec_fixup)
 178                 __stop___barrier_nospec_fixup = .;
 179         }
 180 #endif /* CONFIG_PPC_BARRIER_NOSPEC */
 181
 182 #ifdef CONFIG_PPC_FSL_BOOK3E
 183         . = ALIGN(8);
 184         __spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
 185                 __start__btb_flush_fixup = .;
 186                 *(__btb_flush_fixup)
 187                 __stop__btb_flush_fixup = .;
 188         }
 189 #endif
 190         EXCEPTION_TABLE(0)
 191
 192         NOTES :kernel :notes
 193
 194         /* The dummy segment contents for the bug workaround mentioned above
 195            near PHDRS.  */
 196         .dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
 197                 LONG(0)
 198                 LONG(0)
 199                 LONG(0)
 200         } :kernel :dummy
 201
 202 /*
 203  * Init sections discarded at runtime
 204  */
 205         . = ALIGN(STRICT_ALIGN_SIZE);
 206         __init_begin = .;
 207         INIT_TEXT_SECTION(PAGE_SIZE) :kernel
 208
 209         /* .exit.text is discarded at runtime, not link time,
 210          * to deal with references from __bug_table
 211          */
 212         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 213                 EXIT_TEXT
 214         }
 215
 216         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 217                 INIT_DATA
 218                 __vtop_table_begin = .;
 219                 KEEP(*(.vtop_fixup));
 220                 __vtop_table_end = .;
 221                 __ptov_table_begin = .;
 222                 KEEP(*(.ptov_fixup));
 223                 __ptov_table_end = .;
 224         }
 225
 226         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 227                 INIT_SETUP(16)
 228         }
 229
 230         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 231                 INIT_CALLS
 232         }
 233
 234         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 235                 CON_INITCALL
 236         }
 237
 238         SECURITY_INIT
 239
 240         . = ALIGN(8);
 241         __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
 242                 __start___ftr_fixup = .;
 243                 KEEP(*(__ftr_fixup))
 244                 __stop___ftr_fixup = .;
 245         }
 246         . = ALIGN(8);
 247         __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
 248                 __start___mmu_ftr_fixup = .;
 249                 KEEP(*(__mmu_ftr_fixup))
 250                 __stop___mmu_ftr_fixup = .;
 251         }
 252         . = ALIGN(8);
 253         __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
 254                 __start___lwsync_fixup = .;
 255                 KEEP(*(__lwsync_fixup))
 256                 __stop___lwsync_fixup = .;
 257         }
 258 #ifdef CONFIG_PPC64
 259         . = ALIGN(8);
 260         __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
 261                 __start___fw_ftr_fixup = .;
 262                 KEEP(*(__fw_ftr_fixup))
 263                 __stop___fw_ftr_fixup = .;
 264         }
 265 #endif
 266         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 267                 INIT_RAM_FS
 268         }
 269
 270         PERCPU_SECTION(L1_CACHE_BYTES)
 271
 272         . = ALIGN(8);
 273         .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
 274                 __machine_desc_start = . ;
 275                 KEEP(*(.machine.desc))
 276                 __machine_desc_end = . ;
 277         }
 278 #ifdef CONFIG_RELOCATABLE
 279         . = ALIGN(8);
 280         .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
 281         {
 282 #ifdef CONFIG_PPC32
 283                 __dynamic_symtab = .;
 284 #endif
 285                 *(.dynsym)
 286         }
 287         .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
 288         .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
 289         {
 290                 __dynamic_start = .;
 291                 *(.dynamic)
 292         }
 293         .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
 294         .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
 295         .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
 296         {
 297                 __rela_dyn_start = .;
 298                 *(.rela*)
 299         }
 300 #endif
 301         /* .exit.data is discarded at runtime, not link time,
 302          * to deal with references from .exit.text
 303          */
 304         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 305                 EXIT_DATA
 306         }
 307
 308         /* freed after init ends here */
 309         . = ALIGN(PAGE_SIZE);
 310         __init_end = .;
 311
 312 /*
 313  * And now the various read/write data
 314  */
 315
 316         . = ALIGN(PAGE_SIZE);
 317         _sdata = .;
 318
 319 #ifdef CONFIG_PPC32
 320         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 321                 DATA_DATA
 322 #ifdef CONFIG_UBSAN
 323                 *(.data..Lubsan_data*)
 324                 *(.data..Lubsan_type*)
 325 #endif
 326                 *(.data.rel*)
 327                 *(SDATA_MAIN)
 328                 *(.sdata2)
 329                 *(.got.plt) *(.got)
 330                 *(.plt)
 331         }
 332 #else
 333         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 334                 DATA_DATA
 335                 *(.data.rel*)
 336                 *(.toc1)
 337                 *(.branch_lt)
 338         }
 339
 340 #ifdef CONFIG_DEBUG_INFO_BTF
 341         .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) {
 342                 *(.BTF)
 343         }
 344 #endif
 345
 346         .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
 347                 __start_opd = .;
 348                 KEEP(*(.opd))
 349                 __end_opd = .;
 350         }
 351
 352         . = ALIGN(256);
 353         .got : AT(ADDR(.got) - LOAD_OFFSET) {
 354                 __toc_start = .;
 355 #ifndef CONFIG_RELOCATABLE
 356                 __prom_init_toc_start = .;
 357                 arch/powerpc/kernel/prom_init.o*(.toc .got)
 358                 __prom_init_toc_end = .;
 359 #endif
 360                 *(.got)
 361                 *(.toc)
 362         }
 363 #endif
 364
 365         /* The initial task and kernel stack */
 366         INIT_TASK_DATA_SECTION(THREAD_SIZE)
 367
 368         .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
 369                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 370         }
 371
 372         .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
 373                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 374         }
 375
 376         .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
 377                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 378         }
 379
 380         . = ALIGN(PAGE_SIZE);
 381         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 382                 NOSAVE_DATA
 383         }
 384
 385         BUG_TABLE
 386
 387         . = ALIGN(PAGE_SIZE);
 388         _edata  =  .;
 389         PROVIDE32 (edata = .);
 390
 391 /*
 392  * And finally the bss
 393  */
 394
 395         BSS_SECTION(0, 0, 0)
 396
 397         . = ALIGN(PAGE_SIZE);
 398         _end = . ;
 399         PROVIDE32 (end = .);
 400
 401         STABS_DEBUG
 402
 403         DWARF_DEBUG
 404
 405         DISCARDS
 406         /DISCARD/ : {
 407                 *(*.EMB.apuinfo)
 408                 *(.glink .iplt .plt .rela* .comment)
 409                 *(.gnu.version*)
 410                 *(.gnu.attributes)
 411                 *(.eh_frame)
 412         }
 413 }