arch/powerpc/kernel/head_40x.S

   1 /* SPDX-License-Identifier: GPL-2.0-or-later */
   2 /*
   3  *    Copyright (c) 1995-1996 Gary Thomas <gdt@linuxppc.org>
   4  *      Initial PowerPC version.
   5  *    Copyright (c) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *      Rewritten for PReP
   7  *    Copyright (c) 1996 Paul Mackerras <paulus@cs.anu.edu.au>
   8  *      Low-level exception handers, MMU support, and rewrite.
   9  *    Copyright (c) 1997 Dan Malek <dmalek@jlc.net>
  10  *      PowerPC 8xx modifications.
  11  *    Copyright (c) 1998-1999 TiVo, Inc.
  12  *      PowerPC 403GCX modifications.
  13  *    Copyright (c) 1999 Grant Erickson <grant@lcse.umn.edu>
  14  *      PowerPC 403GCX/405GP modifications.
  15  *    Copyright 2000 MontaVista Software Inc.
  16  *      PPC405 modifications
  17  *      PowerPC 403GCX/405GP modifications.
  18  *      Author: MontaVista Software, Inc.
  19  *              frank_rowand@mvista.com or source@mvista.com
  20  *              debbie_chu@mvista.com
  21  *
  22  *    Module name: head_4xx.S
  23  *
  24  *    Description:
  25  *      Kernel execution entry point code.
  26  */
  27
  28 #include <linux/init.h>
  29 #include <linux/pgtable.h>
  30 #include <linux/sizes.h>
  31 #include <asm/processor.h>
  32 #include <asm/page.h>
  33 #include <asm/mmu.h>
  34 #include <asm/cputable.h>
  35 #include <asm/thread_info.h>
  36 #include <asm/ppc_asm.h>
  37 #include <asm/asm-offsets.h>
  38 #include <asm/ptrace.h>
  39 #include <asm/export.h>
  40
  41 #include "head_32.h"
  42
  43 /* As with the other PowerPC ports, it is expected that when code
  44  * execution begins here, the following registers contain valid, yet
  45  * optional, information:
  46  *
  47  *   r3 - Board info structure pointer (DRAM, frequency, MAC address, etc.)
  48  *   r4 - Starting address of the init RAM disk
  49  *   r5 - Ending address of the init RAM disk
  50  *   r6 - Start of kernel command line string (e.g. "mem=96m")
  51  *   r7 - End of kernel command line string
  52  *
  53  * This is all going to change RSN when we add bi_recs.......  -- Dan
  54  */
  55         __HEAD
  56 _ENTRY(_stext);
  57 _ENTRY(_start);
  58
  59         mr      r31,r3                  /* save device tree ptr */
  60
  61         /* We have to turn on the MMU right away so we get cache modes
  62          * set correctly.
  63          */
  64         bl      initial_mmu
  65
  66 /* We now have the lower 16 Meg mapped into TLB entries, and the caches
  67  * ready to work.
  68  */
  69 turn_on_mmu:
  70         lis     r0,MSR_KERNEL@h
  71         ori     r0,r0,MSR_KERNEL@l
  72         mtspr   SPRN_SRR1,r0
  73         lis     r0,start_here@h
  74         ori     r0,r0,start_here@l
  75         mtspr   SPRN_SRR0,r0
  76         rfi                             /* enables MMU */
  77         b       .                       /* prevent prefetch past rfi */
  78
  79 /*
  80  * This area is used for temporarily saving registers during the
  81  * critical exception prolog.
  82  */
  83         . = 0xc0
  84 crit_save:
  85 _ENTRY(crit_r10)
  86         .space  4
  87 _ENTRY(crit_r11)
  88         .space  4
  89 _ENTRY(crit_srr0)
  90         .space  4
  91 _ENTRY(crit_srr1)
  92         .space  4
  93 _ENTRY(saved_ksp_limit)
  94         .space  4
  95
  96 /*
  97  * Exception prolog for critical exceptions.  This is a little different
  98  * from the normal exception prolog above since a critical exception
  99  * can potentially occur at any point during normal exception processing.
 100  * Thus we cannot use the same SPRG registers as the normal prolog above.
 101  * Instead we use a couple of words of memory at low physical addresses.
 102  * This is OK since we don't support SMP on these processors.
 103  */
 104 #define CRITICAL_EXCEPTION_PROLOG                                            \
 105         stw     r10,crit_r10@l(0);      /* save two registers to work with */\
 106         stw     r11,crit_r11@l(0);                                           \
 107         mfcr    r10;                    /* save CR in r10 for now          */\
 108         mfspr   r11,SPRN_SRR3;          /* check whether user or kernel    */\
 109         andi.   r11,r11,MSR_PR;                                              \
 110         lis     r11,critirq_ctx@ha;                                          \
 111         tophys(r11,r11);                                                     \
 112         lwz     r11,critirq_ctx@l(r11);                                      \
 113         beq     1f;                                                          \
 114         /* COMING FROM USER MODE */                                          \
 115         mfspr   r11,SPRN_SPRG_THREAD;   /* if from user, start at top of   */\
 116         lwz     r11,TASK_STACK-THREAD(r11); /* this thread's kernel stack */\
 117 1:      addi    r11,r11,THREAD_SIZE-INT_FRAME_SIZE; /* Alloc an excpt frm  */\
 118         tophys(r11,r11);                                                     \
 119         stw     r10,_CCR(r11);          /* save various registers          */\
 120         stw     r12,GPR12(r11);                                              \
 121         stw     r9,GPR9(r11);                                                \
 122         mflr    r10;                                                         \
 123         stw     r10,_LINK(r11);                                              \
 124         mfspr   r12,SPRN_DEAR;          /* save DEAR and ESR in the frame  */\
 125         stw     r12,_DEAR(r11);         /* since they may have had stuff   */\
 126         mfspr   r9,SPRN_ESR;            /* in them at the point where the  */\
 127         stw     r9,_ESR(r11);           /* exception was taken             */\
 128         mfspr   r12,SPRN_SRR2;                                               \
 129         stw     r1,GPR1(r11);                                                \
 130         mfspr   r9,SPRN_SRR3;                                                \
 131         stw     r1,0(r11);                                                   \
 132         tovirt(r1,r11);                                                      \
 133         rlwinm  r9,r9,0,14,12;          /* clear MSR_WE (necessary?)       */\
 134         stw     r0,GPR0(r11);                                                \
 135         lis     r10, STACK_FRAME_REGS_MARKER@ha; /* exception frame marker */\
 136         addi    r10, r10, STACK_FRAME_REGS_MARKER@l;                         \
 137         stw     r10, 8(r11);                                                 \
 138         SAVE_4GPRS(3, r11);                                                  \
 139         SAVE_2GPRS(7, r11)
 140
 141         /*
 142          * State at this point:
 143          * r9 saved in stack frame, now saved SRR3 & ~MSR_WE
 144          * r10 saved in crit_r10 and in stack frame, trashed
 145          * r11 saved in crit_r11 and in stack frame,
 146          *      now phys stack/exception frame pointer
 147          * r12 saved in stack frame, now saved SRR2
 148          * CR saved in stack frame, CR0.EQ = !SRR3.PR
 149          * LR, DEAR, ESR in stack frame
 150          * r1 saved in stack frame, now virt stack/excframe pointer
 151          * r0, r3-r8 saved in stack frame
 152          */
 153
 154 /*
 155  * Exception vectors.
 156  */
 157 #define CRITICAL_EXCEPTION(n, label, hdlr)                      \
 158         START_EXCEPTION(n, label);                              \
 159         CRITICAL_EXCEPTION_PROLOG;                              \
 160         addi    r3,r1,STACK_FRAME_OVERHEAD;                     \
 161         EXC_XFER_TEMPLATE(hdlr, n+2, (MSR_KERNEL & ~(MSR_ME|MSR_DE|MSR_CE)), \
 162                           crit_transfer_to_handler, ret_from_crit_exc)
 163
 164 /*
 165  * 0x0100 - Critical Interrupt Exception
 166  */
 167         CRITICAL_EXCEPTION(0x0100, CriticalInterrupt, unknown_exception)
 168
 169 /*
 170  * 0x0200 - Machine Check Exception
 171  */
 172         CRITICAL_EXCEPTION(0x0200, MachineCheck, machine_check_exception)
 173
 174 /*
 175  * 0x0300 - Data Storage Exception
 176  * This happens for just a few reasons.  U0 set (but we don't do that),
 177  * or zone protection fault (user violation, write to protected page).
 178  * The other Data TLB exceptions bail out to this point
 179  * if they can't resolve the lightweight TLB fault.
 180  */
 181         START_EXCEPTION(0x0300, DataStorage)
 182         EXCEPTION_PROLOG
 183         mfspr   r5, SPRN_ESR            /* Grab the ESR, save it, pass arg3 */
 184         stw     r5, _ESR(r11)
 185         mfspr   r4, SPRN_DEAR           /* Grab the DEAR, save it, pass arg2 */
 186         stw     r4, _DEAR(r11)
 187         EXC_XFER_LITE(0x300, handle_page_fault)
 188
 189 /*
 190  * 0x0400 - Instruction Storage Exception
 191  * This is caused by a fetch from non-execute or guarded pages.
 192  */
 193         START_EXCEPTION(0x0400, InstructionAccess)
 194         EXCEPTION_PROLOG
 195         mr      r4,r12                  /* Pass SRR0 as arg2 */
 196         stw     r4, _DEAR(r11)
 197         li      r5,0                    /* Pass zero as arg3 */
 198         EXC_XFER_LITE(0x400, handle_page_fault)
 199
 200 /* 0x0500 - External Interrupt Exception */
 201         EXCEPTION(0x0500, HardwareInterrupt, do_IRQ, EXC_XFER_LITE)
 202
 203 /* 0x0600 - Alignment Exception */
 204         START_EXCEPTION(0x0600, Alignment)
 205         EXCEPTION_PROLOG
 206         mfspr   r4,SPRN_DEAR            /* Grab the DEAR and save it */
 207         stw     r4,_DEAR(r11)
 208         addi    r3,r1,STACK_FRAME_OVERHEAD
 209         EXC_XFER_STD(0x600, alignment_exception)
 210
 211 /* 0x0700 - Program Exception */
 212         START_EXCEPTION(0x0700, ProgramCheck)
 213         EXCEPTION_PROLOG
 214         mfspr   r4,SPRN_ESR             /* Grab the ESR and save it */
 215         stw     r4,_ESR(r11)
 216         addi    r3,r1,STACK_FRAME_OVERHEAD
 217         EXC_XFER_STD(0x700, program_check_exception)
 218
 219         EXCEPTION(0x0800, Trap_08, unknown_exception, EXC_XFER_STD)
 220         EXCEPTION(0x0900, Trap_09, unknown_exception, EXC_XFER_STD)
 221         EXCEPTION(0x0A00, Trap_0A, unknown_exception, EXC_XFER_STD)
 222         EXCEPTION(0x0B00, Trap_0B, unknown_exception, EXC_XFER_STD)
 223
 224 /* 0x0C00 - System Call Exception */
 225         START_EXCEPTION(0x0C00, SystemCall)
 226         SYSCALL_ENTRY   0xc00
 227 /*      Trap_0D is commented out to get more space for system call exception */
 228
 229 /*      EXCEPTION(0x0D00, Trap_0D, unknown_exception, EXC_XFER_STD) */
 230         EXCEPTION(0x0E00, Trap_0E, unknown_exception, EXC_XFER_STD)
 231         EXCEPTION(0x0F00, Trap_0F, unknown_exception, EXC_XFER_STD)
 232
 233 /* 0x1000 - Programmable Interval Timer (PIT) Exception */
 234         . = 0x1000
 235         b Decrementer
 236
 237 /* 0x1010 - Fixed Interval Timer (FIT) Exception
 238 */
 239         . = 0x1010
 240         b FITException
 241
 242 /* 0x1020 - Watchdog Timer (WDT) Exception
 243 */
 244         . = 0x1020
 245         b WDTException
 246
 247 /* 0x1100 - Data TLB Miss Exception
 248  * As the name implies, translation is not in the MMU, so search the
 249  * page tables and fix it.  The only purpose of this function is to
 250  * load TLB entries from the page table if they exist.
 251  */
 252         START_EXCEPTION(0x1100, DTLBMiss)
 253         mtspr   SPRN_SPRG_SCRATCH0, r10 /* Save some working registers */
 254         mtspr   SPRN_SPRG_SCRATCH1, r11
 255         mtspr   SPRN_SPRG_SCRATCH3, r12
 256         mtspr   SPRN_SPRG_SCRATCH4, r9
 257         mfcr    r12
 258         mfspr   r9, SPRN_PID
 259         mtspr   SPRN_SPRG_SCRATCH5, r9
 260         mfspr   r10, SPRN_DEAR          /* Get faulting address */
 261
 262         /* If we are faulting a kernel address, we have to use the
 263          * kernel page tables.
 264          */
 265         lis     r11, PAGE_OFFSET@h
 266         cmplw   r10, r11
 267         blt+    3f
 268         lis     r11, swapper_pg_dir@h
 269         ori     r11, r11, swapper_pg_dir@l
 270         li      r9, 0
 271         mtspr   SPRN_PID, r9            /* TLB will have 0 TID */
 272         b       4f
 273
 274         /* Get the PGD for the current thread.
 275          */
 276 3:
 277         mfspr   r11,SPRN_SPRG_THREAD
 278         lwz     r11,PGDIR(r11)
 279 4:
 280         tophys(r11, r11)
 281         rlwimi  r11, r10, 12, 20, 29    /* Create L1 (pgdir/pmd) address */
 282         lwz     r11, 0(r11)             /* Get L1 entry */
 283         andi.   r9, r11, _PMD_PRESENT   /* Check if it points to a PTE page */
 284         beq     2f                      /* Bail if no table */
 285
 286         rlwimi  r11, r10, 22, 20, 29    /* Compute PTE address */
 287         lwz     r11, 0(r11)             /* Get Linux PTE */
 288         li      r9, _PAGE_PRESENT | _PAGE_ACCESSED
 289         andc.   r9, r9, r11             /* Check permission */
 290         bne     5f
 291
 292         rlwinm  r9, r11, 1, _PAGE_RW    /* dirty => rw */
 293         and     r9, r9, r11             /* hwwrite = dirty & rw */
 294         rlwimi  r11, r9, 0, _PAGE_RW    /* replace rw by hwwrite */
 295
 296         /* Create TLB tag.  This is the faulting address plus a static
 297          * set of bits.  These are size, valid, E, U0.
 298         */
 299         li      r9, 0x00c0
 300         rlwimi  r10, r9, 0, 20, 31
 301
 302         b       finish_tlb_load
 303
 304 2:      /* Check for possible large-page pmd entry */
 305         rlwinm. r9, r11, 2, 22, 24
 306         beq     5f
 307
 308         /* Create TLB tag.  This is the faulting address, plus a static
 309          * set of bits (valid, E, U0) plus the size from the PMD.
 310          */
 311         ori     r9, r9, 0x40
 312         rlwimi  r10, r9, 0, 20, 31
 313
 314         b       finish_tlb_load
 315
 316 5:
 317         /* The bailout.  Restore registers to pre-exception conditions
 318          * and call the heavyweights to help us out.
 319          */
 320         mfspr   r9, SPRN_SPRG_SCRATCH5
 321         mtspr   SPRN_PID, r9
 322         mtcr    r12
 323         mfspr   r9, SPRN_SPRG_SCRATCH4
 324         mfspr   r12, SPRN_SPRG_SCRATCH3
 325         mfspr   r11, SPRN_SPRG_SCRATCH1
 326         mfspr   r10, SPRN_SPRG_SCRATCH0
 327         b       DataStorage
 328
 329 /* 0x1200 - Instruction TLB Miss Exception
 330  * Nearly the same as above, except we get our information from different
 331  * registers and bailout to a different point.
 332  */
 333         START_EXCEPTION(0x1200, ITLBMiss)
 334         mtspr   SPRN_SPRG_SCRATCH0, r10  /* Save some working registers */
 335         mtspr   SPRN_SPRG_SCRATCH1, r11
 336         mtspr   SPRN_SPRG_SCRATCH3, r12
 337         mtspr   SPRN_SPRG_SCRATCH4, r9
 338         mfcr    r12
 339         mfspr   r9, SPRN_PID
 340         mtspr   SPRN_SPRG_SCRATCH5, r9
 341         mfspr   r10, SPRN_SRR0          /* Get faulting address */
 342
 343         /* If we are faulting a kernel address, we have to use the
 344          * kernel page tables.
 345          */
 346         lis     r11, PAGE_OFFSET@h
 347         cmplw   r10, r11
 348         blt+    3f
 349         lis     r11, swapper_pg_dir@h
 350         ori     r11, r11, swapper_pg_dir@l
 351         li      r9, 0
 352         mtspr   SPRN_PID, r9            /* TLB will have 0 TID */
 353         b       4f
 354
 355         /* Get the PGD for the current thread.
 356          */
 357 3:
 358         mfspr   r11,SPRN_SPRG_THREAD
 359         lwz     r11,PGDIR(r11)
 360 4:
 361         tophys(r11, r11)
 362         rlwimi  r11, r10, 12, 20, 29    /* Create L1 (pgdir/pmd) address */
 363         lwz     r11, 0(r11)             /* Get L1 entry */
 364         andi.   r9, r11, _PMD_PRESENT   /* Check if it points to a PTE page */
 365         beq     2f                      /* Bail if no table */
 366
 367         rlwimi  r11, r10, 22, 20, 29    /* Compute PTE address */
 368         lwz     r11, 0(r11)             /* Get Linux PTE */
 369         li      r9, _PAGE_PRESENT | _PAGE_ACCESSED | _PAGE_EXEC
 370         andc.   r9, r9, r11             /* Check permission */
 371         bne     5f
 372
 373         rlwinm  r9, r11, 1, _PAGE_RW    /* dirty => rw */
 374         and     r9, r9, r11             /* hwwrite = dirty & rw */
 375         rlwimi  r11, r9, 0, _PAGE_RW    /* replace rw by hwwrite */
 376
 377         /* Create TLB tag.  This is the faulting address plus a static
 378          * set of bits.  These are size, valid, E, U0.
 379         */
 380         li      r9, 0x00c0
 381         rlwimi  r10, r9, 0, 20, 31
 382
 383         b       finish_tlb_load
 384
 385 2:      /* Check for possible large-page pmd entry */
 386         rlwinm. r9, r11, 2, 22, 24
 387         beq     5f
 388
 389         /* Create TLB tag.  This is the faulting address, plus a static
 390          * set of bits (valid, E, U0) plus the size from the PMD.
 391          */
 392         ori     r9, r9, 0x40
 393         rlwimi  r10, r9, 0, 20, 31
 394
 395         b       finish_tlb_load
 396
 397 5:
 398         /* The bailout.  Restore registers to pre-exception conditions
 399          * and call the heavyweights to help us out.
 400          */
 401         mfspr   r9, SPRN_SPRG_SCRATCH5
 402         mtspr   SPRN_PID, r9
 403         mtcr    r12
 404         mfspr   r9, SPRN_SPRG_SCRATCH4
 405         mfspr   r12, SPRN_SPRG_SCRATCH3
 406         mfspr   r11, SPRN_SPRG_SCRATCH1
 407         mfspr   r10, SPRN_SPRG_SCRATCH0
 408         b       InstructionAccess
 409
 410         EXCEPTION(0x1300, Trap_13, unknown_exception, EXC_XFER_STD)
 411         EXCEPTION(0x1400, Trap_14, unknown_exception, EXC_XFER_STD)
 412         EXCEPTION(0x1500, Trap_15, unknown_exception, EXC_XFER_STD)
 413         EXCEPTION(0x1600, Trap_16, unknown_exception, EXC_XFER_STD)
 414         EXCEPTION(0x1700, Trap_17, unknown_exception, EXC_XFER_STD)
 415         EXCEPTION(0x1800, Trap_18, unknown_exception, EXC_XFER_STD)
 416         EXCEPTION(0x1900, Trap_19, unknown_exception, EXC_XFER_STD)
 417         EXCEPTION(0x1A00, Trap_1A, unknown_exception, EXC_XFER_STD)
 418         EXCEPTION(0x1B00, Trap_1B, unknown_exception, EXC_XFER_STD)
 419         EXCEPTION(0x1C00, Trap_1C, unknown_exception, EXC_XFER_STD)
 420         EXCEPTION(0x1D00, Trap_1D, unknown_exception, EXC_XFER_STD)
 421         EXCEPTION(0x1E00, Trap_1E, unknown_exception, EXC_XFER_STD)
 422         EXCEPTION(0x1F00, Trap_1F, unknown_exception, EXC_XFER_STD)
 423
 424 /* Check for a single step debug exception while in an exception
 425  * handler before state has been saved.  This is to catch the case
 426  * where an instruction that we are trying to single step causes
 427  * an exception (eg ITLB/DTLB miss) and thus the first instruction of
 428  * the exception handler generates a single step debug exception.
 429  *
 430  * If we get a debug trap on the first instruction of an exception handler,
 431  * we reset the MSR_DE in the _exception handler's_ MSR (the debug trap is
 432  * a critical exception, so we are using SPRN_CSRR1 to manipulate the MSR).
 433  * The exception handler was handling a non-critical interrupt, so it will
 434  * save (and later restore) the MSR via SPRN_SRR1, which will still have
 435  * the MSR_DE bit set.
 436  */
 437         /* 0x2000 - Debug Exception */
 438         START_EXCEPTION(0x2000, DebugTrap)
 439         CRITICAL_EXCEPTION_PROLOG
 440
 441         /*
 442          * If this is a single step or branch-taken exception in an
 443          * exception entry sequence, it was probably meant to apply to
 444          * the code where the exception occurred (since exception entry
 445          * doesn't turn off DE automatically).  We simulate the effect
 446          * of turning off DE on entry to an exception handler by turning
 447          * off DE in the SRR3 value and clearing the debug status.
 448          */
 449         mfspr   r10,SPRN_DBSR           /* check single-step/branch taken */
 450         andis.  r10,r10,DBSR_IC@h
 451         beq+    2f
 452
 453         andi.   r10,r9,MSR_IR|MSR_PR    /* check supervisor + MMU off */
 454         beq     1f                      /* branch and fix it up */
 455
 456         mfspr   r10,SPRN_SRR2           /* Faulting instruction address */
 457         cmplwi  r10,0x2100
 458         bgt+    2f                      /* address above exception vectors */
 459
 460         /* here it looks like we got an inappropriate debug exception. */
 461 1:      rlwinm  r9,r9,0,~MSR_DE         /* clear DE in the SRR3 value */
 462         lis     r10,DBSR_IC@h           /* clear the IC event */
 463         mtspr   SPRN_DBSR,r10
 464         /* restore state and get out */
 465         lwz     r10,_CCR(r11)
 466         lwz     r0,GPR0(r11)
 467         lwz     r1,GPR1(r11)
 468         mtcrf   0x80,r10
 469         mtspr   SPRN_SRR2,r12
 470         mtspr   SPRN_SRR3,r9
 471         lwz     r9,GPR9(r11)
 472         lwz     r12,GPR12(r11)
 473         lwz     r10,crit_r10@l(0)
 474         lwz     r11,crit_r11@l(0)
 475         rfci
 476         b       .
 477
 478         /* continue normal handling for a critical exception... */
 479 2:      mfspr   r4,SPRN_DBSR
 480         addi    r3,r1,STACK_FRAME_OVERHEAD
 481         EXC_XFER_TEMPLATE(DebugException, 0x2002, \
 482                 (MSR_KERNEL & ~(MSR_ME|MSR_DE|MSR_CE)), \
 483                 crit_transfer_to_handler, ret_from_crit_exc)
 484
 485         /* Programmable Interval Timer (PIT) Exception. (from 0x1000) */
 486 Decrementer:
 487         EXCEPTION_PROLOG
 488         lis     r0,TSR_PIS@h
 489         mtspr   SPRN_TSR,r0             /* Clear the PIT exception */
 490         addi    r3,r1,STACK_FRAME_OVERHEAD
 491         EXC_XFER_LITE(0x1000, timer_interrupt)
 492
 493         /* Fixed Interval Timer (FIT) Exception. (from 0x1010) */
 494 FITException:
 495         EXCEPTION_PROLOG
 496         addi    r3,r1,STACK_FRAME_OVERHEAD;
 497         EXC_XFER_STD(0x1010, unknown_exception)
 498
 499         /* Watchdog Timer (WDT) Exception. (from 0x1020) */
 500 WDTException:
 501         CRITICAL_EXCEPTION_PROLOG;
 502         addi    r3,r1,STACK_FRAME_OVERHEAD;
 503         EXC_XFER_TEMPLATE(WatchdogException, 0x1020+2,
 504                           (MSR_KERNEL & ~(MSR_ME|MSR_DE|MSR_CE)),
 505                           crit_transfer_to_handler, ret_from_crit_exc)
 506
 507 /* Other PowerPC processors, namely those derived from the 6xx-series
 508  * have vectors from 0x2100 through 0x2F00 defined, but marked as reserved.
 509  * However, for the 4xx-series processors these are neither defined nor
 510  * reserved.
 511  */
 512
 513         /* Damn, I came up one instruction too many to fit into the
 514          * exception space :-).  Both the instruction and data TLB
 515          * miss get to this point to load the TLB.
 516          *      r10 - TLB_TAG value
 517          *      r11 - Linux PTE
 518          *      r9 - available to use
 519          *      PID - loaded with proper value when we get here
 520          *      Upon exit, we reload everything and RFI.
 521          * Actually, it will fit now, but oh well.....a common place
 522          * to load the TLB.
 523          */
 524 tlb_4xx_index:
 525         .long   0
 526 finish_tlb_load:
 527         /*
 528          * Clear out the software-only bits in the PTE to generate the
 529          * TLB_DATA value.  These are the bottom 2 bits of the RPM, the
 530          * top 3 bits of the zone field, and M.
 531          */
 532         li      r9, 0x0ce2
 533         andc    r11, r11, r9
 534
 535         /* load the next available TLB index. */
 536         lwz     r9, tlb_4xx_index@l(0)
 537         addi    r9, r9, 1
 538         andi.   r9, r9, PPC40X_TLB_SIZE - 1
 539         stw     r9, tlb_4xx_index@l(0)
 540
 541         tlbwe   r11, r9, TLB_DATA               /* Load TLB LO */
 542         tlbwe   r10, r9, TLB_TAG                /* Load TLB HI */
 543
 544         /* Done...restore registers and get out of here.
 545         */
 546         mfspr   r9, SPRN_SPRG_SCRATCH5
 547         mtspr   SPRN_PID, r9
 548         mtcr    r12
 549         mfspr   r9, SPRN_SPRG_SCRATCH4
 550         mfspr   r12, SPRN_SPRG_SCRATCH3
 551         mfspr   r11, SPRN_SPRG_SCRATCH1
 552         mfspr   r10, SPRN_SPRG_SCRATCH0
 553         rfi                     /* Should sync shadow TLBs */
 554         b       .               /* prevent prefetch past rfi */
 555
 556 /* This is where the main kernel code starts.
 557  */
 558 start_here:
 559
 560         /* ptr to current */
 561         lis     r2,init_task@h
 562         ori     r2,r2,init_task@l
 563
 564         /* ptr to phys current thread */
 565         tophys(r4,r2)
 566         addi    r4,r4,THREAD    /* init task's THREAD */
 567         mtspr   SPRN_SPRG_THREAD,r4
 568
 569         /* stack */
 570         lis     r1,init_thread_union@ha
 571         addi    r1,r1,init_thread_union@l
 572         li      r0,0
 573         stwu    r0,THREAD_SIZE-STACK_FRAME_OVERHEAD(r1)
 574
 575         bl      early_init      /* We have to do this with MMU on */
 576
 577 /*
 578  * Decide what sort of machine this is and initialize the MMU.
 579  */
 580 #ifdef CONFIG_KASAN
 581         bl      kasan_early_init
 582 #endif
 583         li      r3,0
 584         mr      r4,r31
 585         bl      machine_init
 586         bl      MMU_init
 587
 588 /* Go back to running unmapped so we can load up new values
 589  * and change to using our exception vectors.
 590  * On the 4xx, all we have to do is invalidate the TLB to clear
 591  * the old 16M byte TLB mappings.
 592  */
 593         lis     r4,2f@h
 594         ori     r4,r4,2f@l
 595         tophys(r4,r4)
 596         lis     r3,(MSR_KERNEL & ~(MSR_IR|MSR_DR))@h
 597         ori     r3,r3,(MSR_KERNEL & ~(MSR_IR|MSR_DR))@l
 598         mtspr   SPRN_SRR0,r4
 599         mtspr   SPRN_SRR1,r3
 600         rfi
 601         b       .               /* prevent prefetch past rfi */
 602
 603 /* Load up the kernel context */
 604 2:
 605         sync                    /* Flush to memory before changing TLB */
 606         tlbia
 607         isync                   /* Flush shadow TLBs */
 608
 609         /* set up the PTE pointers for the Abatron bdiGDB.
 610         */
 611         lis     r6, swapper_pg_dir@h
 612         ori     r6, r6, swapper_pg_dir@l
 613         lis     r5, abatron_pteptrs@h
 614         ori     r5, r5, abatron_pteptrs@l
 615         stw     r5, 0xf0(0)     /* Must match your Abatron config file */
 616         tophys(r5,r5)
 617         stw     r6, 0(r5)
 618
 619 /* Now turn on the MMU for real! */
 620         lis     r4,MSR_KERNEL@h
 621         ori     r4,r4,MSR_KERNEL@l
 622         lis     r3,start_kernel@h
 623         ori     r3,r3,start_kernel@l
 624         mtspr   SPRN_SRR0,r3
 625         mtspr   SPRN_SRR1,r4
 626         rfi                     /* enable MMU and jump to start_kernel */
 627         b       .               /* prevent prefetch past rfi */
 628
 629 /* Set up the initial MMU state so we can do the first level of
 630  * kernel initialization.  This maps the first 32 MBytes of memory 1:1
 631  * virtual to physical and more importantly sets the cache mode.
 632  */
 633 initial_mmu:
 634         tlbia                   /* Invalidate all TLB entries */
 635         isync
 636
 637         /* We should still be executing code at physical address 0x0000xxxx
 638          * at this point. However, start_here is at virtual address
 639          * 0xC000xxxx. So, set up a TLB mapping to cover this once
 640          * translation is enabled.
 641          */
 642
 643         lis     r3,KERNELBASE@h         /* Load the kernel virtual address */
 644         ori     r3,r3,KERNELBASE@l
 645         tophys(r4,r3)                   /* Load the kernel physical address */
 646
 647         iccci   r0,r3                   /* Invalidate the i-cache before use */
 648
 649         /* Load the kernel PID.
 650         */
 651         li      r0,0
 652         mtspr   SPRN_PID,r0
 653         sync
 654
 655         /* Configure and load one entry into TLB slots 63 */
 656         clrrwi  r4,r4,10                /* Mask off the real page number */
 657         ori     r4,r4,(TLB_WR | TLB_EX) /* Set the write and execute bits */
 658
 659         clrrwi  r3,r3,10                /* Mask off the effective page number */
 660         ori     r3,r3,(TLB_VALID | TLB_PAGESZ(PAGESZ_16M))
 661
 662         li      r0,63                    /* TLB slot 63 */
 663
 664         tlbwe   r4,r0,TLB_DATA          /* Load the data portion of the entry */
 665         tlbwe   r3,r0,TLB_TAG           /* Load the tag portion of the entry */
 666
 667         li      r0,62                   /* TLB slot 62 */
 668         addis   r4,r4,SZ_16M@h
 669         addis   r3,r3,SZ_16M@h
 670         tlbwe   r4,r0,TLB_DATA          /* Load the data portion of the entry */
 671         tlbwe   r3,r0,TLB_TAG           /* Load the tag portion of the entry */
 672
 673         isync
 674
 675         /* Establish the exception vector base
 676         */
 677         lis     r4,KERNELBASE@h         /* EVPR only uses the high 16-bits */
 678         tophys(r0,r4)                   /* Use the physical address */
 679         mtspr   SPRN_EVPR,r0
 680
 681         blr
 682
 683 _GLOBAL(abort)
 684         mfspr   r13,SPRN_DBCR0
 685         oris    r13,r13,DBCR0_RST_SYSTEM@h
 686         mtspr   SPRN_DBCR0,r13
 687
 688 _GLOBAL(set_context)
 689
 690 #ifdef CONFIG_BDI_SWITCH
 691         /* Context switch the PTE pointer for the Abatron BDI2000.
 692          * The PGDIR is the second parameter.
 693          */
 694         lis     r5, abatron_pteptrs@ha
 695         stw     r4, abatron_pteptrs@l + 0x4(r5)
 696 #endif
 697         sync
 698         mtspr   SPRN_PID,r3
 699         isync                           /* Need an isync to flush shadow */
 700                                         /* TLBs after changing PID */
 701         blr
 702
 703 /* We put a few things here that have to be page-aligned. This stuff
 704  * goes at the beginning of the data segment, which is page-aligned.
 705  */
 706         .data
 707         .align  12
 708         .globl  sdata
 709 sdata:
 710         .globl  empty_zero_page
 711 empty_zero_page:
 712         .space  4096
 713 EXPORT_SYMBOL(empty_zero_page)
 714         .globl  swapper_pg_dir
 715 swapper_pg_dir:
 716         .space  PGD_TABLE_SIZE
 717
 718 /* Room for two PTE pointers, usually the kernel and current user pointers
 719  * to their respective root page table.
 720  */
 721 abatron_pteptrs:
 722         .space  8