arch/parisc/kernel/head.S

   1 /* This file is subject to the terms and conditions of the GNU General Public
   2  * License.  See the file "COPYING" in the main directory of this archive
   3  * for more details.
   4  *
   5  * Copyright (C) 1999-2007 by Helge Deller <deller@gmx.de>
   6  * Copyright 1999 SuSE GmbH (Philipp Rumpf)
   7  * Copyright 1999 Philipp Rumpf (prumpf@tux.org)
   8  * Copyright 2000 Hewlett Packard (Paul Bame, bame@puffin.external.hp.com)
   9  * Copyright (C) 2001 Grant Grundler (Hewlett Packard)
  10  * Copyright (C) 2004 Kyle McMartin <kyle@debian.org>
  11  *
  12  * Initial Version 04-23-1999 by Helge Deller <deller@gmx.de>
  13  */
  14
  15 #include <asm/asm-offsets.h>
  16 #include <asm/psw.h>
  17 #include <asm/pdc.h>
  18
  19 #include <asm/assembly.h>
  20
  21 #include <linux/linkage.h>
  22 #include <linux/init.h>
  23 #include <linux/pgtable.h>
  24
  25         .level  1.1
  26
  27         __INITDATA
  28 ENTRY(boot_args)
  29         .word 0 /* arg0 */
  30         .word 0 /* arg1 */
  31         .word 0 /* arg2 */
  32         .word 0 /* arg3 */
  33 END(boot_args)
  34
  35         __HEAD
  36
  37         .align  4
  38         .import init_task,data
  39         .import init_stack,data
  40         .import fault_vector_20,code    /* IVA parisc 2.0 32 bit */
  41 #ifndef CONFIG_64BIT
  42         .import fault_vector_11,code    /* IVA parisc 1.1 32 bit */
  43         .import $global$                /* forward declaration */
  44 #endif /*!CONFIG_64BIT*/
  45 ENTRY(parisc_kernel_start)
  46         .proc
  47         .callinfo
  48
  49         /* Make sure sr4-sr7 are set to zero for the kernel address space */
  50         mtsp    %r0,%sr4
  51         mtsp    %r0,%sr5
  52         mtsp    %r0,%sr6
  53         mtsp    %r0,%sr7
  54
  55         /* Clear BSS (shouldn't the boot loader do this?) */
  56
  57         .import __bss_start,data
  58         .import __bss_stop,data
  59
  60         load32          PA(__bss_start),%r3
  61         load32          PA(__bss_stop),%r4
  62 $bss_loop:
  63         cmpb,<<,n       %r3,%r4,$bss_loop
  64         stw,ma          %r0,4(%r3)
  65
  66         /* Save away the arguments the boot loader passed in (32 bit args) */
  67         load32          PA(boot_args),%r1
  68         stw,ma          %arg0,4(%r1)
  69         stw,ma          %arg1,4(%r1)
  70         stw,ma          %arg2,4(%r1)
  71         stw,ma          %arg3,4(%r1)
  72
  73 #if defined(CONFIG_PA20)
  74         /* check for 64-bit capable CPU as required by current kernel */
  75         ldi             32,%r10
  76         mtctl           %r10,%cr11
  77         .level 2.0
  78         mfctl,w         %cr11,%r10
  79         .level 1.1
  80         comib,<>,n      0,%r10,$cpu_ok
  81
  82         load32          PA(msg1),%arg0
  83         ldi             msg1_end-msg1,%arg1
  84 $iodc_panic:
  85         copy            %arg0, %r10
  86         copy            %arg1, %r11
  87         load32          PA(init_stack),%sp
  88 #define MEM_CONS 0x3A0
  89         ldw             MEM_CONS+32(%r0),%arg0  // HPA
  90         ldi             ENTRY_IO_COUT,%arg1
  91         ldw             MEM_CONS+36(%r0),%arg2  // SPA
  92         ldw             MEM_CONS+8(%r0),%arg3   // layers
  93         load32          PA(__bss_start),%r1
  94         stw             %r1,-52(%sp)            // arg4
  95         stw             %r0,-56(%sp)            // arg5
  96         stw             %r10,-60(%sp)           // arg6 = ptr to text
  97         stw             %r11,-64(%sp)           // arg7 = len
  98         stw             %r0,-68(%sp)            // arg8
  99         load32          PA(.iodc_panic_ret), %rp
 100         ldw             MEM_CONS+40(%r0),%r1    // ENTRY_IODC
 101         bv,n            (%r1)
 102 .iodc_panic_ret:
 103         b .                             /* wait endless with ... */
 104         or              %r10,%r10,%r10  /* qemu idle sleep */
 105 msg1:   .ascii "Can't boot kernel which was built for PA8x00 CPUs on this machine.\r\n"
 106 msg1_end:
 107
 108 $cpu_ok:
 109 #endif
 110
 111         .level  PA_ASM_LEVEL
 112
 113         /* Initialize startup VM. Just map first 16/32 MB of memory */
 114         load32          PA(swapper_pg_dir),%r4
 115         mtctl           %r4,%cr24       /* Initialize kernel root pointer */
 116         mtctl           %r4,%cr25       /* Initialize user root pointer */
 117
 118 #if CONFIG_PGTABLE_LEVELS == 3
 119         /* Set pmd in pgd */
 120         load32          PA(pmd0),%r5
 121         shrd            %r5,PxD_VALUE_SHIFT,%r3
 122         ldo             (PxD_FLAG_PRESENT+PxD_FLAG_VALID)(%r3),%r3
 123         stw             %r3,ASM_PGD_ENTRY*ASM_PGD_ENTRY_SIZE(%r4)
 124         ldo             ASM_PMD_ENTRY*ASM_PMD_ENTRY_SIZE(%r5),%r4
 125 #else
 126         /* 2-level page table, so pmd == pgd */
 127         ldo             ASM_PGD_ENTRY*ASM_PGD_ENTRY_SIZE(%r4),%r4
 128 #endif
 129
 130         /* Fill in pmd with enough pte directories */
 131         load32          PA(pg0),%r1
 132         SHRREG          %r1,PxD_VALUE_SHIFT,%r3
 133         ldo             (PxD_FLAG_PRESENT+PxD_FLAG_VALID)(%r3),%r3
 134
 135         ldi             ASM_PT_INITIAL,%r1
 136
 137 1:
 138         stw             %r3,0(%r4)
 139         ldo             (PAGE_SIZE >> PxD_VALUE_SHIFT)(%r3),%r3
 140         addib,>         -1,%r1,1b
 141 #if CONFIG_PGTABLE_LEVELS == 3
 142         ldo             ASM_PMD_ENTRY_SIZE(%r4),%r4
 143 #else
 144         ldo             ASM_PGD_ENTRY_SIZE(%r4),%r4
 145 #endif
 146
 147
 148         /* Now initialize the PTEs themselves.  We use RWX for
 149          * everything ... it will get remapped correctly later */
 150         ldo             0+_PAGE_KERNEL_RWX(%r0),%r3 /* Hardwired 0 phys addr start */
 151         load32          (1<<(KERNEL_INITIAL_ORDER-PAGE_SHIFT)),%r11 /* PFN count */
 152         load32          PA(pg0),%r1
 153
 154 $pgt_fill_loop:
 155         STREGM          %r3,ASM_PTE_ENTRY_SIZE(%r1)
 156         ldo             (1<<PFN_PTE_SHIFT)(%r3),%r3 /* add one PFN */
 157         addib,>         -1,%r11,$pgt_fill_loop
 158         nop
 159
 160         /* Load the return address...er...crash 'n burn */
 161         copy            %r0,%r2
 162
 163         /* And the RFI Target address too */
 164         load32          start_parisc,%r11
 165
 166         /* And the initial task pointer */
 167         load32          init_task,%r6
 168         mtctl           %r6,%cr30
 169
 170         /* And the stack pointer too */
 171         load32          init_stack,%sp
 172         tophys_r1       %sp
 173 #if defined(CONFIG_64BIT) && defined(CONFIG_FUNCTION_TRACER)
 174         .import _mcount,data
 175         /* initialize mcount FPTR */
 176         /* Get the global data pointer */
 177         loadgp
 178         load32          PA(_mcount), %r10
 179         std             %dp,0x18(%r10)
 180 #endif
 181
 182 #ifdef CONFIG_64BIT
 183         /* Get PDCE_PROC for monarch CPU. */
 184 #define MEM_PDC_LO 0x388
 185 #define MEM_PDC_HI 0x35C
 186         ldw             MEM_PDC_LO(%r0),%r3
 187         ldw             MEM_PDC_HI(%r0),%r10
 188         depd            %r10, 31, 32, %r3        /* move to upper word */
 189 #endif
 190
 191
 192 #ifdef CONFIG_SMP
 193         /* Set the smp rendezvous address into page zero.
 194         ** It would be safer to do this in init_smp_config() but
 195         ** it's just way easier to deal with here because
 196         ** of 64-bit function ptrs and the address is local to this file.
 197         */
 198         load32          PA(smp_slave_stext),%r10
 199         stw             %r10,0x10(%r0)  /* MEM_RENDEZ */
 200         stw             %r0,0x28(%r0)   /* MEM_RENDEZ_HI - assume addr < 4GB */
 201
 202         /* FALLTHROUGH */
 203         .procend
 204
 205 #ifdef CONFIG_HOTPLUG_CPU
 206         /* common_stext is far away in another section... jump there */
 207         load32          PA(common_stext), %rp
 208         bv,n            (%rp)
 209
 210         /* common_stext and smp_slave_stext needs to be in text section */
 211         .text
 212 #endif
 213
 214         /*
 215         ** Code Common to both Monarch and Slave processors.
 216         ** Entry:
 217         **
 218         **  1.1:
 219         **    %r11 must contain RFI target address.
 220         **    %r25/%r26 args to pass to target function
 221         **    %r2  in case rfi target decides it didn't like something
 222         **
 223         **  2.0w:
 224         **    %r3  PDCE_PROC address
 225         **    %r11 RFI target address
 226         **
 227         ** Caller must init: SR4-7, %sp, %r10, %cr24/25,
 228         */
 229 common_stext:
 230         .proc
 231         .callinfo
 232 #else
 233         /* Clear PDC entry point - we won't use it */
 234         stw             %r0,0x10(%r0)   /* MEM_RENDEZ */
 235         stw             %r0,0x28(%r0)   /* MEM_RENDEZ_HI */
 236 #endif /*CONFIG_SMP*/
 237
 238 #ifdef CONFIG_64BIT
 239         mfctl           %cr30,%r6               /* PCX-W2 firmware bug */
 240         tophys_r1       %r6
 241
 242         /* Save the rfi target address */
 243         STREG           %r11,  TASK_PT_GR11(%r6)
 244         /* Switch to wide mode Superdome doesn't support narrow PDC
 245         ** calls.
 246         */
 247 1:      mfia            %rp             /* clear upper part of pcoq */
 248         ldo             2f-1b(%rp),%rp
 249         depdi           0,31,32,%rp
 250         bv              (%rp)
 251         ssm             PSW_SM_W,%r0
 252
 253         /* Set Wide mode as the "Default" (eg for traps)
 254         ** First trap occurs *right* after (or part of) rfi for slave CPUs.
 255         ** Someday, palo might not do this for the Monarch either.
 256         */
 257 2:
 258
 259         ldo             PDC_PSW(%r0),%arg0              /* 21 */
 260         ldo             PDC_PSW_SET_DEFAULTS(%r0),%arg1 /* 2 */
 261         ldo             PDC_PSW_WIDE_BIT(%r0),%arg2     /* 2 */
 262         load32          PA(stext_pdc_ret), %rp
 263         bv              (%r3)
 264         copy            %r0,%arg3
 265
 266 stext_pdc_ret:
 267         LDREG           TASK_PT_GR11(%r6), %r11
 268         tovirt_r1       %r6
 269         mtctl           %r6,%cr30               /* restore task thread info */
 270 #endif
 271
 272         /* PARANOID: clear user scratch/user space SR's */
 273         mtsp    %r0,%sr0
 274         mtsp    %r0,%sr1
 275         mtsp    %r0,%sr2
 276         mtsp    %r0,%sr3
 277
 278         /* Initialize Protection Registers */
 279         mtctl   %r0,%cr8
 280         mtctl   %r0,%cr9
 281         mtctl   %r0,%cr12
 282         mtctl   %r0,%cr13
 283
 284         /* Initialize the global data pointer */
 285         loadgp
 286
 287         /* Set up our interrupt table.  HPMCs might not work after this!
 288          *
 289          * We need to install the correct iva for PA1.1 or PA2.0. The
 290          * following short sequence of instructions can determine this
 291          * (without being illegal on a PA1.1 machine).
 292          */
 293 #ifndef CONFIG_64BIT
 294         ldi             32,%r10
 295         mtctl           %r10,%cr11
 296         .level 2.0
 297         mfctl,w         %cr11,%r10
 298         .level 1.1
 299         comib,<>,n      0,%r10,$is_pa20
 300         ldil            L%PA(fault_vector_11),%r10
 301         b               $install_iva
 302         ldo             R%PA(fault_vector_11)(%r10),%r10
 303
 304 $is_pa20:
 305         .level          PA_ASM_LEVEL /* restore 1.1 || 2.0w */
 306 #endif /*!CONFIG_64BIT*/
 307         load32          PA(fault_vector_20),%r10
 308
 309 $install_iva:
 310         mtctl           %r10,%cr14
 311
 312         b               aligned_rfi  /* Prepare to RFI! Man all the cannons! */
 313         nop
 314
 315         .align 128
 316 aligned_rfi:
 317         pcxt_ssm_bug
 318
 319         copy            %r3, %arg0      /* PDCE_PROC for smp_callin() */
 320
 321         rsm             PSW_SM_QUIET,%r0        /* off troublesome PSW bits */
 322         /* Don't need NOPs, have 8 compliant insn before rfi */
 323
 324         mtctl           %r0,%cr17       /* Clear IIASQ tail */
 325         mtctl           %r0,%cr17       /* Clear IIASQ head */
 326
 327         /* Load RFI target into PC queue */
 328         mtctl           %r11,%cr18      /* IIAOQ head */
 329         ldo             4(%r11),%r11
 330         mtctl           %r11,%cr18      /* IIAOQ tail */
 331
 332         load32          KERNEL_PSW,%r10
 333         mtctl           %r10,%ipsw
 334
 335         tovirt_r1       %sp
 336
 337         /* Jump through hyperspace to Virt Mode */
 338         rfi
 339         nop
 340
 341         .procend
 342
 343 #ifdef CONFIG_SMP
 344
 345         .import smp_init_current_idle_task,data
 346         .import smp_callin,code
 347
 348 #ifndef CONFIG_64BIT
 349 smp_callin_rtn:
 350         .proc
 351         .callinfo
 352         break   1,1             /*  Break if returned from start_secondary */
 353         nop
 354         nop
 355         .procend
 356 #endif /*!CONFIG_64BIT*/
 357
 358 /***************************************************************************
 359 * smp_slave_stext is executed by all non-monarch Processors when the Monarch
 360 * pokes the slave CPUs in smp.c:smp_boot_cpus().
 361 *
 362 * Once here, registers values are initialized in order to branch to virtual
 363 * mode. Once all available/eligible CPUs are in virtual mode, all are
 364 * released and start out by executing their own idle task.
 365 *****************************************************************************/
 366 smp_slave_stext:
 367         .proc
 368         .callinfo
 369
 370         /*
 371         ** Initialize Space registers
 372         */
 373         mtsp       %r0,%sr4
 374         mtsp       %r0,%sr5
 375         mtsp       %r0,%sr6
 376         mtsp       %r0,%sr7
 377
 378 #ifdef CONFIG_64BIT
 379         /*
 380          *  Enable Wide mode early, in case the task_struct for the idle
 381          *  task in smp_init_current_idle_task was allocated above 4GB.
 382          */
 383 1:      mfia            %rp             /* clear upper part of pcoq */
 384         ldo             2f-1b(%rp),%rp
 385         depdi           0,31,32,%rp
 386         bv              (%rp)
 387         ssm             PSW_SM_W,%r0
 388 2:
 389 #endif
 390
 391         /*  Initialize the SP - monarch sets up smp_init_current_idle_task */
 392         load32          PA(smp_init_current_idle_task),%r6
 393         LDREG           0(%r6),%r6
 394         mtctl           %r6,%cr30
 395         tophys_r1       %r6
 396         LDREG           TASK_STACK(%r6),%sp
 397         tophys_r1       %sp
 398         ldo             FRAME_SIZE(%sp),%sp
 399
 400         /* point CPU to kernel page tables */
 401         load32          PA(swapper_pg_dir),%r4
 402         mtctl           %r4,%cr24       /* Initialize kernel root pointer */
 403         mtctl           %r4,%cr25       /* Initialize user root pointer */
 404
 405 #ifdef CONFIG_64BIT
 406         /* Setup PDCE_PROC entry */
 407         copy            %arg0,%r3
 408 #else
 409         /* Load RFI *return* address in case smp_callin bails */
 410         load32          smp_callin_rtn,%r2
 411 #endif
 412
 413         /* Load RFI target address.  */
 414         load32          smp_callin,%r11
 415
 416         /* ok...common code can handle the rest */
 417         b               common_stext
 418         nop
 419
 420         .procend
 421 #endif /* CONFIG_SMP */
 422
 423 #ifndef CONFIG_64BIT
 424         .section .data..ro_after_init
 425
 426         .align  4
 427         .export $global$,data
 428
 429         .type   $global$,@object
 430         .size   $global$,4
 431 $global$:
 432         .word 0
 433 #endif /*!CONFIG_64BIT*/