arch/openrisc/kernel/vmlinux.lds.S

   1 /*
   2  * OpenRISC vmlinux.lds.S
   3  *
   4  * Linux architectural port borrowing liberally from similar works of
   5  * others.  All original copyrights apply as per the original source
   6  * declaration.
   7  *
   8  * Modifications for the OpenRISC architecture:
   9  * Copyright (C) 2003 Matjaz Breskvar <phoenix@bsemi.com>
  10  * Copyright (C) 2010-2011 Jonas Bonn <jonas@southpole.se>
  11  *
  12  *      This program is free software; you can redistribute it and/or
  13  *      modify it under the terms of the GNU General Public License
  14  *      as published by the Free Software Foundation; either version
  15  *      2 of the License, or (at your option) any later version.
  16  *
  17  * ld script for OpenRISC architecture
  18  */
  19
  20 /* TODO
  21  *              - clean up __offset & stuff
  22  *              - change all 8192 alignment to PAGE !!!
  23  *              - recheck if all alignments are really needed
  24  */
  25
  26 #  define LOAD_OFFSET  PAGE_OFFSET
  27 #  define LOAD_BASE    PAGE_OFFSET
  28
  29 #include <asm/page.h>
  30 #include <asm/cache.h>
  31 #include <asm-generic/vmlinux.lds.h>
  32
  33 #ifdef __OR1K__
  34 #define __OUTPUT_FORMAT        "elf32-or1k"
  35 #else
  36 #define __OUTPUT_FORMAT        "elf32-or32"
  37 #endif
  38
  39 OUTPUT_FORMAT(__OUTPUT_FORMAT, __OUTPUT_FORMAT, __OUTPUT_FORMAT)
  40 jiffies = jiffies_64 + 4;
  41
  42 SECTIONS
  43 {
  44         /* Read-only sections, merged into text segment: */
  45         . = LOAD_BASE ;
  46
  47         _text = .;
  48
  49         /* _s_kernel_ro must be page aligned */
  50         . = ALIGN(PAGE_SIZE);
  51         _s_kernel_ro = .;
  52
  53         .text                   : AT(ADDR(.text) - LOAD_OFFSET)
  54         {
  55           _stext = .;
  56           TEXT_TEXT
  57           SCHED_TEXT
  58           CPUIDLE_TEXT
  59           LOCK_TEXT
  60           KPROBES_TEXT
  61           IRQENTRY_TEXT
  62           SOFTIRQENTRY_TEXT
  63           *(.fixup)
  64           *(.text.__*)
  65           _etext = .;
  66         }
  67         /* TODO: Check if fixup and text.__* are really necessary
  68          * fixup is definitely necessary
  69          */
  70
  71         _sdata = .;
  72
  73         /* Page alignment required for RO_DATA_SECTION */
  74         RO_DATA_SECTION(PAGE_SIZE)
  75         _e_kernel_ro = .;
  76
  77         /* Whatever comes after _e_kernel_ro had better be page-aligend, too */
  78
  79         /* 32 here is cacheline size... recheck this */
  80         RW_DATA_SECTION(32, PAGE_SIZE, PAGE_SIZE)
  81
  82         _edata  =  .;
  83
  84         EXCEPTION_TABLE(4)
  85         NOTES
  86
  87         /* Init code and data */
  88         . = ALIGN(PAGE_SIZE);
  89         __init_begin = .;
  90
  91         HEAD_TEXT_SECTION
  92
  93         /* Page aligned */
  94         INIT_TEXT_SECTION(PAGE_SIZE)
  95
  96         /* Align __setup_start on 16 byte boundary */
  97         INIT_DATA_SECTION(16)
  98
  99         PERCPU_SECTION(L1_CACHE_BYTES)
 100
 101         __init_end = .;
 102
 103         . = ALIGN(PAGE_SIZE);
 104         .initrd                 : AT(ADDR(.initrd) - LOAD_OFFSET)
 105         {
 106                 __initrd_start = .;
 107                 *(.initrd)
 108                 __initrd_end = .;
 109                 FILL (0);
 110                 . = ALIGN (PAGE_SIZE);
 111         }
 112
 113         __vmlinux_end = .;            /* last address of the physical file */
 114
 115         BSS_SECTION(0, 0, 0x20)
 116
 117         _end = .;
 118
 119         /* Throw in the debugging sections */
 120         STABS_DEBUG
 121         DWARF_DEBUG
 122
 123         /* Sections to be discarded -- must be last */
 124         DISCARDS
 125 }