arch/powerpc/kernel/tm.S

   1 /*
   2  * Transactional memory support routines to reclaim and recheckpoint
   3  * transactional process state.
   4  *
   5  * Copyright 2012 Matt Evans & Michael Neuling, IBM Corporation.
   6  */
   7
   8 #include <asm/asm-offsets.h>
   9 #include <asm/ppc_asm.h>
  10 #include <asm/ppc-opcode.h>
  11 #include <asm/ptrace.h>
  12 #include <asm/reg.h>
  13 #include <asm/bug.h>
  14
  15 #ifdef CONFIG_VSX
  16 /* See fpu.S, this is borrowed from there */
  17 #define __SAVE_32FPRS_VSRS(n,c,base)            \
  18 BEGIN_FTR_SECTION                               \
  19         b       2f;                             \
  20 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  21         SAVE_32FPRS(n,base);                    \
  22         b       3f;                             \
  23 2:      SAVE_32VSRS(n,c,base);                  \
  24 3:
  25 #define __REST_32FPRS_VSRS(n,c,base)            \
  26 BEGIN_FTR_SECTION                               \
  27         b       2f;                             \
  28 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  29         REST_32FPRS(n,base);                    \
  30         b       3f;                             \
  31 2:      REST_32VSRS(n,c,base);                  \
  32 3:
  33 #else
  34 #define __SAVE_32FPRS_VSRS(n,c,base)    SAVE_32FPRS(n, base)
  35 #define __REST_32FPRS_VSRS(n,c,base)    REST_32FPRS(n, base)
  36 #endif
  37 #define SAVE_32FPRS_VSRS(n,c,base) \
  38         __SAVE_32FPRS_VSRS(n,__REG_##c,__REG_##base)
  39 #define REST_32FPRS_VSRS(n,c,base) \
  40         __REST_32FPRS_VSRS(n,__REG_##c,__REG_##base)
  41
  42 /* Stack frame offsets for local variables. */
  43 #define TM_FRAME_L0     TM_FRAME_SIZE-16
  44 #define TM_FRAME_L1     TM_FRAME_SIZE-8
  45
  46
  47 /* In order to access the TM SPRs, TM must be enabled.  So, do so: */
  48 _GLOBAL(tm_enable)
  49         mfmsr   r4
  50         li      r3, MSR_TM >> 32
  51         sldi    r3, r3, 32
  52         and.    r0, r4, r3
  53         bne     1f
  54         or      r4, r4, r3
  55         mtmsrd  r4
  56 1:      blr
  57
  58 _GLOBAL(tm_save_sprs)
  59         mfspr   r0, SPRN_TFHAR
  60         std     r0, THREAD_TM_TFHAR(r3)
  61         mfspr   r0, SPRN_TEXASR
  62         std     r0, THREAD_TM_TEXASR(r3)
  63         mfspr   r0, SPRN_TFIAR
  64         std     r0, THREAD_TM_TFIAR(r3)
  65         blr
  66
  67 _GLOBAL(tm_restore_sprs)
  68         ld      r0, THREAD_TM_TFHAR(r3)
  69         mtspr   SPRN_TFHAR, r0
  70         ld      r0, THREAD_TM_TEXASR(r3)
  71         mtspr   SPRN_TEXASR, r0
  72         ld      r0, THREAD_TM_TFIAR(r3)
  73         mtspr   SPRN_TFIAR, r0
  74         blr
  75
  76         /* Passed an 8-bit failure cause as first argument. */
  77 _GLOBAL(tm_abort)
  78         TABORT(R3)
  79         blr
  80
  81 /* void tm_reclaim(struct thread_struct *thread,
  82  *                 unsigned long orig_msr,
  83  *                 uint8_t cause)
  84  *
  85  *      - Performs a full reclaim.  This destroys outstanding
  86  *        transactions and updates thread->regs.tm_ckpt_* with the
  87  *        original checkpointed state.  Note that thread->regs is
  88  *        unchanged.
  89  *      - FP regs are written back to thread->transact_fpr before
  90  *        reclaiming.  These are the transactional (current) versions.
  91  *
  92  * Purpose is to both abort transactions of, and preserve the state of,
  93  * a transactions at a context switch. We preserve/restore both sets of process
  94  * state to restore them when the thread's scheduled again.  We continue in
  95  * userland as though nothing happened, but when the transaction is resumed
  96  * they will abort back to the checkpointed state we save out here.
  97  *
  98  * Call with IRQs off, stacks get all out of sync for some periods in here!
  99  */
 100 _GLOBAL(tm_reclaim)
 101         mfcr    r6
 102         mflr    r0
 103         stw     r6, 8(r1)
 104         std     r0, 16(r1)
 105         std     r2, STK_GOT(r1)
 106         stdu    r1, -TM_FRAME_SIZE(r1)
 107
 108         /* We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD]. */
 109
 110         std     r3, STK_PARAM(R3)(r1)
 111         std     r4, STK_PARAM(R4)(r1)
 112         SAVE_NVGPRS(r1)
 113
 114         /* We need to setup MSR for VSX register save instructions. */
 115         mfmsr   r14
 116         mr      r15, r14
 117         ori     r15, r15, MSR_FP
 118         li      r16, 0
 119         ori     r16, r16, MSR_EE /* IRQs hard off */
 120         andc    r15, r15, r16
 121         oris    r15, r15, MSR_VEC@h
 122 #ifdef CONFIG_VSX
 123         BEGIN_FTR_SECTION
 124         oris    r15,r15, MSR_VSX@h
 125         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 126 #endif
 127         mtmsrd  r15
 128         std     r14, TM_FRAME_L0(r1)
 129
 130         /* Do sanity check on MSR to make sure we are suspended */
 131         li      r7, (MSR_TS_S)@higher
 132         srdi    r6, r14, 32
 133         and     r6, r6, r7
 134 1:      tdeqi   r6, 0
 135         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 136
 137         /* Stash the stack pointer away for use after reclaim */
 138         std     r1, PACAR1(r13)
 139
 140         /* Clear MSR RI since we are about to change r1, EE is already off. */
 141         li      r4, 0
 142         mtmsrd  r4, 1
 143
 144         /*
 145          * BE CAREFUL HERE:
 146          * At this point we can't take an SLB miss since we have MSR_RI
 147          * off. Load only to/from the stack/paca which are in SLB bolted regions
 148          * until we turn MSR RI back on.
 149          *
 150          * The moment we treclaim, ALL of our GPRs will switch
 151          * to user register state.  (FPRs, CCR etc. also!)
 152          * Use an sprg and a tm_scratch in the PACA to shuffle.
 153          */
 154         TRECLAIM(R5)                            /* Cause in r5 */
 155
 156         /* ******************** GPRs ******************** */
 157         /* Stash the checkpointed r13 away in the scratch SPR and get the real
 158          *  paca
 159          */
 160         SET_SCRATCH0(r13)
 161         GET_PACA(r13)
 162
 163         /* Stash the checkpointed r1 away in paca tm_scratch and get the real
 164          * stack pointer back
 165          */
 166         std     r1, PACATMSCRATCH(r13)
 167         ld      r1, PACAR1(r13)
 168
 169         std     r11, GPR11(r1)                  /* Temporary stash */
 170
 171         /*
 172          * Move the saved user r1 to the kernel stack in case PACATMSCRATCH is
 173          * clobbered by an exception once we turn on MSR_RI below.
 174          */
 175         ld      r11, PACATMSCRATCH(r13)
 176         std     r11, GPR1(r1)
 177
 178         /*
 179          * Store r13 away so we can free up the scratch SPR for the SLB fault
 180          * handler (needed once we start accessing the thread_struct).
 181          */
 182         GET_SCRATCH0(r11)
 183         std     r11, GPR13(r1)
 184
 185         /* Reset MSR RI so we can take SLB faults again */
 186         li      r11, MSR_RI
 187         mtmsrd  r11, 1
 188
 189         /* Store the PPR in r11 and reset to decent value */
 190         mfspr   r11, SPRN_PPR
 191         HMT_MEDIUM
 192
 193         /* Now get some more GPRS free */
 194         std     r7, GPR7(r1)                    /* Temporary stash */
 195         std     r12, GPR12(r1)                  /* ''   ''    ''   */
 196         ld      r12, STK_PARAM(R3)(r1)          /* Param 0, thread_struct * */
 197
 198         std     r11, THREAD_TM_PPR(r12)         /* Store PPR and free r11 */
 199
 200         addi    r7, r12, PT_CKPT_REGS           /* Thread's ckpt_regs */
 201
 202         /* Make r7 look like an exception frame so that we
 203          * can use the neat GPRx(n) macros.  r7 is NOT a pt_regs ptr!
 204          */
 205         subi    r7, r7, STACK_FRAME_OVERHEAD
 206
 207         /* Sync the userland GPRs 2-12, 14-31 to thread->regs: */
 208         SAVE_GPR(0, r7)                         /* user r0 */
 209         SAVE_GPR(2, r7)                 /* user r2 */
 210         SAVE_4GPRS(3, r7)                       /* user r3-r6 */
 211         SAVE_GPR(8, r7)                         /* user r8 */
 212         SAVE_GPR(9, r7)                         /* user r9 */
 213         SAVE_GPR(10, r7)                        /* user r10 */
 214         ld      r3, GPR1(r1)                    /* user r1 */
 215         ld      r4, GPR7(r1)                    /* user r7 */
 216         ld      r5, GPR11(r1)                   /* user r11 */
 217         ld      r6, GPR12(r1)                   /* user r12 */
 218         ld      r8, GPR13(r1)                   /* user r13 */
 219         std     r3, GPR1(r7)
 220         std     r4, GPR7(r7)
 221         std     r5, GPR11(r7)
 222         std     r6, GPR12(r7)
 223         std     r8, GPR13(r7)
 224
 225         SAVE_NVGPRS(r7)                         /* user r14-r31 */
 226
 227         /* ******************** NIP ******************** */
 228         mfspr   r3, SPRN_TFHAR
 229         std     r3, _NIP(r7)                    /* Returns to failhandler */
 230         /* The checkpointed NIP is ignored when rescheduling/rechkpting,
 231          * but is used in signal return to 'wind back' to the abort handler.
 232          */
 233
 234         /* ******************** CR,LR,CCR,MSR ********** */
 235         mfctr   r3
 236         mflr    r4
 237         mfcr    r5
 238         mfxer   r6
 239
 240         std     r3, _CTR(r7)
 241         std     r4, _LINK(r7)
 242         std     r5, _CCR(r7)
 243         std     r6, _XER(r7)
 244
 245
 246         /* ******************** TAR, DSCR ********** */
 247         mfspr   r3, SPRN_TAR
 248         mfspr   r4, SPRN_DSCR
 249
 250         std     r3, THREAD_TM_TAR(r12)
 251         std     r4, THREAD_TM_DSCR(r12)
 252
 253         /* MSR and flags:  We don't change CRs, and we don't need to alter
 254          * MSR.
 255          */
 256
 257
 258         /* ******************** FPR/VR/VSRs ************
 259          * After reclaiming, capture the checkpointed FPRs/VRs /if used/.
 260          *
 261          * (If VSX used, FP and VMX are implied.  Or, we don't need to look
 262          * at MSR.VSX as copying FP regs if .FP, vector regs if .VMX covers it.)
 263          *
 264          * We're passed the thread's MSR as the second parameter
 265          *
 266          * We enabled VEC/FP/VSX in the msr above, so we can execute these
 267          * instructions!
 268          */
 269         ld      r4, STK_PARAM(R4)(r1)           /* Second parameter, MSR * */
 270         mr      r3, r12
 271         andis.          r0, r4, MSR_VEC@h
 272         beq     dont_backup_vec
 273
 274         addi    r7, r3, THREAD_CKVRSTATE
 275         SAVE_32VRS(0, r6, r7)   /* r6 scratch, r7 transact vr state */
 276         mfvscr  v0
 277         li      r6, VRSTATE_VSCR
 278         stvx    v0, r7, r6
 279 dont_backup_vec:
 280         mfspr   r0, SPRN_VRSAVE
 281         std     r0, THREAD_CKVRSAVE(r3)
 282
 283         andi.   r0, r4, MSR_FP
 284         beq     dont_backup_fp
 285
 286         addi    r7, r3, THREAD_CKFPSTATE
 287         SAVE_32FPRS_VSRS(0, R6, R7)     /* r6 scratch, r7 transact fp state */
 288
 289         mffs    fr0
 290         stfd    fr0,FPSTATE_FPSCR(r7)
 291
 292 dont_backup_fp:
 293
 294         /* TM regs, incl TEXASR -- these live in thread_struct.  Note they've
 295          * been updated by the treclaim, to explain to userland the failure
 296          * cause (aborted).
 297          */
 298         mfspr   r0, SPRN_TEXASR
 299         mfspr   r3, SPRN_TFHAR
 300         mfspr   r4, SPRN_TFIAR
 301         std     r0, THREAD_TM_TEXASR(r12)
 302         std     r3, THREAD_TM_TFHAR(r12)
 303         std     r4, THREAD_TM_TFIAR(r12)
 304
 305         /* AMR is checkpointed too, but is unsupported by Linux. */
 306
 307         /* Restore original MSR/IRQ state & clear TM mode */
 308         ld      r14, TM_FRAME_L0(r1)            /* Orig MSR */
 309
 310         li      r15, 0
 311         rldimi  r14, r15, MSR_TS_LG, (63-MSR_TS_LG)-1
 312         mtmsrd  r14
 313
 314         REST_NVGPRS(r1)
 315
 316         addi    r1, r1, TM_FRAME_SIZE
 317         lwz     r4, 8(r1)
 318         ld      r0, 16(r1)
 319         mtcr    r4
 320         mtlr    r0
 321         ld      r2, STK_GOT(r1)
 322
 323         /* Load CPU's default DSCR */
 324         ld      r0, PACA_DSCR_DEFAULT(r13)
 325         mtspr   SPRN_DSCR, r0
 326
 327         blr
 328
 329
 330         /* void tm_recheckpoint(struct thread_struct *thread,
 331          *                      unsigned long orig_msr)
 332          *      - Restore the checkpointed register state saved by tm_reclaim
 333          *        when we switch_to a process.
 334          *
 335          *      Call with IRQs off, stacks get all out of sync for
 336          *      some periods in here!
 337          */
 338 _GLOBAL(__tm_recheckpoint)
 339         mfcr    r5
 340         mflr    r0
 341         stw     r5, 8(r1)
 342         std     r0, 16(r1)
 343         std     r2, STK_GOT(r1)
 344         stdu    r1, -TM_FRAME_SIZE(r1)
 345
 346         /* We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD].
 347          * This is used for backing up the NVGPRs:
 348          */
 349         SAVE_NVGPRS(r1)
 350
 351         /* Load complete register state from ts_ckpt* registers */
 352
 353         addi    r7, r3, PT_CKPT_REGS            /* Thread's ckpt_regs */
 354
 355         /* Make r7 look like an exception frame so that we
 356          * can use the neat GPRx(n) macros.  r7 is now NOT a pt_regs ptr!
 357          */
 358         subi    r7, r7, STACK_FRAME_OVERHEAD
 359
 360         mfmsr   r6
 361         /* R4 = original MSR to indicate whether thread used FP/Vector etc. */
 362
 363         /* Enable FP/vec in MSR if necessary! */
 364         lis     r5, MSR_VEC@h
 365         ori     r5, r5, MSR_FP
 366         and.    r5, r4, r5
 367         beq     restore_gprs                    /* if neither, skip both */
 368
 369 #ifdef CONFIG_VSX
 370         BEGIN_FTR_SECTION
 371         oris    r5, r5, MSR_VSX@h
 372         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 373 #endif
 374         or      r5, r6, r5                      /* Set MSR.FP+.VSX/.VEC */
 375         mtmsr   r5
 376
 377 #ifdef CONFIG_ALTIVEC
 378         /*
 379          * FP and VEC registers: These are recheckpointed from
 380          * thread.ckfp_state and thread.ckvr_state respectively. The
 381          * thread.fp_state[] version holds the 'live' (transactional)
 382          * and will be loaded subsequently by any FPUnavailable trap.
 383          */
 384         andis.  r0, r4, MSR_VEC@h
 385         beq     dont_restore_vec
 386
 387         addi    r8, r3, THREAD_CKVRSTATE
 388         li      r5, VRSTATE_VSCR
 389         lvx     v0, r8, r5
 390         mtvscr  v0
 391         REST_32VRS(0, r5, r8)                   /* r5 scratch, r8 ptr */
 392 dont_restore_vec:
 393         ld      r5, THREAD_CKVRSAVE(r3)
 394         mtspr   SPRN_VRSAVE, r5
 395 #endif
 396
 397         andi.   r0, r4, MSR_FP
 398         beq     dont_restore_fp
 399
 400         addi    r8, r3, THREAD_CKFPSTATE
 401         lfd     fr0, FPSTATE_FPSCR(r8)
 402         MTFSF_L(fr0)
 403         REST_32FPRS_VSRS(0, R4, R8)
 404
 405 dont_restore_fp:
 406         mtmsr   r6                              /* FP/Vec off again! */
 407
 408 restore_gprs:
 409
 410         /* ******************** CR,LR,CCR,MSR ********** */
 411         ld      r4, _CTR(r7)
 412         ld      r5, _LINK(r7)
 413         ld      r8, _XER(r7)
 414
 415         mtctr   r4
 416         mtlr    r5
 417         mtxer   r8
 418
 419         /* ******************** TAR ******************** */
 420         ld      r4, THREAD_TM_TAR(r3)
 421         mtspr   SPRN_TAR,       r4
 422
 423         /* Load up the PPR and DSCR in GPRs only at this stage */
 424         ld      r5, THREAD_TM_DSCR(r3)
 425         ld      r6, THREAD_TM_PPR(r3)
 426
 427         REST_GPR(0, r7)                         /* GPR0 */
 428         REST_2GPRS(2, r7)                       /* GPR2-3 */
 429         REST_GPR(4, r7)                         /* GPR4 */
 430         REST_4GPRS(8, r7)                       /* GPR8-11 */
 431         REST_2GPRS(12, r7)                      /* GPR12-13 */
 432
 433         REST_NVGPRS(r7)                         /* GPR14-31 */
 434
 435         /* Load up PPR and DSCR here so we don't run with user values for long
 436          */
 437         mtspr   SPRN_DSCR, r5
 438         mtspr   SPRN_PPR, r6
 439
 440         /* Do final sanity check on TEXASR to make sure FS is set.  Do this
 441          * here before we load up the userspace r1 so any bugs we hit will get
 442          * a call chain */
 443         mfspr   r5, SPRN_TEXASR
 444         srdi    r5, r5, 16
 445         li      r6, (TEXASR_FS)@h
 446         and     r6, r6, r5
 447 1:      tdeqi   r6, 0
 448         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 449
 450         /* Do final sanity check on MSR to make sure we are not transactional
 451          * or suspended
 452          */
 453         mfmsr   r6
 454         li      r5, (MSR_TS_MASK)@higher
 455         srdi    r6, r6, 32
 456         and     r6, r6, r5
 457 1:      tdnei   r6, 0
 458         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 459
 460         /* Restore CR */
 461         ld      r6, _CCR(r7)
 462         mtcr    r6
 463
 464         REST_GPR(6, r7)
 465
 466         /*
 467          * Store r1 and r5 on the stack so that we can access them
 468          * after we clear MSR RI.
 469          */
 470
 471         REST_GPR(5, r7)
 472         std     r5, -8(r1)
 473         ld      r5, GPR1(r7)
 474         std     r5, -16(r1)
 475
 476         REST_GPR(7, r7)
 477
 478         /* Clear MSR RI since we are about to change r1. EE is already off */
 479         li      r5, 0
 480         mtmsrd  r5, 1
 481
 482         /*
 483          * BE CAREFUL HERE:
 484          * At this point we can't take an SLB miss since we have MSR_RI
 485          * off. Load only to/from the stack/paca which are in SLB bolted regions
 486          * until we turn MSR RI back on.
 487          */
 488
 489         SET_SCRATCH0(r1)
 490         ld      r5, -8(r1)
 491         ld      r1, -16(r1)
 492
 493         /* Commit register state as checkpointed state: */
 494         TRECHKPT
 495
 496         HMT_MEDIUM
 497
 498         /* Our transactional state has now changed.
 499          *
 500          * Now just get out of here.  Transactional (current) state will be
 501          * updated once restore is called on the return path in the _switch-ed
 502          * -to process.
 503          */
 504
 505         GET_PACA(r13)
 506         GET_SCRATCH0(r1)
 507
 508         /* R1 is restored, so we are recoverable again.  EE is still off */
 509         li      r4, MSR_RI
 510         mtmsrd  r4, 1
 511
 512         REST_NVGPRS(r1)
 513
 514         addi    r1, r1, TM_FRAME_SIZE
 515         lwz     r4, 8(r1)
 516         ld      r0, 16(r1)
 517         mtcr    r4
 518         mtlr    r0
 519         ld      r2, STK_GOT(r1)
 520
 521         /* Load CPU's default DSCR */
 522         ld      r0, PACA_DSCR_DEFAULT(r13)
 523         mtspr   SPRN_DSCR, r0
 524
 525         blr
 526
 527         /* ****************************************************************** */