arch/powerpc/kernel/exceptions-64s.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * This file contains the 64-bit "server" PowerPC variant
   4  * of the low level exception handling including exception
   5  * vectors, exception return, part of the slb and stab
   6  * handling and other fixed offset specific things.
   7  *
   8  * This file is meant to be #included from head_64.S due to
   9  * position dependent assembly.
  10  *
  11  * Most of this originates from head_64.S and thus has the same
  12  * copyright history.
  13  *
  14  */
  15
  16 #include <asm/hw_irq.h>
  17 #include <asm/exception-64s.h>
  18 #include <asm/ptrace.h>
  19 #include <asm/cpuidle.h>
  20 #include <asm/head-64.h>
  21 #include <asm/feature-fixups.h>
  22 #include <asm/kup.h>
  23
  24 /*
  25  * Following are fixed section helper macros.
  26  *
  27  * EXC_REAL_BEGIN/END  - real, unrelocated exception vectors
  28  * EXC_VIRT_BEGIN/END  - virt (AIL), unrelocated exception vectors
  29  * TRAMP_REAL_BEGIN    - real, unrelocated helpers (virt may call these)
  30  * TRAMP_VIRT_BEGIN    - virt, unreloc helpers (in practice, real can use)
  31  * EXC_COMMON          - After switching to virtual, relocated mode.
  32  */
  33
  34 #define EXC_REAL_BEGIN(name, start, size)                       \
  35         FIXED_SECTION_ENTRY_BEGIN_LOCATION(real_vectors, exc_real_##start##_##name, start, size)
  36
  37 #define EXC_REAL_END(name, start, size)                         \
  38         FIXED_SECTION_ENTRY_END_LOCATION(real_vectors, exc_real_##start##_##name, start, size)
  39
  40 #define EXC_VIRT_BEGIN(name, start, size)                       \
  41         FIXED_SECTION_ENTRY_BEGIN_LOCATION(virt_vectors, exc_virt_##start##_##name, start, size)
  42
  43 #define EXC_VIRT_END(name, start, size)                         \
  44         FIXED_SECTION_ENTRY_END_LOCATION(virt_vectors, exc_virt_##start##_##name, start, size)
  45
  46 #define EXC_COMMON_BEGIN(name)                                  \
  47         USE_TEXT_SECTION();                                     \
  48         .balign IFETCH_ALIGN_BYTES;                             \
  49         .global name;                                           \
  50         _ASM_NOKPROBE_SYMBOL(name);                             \
  51         DEFINE_FIXED_SYMBOL(name);                              \
  52 name:
  53
  54 #define TRAMP_REAL_BEGIN(name)                                  \
  55         FIXED_SECTION_ENTRY_BEGIN(real_trampolines, name)
  56
  57 #define TRAMP_VIRT_BEGIN(name)                                  \
  58         FIXED_SECTION_ENTRY_BEGIN(virt_trampolines, name)
  59
  60 #define EXC_REAL_NONE(start, size)                              \
  61         FIXED_SECTION_ENTRY_BEGIN_LOCATION(real_vectors, exc_real_##start##_##unused, start, size); \
  62         FIXED_SECTION_ENTRY_END_LOCATION(real_vectors, exc_real_##start##_##unused, start, size)
  63
  64 #define EXC_VIRT_NONE(start, size)                              \
  65         FIXED_SECTION_ENTRY_BEGIN_LOCATION(virt_vectors, exc_virt_##start##_##unused, start, size); \
  66         FIXED_SECTION_ENTRY_END_LOCATION(virt_vectors, exc_virt_##start##_##unused, start, size)
  67
  68 /*
  69  * We're short on space and time in the exception prolog, so we can't
  70  * use the normal LOAD_REG_IMMEDIATE macro to load the address of label.
  71  * Instead we get the base of the kernel from paca->kernelbase and or in the low
  72  * part of label. This requires that the label be within 64KB of kernelbase, and
  73  * that kernelbase be 64K aligned.
  74  */
  75 #define LOAD_HANDLER(reg, label)                                        \
  76         ld      reg,PACAKBASE(r13);     /* get high part of &label */   \
  77         ori     reg,reg,FIXED_SYMBOL_ABS_ADDR(label)
  78
  79 #define __LOAD_HANDLER(reg, label)                                      \
  80         ld      reg,PACAKBASE(r13);                                     \
  81         ori     reg,reg,(ABS_ADDR(label))@l
  82
  83 /*
  84  * Branches from unrelocated code (e.g., interrupts) to labels outside
  85  * head-y require >64K offsets.
  86  */
  87 #define __LOAD_FAR_HANDLER(reg, label)                                  \
  88         ld      reg,PACAKBASE(r13);                                     \
  89         ori     reg,reg,(ABS_ADDR(label))@l;                            \
  90         addis   reg,reg,(ABS_ADDR(label))@h
  91
  92 /*
  93  * Branch to label using its 0xC000 address. This results in instruction
  94  * address suitable for MSR[IR]=0 or 1, which allows relocation to be turned
  95  * on using mtmsr rather than rfid.
  96  *
  97  * This could set the 0xc bits for !RELOCATABLE as an immediate, rather than
  98  * load KBASE for a slight optimisation.
  99  */
 100 #define BRANCH_TO_C000(reg, label)                                      \
 101         __LOAD_FAR_HANDLER(reg, label);                                 \
 102         mtctr   reg;                                                    \
 103         bctr
 104
 105 /*
 106  * Interrupt code generation macros
 107  */
 108 #define IVEC            .L_IVEC_\name\()        /* Interrupt vector address */
 109 #define IHSRR           .L_IHSRR_\name\()       /* Sets SRR or HSRR registers */
 110 #define IHSRR_IF_HVMODE .L_IHSRR_IF_HVMODE_\name\() /* HSRR if HV else SRR */
 111 #define IAREA           .L_IAREA_\name\()       /* PACA save area */
 112 #define IVIRT           .L_IVIRT_\name\()       /* Has virt mode entry point */
 113 #define IISIDE          .L_IISIDE_\name\()      /* Uses SRR0/1 not DAR/DSISR */
 114 #define IDAR            .L_IDAR_\name\()        /* Uses DAR (or SRR0) */
 115 #define IDSISR          .L_IDSISR_\name\()      /* Uses DSISR (or SRR1) */
 116 #define ISET_RI         .L_ISET_RI_\name\()     /* Run common code w/ MSR[RI]=1 */
 117 #define IBRANCH_TO_COMMON       .L_IBRANCH_TO_COMMON_\name\() /* ENTRY branch to common */
 118 #define IREALMODE_COMMON        .L_IREALMODE_COMMON_\name\() /* Common runs in realmode */
 119 #define IMASK           .L_IMASK_\name\()       /* IRQ soft-mask bit */
 120 #define IKVM_REAL       .L_IKVM_REAL_\name\()   /* Real entry tests KVM */
 121 #define __IKVM_REAL(name)       .L_IKVM_REAL_ ## name
 122 #define IKVM_VIRT       .L_IKVM_VIRT_\name\()   /* Virt entry tests KVM */
 123 #define ISTACK          .L_ISTACK_\name\()      /* Set regular kernel stack */
 124 #define __ISTACK(name)  .L_ISTACK_ ## name
 125 #define IKUAP           .L_IKUAP_\name\()       /* Do KUAP lock */
 126
 127 #define INT_DEFINE_BEGIN(n)                                             \
 128 .macro int_define_ ## n name
 129
 130 #define INT_DEFINE_END(n)                                               \
 131 .endm ;                                                                 \
 132 int_define_ ## n n ;                                                    \
 133 do_define_int n
 134
 135 .macro do_define_int name
 136         .ifndef IVEC
 137                 .error "IVEC not defined"
 138         .endif
 139         .ifndef IHSRR
 140                 IHSRR=0
 141         .endif
 142         .ifndef IHSRR_IF_HVMODE
 143                 IHSRR_IF_HVMODE=0
 144         .endif
 145         .ifndef IAREA
 146                 IAREA=PACA_EXGEN
 147         .endif
 148         .ifndef IVIRT
 149                 IVIRT=1
 150         .endif
 151         .ifndef IISIDE
 152                 IISIDE=0
 153         .endif
 154         .ifndef IDAR
 155                 IDAR=0
 156         .endif
 157         .ifndef IDSISR
 158                 IDSISR=0
 159         .endif
 160         .ifndef ISET_RI
 161                 ISET_RI=1
 162         .endif
 163         .ifndef IBRANCH_TO_COMMON
 164                 IBRANCH_TO_COMMON=1
 165         .endif
 166         .ifndef IREALMODE_COMMON
 167                 IREALMODE_COMMON=0
 168         .else
 169                 .if ! IBRANCH_TO_COMMON
 170                         .error "IREALMODE_COMMON=1 but IBRANCH_TO_COMMON=0"
 171                 .endif
 172         .endif
 173         .ifndef IMASK
 174                 IMASK=0
 175         .endif
 176         .ifndef IKVM_REAL
 177                 IKVM_REAL=0
 178         .endif
 179         .ifndef IKVM_VIRT
 180                 IKVM_VIRT=0
 181         .endif
 182         .ifndef ISTACK
 183                 ISTACK=1
 184         .endif
 185         .ifndef IKUAP
 186                 IKUAP=1
 187         .endif
 188 .endm
 189
 190 /*
 191  * All interrupts which set HSRR registers, as well as SRESET and MCE and
 192  * syscall when invoked with "sc 1" switch to MSR[HV]=1 (HVMODE) to be taken,
 193  * so they all generally need to test whether they were taken in guest context.
 194  *
 195  * Note: SRESET and MCE may also be sent to the guest by the hypervisor, and be
 196  * taken with MSR[HV]=0.
 197  *
 198  * Interrupts which set SRR registers (with the above exceptions) do not
 199  * elevate to MSR[HV]=1 mode, though most can be taken when running with
 200  * MSR[HV]=1  (e.g., bare metal kernel and userspace). So these interrupts do
 201  * not need to test whether a guest is running because they get delivered to
 202  * the guest directly, including nested HV KVM guests.
 203  *
 204  * The exception is PR KVM, where the guest runs with MSR[PR]=1 and the host
 205  * runs with MSR[HV]=0, so the host takes all interrupts on behalf of the
 206  * guest. PR KVM runs with LPCR[AIL]=0 which causes interrupts to always be
 207  * delivered to the real-mode entry point, therefore such interrupts only test
 208  * KVM in their real mode handlers, and only when PR KVM is possible.
 209  *
 210  * Interrupts that are taken in MSR[HV]=0 and escalate to MSR[HV]=1 are always
 211  * delivered in real-mode when the MMU is in hash mode because the MMU
 212  * registers are not set appropriately to translate host addresses. In nested
 213  * radix mode these can be delivered in virt-mode as the host translations are
 214  * used implicitly (see: effective LPID, effective PID).
 215  */
 216
 217 /*
 218  * If an interrupt is taken while a guest is running, it is immediately routed
 219  * to KVM to handle.
 220  */
 221
 222 .macro KVMTEST name handler
 223 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
 224         lbz     r10,HSTATE_IN_GUEST(r13)
 225         cmpwi   r10,0
 226         /* HSRR variants have the 0x2 bit added to their trap number */
 227         .if IHSRR_IF_HVMODE
 228         BEGIN_FTR_SECTION
 229         li      r10,(IVEC + 0x2)
 230         FTR_SECTION_ELSE
 231         li      r10,(IVEC)
 232         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 233         .elseif IHSRR
 234         li      r10,(IVEC + 0x2)
 235         .else
 236         li      r10,(IVEC)
 237         .endif
 238         bne     \handler
 239 #endif
 240 .endm
 241
 242 /*
 243  * This is the BOOK3S interrupt entry code macro.
 244  *
 245  * This can result in one of several things happening:
 246  * - Branch to the _common handler, relocated, in virtual mode.
 247  *   These are normal interrupts (synchronous and asynchronous) handled by
 248  *   the kernel.
 249  * - Branch to KVM, relocated but real mode interrupts remain in real mode.
 250  *   These occur when HSTATE_IN_GUEST is set. The interrupt may be caused by
 251  *   / intended for host or guest kernel, but KVM must always be involved
 252  *   because the machine state is set for guest execution.
 253  * - Branch to the masked handler, unrelocated.
 254  *   These occur when maskable asynchronous interrupts are taken with the
 255  *   irq_soft_mask set.
 256  * - Branch to an "early" handler in real mode but relocated.
 257  *   This is done if early=1. MCE and HMI use these to handle errors in real
 258  *   mode.
 259  * - Fall through and continue executing in real, unrelocated mode.
 260  *   This is done if early=2.
 261  */
 262
 263 .macro GEN_BRANCH_TO_COMMON name, virt
 264         .if IREALMODE_COMMON
 265         LOAD_HANDLER(r10, \name\()_common)
 266         mtctr   r10
 267         bctr
 268         .else
 269         .if \virt
 270 #ifndef CONFIG_RELOCATABLE
 271         b       \name\()_common_virt
 272 #else
 273         LOAD_HANDLER(r10, \name\()_common_virt)
 274         mtctr   r10
 275         bctr
 276 #endif
 277         .else
 278         LOAD_HANDLER(r10, \name\()_common_real)
 279         mtctr   r10
 280         bctr
 281         .endif
 282         .endif
 283 .endm
 284
 285 .macro GEN_INT_ENTRY name, virt, ool=0
 286         SET_SCRATCH0(r13)                       /* save r13 */
 287         GET_PACA(r13)
 288         std     r9,IAREA+EX_R9(r13)             /* save r9 */
 289 BEGIN_FTR_SECTION
 290         mfspr   r9,SPRN_PPR
 291 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 292         HMT_MEDIUM
 293         std     r10,IAREA+EX_R10(r13)           /* save r10 - r12 */
 294 BEGIN_FTR_SECTION
 295         mfspr   r10,SPRN_CFAR
 296 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 297         .if \ool
 298         .if !\virt
 299         b       tramp_real_\name
 300         .pushsection .text
 301         TRAMP_REAL_BEGIN(tramp_real_\name)
 302         .else
 303         b       tramp_virt_\name
 304         .pushsection .text
 305         TRAMP_VIRT_BEGIN(tramp_virt_\name)
 306         .endif
 307         .endif
 308
 309 BEGIN_FTR_SECTION
 310         std     r9,IAREA+EX_PPR(r13)
 311 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 312 BEGIN_FTR_SECTION
 313         std     r10,IAREA+EX_CFAR(r13)
 314 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 315         INTERRUPT_TO_KERNEL
 316         mfctr   r10
 317         std     r10,IAREA+EX_CTR(r13)
 318         mfcr    r9
 319         std     r11,IAREA+EX_R11(r13)
 320         std     r12,IAREA+EX_R12(r13)
 321
 322         /*
 323          * DAR/DSISR, SCRATCH0 must be read before setting MSR[RI],
 324          * because a d-side MCE will clobber those registers so is
 325          * not recoverable if they are live.
 326          */
 327         GET_SCRATCH0(r10)
 328         std     r10,IAREA+EX_R13(r13)
 329         .if IDAR && !IISIDE
 330         .if IHSRR
 331         mfspr   r10,SPRN_HDAR
 332         .else
 333         mfspr   r10,SPRN_DAR
 334         .endif
 335         std     r10,IAREA+EX_DAR(r13)
 336         .endif
 337         .if IDSISR && !IISIDE
 338         .if IHSRR
 339         mfspr   r10,SPRN_HDSISR
 340         .else
 341         mfspr   r10,SPRN_DSISR
 342         .endif
 343         stw     r10,IAREA+EX_DSISR(r13)
 344         .endif
 345
 346         .if IHSRR_IF_HVMODE
 347         BEGIN_FTR_SECTION
 348         mfspr   r11,SPRN_HSRR0          /* save HSRR0 */
 349         mfspr   r12,SPRN_HSRR1          /* and HSRR1 */
 350         FTR_SECTION_ELSE
 351         mfspr   r11,SPRN_SRR0           /* save SRR0 */
 352         mfspr   r12,SPRN_SRR1           /* and SRR1 */
 353         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 354         .elseif IHSRR
 355         mfspr   r11,SPRN_HSRR0          /* save HSRR0 */
 356         mfspr   r12,SPRN_HSRR1          /* and HSRR1 */
 357         .else
 358         mfspr   r11,SPRN_SRR0           /* save SRR0 */
 359         mfspr   r12,SPRN_SRR1           /* and SRR1 */
 360         .endif
 361
 362         .if IBRANCH_TO_COMMON
 363         GEN_BRANCH_TO_COMMON \name \virt
 364         .endif
 365
 366         .if \ool
 367         .popsection
 368         .endif
 369 .endm
 370
 371 /*
 372  * __GEN_COMMON_ENTRY is required to receive the branch from interrupt
 373  * entry, except in the case of the real-mode handlers which require
 374  * __GEN_REALMODE_COMMON_ENTRY.
 375  *
 376  * This switches to virtual mode and sets MSR[RI].
 377  */
 378 .macro __GEN_COMMON_ENTRY name
 379 DEFINE_FIXED_SYMBOL(\name\()_common_real)
 380 \name\()_common_real:
 381         .if IKVM_REAL
 382                 KVMTEST \name kvm_interrupt
 383         .endif
 384
 385         ld      r10,PACAKMSR(r13)       /* get MSR value for kernel */
 386         /* MSR[RI] is clear iff using SRR regs */
 387         .if IHSRR_IF_HVMODE
 388         BEGIN_FTR_SECTION
 389         xori    r10,r10,MSR_RI
 390         END_FTR_SECTION_IFCLR(CPU_FTR_HVMODE)
 391         .elseif ! IHSRR
 392         xori    r10,r10,MSR_RI
 393         .endif
 394         mtmsrd  r10
 395
 396         .if IVIRT
 397         .if IKVM_VIRT
 398         b       1f /* skip the virt test coming from real */
 399         .endif
 400
 401         .balign IFETCH_ALIGN_BYTES
 402 DEFINE_FIXED_SYMBOL(\name\()_common_virt)
 403 \name\()_common_virt:
 404         .if IKVM_VIRT
 405                 KVMTEST \name kvm_interrupt
 406 1:
 407         .endif
 408         .endif /* IVIRT */
 409 .endm
 410
 411 /*
 412  * Don't switch to virt mode. Used for early MCE and HMI handlers that
 413  * want to run in real mode.
 414  */
 415 .macro __GEN_REALMODE_COMMON_ENTRY name
 416 DEFINE_FIXED_SYMBOL(\name\()_common_real)
 417 \name\()_common_real:
 418         .if IKVM_REAL
 419                 KVMTEST \name kvm_interrupt
 420         .endif
 421 .endm
 422
 423 .macro __GEN_COMMON_BODY name
 424         .if IMASK
 425                 .if ! ISTACK
 426                 .error "No support for masked interrupt to use custom stack"
 427                 .endif
 428
 429                 /* If coming from user, skip soft-mask tests. */
 430                 andi.   r10,r12,MSR_PR
 431                 bne     3f
 432
 433                 /*
 434                  * Kernel code running below __end_soft_masked may be
 435                  * implicitly soft-masked if it is within the regions
 436                  * in the soft mask table.
 437                  */
 438                 LOAD_HANDLER(r10, __end_soft_masked)
 439                 cmpld   r11,r10
 440                 bge+    1f
 441
 442                 /* SEARCH_SOFT_MASK_TABLE clobbers r9,r10,r12 */
 443                 mtctr   r12
 444                 stw     r9,PACA_EXGEN+EX_CCR(r13)
 445                 SEARCH_SOFT_MASK_TABLE
 446                 cmpdi   r12,0
 447                 mfctr   r12             /* Restore r12 to SRR1 */
 448                 lwz     r9,PACA_EXGEN+EX_CCR(r13)
 449                 beq     1f              /* Not in soft-mask table */
 450                 li      r10,IMASK
 451                 b       2f              /* In soft-mask table, always mask */
 452
 453                 /* Test the soft mask state against our interrupt's bit */
 454 1:              lbz     r10,PACAIRQSOFTMASK(r13)
 455 2:              andi.   r10,r10,IMASK
 456                 /* Associate vector numbers with bits in paca->irq_happened */
 457                 .if IVEC == 0x500 || IVEC == 0xea0
 458                 li      r10,PACA_IRQ_EE
 459                 .elseif IVEC == 0x900
 460                 li      r10,PACA_IRQ_DEC
 461                 .elseif IVEC == 0xa00 || IVEC == 0xe80
 462                 li      r10,PACA_IRQ_DBELL
 463                 .elseif IVEC == 0xe60
 464                 li      r10,PACA_IRQ_HMI
 465                 .elseif IVEC == 0xf00
 466                 li      r10,PACA_IRQ_PMI
 467                 .else
 468                 .abort "Bad maskable vector"
 469                 .endif
 470
 471                 .if IHSRR_IF_HVMODE
 472                 BEGIN_FTR_SECTION
 473                 bne     masked_Hinterrupt
 474                 FTR_SECTION_ELSE
 475                 bne     masked_interrupt
 476                 ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 477                 .elseif IHSRR
 478                 bne     masked_Hinterrupt
 479                 .else
 480                 bne     masked_interrupt
 481                 .endif
 482         .endif
 483
 484         .if ISTACK
 485         andi.   r10,r12,MSR_PR          /* See if coming from user      */
 486 3:      mr      r10,r1                  /* Save r1                      */
 487         subi    r1,r1,INT_FRAME_SIZE    /* alloc frame on kernel stack  */
 488         beq-    100f
 489         ld      r1,PACAKSAVE(r13)       /* kernel stack to use          */
 490 100:    tdgei   r1,-INT_FRAME_SIZE      /* trap if r1 is in userspace   */
 491         EMIT_BUG_ENTRY 100b,__FILE__,__LINE__,0
 492         .endif
 493
 494         std     r9,_CCR(r1)             /* save CR in stackframe        */
 495         std     r11,_NIP(r1)            /* save SRR0 in stackframe      */
 496         std     r12,_MSR(r1)            /* save SRR1 in stackframe      */
 497         std     r10,0(r1)               /* make stack chain pointer     */
 498         std     r0,GPR0(r1)             /* save r0 in stackframe        */
 499         std     r10,GPR1(r1)            /* save r1 in stackframe        */
 500
 501         /* Mark our [H]SRRs valid for return */
 502         li      r10,1
 503         .if IHSRR_IF_HVMODE
 504         BEGIN_FTR_SECTION
 505         stb     r10,PACAHSRR_VALID(r13)
 506         FTR_SECTION_ELSE
 507         stb     r10,PACASRR_VALID(r13)
 508         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 509         .elseif IHSRR
 510         stb     r10,PACAHSRR_VALID(r13)
 511         .else
 512         stb     r10,PACASRR_VALID(r13)
 513         .endif
 514
 515         .if ISET_RI
 516         li      r10,MSR_RI
 517         mtmsrd  r10,1                   /* Set MSR_RI */
 518         .endif
 519
 520         .if ISTACK
 521         .if IKUAP
 522         kuap_save_amr_and_lock r9, r10, cr1, cr0
 523         .endif
 524         beq     101f                    /* if from kernel mode          */
 525 BEGIN_FTR_SECTION
 526         ld      r9,IAREA+EX_PPR(r13)    /* Read PPR from paca           */
 527         std     r9,_PPR(r1)
 528 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 529 101:
 530         .else
 531         .if IKUAP
 532         kuap_save_amr_and_lock r9, r10, cr1
 533         .endif
 534         .endif
 535
 536         /* Save original regs values from save area to stack frame. */
 537         ld      r9,IAREA+EX_R9(r13)     /* move r9, r10 to stackframe   */
 538         ld      r10,IAREA+EX_R10(r13)
 539         std     r9,GPR9(r1)
 540         std     r10,GPR10(r1)
 541         ld      r9,IAREA+EX_R11(r13)    /* move r11 - r13 to stackframe */
 542         ld      r10,IAREA+EX_R12(r13)
 543         ld      r11,IAREA+EX_R13(r13)
 544         std     r9,GPR11(r1)
 545         std     r10,GPR12(r1)
 546         std     r11,GPR13(r1)
 547
 548         SAVE_NVGPRS(r1)
 549
 550         .if IDAR
 551         .if IISIDE
 552         ld      r10,_NIP(r1)
 553         .else
 554         ld      r10,IAREA+EX_DAR(r13)
 555         .endif
 556         std     r10,_DAR(r1)
 557         .endif
 558
 559         .if IDSISR
 560         .if IISIDE
 561         ld      r10,_MSR(r1)
 562         lis     r11,DSISR_SRR1_MATCH_64S@h
 563         and     r10,r10,r11
 564         .else
 565         lwz     r10,IAREA+EX_DSISR(r13)
 566         .endif
 567         std     r10,_DSISR(r1)
 568         .endif
 569
 570 BEGIN_FTR_SECTION
 571         ld      r10,IAREA+EX_CFAR(r13)
 572         std     r10,ORIG_GPR3(r1)
 573 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 574         ld      r10,IAREA+EX_CTR(r13)
 575         std     r10,_CTR(r1)
 576         std     r2,GPR2(r1)             /* save r2 in stackframe        */
 577         SAVE_GPRS(3, 8, r1)             /* save r3 - r8 in stackframe   */
 578         mflr    r9                      /* Get LR, later save to stack  */
 579         ld      r2,PACATOC(r13)         /* get kernel TOC into r2       */
 580         std     r9,_LINK(r1)
 581         lbz     r10,PACAIRQSOFTMASK(r13)
 582         mfspr   r11,SPRN_XER            /* save XER in stackframe       */
 583         std     r10,SOFTE(r1)
 584         std     r11,_XER(r1)
 585         li      r9,IVEC
 586         std     r9,_TRAP(r1)            /* set trap number              */
 587         li      r10,0
 588         ld      r11,exception_marker@toc(r2)
 589         std     r10,RESULT(r1)          /* clear regs->result           */
 590         std     r11,STACK_FRAME_OVERHEAD-16(r1) /* mark the frame       */
 591 .endm
 592
 593 /*
 594  * On entry r13 points to the paca, r9-r13 are saved in the paca,
 595  * r9 contains the saved CR, r11 and r12 contain the saved SRR0 and
 596  * SRR1, and relocation is on.
 597  *
 598  * If stack=0, then the stack is already set in r1, and r1 is saved in r10.
 599  * PPR save and CPU accounting is not done for the !stack case (XXX why not?)
 600  */
 601 .macro GEN_COMMON name
 602         __GEN_COMMON_ENTRY \name
 603         __GEN_COMMON_BODY \name
 604 .endm
 605
 606 .macro SEARCH_RESTART_TABLE
 607 #ifdef CONFIG_RELOCATABLE
 608         mr      r12,r2
 609         ld      r2,PACATOC(r13)
 610         LOAD_REG_ADDR(r9, __start___restart_table)
 611         LOAD_REG_ADDR(r10, __stop___restart_table)
 612         mr      r2,r12
 613 #else
 614         LOAD_REG_IMMEDIATE_SYM(r9, r12, __start___restart_table)
 615         LOAD_REG_IMMEDIATE_SYM(r10, r12, __stop___restart_table)
 616 #endif
 617 300:
 618         cmpd    r9,r10
 619         beq     302f
 620         ld      r12,0(r9)
 621         cmpld   r11,r12
 622         blt     301f
 623         ld      r12,8(r9)
 624         cmpld   r11,r12
 625         bge     301f
 626         ld      r12,16(r9)
 627         b       303f
 628 301:
 629         addi    r9,r9,24
 630         b       300b
 631 302:
 632         li      r12,0
 633 303:
 634 .endm
 635
 636 .macro SEARCH_SOFT_MASK_TABLE
 637 #ifdef CONFIG_RELOCATABLE
 638         mr      r12,r2
 639         ld      r2,PACATOC(r13)
 640         LOAD_REG_ADDR(r9, __start___soft_mask_table)
 641         LOAD_REG_ADDR(r10, __stop___soft_mask_table)
 642         mr      r2,r12
 643 #else
 644         LOAD_REG_IMMEDIATE_SYM(r9, r12, __start___soft_mask_table)
 645         LOAD_REG_IMMEDIATE_SYM(r10, r12, __stop___soft_mask_table)
 646 #endif
 647 300:
 648         cmpd    r9,r10
 649         beq     302f
 650         ld      r12,0(r9)
 651         cmpld   r11,r12
 652         blt     301f
 653         ld      r12,8(r9)
 654         cmpld   r11,r12
 655         bge     301f
 656         li      r12,1
 657         b       303f
 658 301:
 659         addi    r9,r9,16
 660         b       300b
 661 302:
 662         li      r12,0
 663 303:
 664 .endm
 665
 666 /*
 667  * Restore all registers including H/SRR0/1 saved in a stack frame of a
 668  * standard exception.
 669  */
 670 .macro EXCEPTION_RESTORE_REGS hsrr=0
 671         /* Move original SRR0 and SRR1 into the respective regs */
 672         ld      r9,_MSR(r1)
 673         li      r10,0
 674         .if \hsrr
 675         mtspr   SPRN_HSRR1,r9
 676         stb     r10,PACAHSRR_VALID(r13)
 677         .else
 678         mtspr   SPRN_SRR1,r9
 679         stb     r10,PACASRR_VALID(r13)
 680         .endif
 681         ld      r9,_NIP(r1)
 682         .if \hsrr
 683         mtspr   SPRN_HSRR0,r9
 684         .else
 685         mtspr   SPRN_SRR0,r9
 686         .endif
 687         ld      r9,_CTR(r1)
 688         mtctr   r9
 689         ld      r9,_XER(r1)
 690         mtxer   r9
 691         ld      r9,_LINK(r1)
 692         mtlr    r9
 693         ld      r9,_CCR(r1)
 694         mtcr    r9
 695         REST_GPRS(2, 13, r1)
 696         REST_GPR(0, r1)
 697         /* restore original r1. */
 698         ld      r1,GPR1(r1)
 699 .endm
 700
 701 /*
 702  * There are a few constraints to be concerned with.
 703  * - Real mode exceptions code/data must be located at their physical location.
 704  * - Virtual mode exceptions must be mapped at their 0xc000... location.
 705  * - Fixed location code must not call directly beyond the __end_interrupts
 706  *   area when built with CONFIG_RELOCATABLE. LOAD_HANDLER / bctr sequence
 707  *   must be used.
 708  * - LOAD_HANDLER targets must be within first 64K of physical 0 /
 709  *   virtual 0xc00...
 710  * - Conditional branch targets must be within +/-32K of caller.
 711  *
 712  * "Virtual exceptions" run with relocation on (MSR_IR=1, MSR_DR=1), and
 713  * therefore don't have to run in physically located code or rfid to
 714  * virtual mode kernel code. However on relocatable kernels they do have
 715  * to branch to KERNELBASE offset because the rest of the kernel (outside
 716  * the exception vectors) may be located elsewhere.
 717  *
 718  * Virtual exceptions correspond with physical, except their entry points
 719  * are offset by 0xc000000000000000 and also tend to get an added 0x4000
 720  * offset applied. Virtual exceptions are enabled with the Alternate
 721  * Interrupt Location (AIL) bit set in the LPCR. However this does not
 722  * guarantee they will be delivered virtually. Some conditions (see the ISA)
 723  * cause exceptions to be delivered in real mode.
 724  *
 725  * The scv instructions are a special case. They get a 0x3000 offset applied.
 726  * scv exceptions have unique reentrancy properties, see below.
 727  *
 728  * It's impossible to receive interrupts below 0x300 via AIL.
 729  *
 730  * KVM: None of the virtual exceptions are from the guest. Anything that
 731  * escalated to HV=1 from HV=0 is delivered via real mode handlers.
 732  *
 733  *
 734  * We layout physical memory as follows:
 735  * 0x0000 - 0x00ff : Secondary processor spin code
 736  * 0x0100 - 0x18ff : Real mode pSeries interrupt vectors
 737  * 0x1900 - 0x2fff : Real mode trampolines
 738  * 0x3000 - 0x58ff : Relon (IR=1,DR=1) mode pSeries interrupt vectors
 739  * 0x5900 - 0x6fff : Relon mode trampolines
 740  * 0x7000 - 0x7fff : FWNMI data area
 741  * 0x8000 -   .... : Common interrupt handlers, remaining early
 742  *                   setup code, rest of kernel.
 743  *
 744  * We could reclaim 0x4000-0x42ff for real mode trampolines if the space
 745  * is necessary. Until then it's more consistent to explicitly put VIRT_NONE
 746  * vectors there.
 747  */
 748 OPEN_FIXED_SECTION(real_vectors,        0x0100, 0x1900)
 749 OPEN_FIXED_SECTION(real_trampolines,    0x1900, 0x3000)
 750 OPEN_FIXED_SECTION(virt_vectors,        0x3000, 0x5900)
 751 OPEN_FIXED_SECTION(virt_trampolines,    0x5900, 0x7000)
 752
 753 #ifdef CONFIG_PPC_POWERNV
 754         .globl start_real_trampolines
 755         .globl end_real_trampolines
 756         .globl start_virt_trampolines
 757         .globl end_virt_trampolines
 758 #endif
 759
 760 #if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
 761 /*
 762  * Data area reserved for FWNMI option.
 763  * This address (0x7000) is fixed by the RPA.
 764  * pseries and powernv need to keep the whole page from
 765  * 0x7000 to 0x8000 free for use by the firmware
 766  */
 767 ZERO_FIXED_SECTION(fwnmi_page,          0x7000, 0x8000)
 768 OPEN_TEXT_SECTION(0x8000)
 769 #else
 770 OPEN_TEXT_SECTION(0x7000)
 771 #endif
 772
 773 USE_FIXED_SECTION(real_vectors)
 774
 775 /*
 776  * This is the start of the interrupt handlers for pSeries
 777  * This code runs with relocation off.
 778  * Code from here to __end_interrupts gets copied down to real
 779  * address 0x100 when we are running a relocatable kernel.
 780  * Therefore any relative branches in this section must only
 781  * branch to labels in this section.
 782  */
 783         .globl __start_interrupts
 784 __start_interrupts:
 785
 786 /**
 787  * Interrupt 0x3000 - System Call Vectored Interrupt (syscall).
 788  * This is a synchronous interrupt invoked with the "scv" instruction. The
 789  * system call does not alter the HV bit, so it is directed to the OS.
 790  *
 791  * Handling:
 792  * scv instructions enter the kernel without changing EE, RI, ME, or HV.
 793  * In particular, this means we can take a maskable interrupt at any point
 794  * in the scv handler, which is unlike any other interrupt. This is solved
 795  * by treating the instruction addresses in the handler as being soft-masked,
 796  * by adding a SOFT_MASK_TABLE entry for them.
 797  *
 798  * AIL-0 mode scv exceptions go to 0x17000-0x17fff, but we set AIL-3 and
 799  * ensure scv is never executed with relocation off, which means AIL-0
 800  * should never happen.
 801  *
 802  * Before leaving the following inside-__end_soft_masked text, at least of the
 803  * following must be true:
 804  * - MSR[PR]=1 (i.e., return to userspace)
 805  * - MSR_EE|MSR_RI is clear (no reentrant exceptions)
 806  * - Standard kernel environment is set up (stack, paca, etc)
 807  *
 808  * Call convention:
 809  *
 810  * syscall register convention is in Documentation/powerpc/syscall64-abi.rst
 811  */
 812 EXC_VIRT_BEGIN(system_call_vectored, 0x3000, 0x1000)
 813         /* SCV 0 */
 814         mr      r9,r13
 815         GET_PACA(r13)
 816         mflr    r11
 817         mfctr   r12
 818         li      r10,IRQS_ALL_DISABLED
 819         stb     r10,PACAIRQSOFTMASK(r13)
 820 #ifdef CONFIG_RELOCATABLE
 821         b       system_call_vectored_tramp
 822 #else
 823         b       system_call_vectored_common
 824 #endif
 825         nop
 826
 827         /* SCV 1 - 127 */
 828         .rept   127
 829         mr      r9,r13
 830         GET_PACA(r13)
 831         mflr    r11
 832         mfctr   r12
 833         li      r10,IRQS_ALL_DISABLED
 834         stb     r10,PACAIRQSOFTMASK(r13)
 835         li      r0,-1 /* cause failure */
 836 #ifdef CONFIG_RELOCATABLE
 837         b       system_call_vectored_sigill_tramp
 838 #else
 839         b       system_call_vectored_sigill
 840 #endif
 841         .endr
 842 EXC_VIRT_END(system_call_vectored, 0x3000, 0x1000)
 843
 844 // Treat scv vectors as soft-masked, see comment above.
 845 // Use absolute values rather than labels here, so they don't get relocated,
 846 // because this code runs unrelocated.
 847 SOFT_MASK_TABLE(0xc000000000003000, 0xc000000000004000)
 848
 849 #ifdef CONFIG_RELOCATABLE
 850 TRAMP_VIRT_BEGIN(system_call_vectored_tramp)
 851         __LOAD_HANDLER(r10, system_call_vectored_common)
 852         mtctr   r10
 853         bctr
 854
 855 TRAMP_VIRT_BEGIN(system_call_vectored_sigill_tramp)
 856         __LOAD_HANDLER(r10, system_call_vectored_sigill)
 857         mtctr   r10
 858         bctr
 859 #endif
 860
 861
 862 /* No virt vectors corresponding with 0x0..0x100 */
 863 EXC_VIRT_NONE(0x4000, 0x100)
 864
 865
 866 /**
 867  * Interrupt 0x100 - System Reset Interrupt (SRESET aka NMI).
 868  * This is a non-maskable, asynchronous interrupt always taken in real-mode.
 869  * It is caused by:
 870  * - Wake from power-saving state, on powernv.
 871  * - An NMI from another CPU, triggered by firmware or hypercall.
 872  * - As crash/debug signal injected from BMC, firmware or hypervisor.
 873  *
 874  * Handling:
 875  * Power-save wakeup is the only performance critical path, so this is
 876  * determined quickly as possible first. In this case volatile registers
 877  * can be discarded and SPRs like CFAR don't need to be read.
 878  *
 879  * If not a powersave wakeup, then it's run as a regular interrupt, however
 880  * it uses its own stack and PACA save area to preserve the regular kernel
 881  * environment for debugging.
 882  *
 883  * This interrupt is not maskable, so triggering it when MSR[RI] is clear,
 884  * or SCRATCH0 is in use, etc. may cause a crash. It's also not entirely
 885  * correct to switch to virtual mode to run the regular interrupt handler
 886  * because it might be interrupted when the MMU is in a bad state (e.g., SLB
 887  * is clear).
 888  *
 889  * FWNMI:
 890  * PAPR specifies a "fwnmi" facility which sends the sreset to a different
 891  * entry point with a different register set up. Some hypervisors will
 892  * send the sreset to 0x100 in the guest if it is not fwnmi capable.
 893  *
 894  * KVM:
 895  * Unlike most SRR interrupts, this may be taken by the host while executing
 896  * in a guest, so a KVM test is required. KVM will pull the CPU out of guest
 897  * mode and then raise the sreset.
 898  */
 899 INT_DEFINE_BEGIN(system_reset)
 900         IVEC=0x100
 901         IAREA=PACA_EXNMI
 902         IVIRT=0 /* no virt entry point */
 903         /*
 904          * MSR_RI is not enabled, because PACA_EXNMI and nmi stack is
 905          * being used, so a nested NMI exception would corrupt it.
 906          */
 907         ISET_RI=0
 908         ISTACK=0
 909         IKVM_REAL=1
 910 INT_DEFINE_END(system_reset)
 911
 912 EXC_REAL_BEGIN(system_reset, 0x100, 0x100)
 913 #ifdef CONFIG_PPC_P7_NAP
 914         /*
 915          * If running native on arch 2.06 or later, check if we are waking up
 916          * from nap/sleep/winkle, and branch to idle handler. This tests SRR1
 917          * bits 46:47. A non-0 value indicates that we are coming from a power
 918          * saving state. The idle wakeup handler initially runs in real mode,
 919          * but we branch to the 0xc000... address so we can turn on relocation
 920          * with mtmsrd later, after SPRs are restored.
 921          *
 922          * Careful to minimise cost for the fast path (idle wakeup) while
 923          * also avoiding clobbering CFAR for the debug path (non-idle).
 924          *
 925          * For the idle wake case volatile registers can be clobbered, which
 926          * is why we use those initially. If it turns out to not be an idle
 927          * wake, carefully put everything back the way it was, so we can use
 928          * common exception macros to handle it.
 929          */
 930 BEGIN_FTR_SECTION
 931         SET_SCRATCH0(r13)
 932         GET_PACA(r13)
 933         std     r3,PACA_EXNMI+0*8(r13)
 934         std     r4,PACA_EXNMI+1*8(r13)
 935         std     r5,PACA_EXNMI+2*8(r13)
 936         mfspr   r3,SPRN_SRR1
 937         mfocrf  r4,0x80
 938         rlwinm. r5,r3,47-31,30,31
 939         bne+    system_reset_idle_wake
 940         /* Not powersave wakeup. Restore regs for regular interrupt handler. */
 941         mtocrf  0x80,r4
 942         ld      r3,PACA_EXNMI+0*8(r13)
 943         ld      r4,PACA_EXNMI+1*8(r13)
 944         ld      r5,PACA_EXNMI+2*8(r13)
 945         GET_SCRATCH0(r13)
 946 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 947 #endif
 948
 949         GEN_INT_ENTRY system_reset, virt=0
 950         /*
 951          * In theory, we should not enable relocation here if it was disabled
 952          * in SRR1, because the MMU may not be configured to support it (e.g.,
 953          * SLB may have been cleared). In practice, there should only be a few
 954          * small windows where that's the case, and sreset is considered to
 955          * be dangerous anyway.
 956          */
 957 EXC_REAL_END(system_reset, 0x100, 0x100)
 958 EXC_VIRT_NONE(0x4100, 0x100)
 959
 960 #ifdef CONFIG_PPC_P7_NAP
 961 TRAMP_REAL_BEGIN(system_reset_idle_wake)
 962         /* We are waking up from idle, so may clobber any volatile register */
 963         cmpwi   cr1,r5,2
 964         bltlr   cr1     /* no state loss, return to idle caller with r3=SRR1 */
 965         BRANCH_TO_C000(r12, DOTSYM(idle_return_gpr_loss))
 966 #endif
 967
 968 #ifdef CONFIG_PPC_PSERIES
 969 /*
 970  * Vectors for the FWNMI option.  Share common code.
 971  */
 972 TRAMP_REAL_BEGIN(system_reset_fwnmi)
 973         GEN_INT_ENTRY system_reset, virt=0
 974
 975 #endif /* CONFIG_PPC_PSERIES */
 976
 977 EXC_COMMON_BEGIN(system_reset_common)
 978         __GEN_COMMON_ENTRY system_reset
 979         /*
 980          * Increment paca->in_nmi then enable MSR_RI. SLB or MCE will be able
 981          * to recover, but nested NMI will notice in_nmi and not recover
 982          * because of the use of the NMI stack. in_nmi reentrancy is tested in
 983          * system_reset_exception.
 984          */
 985         lhz     r10,PACA_IN_NMI(r13)
 986         addi    r10,r10,1
 987         sth     r10,PACA_IN_NMI(r13)
 988         li      r10,MSR_RI
 989         mtmsrd  r10,1
 990
 991         mr      r10,r1
 992         ld      r1,PACA_NMI_EMERG_SP(r13)
 993         subi    r1,r1,INT_FRAME_SIZE
 994         __GEN_COMMON_BODY system_reset
 995
 996         addi    r3,r1,STACK_FRAME_OVERHEAD
 997         bl      system_reset_exception
 998
 999         /* Clear MSR_RI before setting SRR0 and SRR1. */
1000         li      r9,0
1001         mtmsrd  r9,1
1002
1003         /*
1004          * MSR_RI is clear, now we can decrement paca->in_nmi.
1005          */
1006         lhz     r10,PACA_IN_NMI(r13)
1007         subi    r10,r10,1
1008         sth     r10,PACA_IN_NMI(r13)
1009
1010         kuap_kernel_restore r9, r10
1011         EXCEPTION_RESTORE_REGS
1012         RFI_TO_USER_OR_KERNEL
1013
1014
1015 /**
1016  * Interrupt 0x200 - Machine Check Interrupt (MCE).
1017  * This is a non-maskable interrupt always taken in real-mode. It can be
1018  * synchronous or asynchronous, caused by hardware or software, and it may be
1019  * taken in a power-saving state.
1020  *
1021  * Handling:
1022  * Similarly to system reset, this uses its own stack and PACA save area,
1023  * the difference is re-entrancy is allowed on the machine check stack.
1024  *
1025  * machine_check_early is run in real mode, and carefully decodes the
1026  * machine check and tries to handle it (e.g., flush the SLB if there was an
1027  * error detected there), determines if it was recoverable and logs the
1028  * event.
1029  *
1030  * This early code does not "reconcile" irq soft-mask state like SRESET or
1031  * regular interrupts do, so irqs_disabled() among other things may not work
1032  * properly (irq disable/enable already doesn't work because irq tracing can
1033  * not work in real mode).
1034  *
1035  * Then, depending on the execution context when the interrupt is taken, there
1036  * are 3 main actions:
1037  * - Executing in kernel mode. The event is queued with irq_work, which means
1038  *   it is handled when it is next safe to do so (i.e., the kernel has enabled
1039  *   interrupts), which could be immediately when the interrupt returns. This
1040  *   avoids nasty issues like switching to virtual mode when the MMU is in a
1041  *   bad state, or when executing OPAL code. (SRESET is exposed to such issues,
1042  *   but it has different priorities). Check to see if the CPU was in power
1043  *   save, and return via the wake up code if it was.
1044  *
1045  * - Executing in user mode. machine_check_exception is run like a normal
1046  *   interrupt handler, which processes the data generated by the early handler.
1047  *
1048  * - Executing in guest mode. The interrupt is run with its KVM test, and
1049  *   branches to KVM to deal with. KVM may queue the event for the host
1050  *   to report later.
1051  *
1052  * This interrupt is not maskable, so if it triggers when MSR[RI] is clear,
1053  * or SCRATCH0 is in use, it may cause a crash.
1054  *
1055  * KVM:
1056  * See SRESET.
1057  */
1058 INT_DEFINE_BEGIN(machine_check_early)
1059         IVEC=0x200
1060         IAREA=PACA_EXMC
1061         IVIRT=0 /* no virt entry point */
1062         IREALMODE_COMMON=1
1063         /*
1064          * MSR_RI is not enabled, because PACA_EXMC is being used, so a
1065          * nested machine check corrupts it. machine_check_common enables
1066          * MSR_RI.
1067          */
1068         ISET_RI=0
1069         ISTACK=0
1070         IDAR=1
1071         IDSISR=1
1072         IKUAP=0 /* We don't touch AMR here, we never go to virtual mode */
1073 INT_DEFINE_END(machine_check_early)
1074
1075 INT_DEFINE_BEGIN(machine_check)
1076         IVEC=0x200
1077         IAREA=PACA_EXMC
1078         IVIRT=0 /* no virt entry point */
1079         ISET_RI=0
1080         IDAR=1
1081         IDSISR=1
1082         IKVM_REAL=1
1083 INT_DEFINE_END(machine_check)
1084
1085 EXC_REAL_BEGIN(machine_check, 0x200, 0x100)
1086         GEN_INT_ENTRY machine_check_early, virt=0
1087 EXC_REAL_END(machine_check, 0x200, 0x100)
1088 EXC_VIRT_NONE(0x4200, 0x100)
1089
1090 #ifdef CONFIG_PPC_PSERIES
1091 TRAMP_REAL_BEGIN(machine_check_fwnmi)
1092         /* See comment at machine_check exception, don't turn on RI */
1093         GEN_INT_ENTRY machine_check_early, virt=0
1094 #endif
1095
1096 #define MACHINE_CHECK_HANDLER_WINDUP                    \
1097         /* Clear MSR_RI before setting SRR0 and SRR1. */\
1098         li      r9,0;                                   \
1099         mtmsrd  r9,1;           /* Clear MSR_RI */      \
1100         /* Decrement paca->in_mce now RI is clear. */   \
1101         lhz     r12,PACA_IN_MCE(r13);                   \
1102         subi    r12,r12,1;                              \
1103         sth     r12,PACA_IN_MCE(r13);                   \
1104         EXCEPTION_RESTORE_REGS
1105
1106 EXC_COMMON_BEGIN(machine_check_early_common)
1107         __GEN_REALMODE_COMMON_ENTRY machine_check_early
1108
1109         /*
1110          * Switch to mc_emergency stack and handle re-entrancy (we limit
1111          * the nested MCE upto level 4 to avoid stack overflow).
1112          * Save MCE registers srr1, srr0, dar and dsisr and then set ME=1
1113          *
1114          * We use paca->in_mce to check whether this is the first entry or
1115          * nested machine check. We increment paca->in_mce to track nested
1116          * machine checks.
1117          *
1118          * If this is the first entry then set stack pointer to
1119          * paca->mc_emergency_sp, otherwise r1 is already pointing to
1120          * stack frame on mc_emergency stack.
1121          *
1122          * NOTE: We are here with MSR_ME=0 (off), which means we risk a
1123          * checkstop if we get another machine check exception before we do
1124          * rfid with MSR_ME=1.
1125          *
1126          * This interrupt can wake directly from idle. If that is the case,
1127          * the machine check is handled then the idle wakeup code is called
1128          * to restore state.
1129          */
1130         lhz     r10,PACA_IN_MCE(r13)
1131         cmpwi   r10,0                   /* Are we in nested machine check */
1132         cmpwi   cr1,r10,MAX_MCE_DEPTH   /* Are we at maximum nesting */
1133         addi    r10,r10,1               /* increment paca->in_mce */
1134         sth     r10,PACA_IN_MCE(r13)
1135
1136         mr      r10,r1                  /* Save r1 */
1137         bne     1f
1138         /* First machine check entry */
1139         ld      r1,PACAMCEMERGSP(r13)   /* Use MC emergency stack */
1140 1:      /* Limit nested MCE to level 4 to avoid stack overflow */
1141         bgt     cr1,unrecoverable_mce   /* Check if we hit limit of 4 */
1142         subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame */
1143
1144         __GEN_COMMON_BODY machine_check_early
1145
1146 BEGIN_FTR_SECTION
1147         bl      enable_machine_check
1148 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
1149         li      r10,MSR_RI
1150         mtmsrd  r10,1
1151
1152         addi    r3,r1,STACK_FRAME_OVERHEAD
1153         bl      machine_check_early
1154         std     r3,RESULT(r1)   /* Save result */
1155         ld      r12,_MSR(r1)
1156
1157 #ifdef CONFIG_PPC_P7_NAP
1158         /*
1159          * Check if thread was in power saving mode. We come here when any
1160          * of the following is true:
1161          * a. thread wasn't in power saving mode
1162          * b. thread was in power saving mode with no state loss,
1163          *    supervisor state loss or hypervisor state loss.
1164          *
1165          * Go back to nap/sleep/winkle mode again if (b) is true.
1166          */
1167 BEGIN_FTR_SECTION
1168         rlwinm. r11,r12,47-31,30,31
1169         bne     machine_check_idle_common
1170 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
1171 #endif
1172
1173 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
1174         /*
1175          * Check if we are coming from guest. If yes, then run the normal
1176          * exception handler which will take the
1177          * machine_check_kvm->kvm_interrupt branch to deliver the MC event
1178          * to guest.
1179          */
1180         lbz     r11,HSTATE_IN_GUEST(r13)
1181         cmpwi   r11,0                   /* Check if coming from guest */
1182         bne     mce_deliver             /* continue if we are. */
1183 #endif
1184
1185         /*
1186          * Check if we are coming from userspace. If yes, then run the normal
1187          * exception handler which will deliver the MC event to this kernel.
1188          */
1189         andi.   r11,r12,MSR_PR          /* See if coming from user. */
1190         bne     mce_deliver             /* continue in V mode if we are. */
1191
1192         /*
1193          * At this point we are coming from kernel context.
1194          * Queue up the MCE event and return from the interrupt.
1195          * But before that, check if this is an un-recoverable exception.
1196          * If yes, then stay on emergency stack and panic.
1197          */
1198         andi.   r11,r12,MSR_RI
1199         beq     unrecoverable_mce
1200
1201         /*
1202          * Check if we have successfully handled/recovered from error, if not
1203          * then stay on emergency stack and panic.
1204          */
1205         ld      r3,RESULT(r1)   /* Load result */
1206         cmpdi   r3,0            /* see if we handled MCE successfully */
1207         beq     unrecoverable_mce /* if !handled then panic */
1208
1209         /*
1210          * Return from MC interrupt.
1211          * Queue up the MCE event so that we can log it later, while
1212          * returning from kernel or opal call.
1213          */
1214         bl      machine_check_queue_event
1215         MACHINE_CHECK_HANDLER_WINDUP
1216         RFI_TO_KERNEL
1217
1218 mce_deliver:
1219         /*
1220          * This is a host user or guest MCE. Restore all registers, then
1221          * run the "late" handler. For host user, this will run the
1222          * machine_check_exception handler in virtual mode like a normal
1223          * interrupt handler. For guest, this will trigger the KVM test
1224          * and branch to the KVM interrupt similarly to other interrupts.
1225          */
1226 BEGIN_FTR_SECTION
1227         ld      r10,ORIG_GPR3(r1)
1228         mtspr   SPRN_CFAR,r10
1229 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
1230         MACHINE_CHECK_HANDLER_WINDUP
1231         GEN_INT_ENTRY machine_check, virt=0
1232
1233 EXC_COMMON_BEGIN(machine_check_common)
1234         /*
1235          * Machine check is different because we use a different
1236          * save area: PACA_EXMC instead of PACA_EXGEN.
1237          */
1238         GEN_COMMON machine_check
1239
1240         /* Enable MSR_RI when finished with PACA_EXMC */
1241         li      r10,MSR_RI
1242         mtmsrd  r10,1
1243         addi    r3,r1,STACK_FRAME_OVERHEAD
1244         bl      machine_check_exception_async
1245         b       interrupt_return_srr
1246
1247
1248 #ifdef CONFIG_PPC_P7_NAP
1249 /*
1250  * This is an idle wakeup. Low level machine check has already been
1251  * done. Queue the event then call the idle code to do the wake up.
1252  */
1253 EXC_COMMON_BEGIN(machine_check_idle_common)
1254         bl      machine_check_queue_event
1255
1256         /*
1257          * GPR-loss wakeups are relatively straightforward, because the
1258          * idle sleep code has saved all non-volatile registers on its
1259          * own stack, and r1 in PACAR1.
1260          *
1261          * For no-loss wakeups the r1 and lr registers used by the
1262          * early machine check handler have to be restored first. r2 is
1263          * the kernel TOC, so no need to restore it.
1264          *
1265          * Then decrement MCE nesting after finishing with the stack.
1266          */
1267         ld      r3,_MSR(r1)
1268         ld      r4,_LINK(r1)
1269         ld      r1,GPR1(r1)
1270
1271         lhz     r11,PACA_IN_MCE(r13)
1272         subi    r11,r11,1
1273         sth     r11,PACA_IN_MCE(r13)
1274
1275         mtlr    r4
1276         rlwinm  r10,r3,47-31,30,31
1277         cmpwi   cr1,r10,2
1278         bltlr   cr1     /* no state loss, return to idle caller with r3=SRR1 */
1279         b       idle_return_gpr_loss
1280 #endif
1281
1282 EXC_COMMON_BEGIN(unrecoverable_mce)
1283         /*
1284          * We are going down. But there are chances that we might get hit by
1285          * another MCE during panic path and we may run into unstable state
1286          * with no way out. Hence, turn ME bit off while going down, so that
1287          * when another MCE is hit during panic path, system will checkstop
1288          * and hypervisor will get restarted cleanly by SP.
1289          */
1290 BEGIN_FTR_SECTION
1291         li      r10,0 /* clear MSR_RI */
1292         mtmsrd  r10,1
1293         bl      disable_machine_check
1294 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
1295         ld      r10,PACAKMSR(r13)
1296         li      r3,MSR_ME
1297         andc    r10,r10,r3
1298         mtmsrd  r10
1299
1300         lhz     r12,PACA_IN_MCE(r13)
1301         subi    r12,r12,1
1302         sth     r12,PACA_IN_MCE(r13)
1303
1304         /*
1305          * Invoke machine_check_exception to print MCE event and panic.
1306          * This is the NMI version of the handler because we are called from
1307          * the early handler which is a true NMI.
1308          */
1309         addi    r3,r1,STACK_FRAME_OVERHEAD
1310         bl      machine_check_exception
1311
1312         /*
1313          * We will not reach here. Even if we did, there is no way out.
1314          * Call unrecoverable_exception and die.
1315          */
1316         addi    r3,r1,STACK_FRAME_OVERHEAD
1317         bl      unrecoverable_exception
1318         b       .
1319
1320
1321 /**
1322  * Interrupt 0x300 - Data Storage Interrupt (DSI).
1323  * This is a synchronous interrupt generated due to a data access exception,
1324  * e.g., a load orstore which does not have a valid page table entry with
1325  * permissions. DAWR matches also fault here, as do RC updates, and minor misc
1326  * errors e.g., copy/paste, AMO, certain invalid CI accesses, etc.
1327  *
1328  * Handling:
1329  * - Hash MMU
1330  *   Go to do_hash_fault, which attempts to fill the HPT from an entry in the
1331  *   Linux page table. Hash faults can hit in kernel mode in a fairly
1332  *   arbitrary state (e.g., interrupts disabled, locks held) when accessing
1333  *   "non-bolted" regions, e.g., vmalloc space. However these should always be
1334  *   backed by Linux page table entries.
1335  *
1336  *   If no entry is found the Linux page fault handler is invoked (by
1337  *   do_hash_fault). Linux page faults can happen in kernel mode due to user
1338  *   copy operations of course.
1339  *
1340  *   KVM: The KVM HDSI handler may perform a load with MSR[DR]=1 in guest
1341  *   MMU context, which may cause a DSI in the host, which must go to the
1342  *   KVM handler. MSR[IR] is not enabled, so the real-mode handler will
1343  *   always be used regardless of AIL setting.
1344  *
1345  * - Radix MMU
1346  *   The hardware loads from the Linux page table directly, so a fault goes
1347  *   immediately to Linux page fault.
1348  *
1349  * Conditions like DAWR match are handled on the way in to Linux page fault.
1350  */
1351 INT_DEFINE_BEGIN(data_access)
1352         IVEC=0x300
1353         IDAR=1
1354         IDSISR=1
1355         IKVM_REAL=1
1356 INT_DEFINE_END(data_access)
1357
1358 EXC_REAL_BEGIN(data_access, 0x300, 0x80)
1359         GEN_INT_ENTRY data_access, virt=0
1360 EXC_REAL_END(data_access, 0x300, 0x80)
1361 EXC_VIRT_BEGIN(data_access, 0x4300, 0x80)
1362         GEN_INT_ENTRY data_access, virt=1
1363 EXC_VIRT_END(data_access, 0x4300, 0x80)
1364 EXC_COMMON_BEGIN(data_access_common)
1365         GEN_COMMON data_access
1366         ld      r4,_DSISR(r1)
1367         addi    r3,r1,STACK_FRAME_OVERHEAD
1368         andis.  r0,r4,DSISR_DABRMATCH@h
1369         bne-    1f
1370 BEGIN_MMU_FTR_SECTION
1371         bl      do_hash_fault
1372 MMU_FTR_SECTION_ELSE
1373         bl      do_page_fault
1374 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
1375         b       interrupt_return_srr
1376
1377 1:      bl      do_break
1378         /*
1379          * do_break() may have changed the NV GPRS while handling a breakpoint.
1380          * If so, we need to restore them with their updated values.
1381          */
1382         REST_NVGPRS(r1)
1383         b       interrupt_return_srr
1384
1385
1386 /**
1387  * Interrupt 0x380 - Data Segment Interrupt (DSLB).
1388  * This is a synchronous interrupt in response to an MMU fault missing SLB
1389  * entry for HPT, or an address outside RPT translation range.
1390  *
1391  * Handling:
1392  * - HPT:
1393  *   This refills the SLB, or reports an access fault similarly to a bad page
1394  *   fault. When coming from user-mode, the SLB handler may access any kernel
1395  *   data, though it may itself take a DSLB. When coming from kernel mode,
1396  *   recursive faults must be avoided so access is restricted to the kernel
1397  *   image text/data, kernel stack, and any data allocated below
1398  *   ppc64_bolted_size (first segment). The kernel handler must avoid stomping
1399  *   on user-handler data structures.
1400  *
1401  *   KVM: Same as 0x300, DSLB must test for KVM guest.
1402  */
1403 INT_DEFINE_BEGIN(data_access_slb)
1404         IVEC=0x380
1405         IDAR=1
1406         IKVM_REAL=1
1407 INT_DEFINE_END(data_access_slb)
1408
1409 EXC_REAL_BEGIN(data_access_slb, 0x380, 0x80)
1410         GEN_INT_ENTRY data_access_slb, virt=0
1411 EXC_REAL_END(data_access_slb, 0x380, 0x80)
1412 EXC_VIRT_BEGIN(data_access_slb, 0x4380, 0x80)
1413         GEN_INT_ENTRY data_access_slb, virt=1
1414 EXC_VIRT_END(data_access_slb, 0x4380, 0x80)
1415 EXC_COMMON_BEGIN(data_access_slb_common)
1416         GEN_COMMON data_access_slb
1417 BEGIN_MMU_FTR_SECTION
1418         /* HPT case, do SLB fault */
1419         addi    r3,r1,STACK_FRAME_OVERHEAD
1420         bl      do_slb_fault
1421         cmpdi   r3,0
1422         bne-    1f
1423         b       fast_interrupt_return_srr
1424 1:      /* Error case */
1425 MMU_FTR_SECTION_ELSE
1426         /* Radix case, access is outside page table range */
1427         li      r3,-EFAULT
1428 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
1429         std     r3,RESULT(r1)
1430         addi    r3,r1,STACK_FRAME_OVERHEAD
1431         bl      do_bad_slb_fault
1432         b       interrupt_return_srr
1433
1434
1435 /**
1436  * Interrupt 0x400 - Instruction Storage Interrupt (ISI).
1437  * This is a synchronous interrupt in response to an MMU fault due to an
1438  * instruction fetch.
1439  *
1440  * Handling:
1441  * Similar to DSI, though in response to fetch. The faulting address is found
1442  * in SRR0 (rather than DAR), and status in SRR1 (rather than DSISR).
1443  */
1444 INT_DEFINE_BEGIN(instruction_access)
1445         IVEC=0x400
1446         IISIDE=1
1447         IDAR=1
1448         IDSISR=1
1449 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1450         IKVM_REAL=1
1451 #endif
1452 INT_DEFINE_END(instruction_access)
1453
1454 EXC_REAL_BEGIN(instruction_access, 0x400, 0x80)
1455         GEN_INT_ENTRY instruction_access, virt=0
1456 EXC_REAL_END(instruction_access, 0x400, 0x80)
1457 EXC_VIRT_BEGIN(instruction_access, 0x4400, 0x80)
1458         GEN_INT_ENTRY instruction_access, virt=1
1459 EXC_VIRT_END(instruction_access, 0x4400, 0x80)
1460 EXC_COMMON_BEGIN(instruction_access_common)
1461         GEN_COMMON instruction_access
1462         addi    r3,r1,STACK_FRAME_OVERHEAD
1463 BEGIN_MMU_FTR_SECTION
1464         bl      do_hash_fault
1465 MMU_FTR_SECTION_ELSE
1466         bl      do_page_fault
1467 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
1468         b       interrupt_return_srr
1469
1470
1471 /**
1472  * Interrupt 0x480 - Instruction Segment Interrupt (ISLB).
1473  * This is a synchronous interrupt in response to an MMU fault due to an
1474  * instruction fetch.
1475  *
1476  * Handling:
1477  * Similar to DSLB, though in response to fetch. The faulting address is found
1478  * in SRR0 (rather than DAR).
1479  */
1480 INT_DEFINE_BEGIN(instruction_access_slb)
1481         IVEC=0x480
1482         IISIDE=1
1483         IDAR=1
1484 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1485         IKVM_REAL=1
1486 #endif
1487 INT_DEFINE_END(instruction_access_slb)
1488
1489 EXC_REAL_BEGIN(instruction_access_slb, 0x480, 0x80)
1490         GEN_INT_ENTRY instruction_access_slb, virt=0
1491 EXC_REAL_END(instruction_access_slb, 0x480, 0x80)
1492 EXC_VIRT_BEGIN(instruction_access_slb, 0x4480, 0x80)
1493         GEN_INT_ENTRY instruction_access_slb, virt=1
1494 EXC_VIRT_END(instruction_access_slb, 0x4480, 0x80)
1495 EXC_COMMON_BEGIN(instruction_access_slb_common)
1496         GEN_COMMON instruction_access_slb
1497 BEGIN_MMU_FTR_SECTION
1498         /* HPT case, do SLB fault */
1499         addi    r3,r1,STACK_FRAME_OVERHEAD
1500         bl      do_slb_fault
1501         cmpdi   r3,0
1502         bne-    1f
1503         b       fast_interrupt_return_srr
1504 1:      /* Error case */
1505 MMU_FTR_SECTION_ELSE
1506         /* Radix case, access is outside page table range */
1507         li      r3,-EFAULT
1508 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
1509         std     r3,RESULT(r1)
1510         addi    r3,r1,STACK_FRAME_OVERHEAD
1511         bl      do_bad_slb_fault
1512         b       interrupt_return_srr
1513
1514
1515 /**
1516  * Interrupt 0x500 - External Interrupt.
1517  * This is an asynchronous maskable interrupt in response to an "external
1518  * exception" from the interrupt controller or hypervisor (e.g., device
1519  * interrupt). It is maskable in hardware by clearing MSR[EE], and
1520  * soft-maskable with IRQS_DISABLED mask (i.e., local_irq_disable()).
1521  *
1522  * When running in HV mode, Linux sets up the LPCR[LPES] bit such that
1523  * interrupts are delivered with HSRR registers, guests use SRRs, which
1524  * reqiures IHSRR_IF_HVMODE.
1525  *
1526  * On bare metal POWER9 and later, Linux sets the LPCR[HVICE] bit such that
1527  * external interrupts are delivered as Hypervisor Virtualization Interrupts
1528  * rather than External Interrupts.
1529  *
1530  * Handling:
1531  * This calls into Linux IRQ handler. NVGPRs are not saved to reduce overhead,
1532  * because registers at the time of the interrupt are not so important as it is
1533  * asynchronous.
1534  *
1535  * If soft masked, the masked handler will note the pending interrupt for
1536  * replay, and clear MSR[EE] in the interrupted context.
1537  */
1538 INT_DEFINE_BEGIN(hardware_interrupt)
1539         IVEC=0x500
1540         IHSRR_IF_HVMODE=1
1541         IMASK=IRQS_DISABLED
1542         IKVM_REAL=1
1543         IKVM_VIRT=1
1544 INT_DEFINE_END(hardware_interrupt)
1545
1546 EXC_REAL_BEGIN(hardware_interrupt, 0x500, 0x100)
1547         GEN_INT_ENTRY hardware_interrupt, virt=0
1548 EXC_REAL_END(hardware_interrupt, 0x500, 0x100)
1549 EXC_VIRT_BEGIN(hardware_interrupt, 0x4500, 0x100)
1550         GEN_INT_ENTRY hardware_interrupt, virt=1
1551 EXC_VIRT_END(hardware_interrupt, 0x4500, 0x100)
1552 EXC_COMMON_BEGIN(hardware_interrupt_common)
1553         GEN_COMMON hardware_interrupt
1554         addi    r3,r1,STACK_FRAME_OVERHEAD
1555         bl      do_IRQ
1556         BEGIN_FTR_SECTION
1557         b       interrupt_return_hsrr
1558         FTR_SECTION_ELSE
1559         b       interrupt_return_srr
1560         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
1561
1562
1563 /**
1564  * Interrupt 0x600 - Alignment Interrupt
1565  * This is a synchronous interrupt in response to data alignment fault.
1566  */
1567 INT_DEFINE_BEGIN(alignment)
1568         IVEC=0x600
1569         IDAR=1
1570         IDSISR=1
1571 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1572         IKVM_REAL=1
1573 #endif
1574 INT_DEFINE_END(alignment)
1575
1576 EXC_REAL_BEGIN(alignment, 0x600, 0x100)
1577         GEN_INT_ENTRY alignment, virt=0
1578 EXC_REAL_END(alignment, 0x600, 0x100)
1579 EXC_VIRT_BEGIN(alignment, 0x4600, 0x100)
1580         GEN_INT_ENTRY alignment, virt=1
1581 EXC_VIRT_END(alignment, 0x4600, 0x100)
1582 EXC_COMMON_BEGIN(alignment_common)
1583         GEN_COMMON alignment
1584         addi    r3,r1,STACK_FRAME_OVERHEAD
1585         bl      alignment_exception
1586         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
1587         b       interrupt_return_srr
1588
1589
1590 /**
1591  * Interrupt 0x700 - Program Interrupt (program check).
1592  * This is a synchronous interrupt in response to various instruction faults:
1593  * traps, privilege errors, TM errors, floating point exceptions.
1594  *
1595  * Handling:
1596  * This interrupt may use the "emergency stack" in some cases when being taken
1597  * from kernel context, which complicates handling.
1598  */
1599 INT_DEFINE_BEGIN(program_check)
1600         IVEC=0x700
1601 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1602         IKVM_REAL=1
1603 #endif
1604 INT_DEFINE_END(program_check)
1605
1606 EXC_REAL_BEGIN(program_check, 0x700, 0x100)
1607
1608 #ifdef CONFIG_CPU_LITTLE_ENDIAN
1609         /*
1610          * There's a short window during boot where although the kernel is
1611          * running little endian, any exceptions will cause the CPU to switch
1612          * back to big endian. For example a WARN() boils down to a trap
1613          * instruction, which will cause a program check, and we end up here but
1614          * with the CPU in big endian mode. The first instruction of the program
1615          * check handler (in GEN_INT_ENTRY below) is an mtsprg, which when
1616          * executed in the wrong endian is an lhzu with a ~3GB displacement from
1617          * r3. The content of r3 is random, so that is a load from some random
1618          * location, and depending on the system can easily lead to a checkstop,
1619          * or an infinitely recursive page fault.
1620          *
1621          * So to handle that case we have a trampoline here that can detect we
1622          * are in the wrong endian and flip us back to the correct endian. We
1623          * can't flip MSR[LE] using mtmsr, so we have to use rfid. That requires
1624          * backing up SRR0/1 as well as a GPR. To do that we use SPRG0/2/3, as
1625          * SPRG1 is already used for the paca. SPRG3 is user readable, but this
1626          * trampoline is only active very early in boot, and SPRG3 will be
1627          * reinitialised in vdso_getcpu_init() before userspace starts.
1628          */
1629 BEGIN_FTR_SECTION
1630         tdi   0,0,0x48    // Trap never, or in reverse endian: b . + 8
1631         b     1f          // Skip trampoline if endian is correct
1632         .long 0xa643707d  // mtsprg  0, r11      Backup r11
1633         .long 0xa6027a7d  // mfsrr0  r11
1634         .long 0xa643727d  // mtsprg  2, r11      Backup SRR0 in SPRG2
1635         .long 0xa6027b7d  // mfsrr1  r11
1636         .long 0xa643737d  // mtsprg  3, r11      Backup SRR1 in SPRG3
1637         .long 0xa600607d  // mfmsr   r11
1638         .long 0x01006b69  // xori    r11, r11, 1 Invert MSR[LE]
1639         .long 0xa6037b7d  // mtsrr1  r11
1640         .long 0x34076039  // li      r11, 0x734
1641         .long 0xa6037a7d  // mtsrr0  r11
1642         .long 0x2400004c  // rfid
1643         mfsprg r11, 3
1644         mtsrr1 r11        // Restore SRR1
1645         mfsprg r11, 2
1646         mtsrr0 r11        // Restore SRR0
1647         mfsprg r11, 0     // Restore r11
1648 1:
1649 END_FTR_SECTION(0, 1)     // nop out after boot
1650 #endif /* CONFIG_CPU_LITTLE_ENDIAN */
1651
1652         GEN_INT_ENTRY program_check, virt=0
1653 EXC_REAL_END(program_check, 0x700, 0x100)
1654 EXC_VIRT_BEGIN(program_check, 0x4700, 0x100)
1655         GEN_INT_ENTRY program_check, virt=1
1656 EXC_VIRT_END(program_check, 0x4700, 0x100)
1657 EXC_COMMON_BEGIN(program_check_common)
1658         __GEN_COMMON_ENTRY program_check
1659
1660         /*
1661          * It's possible to receive a TM Bad Thing type program check with
1662          * userspace register values (in particular r1), but with SRR1 reporting
1663          * that we came from the kernel. Normally that would confuse the bad
1664          * stack logic, and we would report a bad kernel stack pointer. Instead
1665          * we switch to the emergency stack if we're taking a TM Bad Thing from
1666          * the kernel.
1667          */
1668
1669         andi.   r10,r12,MSR_PR
1670         bne     .Lnormal_stack          /* If userspace, go normal path */
1671
1672         andis.  r10,r12,(SRR1_PROGTM)@h
1673         bne     .Lemergency_stack       /* If TM, emergency             */
1674
1675         cmpdi   r1,-INT_FRAME_SIZE      /* check if r1 is in userspace  */
1676         blt     .Lnormal_stack          /* normal path if not           */
1677
1678         /* Use the emergency stack                                      */
1679 .Lemergency_stack:
1680         andi.   r10,r12,MSR_PR          /* Set CR0 correctly for label  */
1681                                         /* 3 in EXCEPTION_PROLOG_COMMON */
1682         mr      r10,r1                  /* Save r1                      */
1683         ld      r1,PACAEMERGSP(r13)     /* Use emergency stack          */
1684         subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame            */
1685         __ISTACK(program_check)=0
1686         __GEN_COMMON_BODY program_check
1687         b .Ldo_program_check
1688
1689 .Lnormal_stack:
1690         __ISTACK(program_check)=1
1691         __GEN_COMMON_BODY program_check
1692
1693 .Ldo_program_check:
1694         addi    r3,r1,STACK_FRAME_OVERHEAD
1695         bl      program_check_exception
1696         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
1697         b       interrupt_return_srr
1698
1699
1700 /*
1701  * Interrupt 0x800 - Floating-Point Unavailable Interrupt.
1702  * This is a synchronous interrupt in response to executing an fp instruction
1703  * with MSR[FP]=0.
1704  *
1705  * Handling:
1706  * This will load FP registers and enable the FP bit if coming from userspace,
1707  * otherwise report a bad kernel use of FP.
1708  */
1709 INT_DEFINE_BEGIN(fp_unavailable)
1710         IVEC=0x800
1711 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1712         IKVM_REAL=1
1713 #endif
1714 INT_DEFINE_END(fp_unavailable)
1715
1716 EXC_REAL_BEGIN(fp_unavailable, 0x800, 0x100)
1717         GEN_INT_ENTRY fp_unavailable, virt=0
1718 EXC_REAL_END(fp_unavailable, 0x800, 0x100)
1719 EXC_VIRT_BEGIN(fp_unavailable, 0x4800, 0x100)
1720         GEN_INT_ENTRY fp_unavailable, virt=1
1721 EXC_VIRT_END(fp_unavailable, 0x4800, 0x100)
1722 EXC_COMMON_BEGIN(fp_unavailable_common)
1723         GEN_COMMON fp_unavailable
1724         bne     1f                      /* if from user, just load it up */
1725         addi    r3,r1,STACK_FRAME_OVERHEAD
1726         bl      kernel_fp_unavailable_exception
1727 0:      trap
1728         EMIT_BUG_ENTRY 0b, __FILE__, __LINE__, 0
1729 1:
1730 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1731 BEGIN_FTR_SECTION
1732         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
1733          * transaction), go do TM stuff
1734          */
1735         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
1736         bne-    2f
1737 END_FTR_SECTION_IFSET(CPU_FTR_TM)
1738 #endif
1739         bl      load_up_fpu
1740         b       fast_interrupt_return_srr
1741 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1742 2:      /* User process was in a transaction */
1743         addi    r3,r1,STACK_FRAME_OVERHEAD
1744         bl      fp_unavailable_tm
1745         b       interrupt_return_srr
1746 #endif
1747
1748
1749 /**
1750  * Interrupt 0x900 - Decrementer Interrupt.
1751  * This is an asynchronous interrupt in response to a decrementer exception
1752  * (e.g., DEC has wrapped below zero). It is maskable in hardware by clearing
1753  * MSR[EE], and soft-maskable with IRQS_DISABLED mask (i.e.,
1754  * local_irq_disable()).
1755  *
1756  * Handling:
1757  * This calls into Linux timer handler. NVGPRs are not saved (see 0x500).
1758  *
1759  * If soft masked, the masked handler will note the pending interrupt for
1760  * replay, and bump the decrementer to a high value, leaving MSR[EE] enabled
1761  * in the interrupted context.
1762  * If PPC_WATCHDOG is configured, the soft masked handler will actually set
1763  * things back up to run soft_nmi_interrupt as a regular interrupt handler
1764  * on the emergency stack.
1765  */
1766 INT_DEFINE_BEGIN(decrementer)
1767         IVEC=0x900
1768         IMASK=IRQS_DISABLED
1769 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1770         IKVM_REAL=1
1771 #endif
1772 INT_DEFINE_END(decrementer)
1773
1774 EXC_REAL_BEGIN(decrementer, 0x900, 0x80)
1775         GEN_INT_ENTRY decrementer, virt=0
1776 EXC_REAL_END(decrementer, 0x900, 0x80)
1777 EXC_VIRT_BEGIN(decrementer, 0x4900, 0x80)
1778         GEN_INT_ENTRY decrementer, virt=1
1779 EXC_VIRT_END(decrementer, 0x4900, 0x80)
1780 EXC_COMMON_BEGIN(decrementer_common)
1781         GEN_COMMON decrementer
1782         addi    r3,r1,STACK_FRAME_OVERHEAD
1783         bl      timer_interrupt
1784         b       interrupt_return_srr
1785
1786
1787 /**
1788  * Interrupt 0x980 - Hypervisor Decrementer Interrupt.
1789  * This is an asynchronous interrupt, similar to 0x900 but for the HDEC
1790  * register.
1791  *
1792  * Handling:
1793  * Linux does not use this outside KVM where it's used to keep a host timer
1794  * while the guest is given control of DEC. It should normally be caught by
1795  * the KVM test and routed there.
1796  */
1797 INT_DEFINE_BEGIN(hdecrementer)
1798         IVEC=0x980
1799         IHSRR=1
1800         ISTACK=0
1801         IKVM_REAL=1
1802         IKVM_VIRT=1
1803 INT_DEFINE_END(hdecrementer)
1804
1805 EXC_REAL_BEGIN(hdecrementer, 0x980, 0x80)
1806         GEN_INT_ENTRY hdecrementer, virt=0
1807 EXC_REAL_END(hdecrementer, 0x980, 0x80)
1808 EXC_VIRT_BEGIN(hdecrementer, 0x4980, 0x80)
1809         GEN_INT_ENTRY hdecrementer, virt=1
1810 EXC_VIRT_END(hdecrementer, 0x4980, 0x80)
1811 EXC_COMMON_BEGIN(hdecrementer_common)
1812         __GEN_COMMON_ENTRY hdecrementer
1813         /*
1814          * Hypervisor decrementer interrupts not caught by the KVM test
1815          * shouldn't occur but are sometimes left pending on exit from a KVM
1816          * guest.  We don't need to do anything to clear them, as they are
1817          * edge-triggered.
1818          *
1819          * Be careful to avoid touching the kernel stack.
1820          */
1821         li      r10,0
1822         stb     r10,PACAHSRR_VALID(r13)
1823         ld      r10,PACA_EXGEN+EX_CTR(r13)
1824         mtctr   r10
1825         mtcrf   0x80,r9
1826         ld      r9,PACA_EXGEN+EX_R9(r13)
1827         ld      r10,PACA_EXGEN+EX_R10(r13)
1828         ld      r11,PACA_EXGEN+EX_R11(r13)
1829         ld      r12,PACA_EXGEN+EX_R12(r13)
1830         ld      r13,PACA_EXGEN+EX_R13(r13)
1831         HRFI_TO_KERNEL
1832
1833
1834 /**
1835  * Interrupt 0xa00 - Directed Privileged Doorbell Interrupt.
1836  * This is an asynchronous interrupt in response to a msgsndp doorbell.
1837  * It is maskable in hardware by clearing MSR[EE], and soft-maskable with
1838  * IRQS_DISABLED mask (i.e., local_irq_disable()).
1839  *
1840  * Handling:
1841  * Guests may use this for IPIs between threads in a core if the
1842  * hypervisor supports it. NVGPRS are not saved (see 0x500).
1843  *
1844  * If soft masked, the masked handler will note the pending interrupt for
1845  * replay, leaving MSR[EE] enabled in the interrupted context because the
1846  * doorbells are edge triggered.
1847  */
1848 INT_DEFINE_BEGIN(doorbell_super)
1849         IVEC=0xa00
1850         IMASK=IRQS_DISABLED
1851 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1852         IKVM_REAL=1
1853 #endif
1854 INT_DEFINE_END(doorbell_super)
1855
1856 EXC_REAL_BEGIN(doorbell_super, 0xa00, 0x100)
1857         GEN_INT_ENTRY doorbell_super, virt=0
1858 EXC_REAL_END(doorbell_super, 0xa00, 0x100)
1859 EXC_VIRT_BEGIN(doorbell_super, 0x4a00, 0x100)
1860         GEN_INT_ENTRY doorbell_super, virt=1
1861 EXC_VIRT_END(doorbell_super, 0x4a00, 0x100)
1862 EXC_COMMON_BEGIN(doorbell_super_common)
1863         GEN_COMMON doorbell_super
1864         addi    r3,r1,STACK_FRAME_OVERHEAD
1865 #ifdef CONFIG_PPC_DOORBELL
1866         bl      doorbell_exception
1867 #else
1868         bl      unknown_async_exception
1869 #endif
1870         b       interrupt_return_srr
1871
1872
1873 EXC_REAL_NONE(0xb00, 0x100)
1874 EXC_VIRT_NONE(0x4b00, 0x100)
1875
1876 /**
1877  * Interrupt 0xc00 - System Call Interrupt (syscall, hcall).
1878  * This is a synchronous interrupt invoked with the "sc" instruction. The
1879  * system call is invoked with "sc 0" and does not alter the HV bit, so it
1880  * is directed to the currently running OS. The hypercall is invoked with
1881  * "sc 1" and it sets HV=1, so it elevates to hypervisor.
1882  *
1883  * In HPT, sc 1 always goes to 0xc00 real mode. In RADIX, sc 1 can go to
1884  * 0x4c00 virtual mode.
1885  *
1886  * Handling:
1887  * If the KVM test fires then it was due to a hypercall and is accordingly
1888  * routed to KVM. Otherwise this executes a normal Linux system call.
1889  *
1890  * Call convention:
1891  *
1892  * syscall and hypercalls register conventions are documented in
1893  * Documentation/powerpc/syscall64-abi.rst and
1894  * Documentation/powerpc/papr_hcalls.rst respectively.
1895  *
1896  * The intersection of volatile registers that don't contain possible
1897  * inputs is: cr0, xer, ctr. We may use these as scratch regs upon entry
1898  * without saving, though xer is not a good idea to use, as hardware may
1899  * interpret some bits so it may be costly to change them.
1900  */
1901 INT_DEFINE_BEGIN(system_call)
1902         IVEC=0xc00
1903         IKVM_REAL=1
1904         IKVM_VIRT=1
1905 INT_DEFINE_END(system_call)
1906
1907 .macro SYSTEM_CALL virt
1908 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
1909         /*
1910          * There is a little bit of juggling to get syscall and hcall
1911          * working well. Save r13 in ctr to avoid using SPRG scratch
1912          * register.
1913          *
1914          * Userspace syscalls have already saved the PPR, hcalls must save
1915          * it before setting HMT_MEDIUM.
1916          */
1917         mtctr   r13
1918         GET_PACA(r13)
1919         std     r10,PACA_EXGEN+EX_R10(r13)
1920         INTERRUPT_TO_KERNEL
1921         KVMTEST system_call kvm_hcall /* uses r10, branch to kvm_hcall */
1922         mfctr   r9
1923 #else
1924         mr      r9,r13
1925         GET_PACA(r13)
1926         INTERRUPT_TO_KERNEL
1927 #endif
1928
1929 #ifdef CONFIG_PPC_FAST_ENDIAN_SWITCH
1930 BEGIN_FTR_SECTION
1931         cmpdi   r0,0x1ebe
1932         beq-    1f
1933 END_FTR_SECTION_IFSET(CPU_FTR_REAL_LE)
1934 #endif
1935
1936         /* We reach here with PACA in r13, r13 in r9. */
1937         mfspr   r11,SPRN_SRR0
1938         mfspr   r12,SPRN_SRR1
1939
1940         HMT_MEDIUM
1941
1942         .if ! \virt
1943         __LOAD_HANDLER(r10, system_call_common_real)
1944         mtctr   r10
1945         bctr
1946         .else
1947 #ifdef CONFIG_RELOCATABLE
1948         __LOAD_HANDLER(r10, system_call_common)
1949         mtctr   r10
1950         bctr
1951 #else
1952         b       system_call_common
1953 #endif
1954         .endif
1955
1956 #ifdef CONFIG_PPC_FAST_ENDIAN_SWITCH
1957         /* Fast LE/BE switch system call */
1958 1:      mfspr   r12,SPRN_SRR1
1959         xori    r12,r12,MSR_LE
1960         mtspr   SPRN_SRR1,r12
1961         mr      r13,r9
1962         RFI_TO_USER     /* return to userspace */
1963         b       .       /* prevent speculative execution */
1964 #endif
1965 .endm
1966
1967 EXC_REAL_BEGIN(system_call, 0xc00, 0x100)
1968         SYSTEM_CALL 0
1969 EXC_REAL_END(system_call, 0xc00, 0x100)
1970 EXC_VIRT_BEGIN(system_call, 0x4c00, 0x100)
1971         SYSTEM_CALL 1
1972 EXC_VIRT_END(system_call, 0x4c00, 0x100)
1973
1974 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
1975 TRAMP_REAL_BEGIN(kvm_hcall)
1976         std     r9,PACA_EXGEN+EX_R9(r13)
1977         std     r11,PACA_EXGEN+EX_R11(r13)
1978         std     r12,PACA_EXGEN+EX_R12(r13)
1979         mfcr    r9
1980         mfctr   r10
1981         std     r10,PACA_EXGEN+EX_R13(r13)
1982         li      r10,0
1983         std     r10,PACA_EXGEN+EX_CFAR(r13)
1984         std     r10,PACA_EXGEN+EX_CTR(r13)
1985          /*
1986           * Save the PPR (on systems that support it) before changing to
1987           * HMT_MEDIUM. That allows the KVM code to save that value into the
1988           * guest state (it is the guest's PPR value).
1989           */
1990 BEGIN_FTR_SECTION
1991         mfspr   r10,SPRN_PPR
1992         std     r10,PACA_EXGEN+EX_PPR(r13)
1993 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
1994
1995         HMT_MEDIUM
1996
1997 #ifdef CONFIG_RELOCATABLE
1998         /*
1999          * Requires __LOAD_FAR_HANDLER beause kvmppc_hcall lives
2000          * outside the head section.
2001          */
2002         __LOAD_FAR_HANDLER(r10, kvmppc_hcall)
2003         mtctr   r10
2004         bctr
2005 #else
2006         b       kvmppc_hcall
2007 #endif
2008 #endif
2009
2010 /**
2011  * Interrupt 0xd00 - Trace Interrupt.
2012  * This is a synchronous interrupt in response to instruction step or
2013  * breakpoint faults.
2014  */
2015 INT_DEFINE_BEGIN(single_step)
2016         IVEC=0xd00
2017 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2018         IKVM_REAL=1
2019 #endif
2020 INT_DEFINE_END(single_step)
2021
2022 EXC_REAL_BEGIN(single_step, 0xd00, 0x100)
2023         GEN_INT_ENTRY single_step, virt=0
2024 EXC_REAL_END(single_step, 0xd00, 0x100)
2025 EXC_VIRT_BEGIN(single_step, 0x4d00, 0x100)
2026         GEN_INT_ENTRY single_step, virt=1
2027 EXC_VIRT_END(single_step, 0x4d00, 0x100)
2028 EXC_COMMON_BEGIN(single_step_common)
2029         GEN_COMMON single_step
2030         addi    r3,r1,STACK_FRAME_OVERHEAD
2031         bl      single_step_exception
2032         b       interrupt_return_srr
2033
2034
2035 /**
2036  * Interrupt 0xe00 - Hypervisor Data Storage Interrupt (HDSI).
2037  * This is a synchronous interrupt in response to an MMU fault caused by a
2038  * guest data access.
2039  *
2040  * Handling:
2041  * This should always get routed to KVM. In radix MMU mode, this is caused
2042  * by a guest nested radix access that can't be performed due to the
2043  * partition scope page table. In hash mode, this can be caused by guests
2044  * running with translation disabled (virtual real mode) or with VPM enabled.
2045  * KVM will update the page table structures or disallow the access.
2046  */
2047 INT_DEFINE_BEGIN(h_data_storage)
2048         IVEC=0xe00
2049         IHSRR=1
2050         IDAR=1
2051         IDSISR=1
2052         IKVM_REAL=1
2053         IKVM_VIRT=1
2054 INT_DEFINE_END(h_data_storage)
2055
2056 EXC_REAL_BEGIN(h_data_storage, 0xe00, 0x20)
2057         GEN_INT_ENTRY h_data_storage, virt=0, ool=1
2058 EXC_REAL_END(h_data_storage, 0xe00, 0x20)
2059 EXC_VIRT_BEGIN(h_data_storage, 0x4e00, 0x20)
2060         GEN_INT_ENTRY h_data_storage, virt=1, ool=1
2061 EXC_VIRT_END(h_data_storage, 0x4e00, 0x20)
2062 EXC_COMMON_BEGIN(h_data_storage_common)
2063         GEN_COMMON h_data_storage
2064         addi    r3,r1,STACK_FRAME_OVERHEAD
2065 BEGIN_MMU_FTR_SECTION
2066         bl      do_bad_page_fault_segv
2067 MMU_FTR_SECTION_ELSE
2068         bl      unknown_exception
2069 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_TYPE_RADIX)
2070         b       interrupt_return_hsrr
2071
2072
2073 /**
2074  * Interrupt 0xe20 - Hypervisor Instruction Storage Interrupt (HISI).
2075  * This is a synchronous interrupt in response to an MMU fault caused by a
2076  * guest instruction fetch, similar to HDSI.
2077  */
2078 INT_DEFINE_BEGIN(h_instr_storage)
2079         IVEC=0xe20
2080         IHSRR=1
2081         IKVM_REAL=1
2082         IKVM_VIRT=1
2083 INT_DEFINE_END(h_instr_storage)
2084
2085 EXC_REAL_BEGIN(h_instr_storage, 0xe20, 0x20)
2086         GEN_INT_ENTRY h_instr_storage, virt=0, ool=1
2087 EXC_REAL_END(h_instr_storage, 0xe20, 0x20)
2088 EXC_VIRT_BEGIN(h_instr_storage, 0x4e20, 0x20)
2089         GEN_INT_ENTRY h_instr_storage, virt=1, ool=1
2090 EXC_VIRT_END(h_instr_storage, 0x4e20, 0x20)
2091 EXC_COMMON_BEGIN(h_instr_storage_common)
2092         GEN_COMMON h_instr_storage
2093         addi    r3,r1,STACK_FRAME_OVERHEAD
2094         bl      unknown_exception
2095         b       interrupt_return_hsrr
2096
2097
2098 /**
2099  * Interrupt 0xe40 - Hypervisor Emulation Assistance Interrupt.
2100  */
2101 INT_DEFINE_BEGIN(emulation_assist)
2102         IVEC=0xe40
2103         IHSRR=1
2104         IKVM_REAL=1
2105         IKVM_VIRT=1
2106 INT_DEFINE_END(emulation_assist)
2107
2108 EXC_REAL_BEGIN(emulation_assist, 0xe40, 0x20)
2109         GEN_INT_ENTRY emulation_assist, virt=0, ool=1
2110 EXC_REAL_END(emulation_assist, 0xe40, 0x20)
2111 EXC_VIRT_BEGIN(emulation_assist, 0x4e40, 0x20)
2112         GEN_INT_ENTRY emulation_assist, virt=1, ool=1
2113 EXC_VIRT_END(emulation_assist, 0x4e40, 0x20)
2114 EXC_COMMON_BEGIN(emulation_assist_common)
2115         GEN_COMMON emulation_assist
2116         addi    r3,r1,STACK_FRAME_OVERHEAD
2117         bl      emulation_assist_interrupt
2118         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
2119         b       interrupt_return_hsrr
2120
2121
2122 /**
2123  * Interrupt 0xe60 - Hypervisor Maintenance Interrupt (HMI).
2124  * This is an asynchronous interrupt caused by a Hypervisor Maintenance
2125  * Exception. It is always taken in real mode but uses HSRR registers
2126  * unlike SRESET and MCE.
2127  *
2128  * It is maskable in hardware by clearing MSR[EE], and partially soft-maskable
2129  * with IRQS_DISABLED mask (i.e., local_irq_disable()).
2130  *
2131  * Handling:
2132  * This is a special case, this is handled similarly to machine checks, with an
2133  * initial real mode handler that is not soft-masked, which attempts to fix the
2134  * problem. Then a regular handler which is soft-maskable and reports the
2135  * problem.
2136  *
2137  * The emergency stack is used for the early real mode handler.
2138  *
2139  * XXX: unclear why MCE and HMI schemes could not be made common, e.g.,
2140  * either use soft-masking for the MCE, or use irq_work for the HMI.
2141  *
2142  * KVM:
2143  * Unlike MCE, this calls into KVM without calling the real mode handler
2144  * first.
2145  */
2146 INT_DEFINE_BEGIN(hmi_exception_early)
2147         IVEC=0xe60
2148         IHSRR=1
2149         IREALMODE_COMMON=1
2150         ISTACK=0
2151         IKUAP=0 /* We don't touch AMR here, we never go to virtual mode */
2152         IKVM_REAL=1
2153 INT_DEFINE_END(hmi_exception_early)
2154
2155 INT_DEFINE_BEGIN(hmi_exception)
2156         IVEC=0xe60
2157         IHSRR=1
2158         IMASK=IRQS_DISABLED
2159         IKVM_REAL=1
2160 INT_DEFINE_END(hmi_exception)
2161
2162 EXC_REAL_BEGIN(hmi_exception, 0xe60, 0x20)
2163         GEN_INT_ENTRY hmi_exception_early, virt=0, ool=1
2164 EXC_REAL_END(hmi_exception, 0xe60, 0x20)
2165 EXC_VIRT_NONE(0x4e60, 0x20)
2166
2167 EXC_COMMON_BEGIN(hmi_exception_early_common)
2168         __GEN_REALMODE_COMMON_ENTRY hmi_exception_early
2169
2170         mr      r10,r1                  /* Save r1 */
2171         ld      r1,PACAEMERGSP(r13)     /* Use emergency stack for realmode */
2172         subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame            */
2173
2174         __GEN_COMMON_BODY hmi_exception_early
2175
2176         addi    r3,r1,STACK_FRAME_OVERHEAD
2177         bl      hmi_exception_realmode
2178         cmpdi   cr0,r3,0
2179         bne     1f
2180
2181         EXCEPTION_RESTORE_REGS hsrr=1
2182         HRFI_TO_USER_OR_KERNEL
2183
2184 1:
2185         /*
2186          * Go to virtual mode and pull the HMI event information from
2187          * firmware.
2188          */
2189         EXCEPTION_RESTORE_REGS hsrr=1
2190         GEN_INT_ENTRY hmi_exception, virt=0
2191
2192 EXC_COMMON_BEGIN(hmi_exception_common)
2193         GEN_COMMON hmi_exception
2194         addi    r3,r1,STACK_FRAME_OVERHEAD
2195         bl      handle_hmi_exception
2196         b       interrupt_return_hsrr
2197
2198
2199 /**
2200  * Interrupt 0xe80 - Directed Hypervisor Doorbell Interrupt.
2201  * This is an asynchronous interrupt in response to a msgsnd doorbell.
2202  * Similar to the 0xa00 doorbell but for host rather than guest.
2203  */
2204 INT_DEFINE_BEGIN(h_doorbell)
2205         IVEC=0xe80
2206         IHSRR=1
2207         IMASK=IRQS_DISABLED
2208         IKVM_REAL=1
2209         IKVM_VIRT=1
2210 INT_DEFINE_END(h_doorbell)
2211
2212 EXC_REAL_BEGIN(h_doorbell, 0xe80, 0x20)
2213         GEN_INT_ENTRY h_doorbell, virt=0, ool=1
2214 EXC_REAL_END(h_doorbell, 0xe80, 0x20)
2215 EXC_VIRT_BEGIN(h_doorbell, 0x4e80, 0x20)
2216         GEN_INT_ENTRY h_doorbell, virt=1, ool=1
2217 EXC_VIRT_END(h_doorbell, 0x4e80, 0x20)
2218 EXC_COMMON_BEGIN(h_doorbell_common)
2219         GEN_COMMON h_doorbell
2220         addi    r3,r1,STACK_FRAME_OVERHEAD
2221 #ifdef CONFIG_PPC_DOORBELL
2222         bl      doorbell_exception
2223 #else
2224         bl      unknown_async_exception
2225 #endif
2226         b       interrupt_return_hsrr
2227
2228
2229 /**
2230  * Interrupt 0xea0 - Hypervisor Virtualization Interrupt.
2231  * This is an asynchronous interrupt in response to an "external exception".
2232  * Similar to 0x500 but for host only.
2233  */
2234 INT_DEFINE_BEGIN(h_virt_irq)
2235         IVEC=0xea0
2236         IHSRR=1
2237         IMASK=IRQS_DISABLED
2238         IKVM_REAL=1
2239         IKVM_VIRT=1
2240 INT_DEFINE_END(h_virt_irq)
2241
2242 EXC_REAL_BEGIN(h_virt_irq, 0xea0, 0x20)
2243         GEN_INT_ENTRY h_virt_irq, virt=0, ool=1
2244 EXC_REAL_END(h_virt_irq, 0xea0, 0x20)
2245 EXC_VIRT_BEGIN(h_virt_irq, 0x4ea0, 0x20)
2246         GEN_INT_ENTRY h_virt_irq, virt=1, ool=1
2247 EXC_VIRT_END(h_virt_irq, 0x4ea0, 0x20)
2248 EXC_COMMON_BEGIN(h_virt_irq_common)
2249         GEN_COMMON h_virt_irq
2250         addi    r3,r1,STACK_FRAME_OVERHEAD
2251         bl      do_IRQ
2252         b       interrupt_return_hsrr
2253
2254
2255 EXC_REAL_NONE(0xec0, 0x20)
2256 EXC_VIRT_NONE(0x4ec0, 0x20)
2257 EXC_REAL_NONE(0xee0, 0x20)
2258 EXC_VIRT_NONE(0x4ee0, 0x20)
2259
2260
2261 /*
2262  * Interrupt 0xf00 - Performance Monitor Interrupt (PMI, PMU).
2263  * This is an asynchronous interrupt in response to a PMU exception.
2264  * It is maskable in hardware by clearing MSR[EE], and soft-maskable with
2265  * IRQS_PMI_DISABLED mask (NOTE: NOT local_irq_disable()).
2266  *
2267  * Handling:
2268  * This calls into the perf subsystem.
2269  *
2270  * Like the watchdog soft-nmi, it appears an NMI interrupt to Linux, in that it
2271  * runs under local_irq_disable. However it may be soft-masked in
2272  * powerpc-specific code.
2273  *
2274  * If soft masked, the masked handler will note the pending interrupt for
2275  * replay, and clear MSR[EE] in the interrupted context.
2276  */
2277 INT_DEFINE_BEGIN(performance_monitor)
2278         IVEC=0xf00
2279         IMASK=IRQS_PMI_DISABLED
2280 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2281         IKVM_REAL=1
2282 #endif
2283 INT_DEFINE_END(performance_monitor)
2284
2285 EXC_REAL_BEGIN(performance_monitor, 0xf00, 0x20)
2286         GEN_INT_ENTRY performance_monitor, virt=0, ool=1
2287 EXC_REAL_END(performance_monitor, 0xf00, 0x20)
2288 EXC_VIRT_BEGIN(performance_monitor, 0x4f00, 0x20)
2289         GEN_INT_ENTRY performance_monitor, virt=1, ool=1
2290 EXC_VIRT_END(performance_monitor, 0x4f00, 0x20)
2291 EXC_COMMON_BEGIN(performance_monitor_common)
2292         GEN_COMMON performance_monitor
2293         addi    r3,r1,STACK_FRAME_OVERHEAD
2294         bl      performance_monitor_exception
2295         b       interrupt_return_srr
2296
2297
2298 /**
2299  * Interrupt 0xf20 - Vector Unavailable Interrupt.
2300  * This is a synchronous interrupt in response to
2301  * executing a vector (or altivec) instruction with MSR[VEC]=0.
2302  * Similar to FP unavailable.
2303  */
2304 INT_DEFINE_BEGIN(altivec_unavailable)
2305         IVEC=0xf20
2306 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2307         IKVM_REAL=1
2308 #endif
2309 INT_DEFINE_END(altivec_unavailable)
2310
2311 EXC_REAL_BEGIN(altivec_unavailable, 0xf20, 0x20)
2312         GEN_INT_ENTRY altivec_unavailable, virt=0, ool=1
2313 EXC_REAL_END(altivec_unavailable, 0xf20, 0x20)
2314 EXC_VIRT_BEGIN(altivec_unavailable, 0x4f20, 0x20)
2315         GEN_INT_ENTRY altivec_unavailable, virt=1, ool=1
2316 EXC_VIRT_END(altivec_unavailable, 0x4f20, 0x20)
2317 EXC_COMMON_BEGIN(altivec_unavailable_common)
2318         GEN_COMMON altivec_unavailable
2319 #ifdef CONFIG_ALTIVEC
2320 BEGIN_FTR_SECTION
2321         beq     1f
2322 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2323   BEGIN_FTR_SECTION_NESTED(69)
2324         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
2325          * transaction), go do TM stuff
2326          */
2327         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
2328         bne-    2f
2329   END_FTR_SECTION_NESTED(CPU_FTR_TM, CPU_FTR_TM, 69)
2330 #endif
2331         bl      load_up_altivec
2332         b       fast_interrupt_return_srr
2333 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2334 2:      /* User process was in a transaction */
2335         addi    r3,r1,STACK_FRAME_OVERHEAD
2336         bl      altivec_unavailable_tm
2337         b       interrupt_return_srr
2338 #endif
2339 1:
2340 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2341 #endif
2342         addi    r3,r1,STACK_FRAME_OVERHEAD
2343         bl      altivec_unavailable_exception
2344         b       interrupt_return_srr
2345
2346
2347 /**
2348  * Interrupt 0xf40 - VSX Unavailable Interrupt.
2349  * This is a synchronous interrupt in response to
2350  * executing a VSX instruction with MSR[VSX]=0.
2351  * Similar to FP unavailable.
2352  */
2353 INT_DEFINE_BEGIN(vsx_unavailable)
2354         IVEC=0xf40
2355 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2356         IKVM_REAL=1
2357 #endif
2358 INT_DEFINE_END(vsx_unavailable)
2359
2360 EXC_REAL_BEGIN(vsx_unavailable, 0xf40, 0x20)
2361         GEN_INT_ENTRY vsx_unavailable, virt=0, ool=1
2362 EXC_REAL_END(vsx_unavailable, 0xf40, 0x20)
2363 EXC_VIRT_BEGIN(vsx_unavailable, 0x4f40, 0x20)
2364         GEN_INT_ENTRY vsx_unavailable, virt=1, ool=1
2365 EXC_VIRT_END(vsx_unavailable, 0x4f40, 0x20)
2366 EXC_COMMON_BEGIN(vsx_unavailable_common)
2367         GEN_COMMON vsx_unavailable
2368 #ifdef CONFIG_VSX
2369 BEGIN_FTR_SECTION
2370         beq     1f
2371 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2372   BEGIN_FTR_SECTION_NESTED(69)
2373         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
2374          * transaction), go do TM stuff
2375          */
2376         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
2377         bne-    2f
2378   END_FTR_SECTION_NESTED(CPU_FTR_TM, CPU_FTR_TM, 69)
2379 #endif
2380         b       load_up_vsx
2381 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2382 2:      /* User process was in a transaction */
2383         addi    r3,r1,STACK_FRAME_OVERHEAD
2384         bl      vsx_unavailable_tm
2385         b       interrupt_return_srr
2386 #endif
2387 1:
2388 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
2389 #endif
2390         addi    r3,r1,STACK_FRAME_OVERHEAD
2391         bl      vsx_unavailable_exception
2392         b       interrupt_return_srr
2393
2394
2395 /**
2396  * Interrupt 0xf60 - Facility Unavailable Interrupt.
2397  * This is a synchronous interrupt in response to
2398  * executing an instruction without access to the facility that can be
2399  * resolved by the OS (e.g., FSCR, MSR).
2400  * Similar to FP unavailable.
2401  */
2402 INT_DEFINE_BEGIN(facility_unavailable)
2403         IVEC=0xf60
2404 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2405         IKVM_REAL=1
2406 #endif
2407 INT_DEFINE_END(facility_unavailable)
2408
2409 EXC_REAL_BEGIN(facility_unavailable, 0xf60, 0x20)
2410         GEN_INT_ENTRY facility_unavailable, virt=0, ool=1
2411 EXC_REAL_END(facility_unavailable, 0xf60, 0x20)
2412 EXC_VIRT_BEGIN(facility_unavailable, 0x4f60, 0x20)
2413         GEN_INT_ENTRY facility_unavailable, virt=1, ool=1
2414 EXC_VIRT_END(facility_unavailable, 0x4f60, 0x20)
2415 EXC_COMMON_BEGIN(facility_unavailable_common)
2416         GEN_COMMON facility_unavailable
2417         addi    r3,r1,STACK_FRAME_OVERHEAD
2418         bl      facility_unavailable_exception
2419         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
2420         b       interrupt_return_srr
2421
2422
2423 /**
2424  * Interrupt 0xf60 - Hypervisor Facility Unavailable Interrupt.
2425  * This is a synchronous interrupt in response to
2426  * executing an instruction without access to the facility that can only
2427  * be resolved in HV mode (e.g., HFSCR).
2428  * Similar to FP unavailable.
2429  */
2430 INT_DEFINE_BEGIN(h_facility_unavailable)
2431         IVEC=0xf80
2432         IHSRR=1
2433         IKVM_REAL=1
2434         IKVM_VIRT=1
2435 INT_DEFINE_END(h_facility_unavailable)
2436
2437 EXC_REAL_BEGIN(h_facility_unavailable, 0xf80, 0x20)
2438         GEN_INT_ENTRY h_facility_unavailable, virt=0, ool=1
2439 EXC_REAL_END(h_facility_unavailable, 0xf80, 0x20)
2440 EXC_VIRT_BEGIN(h_facility_unavailable, 0x4f80, 0x20)
2441         GEN_INT_ENTRY h_facility_unavailable, virt=1, ool=1
2442 EXC_VIRT_END(h_facility_unavailable, 0x4f80, 0x20)
2443 EXC_COMMON_BEGIN(h_facility_unavailable_common)
2444         GEN_COMMON h_facility_unavailable
2445         addi    r3,r1,STACK_FRAME_OVERHEAD
2446         bl      facility_unavailable_exception
2447         REST_NVGPRS(r1) /* XXX Shouldn't be necessary in practice */
2448         b       interrupt_return_hsrr
2449
2450
2451 EXC_REAL_NONE(0xfa0, 0x20)
2452 EXC_VIRT_NONE(0x4fa0, 0x20)
2453 EXC_REAL_NONE(0xfc0, 0x20)
2454 EXC_VIRT_NONE(0x4fc0, 0x20)
2455 EXC_REAL_NONE(0xfe0, 0x20)
2456 EXC_VIRT_NONE(0x4fe0, 0x20)
2457
2458 EXC_REAL_NONE(0x1000, 0x100)
2459 EXC_VIRT_NONE(0x5000, 0x100)
2460 EXC_REAL_NONE(0x1100, 0x100)
2461 EXC_VIRT_NONE(0x5100, 0x100)
2462
2463 #ifdef CONFIG_CBE_RAS
2464 INT_DEFINE_BEGIN(cbe_system_error)
2465         IVEC=0x1200
2466         IHSRR=1
2467 INT_DEFINE_END(cbe_system_error)
2468
2469 EXC_REAL_BEGIN(cbe_system_error, 0x1200, 0x100)
2470         GEN_INT_ENTRY cbe_system_error, virt=0
2471 EXC_REAL_END(cbe_system_error, 0x1200, 0x100)
2472 EXC_VIRT_NONE(0x5200, 0x100)
2473 EXC_COMMON_BEGIN(cbe_system_error_common)
2474         GEN_COMMON cbe_system_error
2475         addi    r3,r1,STACK_FRAME_OVERHEAD
2476         bl      cbe_system_error_exception
2477         b       interrupt_return_hsrr
2478
2479 #else /* CONFIG_CBE_RAS */
2480 EXC_REAL_NONE(0x1200, 0x100)
2481 EXC_VIRT_NONE(0x5200, 0x100)
2482 #endif
2483
2484 /**
2485  * Interrupt 0x1300 - Instruction Address Breakpoint Interrupt.
2486  * This has been removed from the ISA before 2.01, which is the earliest
2487  * 64-bit BookS ISA supported, however the G5 / 970 implements this
2488  * interrupt with a non-architected feature available through the support
2489  * processor interface.
2490  */
2491 INT_DEFINE_BEGIN(instruction_breakpoint)
2492         IVEC=0x1300
2493 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2494         IKVM_REAL=1
2495 #endif
2496 INT_DEFINE_END(instruction_breakpoint)
2497
2498 EXC_REAL_BEGIN(instruction_breakpoint, 0x1300, 0x100)
2499         GEN_INT_ENTRY instruction_breakpoint, virt=0
2500 EXC_REAL_END(instruction_breakpoint, 0x1300, 0x100)
2501 EXC_VIRT_BEGIN(instruction_breakpoint, 0x5300, 0x100)
2502         GEN_INT_ENTRY instruction_breakpoint, virt=1
2503 EXC_VIRT_END(instruction_breakpoint, 0x5300, 0x100)
2504 EXC_COMMON_BEGIN(instruction_breakpoint_common)
2505         GEN_COMMON instruction_breakpoint
2506         addi    r3,r1,STACK_FRAME_OVERHEAD
2507         bl      instruction_breakpoint_exception
2508         b       interrupt_return_srr
2509
2510
2511 EXC_REAL_NONE(0x1400, 0x100)
2512 EXC_VIRT_NONE(0x5400, 0x100)
2513
2514 /**
2515  * Interrupt 0x1500 - Soft Patch Interrupt
2516  *
2517  * Handling:
2518  * This is an implementation specific interrupt which can be used for a
2519  * range of exceptions.
2520  *
2521  * This interrupt handler is unique in that it runs the denormal assist
2522  * code even for guests (and even in guest context) without going to KVM,
2523  * for speed. POWER9 does not raise denorm exceptions, so this special case
2524  * could be phased out in future to reduce special cases.
2525  */
2526 INT_DEFINE_BEGIN(denorm_exception)
2527         IVEC=0x1500
2528         IHSRR=1
2529         IBRANCH_TO_COMMON=0
2530         IKVM_REAL=1
2531 INT_DEFINE_END(denorm_exception)
2532
2533 EXC_REAL_BEGIN(denorm_exception, 0x1500, 0x100)
2534         GEN_INT_ENTRY denorm_exception, virt=0
2535 #ifdef CONFIG_PPC_DENORMALISATION
2536         andis.  r10,r12,(HSRR1_DENORM)@h /* denorm? */
2537         bne+    denorm_assist
2538 #endif
2539         GEN_BRANCH_TO_COMMON denorm_exception, virt=0
2540 EXC_REAL_END(denorm_exception, 0x1500, 0x100)
2541 #ifdef CONFIG_PPC_DENORMALISATION
2542 EXC_VIRT_BEGIN(denorm_exception, 0x5500, 0x100)
2543         GEN_INT_ENTRY denorm_exception, virt=1
2544         andis.  r10,r12,(HSRR1_DENORM)@h /* denorm? */
2545         bne+    denorm_assist
2546         GEN_BRANCH_TO_COMMON denorm_exception, virt=1
2547 EXC_VIRT_END(denorm_exception, 0x5500, 0x100)
2548 #else
2549 EXC_VIRT_NONE(0x5500, 0x100)
2550 #endif
2551
2552 #ifdef CONFIG_PPC_DENORMALISATION
2553 TRAMP_REAL_BEGIN(denorm_assist)
2554 BEGIN_FTR_SECTION
2555 /*
2556  * To denormalise we need to move a copy of the register to itself.
2557  * For POWER6 do that here for all FP regs.
2558  */
2559         mfmsr   r10
2560         ori     r10,r10,(MSR_FP|MSR_FE0|MSR_FE1)
2561         xori    r10,r10,(MSR_FE0|MSR_FE1)
2562         mtmsrd  r10
2563         sync
2564
2565         .Lreg=0
2566         .rept 32
2567         fmr     .Lreg,.Lreg
2568         .Lreg=.Lreg+1
2569         .endr
2570
2571 FTR_SECTION_ELSE
2572 /*
2573  * To denormalise we need to move a copy of the register to itself.
2574  * For POWER7 do that here for the first 32 VSX registers only.
2575  */
2576         mfmsr   r10
2577         oris    r10,r10,MSR_VSX@h
2578         mtmsrd  r10
2579         sync
2580
2581         .Lreg=0
2582         .rept 32
2583         XVCPSGNDP(.Lreg,.Lreg,.Lreg)
2584         .Lreg=.Lreg+1
2585         .endr
2586
2587 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_206)
2588
2589 BEGIN_FTR_SECTION
2590         b       denorm_done
2591 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
2592 /*
2593  * To denormalise we need to move a copy of the register to itself.
2594  * For POWER8 we need to do that for all 64 VSX registers
2595  */
2596         .Lreg=32
2597         .rept 32
2598         XVCPSGNDP(.Lreg,.Lreg,.Lreg)
2599         .Lreg=.Lreg+1
2600         .endr
2601
2602 denorm_done:
2603         mfspr   r11,SPRN_HSRR0
2604         subi    r11,r11,4
2605         mtspr   SPRN_HSRR0,r11
2606         mtcrf   0x80,r9
2607         ld      r9,PACA_EXGEN+EX_R9(r13)
2608 BEGIN_FTR_SECTION
2609         ld      r10,PACA_EXGEN+EX_PPR(r13)
2610         mtspr   SPRN_PPR,r10
2611 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
2612 BEGIN_FTR_SECTION
2613         ld      r10,PACA_EXGEN+EX_CFAR(r13)
2614         mtspr   SPRN_CFAR,r10
2615 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
2616         li      r10,0
2617         stb     r10,PACAHSRR_VALID(r13)
2618         ld      r10,PACA_EXGEN+EX_R10(r13)
2619         ld      r11,PACA_EXGEN+EX_R11(r13)
2620         ld      r12,PACA_EXGEN+EX_R12(r13)
2621         ld      r13,PACA_EXGEN+EX_R13(r13)
2622         HRFI_TO_UNKNOWN
2623         b       .
2624 #endif
2625
2626 EXC_COMMON_BEGIN(denorm_exception_common)
2627         GEN_COMMON denorm_exception
2628         addi    r3,r1,STACK_FRAME_OVERHEAD
2629         bl      unknown_exception
2630         b       interrupt_return_hsrr
2631
2632
2633 #ifdef CONFIG_CBE_RAS
2634 INT_DEFINE_BEGIN(cbe_maintenance)
2635         IVEC=0x1600
2636         IHSRR=1
2637 INT_DEFINE_END(cbe_maintenance)
2638
2639 EXC_REAL_BEGIN(cbe_maintenance, 0x1600, 0x100)
2640         GEN_INT_ENTRY cbe_maintenance, virt=0
2641 EXC_REAL_END(cbe_maintenance, 0x1600, 0x100)
2642 EXC_VIRT_NONE(0x5600, 0x100)
2643 EXC_COMMON_BEGIN(cbe_maintenance_common)
2644         GEN_COMMON cbe_maintenance
2645         addi    r3,r1,STACK_FRAME_OVERHEAD
2646         bl      cbe_maintenance_exception
2647         b       interrupt_return_hsrr
2648
2649 #else /* CONFIG_CBE_RAS */
2650 EXC_REAL_NONE(0x1600, 0x100)
2651 EXC_VIRT_NONE(0x5600, 0x100)
2652 #endif
2653
2654
2655 INT_DEFINE_BEGIN(altivec_assist)
2656         IVEC=0x1700
2657 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2658         IKVM_REAL=1
2659 #endif
2660 INT_DEFINE_END(altivec_assist)
2661
2662 EXC_REAL_BEGIN(altivec_assist, 0x1700, 0x100)
2663         GEN_INT_ENTRY altivec_assist, virt=0
2664 EXC_REAL_END(altivec_assist, 0x1700, 0x100)
2665 EXC_VIRT_BEGIN(altivec_assist, 0x5700, 0x100)
2666         GEN_INT_ENTRY altivec_assist, virt=1
2667 EXC_VIRT_END(altivec_assist, 0x5700, 0x100)
2668 EXC_COMMON_BEGIN(altivec_assist_common)
2669         GEN_COMMON altivec_assist
2670         addi    r3,r1,STACK_FRAME_OVERHEAD
2671 #ifdef CONFIG_ALTIVEC
2672         bl      altivec_assist_exception
2673         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
2674 #else
2675         bl      unknown_exception
2676 #endif
2677         b       interrupt_return_srr
2678
2679
2680 #ifdef CONFIG_CBE_RAS
2681 INT_DEFINE_BEGIN(cbe_thermal)
2682         IVEC=0x1800
2683         IHSRR=1
2684 INT_DEFINE_END(cbe_thermal)
2685
2686 EXC_REAL_BEGIN(cbe_thermal, 0x1800, 0x100)
2687         GEN_INT_ENTRY cbe_thermal, virt=0
2688 EXC_REAL_END(cbe_thermal, 0x1800, 0x100)
2689 EXC_VIRT_NONE(0x5800, 0x100)
2690 EXC_COMMON_BEGIN(cbe_thermal_common)
2691         GEN_COMMON cbe_thermal
2692         addi    r3,r1,STACK_FRAME_OVERHEAD
2693         bl      cbe_thermal_exception
2694         b       interrupt_return_hsrr
2695
2696 #else /* CONFIG_CBE_RAS */
2697 EXC_REAL_NONE(0x1800, 0x100)
2698 EXC_VIRT_NONE(0x5800, 0x100)
2699 #endif
2700
2701
2702 #ifdef CONFIG_PPC_WATCHDOG
2703
2704 INT_DEFINE_BEGIN(soft_nmi)
2705         IVEC=0x900
2706         ISTACK=0
2707 INT_DEFINE_END(soft_nmi)
2708
2709 /*
2710  * Branch to soft_nmi_interrupt using the emergency stack. The emergency
2711  * stack is one that is usable by maskable interrupts so long as MSR_EE
2712  * remains off. It is used for recovery when something has corrupted the
2713  * normal kernel stack, for example. The "soft NMI" must not use the process
2714  * stack because we want irq disabled sections to avoid touching the stack
2715  * at all (other than PMU interrupts), so use the emergency stack for this,
2716  * and run it entirely with interrupts hard disabled.
2717  */
2718 EXC_COMMON_BEGIN(soft_nmi_common)
2719         mr      r10,r1
2720         ld      r1,PACAEMERGSP(r13)
2721         subi    r1,r1,INT_FRAME_SIZE
2722         __GEN_COMMON_BODY soft_nmi
2723
2724         addi    r3,r1,STACK_FRAME_OVERHEAD
2725         bl      soft_nmi_interrupt
2726
2727         /* Clear MSR_RI before setting SRR0 and SRR1. */
2728         li      r9,0
2729         mtmsrd  r9,1
2730
2731         kuap_kernel_restore r9, r10
2732
2733         EXCEPTION_RESTORE_REGS hsrr=0
2734         RFI_TO_KERNEL
2735
2736 #endif /* CONFIG_PPC_WATCHDOG */
2737
2738 /*
2739  * An interrupt came in while soft-disabled. We set paca->irq_happened, then:
2740  * - If it was a decrementer interrupt, we bump the dec to max and and return.
2741  * - If it was a doorbell we return immediately since doorbells are edge
2742  *   triggered and won't automatically refire.
2743  * - If it was a HMI we return immediately since we handled it in realmode
2744  *   and it won't refire.
2745  * - Else it is one of PACA_IRQ_MUST_HARD_MASK, so hard disable and return.
2746  * This is called with r10 containing the value to OR to the paca field.
2747  */
2748 .macro MASKED_INTERRUPT hsrr=0
2749         .if \hsrr
2750 masked_Hinterrupt:
2751         .else
2752 masked_interrupt:
2753         .endif
2754         stw     r9,PACA_EXGEN+EX_CCR(r13)
2755         lbz     r9,PACAIRQHAPPENED(r13)
2756         or      r9,r9,r10
2757         stb     r9,PACAIRQHAPPENED(r13)
2758
2759         .if ! \hsrr
2760         cmpwi   r10,PACA_IRQ_DEC
2761         bne     1f
2762         LOAD_REG_IMMEDIATE(r9, 0x7fffffff)
2763         mtspr   SPRN_DEC,r9
2764 #ifdef CONFIG_PPC_WATCHDOG
2765         lwz     r9,PACA_EXGEN+EX_CCR(r13)
2766         b       soft_nmi_common
2767 #else
2768         b       2f
2769 #endif
2770         .endif
2771
2772 1:      andi.   r10,r10,PACA_IRQ_MUST_HARD_MASK
2773         beq     2f
2774         xori    r12,r12,MSR_EE  /* clear MSR_EE */
2775         .if \hsrr
2776         mtspr   SPRN_HSRR1,r12
2777         .else
2778         mtspr   SPRN_SRR1,r12
2779         .endif
2780         ori     r9,r9,PACA_IRQ_HARD_DIS
2781         stb     r9,PACAIRQHAPPENED(r13)
2782 2:      /* done */
2783         li      r9,0
2784         .if \hsrr
2785         stb     r9,PACAHSRR_VALID(r13)
2786         .else
2787         stb     r9,PACASRR_VALID(r13)
2788         .endif
2789
2790         SEARCH_RESTART_TABLE
2791         cmpdi   r12,0
2792         beq     3f
2793         .if \hsrr
2794         mtspr   SPRN_HSRR0,r12
2795         .else
2796         mtspr   SPRN_SRR0,r12
2797         .endif
2798 3:
2799
2800         ld      r9,PACA_EXGEN+EX_CTR(r13)
2801         mtctr   r9
2802         lwz     r9,PACA_EXGEN+EX_CCR(r13)
2803         mtcrf   0x80,r9
2804         std     r1,PACAR1(r13)
2805         ld      r9,PACA_EXGEN+EX_R9(r13)
2806         ld      r10,PACA_EXGEN+EX_R10(r13)
2807         ld      r11,PACA_EXGEN+EX_R11(r13)
2808         ld      r12,PACA_EXGEN+EX_R12(r13)
2809         ld      r13,PACA_EXGEN+EX_R13(r13)
2810         /* May return to masked low address where r13 is not set up */
2811         .if \hsrr
2812         HRFI_TO_KERNEL
2813         .else
2814         RFI_TO_KERNEL
2815         .endif
2816         b       .
2817 .endm
2818
2819 TRAMP_REAL_BEGIN(stf_barrier_fallback)
2820         std     r9,PACA_EXRFI+EX_R9(r13)
2821         std     r10,PACA_EXRFI+EX_R10(r13)
2822         sync
2823         ld      r9,PACA_EXRFI+EX_R9(r13)
2824         ld      r10,PACA_EXRFI+EX_R10(r13)
2825         ori     31,31,0
2826         .rept 14
2827         b       1f
2828 1:
2829         .endr
2830         blr
2831
2832 /* Clobbers r10, r11, ctr */
2833 .macro L1D_DISPLACEMENT_FLUSH
2834         ld      r10,PACA_RFI_FLUSH_FALLBACK_AREA(r13)
2835         ld      r11,PACA_L1D_FLUSH_SIZE(r13)
2836         srdi    r11,r11,(7 + 3) /* 128 byte lines, unrolled 8x */
2837         mtctr   r11
2838         DCBT_BOOK3S_STOP_ALL_STREAM_IDS(r11) /* Stop prefetch streams */
2839
2840         /* order ld/st prior to dcbt stop all streams with flushing */
2841         sync
2842
2843         /*
2844          * The load addresses are at staggered offsets within cachelines,
2845          * which suits some pipelines better (on others it should not
2846          * hurt).
2847          */
2848 1:
2849         ld      r11,(0x80 + 8)*0(r10)
2850         ld      r11,(0x80 + 8)*1(r10)
2851         ld      r11,(0x80 + 8)*2(r10)
2852         ld      r11,(0x80 + 8)*3(r10)
2853         ld      r11,(0x80 + 8)*4(r10)
2854         ld      r11,(0x80 + 8)*5(r10)
2855         ld      r11,(0x80 + 8)*6(r10)
2856         ld      r11,(0x80 + 8)*7(r10)
2857         addi    r10,r10,0x80*8
2858         bdnz    1b
2859 .endm
2860
2861 TRAMP_REAL_BEGIN(entry_flush_fallback)
2862         std     r9,PACA_EXRFI+EX_R9(r13)
2863         std     r10,PACA_EXRFI+EX_R10(r13)
2864         std     r11,PACA_EXRFI+EX_R11(r13)
2865         mfctr   r9
2866         L1D_DISPLACEMENT_FLUSH
2867         mtctr   r9
2868         ld      r9,PACA_EXRFI+EX_R9(r13)
2869         ld      r10,PACA_EXRFI+EX_R10(r13)
2870         ld      r11,PACA_EXRFI+EX_R11(r13)
2871         blr
2872
2873 /*
2874  * The SCV entry flush happens with interrupts enabled, so it must disable
2875  * to prevent EXRFI being clobbered by NMIs (e.g., soft_nmi_common). r10
2876  * (containing LR) does not need to be preserved here because scv entry
2877  * puts 0 in the pt_regs, CTR can be clobbered for the same reason.
2878  */
2879 TRAMP_REAL_BEGIN(scv_entry_flush_fallback)
2880         li      r10,0
2881         mtmsrd  r10,1
2882         lbz     r10,PACAIRQHAPPENED(r13)
2883         ori     r10,r10,PACA_IRQ_HARD_DIS
2884         stb     r10,PACAIRQHAPPENED(r13)
2885         std     r11,PACA_EXRFI+EX_R11(r13)
2886         L1D_DISPLACEMENT_FLUSH
2887         ld      r11,PACA_EXRFI+EX_R11(r13)
2888         li      r10,MSR_RI
2889         mtmsrd  r10,1
2890         blr
2891
2892 TRAMP_REAL_BEGIN(rfi_flush_fallback)
2893         SET_SCRATCH0(r13);
2894         GET_PACA(r13);
2895         std     r1,PACA_EXRFI+EX_R12(r13)
2896         ld      r1,PACAKSAVE(r13)
2897         std     r9,PACA_EXRFI+EX_R9(r13)
2898         std     r10,PACA_EXRFI+EX_R10(r13)
2899         std     r11,PACA_EXRFI+EX_R11(r13)
2900         mfctr   r9
2901         L1D_DISPLACEMENT_FLUSH
2902         mtctr   r9
2903         ld      r9,PACA_EXRFI+EX_R9(r13)
2904         ld      r10,PACA_EXRFI+EX_R10(r13)
2905         ld      r11,PACA_EXRFI+EX_R11(r13)
2906         ld      r1,PACA_EXRFI+EX_R12(r13)
2907         GET_SCRATCH0(r13);
2908         rfid
2909
2910 TRAMP_REAL_BEGIN(hrfi_flush_fallback)
2911         SET_SCRATCH0(r13);
2912         GET_PACA(r13);
2913         std     r1,PACA_EXRFI+EX_R12(r13)
2914         ld      r1,PACAKSAVE(r13)
2915         std     r9,PACA_EXRFI+EX_R9(r13)
2916         std     r10,PACA_EXRFI+EX_R10(r13)
2917         std     r11,PACA_EXRFI+EX_R11(r13)
2918         mfctr   r9
2919         L1D_DISPLACEMENT_FLUSH
2920         mtctr   r9
2921         ld      r9,PACA_EXRFI+EX_R9(r13)
2922         ld      r10,PACA_EXRFI+EX_R10(r13)
2923         ld      r11,PACA_EXRFI+EX_R11(r13)
2924         ld      r1,PACA_EXRFI+EX_R12(r13)
2925         GET_SCRATCH0(r13);
2926         hrfid
2927
2928 TRAMP_REAL_BEGIN(rfscv_flush_fallback)
2929         /* system call volatile */
2930         mr      r7,r13
2931         GET_PACA(r13);
2932         mr      r8,r1
2933         ld      r1,PACAKSAVE(r13)
2934         mfctr   r9
2935         ld      r10,PACA_RFI_FLUSH_FALLBACK_AREA(r13)
2936         ld      r11,PACA_L1D_FLUSH_SIZE(r13)
2937         srdi    r11,r11,(7 + 3) /* 128 byte lines, unrolled 8x */
2938         mtctr   r11
2939         DCBT_BOOK3S_STOP_ALL_STREAM_IDS(r11) /* Stop prefetch streams */
2940
2941         /* order ld/st prior to dcbt stop all streams with flushing */
2942         sync
2943
2944         /*
2945          * The load adresses are at staggered offsets within cachelines,
2946          * which suits some pipelines better (on others it should not
2947          * hurt).
2948          */
2949 1:
2950         ld      r11,(0x80 + 8)*0(r10)
2951         ld      r11,(0x80 + 8)*1(r10)
2952         ld      r11,(0x80 + 8)*2(r10)
2953         ld      r11,(0x80 + 8)*3(r10)
2954         ld      r11,(0x80 + 8)*4(r10)
2955         ld      r11,(0x80 + 8)*5(r10)
2956         ld      r11,(0x80 + 8)*6(r10)
2957         ld      r11,(0x80 + 8)*7(r10)
2958         addi    r10,r10,0x80*8
2959         bdnz    1b
2960
2961         mtctr   r9
2962         li      r9,0
2963         li      r10,0
2964         li      r11,0
2965         mr      r1,r8
2966         mr      r13,r7
2967         RFSCV
2968
2969 USE_TEXT_SECTION()
2970
2971 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
2972 kvm_interrupt:
2973         /*
2974          * The conditional branch in KVMTEST can't reach all the way,
2975          * make a stub.
2976          */
2977         b       kvmppc_interrupt
2978 #endif
2979
2980 _GLOBAL(do_uaccess_flush)
2981         UACCESS_FLUSH_FIXUP_SECTION
2982         nop
2983         nop
2984         nop
2985         blr
2986         L1D_DISPLACEMENT_FLUSH
2987         blr
2988 _ASM_NOKPROBE_SYMBOL(do_uaccess_flush)
2989 EXPORT_SYMBOL(do_uaccess_flush)
2990
2991
2992 MASKED_INTERRUPT
2993 MASKED_INTERRUPT hsrr=1
2994
2995         /*
2996          * Relocation-on interrupts: A subset of the interrupts can be delivered
2997          * with IR=1/DR=1, if AIL==2 and MSR.HV won't be changed by delivering
2998          * it.  Addresses are the same as the original interrupt addresses, but
2999          * offset by 0xc000000000004000.
3000          * It's impossible to receive interrupts below 0x300 via this mechanism.
3001          * KVM: None of these traps are from the guest ; anything that escalated
3002          * to HV=1 from HV=0 is delivered via real mode handlers.
3003          */
3004
3005         /*
3006          * This uses the standard macro, since the original 0x300 vector
3007          * only has extra guff for STAB-based processors -- which never
3008          * come here.
3009          */
3010
3011 USE_FIXED_SECTION(virt_trampolines)
3012         /*
3013          * All code below __end_soft_masked is treated as soft-masked. If
3014          * any code runs here with MSR[EE]=1, it must then cope with pending
3015          * soft interrupt being raised (i.e., by ensuring it is replayed).
3016          *
3017          * The __end_interrupts marker must be past the out-of-line (OOL)
3018          * handlers, so that they are copied to real address 0x100 when running
3019          * a relocatable kernel. This ensures they can be reached from the short
3020          * trampoline handlers (like 0x4f00, 0x4f20, etc.) which branch
3021          * directly, without using LOAD_HANDLER().
3022          */
3023         .align  7
3024         .globl  __end_interrupts
3025 __end_interrupts:
3026 DEFINE_FIXED_SYMBOL(__end_interrupts)
3027
3028 CLOSE_FIXED_SECTION(real_vectors);
3029 CLOSE_FIXED_SECTION(real_trampolines);
3030 CLOSE_FIXED_SECTION(virt_vectors);
3031 CLOSE_FIXED_SECTION(virt_trampolines);
3032
3033 USE_TEXT_SECTION()
3034
3035 /* MSR[RI] should be clear because this uses SRR[01] */
3036 enable_machine_check:
3037         mflr    r0
3038         bcl     20,31,$+4
3039 0:      mflr    r3
3040         addi    r3,r3,(1f - 0b)
3041         mtspr   SPRN_SRR0,r3
3042         mfmsr   r3
3043         ori     r3,r3,MSR_ME
3044         mtspr   SPRN_SRR1,r3
3045         RFI_TO_KERNEL
3046 1:      mtlr    r0
3047         blr
3048
3049 /* MSR[RI] should be clear because this uses SRR[01] */
3050 disable_machine_check:
3051         mflr    r0
3052         bcl     20,31,$+4
3053 0:      mflr    r3
3054         addi    r3,r3,(1f - 0b)
3055         mtspr   SPRN_SRR0,r3
3056         mfmsr   r3
3057         li      r4,MSR_ME
3058         andc    r3,r3,r4
3059         mtspr   SPRN_SRR1,r3
3060         RFI_TO_KERNEL
3061 1:      mtlr    r0
3062         blr