arch/mips/kernel/cps-vec.S

   1 /*
   2  * Copyright (C) 2013 Imagination Technologies
   3  * Author: Paul Burton <paul.burton@imgtec.com>
   4  *
   5  * This program is free software; you can redistribute it and/or modify it
   6  * under the terms of the GNU General Public License as published by the
   7  * Free Software Foundation;  either version 2 of the  License, or (at your
   8  * option) any later version.
   9  */
  10
  11 #include <asm/addrspace.h>
  12 #include <asm/asm.h>
  13 #include <asm/asm-offsets.h>
  14 #include <asm/asmmacro.h>
  15 #include <asm/cacheops.h>
  16 #include <asm/eva.h>
  17 #include <asm/mipsregs.h>
  18 #include <asm/mipsmtregs.h>
  19 #include <asm/pm.h>
  20
  21 #define GCR_CL_COHERENCE_OFS    0x2008
  22 #define GCR_CL_ID_OFS           0x2028
  23
  24 .extern mips_cm_base
  25
  26 .set noreorder
  27
  28 #ifdef CONFIG_64BIT
  29 # define STATUS_BITDEPS         ST0_KX
  30 #else
  31 # define STATUS_BITDEPS         0
  32 #endif
  33
  34 #ifdef CONFIG_MIPS_CPS_NS16550
  35
  36 #define DUMP_EXCEP(name)                \
  37         PTR_LA  a0, 8f;                 \
  38         jal     mips_cps_bev_dump;      \
  39          nop;                           \
  40         TEXT(name)
  41
  42 #else /* !CONFIG_MIPS_CPS_NS16550 */
  43
  44 #define DUMP_EXCEP(name)
  45
  46 #endif /* !CONFIG_MIPS_CPS_NS16550 */
  47
  48         /*
  49          * Set dest to non-zero if the core supports the MT ASE, else zero. If
  50          * MT is not supported then branch to nomt.
  51          */
  52         .macro  has_mt  dest, nomt
  53         mfc0    \dest, CP0_CONFIG, 1
  54         bgez    \dest, \nomt
  55          mfc0   \dest, CP0_CONFIG, 2
  56         bgez    \dest, \nomt
  57          mfc0   \dest, CP0_CONFIG, 3
  58         andi    \dest, \dest, MIPS_CONF3_MT
  59         beqz    \dest, \nomt
  60          nop
  61         .endm
  62
  63 .section .text.cps-vec
  64 .balign 0x1000
  65
  66 LEAF(mips_cps_core_entry)
  67         /*
  68          * These first 4 bytes will be patched by cps_smp_setup to load the
  69          * CCA to use into register s0.
  70          */
  71         .word   0
  72
  73         /* Check whether we're here due to an NMI */
  74         mfc0    k0, CP0_STATUS
  75         and     k0, k0, ST0_NMI
  76         beqz    k0, not_nmi
  77          nop
  78
  79         /* This is an NMI */
  80         PTR_LA  k0, nmi_handler
  81         jr      k0
  82          nop
  83
  84 not_nmi:
  85         /* Setup Cause */
  86         li      t0, CAUSEF_IV
  87         mtc0    t0, CP0_CAUSE
  88
  89         /* Setup Status */
  90         li      t0, ST0_CU1 | ST0_CU0 | ST0_BEV | STATUS_BITDEPS
  91         mtc0    t0, CP0_STATUS
  92
  93         /*
  94          * Clear the bits used to index the caches. Note that the architecture
  95          * dictates that writing to any of TagLo or TagHi selects 0 or 2 should
  96          * be valid for all MIPS32 CPUs, even those for which said writes are
  97          * unnecessary.
  98          */
  99         mtc0    zero, CP0_TAGLO, 0
 100         mtc0    zero, CP0_TAGHI, 0
 101         mtc0    zero, CP0_TAGLO, 2
 102         mtc0    zero, CP0_TAGHI, 2
 103         ehb
 104
 105         /* Primary cache configuration is indicated by Config1 */
 106         mfc0    v0, CP0_CONFIG, 1
 107
 108         /* Detect I-cache line size */
 109         _EXT    t0, v0, MIPS_CONF1_IL_SHF, MIPS_CONF1_IL_SZ
 110         beqz    t0, icache_done
 111          li     t1, 2
 112         sllv    t0, t1, t0
 113
 114         /* Detect I-cache size */
 115         _EXT    t1, v0, MIPS_CONF1_IS_SHF, MIPS_CONF1_IS_SZ
 116         xori    t2, t1, 0x7
 117         beqz    t2, 1f
 118          li     t3, 32
 119         addiu   t1, t1, 1
 120         sllv    t1, t3, t1
 121 1:      /* At this point t1 == I-cache sets per way */
 122         _EXT    t2, v0, MIPS_CONF1_IA_SHF, MIPS_CONF1_IA_SZ
 123         addiu   t2, t2, 1
 124         mul     t1, t1, t0
 125         mul     t1, t1, t2
 126
 127         li      a0, CKSEG0
 128         PTR_ADD a1, a0, t1
 129 1:      cache   Index_Store_Tag_I, 0(a0)
 130         PTR_ADD a0, a0, t0
 131         bne     a0, a1, 1b
 132          nop
 133 icache_done:
 134
 135         /* Detect D-cache line size */
 136         _EXT    t0, v0, MIPS_CONF1_DL_SHF, MIPS_CONF1_DL_SZ
 137         beqz    t0, dcache_done
 138          li     t1, 2
 139         sllv    t0, t1, t0
 140
 141         /* Detect D-cache size */
 142         _EXT    t1, v0, MIPS_CONF1_DS_SHF, MIPS_CONF1_DS_SZ
 143         xori    t2, t1, 0x7
 144         beqz    t2, 1f
 145          li     t3, 32
 146         addiu   t1, t1, 1
 147         sllv    t1, t3, t1
 148 1:      /* At this point t1 == D-cache sets per way */
 149         _EXT    t2, v0, MIPS_CONF1_DA_SHF, MIPS_CONF1_DA_SZ
 150         addiu   t2, t2, 1
 151         mul     t1, t1, t0
 152         mul     t1, t1, t2
 153
 154         li      a0, CKSEG0
 155         PTR_ADDU a1, a0, t1
 156         PTR_SUBU a1, a1, t0
 157 1:      cache   Index_Store_Tag_D, 0(a0)
 158         bne     a0, a1, 1b
 159          PTR_ADD a0, a0, t0
 160 dcache_done:
 161
 162         /* Set Kseg0 CCA to that in s0 */
 163         mfc0    t0, CP0_CONFIG
 164         ori     t0, 0x7
 165         xori    t0, 0x7
 166         or      t0, t0, s0
 167         mtc0    t0, CP0_CONFIG
 168         ehb
 169
 170         /* Calculate an uncached address for the CM GCRs */
 171         MFC0    v1, CP0_CMGCRBASE
 172         PTR_SLL v1, v1, 4
 173         PTR_LI  t0, UNCAC_BASE
 174         PTR_ADDU v1, v1, t0
 175
 176         /* Enter the coherent domain */
 177         li      t0, 0xff
 178         sw      t0, GCR_CL_COHERENCE_OFS(v1)
 179         ehb
 180
 181         /* Jump to kseg0 */
 182         PTR_LA  t0, 1f
 183         jr      t0
 184          nop
 185
 186         /*
 187          * We're up, cached & coherent. Perform any further required core-level
 188          * initialisation.
 189          */
 190 1:      jal     mips_cps_core_init
 191          nop
 192
 193         /* Do any EVA initialization if necessary */
 194         eva_init
 195
 196         /*
 197          * Boot any other VPEs within this core that should be online, and
 198          * deactivate this VPE if it should be offline.
 199          */
 200         jal     mips_cps_boot_vpes
 201          nop
 202
 203         /* Off we go! */
 204         PTR_L   t1, VPEBOOTCFG_PC(v0)
 205         PTR_L   gp, VPEBOOTCFG_GP(v0)
 206         PTR_L   sp, VPEBOOTCFG_SP(v0)
 207         jr      t1
 208          nop
 209         END(mips_cps_core_entry)
 210
 211 .org 0x200
 212 LEAF(excep_tlbfill)
 213         DUMP_EXCEP("TLB Fill")
 214         b       .
 215          nop
 216         END(excep_tlbfill)
 217
 218 .org 0x280
 219 LEAF(excep_xtlbfill)
 220         DUMP_EXCEP("XTLB Fill")
 221         b       .
 222          nop
 223         END(excep_xtlbfill)
 224
 225 .org 0x300
 226 LEAF(excep_cache)
 227         DUMP_EXCEP("Cache")
 228         b       .
 229          nop
 230         END(excep_cache)
 231
 232 .org 0x380
 233 LEAF(excep_genex)
 234         DUMP_EXCEP("General")
 235         b       .
 236          nop
 237         END(excep_genex)
 238
 239 .org 0x400
 240 LEAF(excep_intex)
 241         DUMP_EXCEP("Interrupt")
 242         b       .
 243          nop
 244         END(excep_intex)
 245
 246 .org 0x480
 247 LEAF(excep_ejtag)
 248         PTR_LA  k0, ejtag_debug_handler
 249         jr      k0
 250          nop
 251         END(excep_ejtag)
 252
 253 LEAF(mips_cps_core_init)
 254 #ifdef CONFIG_MIPS_MT_SMP
 255         /* Check that the core implements the MT ASE */
 256         has_mt  t0, 3f
 257
 258         .set    push
 259         .set    mt
 260
 261         /* Only allow 1 TC per VPE to execute... */
 262         dmt
 263
 264         /* ...and for the moment only 1 VPE */
 265         dvpe
 266         PTR_LA  t1, 1f
 267         jr.hb   t1
 268          nop
 269
 270         /* Enter VPE configuration state */
 271 1:      mfc0    t0, CP0_MVPCONTROL
 272         ori     t0, t0, MVPCONTROL_VPC
 273         mtc0    t0, CP0_MVPCONTROL
 274
 275         /* Retrieve the number of VPEs within the core */
 276         mfc0    t0, CP0_MVPCONF0
 277         srl     t0, t0, MVPCONF0_PVPE_SHIFT
 278         andi    t0, t0, (MVPCONF0_PVPE >> MVPCONF0_PVPE_SHIFT)
 279         addiu   ta3, t0, 1
 280
 281         /* If there's only 1, we're done */
 282         beqz    t0, 2f
 283          nop
 284
 285         /* Loop through each VPE within this core */
 286         li      ta1, 1
 287
 288 1:      /* Operate on the appropriate TC */
 289         mtc0    ta1, CP0_VPECONTROL
 290         ehb
 291
 292         /* Bind TC to VPE (1:1 TC:VPE mapping) */
 293         mttc0   ta1, CP0_TCBIND
 294
 295         /* Set exclusive TC, non-active, master */
 296         li      t0, VPECONF0_MVP
 297         sll     t1, ta1, VPECONF0_XTC_SHIFT
 298         or      t0, t0, t1
 299         mttc0   t0, CP0_VPECONF0
 300
 301         /* Set TC non-active, non-allocatable */
 302         mttc0   zero, CP0_TCSTATUS
 303
 304         /* Set TC halted */
 305         li      t0, TCHALT_H
 306         mttc0   t0, CP0_TCHALT
 307
 308         /* Next VPE */
 309         addiu   ta1, ta1, 1
 310         slt     t0, ta1, ta3
 311         bnez    t0, 1b
 312          nop
 313
 314         /* Leave VPE configuration state */
 315 2:      mfc0    t0, CP0_MVPCONTROL
 316         xori    t0, t0, MVPCONTROL_VPC
 317         mtc0    t0, CP0_MVPCONTROL
 318
 319 3:      .set    pop
 320 #endif
 321         jr      ra
 322          nop
 323         END(mips_cps_core_init)
 324
 325 LEAF(mips_cps_boot_vpes)
 326         /* Retrieve CM base address */
 327         PTR_LA  t0, mips_cm_base
 328         PTR_L   t0, 0(t0)
 329
 330         /* Calculate a pointer to this cores struct core_boot_config */
 331         lw      t0, GCR_CL_ID_OFS(t0)
 332         li      t1, COREBOOTCFG_SIZE
 333         mul     t0, t0, t1
 334         PTR_LA  t1, mips_cps_core_bootcfg
 335         PTR_L   t1, 0(t1)
 336         PTR_ADDU t0, t0, t1
 337
 338         /* Calculate this VPEs ID. If the core doesn't support MT use 0 */
 339         li      t9, 0
 340 #ifdef CONFIG_MIPS_MT_SMP
 341         has_mt  ta2, 1f
 342
 343         /* Find the number of VPEs present in the core */
 344         mfc0    t1, CP0_MVPCONF0
 345         srl     t1, t1, MVPCONF0_PVPE_SHIFT
 346         andi    t1, t1, MVPCONF0_PVPE >> MVPCONF0_PVPE_SHIFT
 347         addiu   t1, t1, 1
 348
 349         /* Calculate a mask for the VPE ID from EBase.CPUNum */
 350         clz     t1, t1
 351         li      t2, 31
 352         subu    t1, t2, t1
 353         li      t2, 1
 354         sll     t1, t2, t1
 355         addiu   t1, t1, -1
 356
 357         /* Retrieve the VPE ID from EBase.CPUNum */
 358         mfc0    t9, $15, 1
 359         and     t9, t9, t1
 360 #endif
 361
 362 1:      /* Calculate a pointer to this VPEs struct vpe_boot_config */
 363         li      t1, VPEBOOTCFG_SIZE
 364         mul     v0, t9, t1
 365         PTR_L   ta3, COREBOOTCFG_VPECONFIG(t0)
 366         PTR_ADDU v0, v0, ta3
 367
 368 #ifdef CONFIG_MIPS_MT_SMP
 369
 370         /* If the core doesn't support MT then return */
 371         bnez    ta2, 1f
 372          nop
 373         jr      ra
 374          nop
 375
 376         .set    push
 377         .set    mt
 378
 379 1:      /* Enter VPE configuration state */
 380         dvpe
 381         PTR_LA  t1, 1f
 382         jr.hb   t1
 383          nop
 384 1:      mfc0    t1, CP0_MVPCONTROL
 385         ori     t1, t1, MVPCONTROL_VPC
 386         mtc0    t1, CP0_MVPCONTROL
 387         ehb
 388
 389         /* Loop through each VPE */
 390         PTR_L   ta2, COREBOOTCFG_VPEMASK(t0)
 391         move    t8, ta2
 392         li      ta1, 0
 393
 394         /* Check whether the VPE should be running. If not, skip it */
 395 1:      andi    t0, ta2, 1
 396         beqz    t0, 2f
 397          nop
 398
 399         /* Operate on the appropriate TC */
 400         mfc0    t0, CP0_VPECONTROL
 401         ori     t0, t0, VPECONTROL_TARGTC
 402         xori    t0, t0, VPECONTROL_TARGTC
 403         or      t0, t0, ta1
 404         mtc0    t0, CP0_VPECONTROL
 405         ehb
 406
 407         /* Skip the VPE if its TC is not halted */
 408         mftc0   t0, CP0_TCHALT
 409         beqz    t0, 2f
 410          nop
 411
 412         /* Calculate a pointer to the VPEs struct vpe_boot_config */
 413         li      t0, VPEBOOTCFG_SIZE
 414         mul     t0, t0, ta1
 415         addu    t0, t0, ta3
 416
 417         /* Set the TC restart PC */
 418         lw      t1, VPEBOOTCFG_PC(t0)
 419         mttc0   t1, CP0_TCRESTART
 420
 421         /* Set the TC stack pointer */
 422         lw      t1, VPEBOOTCFG_SP(t0)
 423         mttgpr  t1, sp
 424
 425         /* Set the TC global pointer */
 426         lw      t1, VPEBOOTCFG_GP(t0)
 427         mttgpr  t1, gp
 428
 429         /* Copy config from this VPE */
 430         mfc0    t0, CP0_CONFIG
 431         mttc0   t0, CP0_CONFIG
 432
 433         /* Ensure no software interrupts are pending */
 434         mttc0   zero, CP0_CAUSE
 435         mttc0   zero, CP0_STATUS
 436
 437         /* Set TC active, not interrupt exempt */
 438         mftc0   t0, CP0_TCSTATUS
 439         li      t1, ~TCSTATUS_IXMT
 440         and     t0, t0, t1
 441         ori     t0, t0, TCSTATUS_A
 442         mttc0   t0, CP0_TCSTATUS
 443
 444         /* Clear the TC halt bit */
 445         mttc0   zero, CP0_TCHALT
 446
 447         /* Set VPE active */
 448         mftc0   t0, CP0_VPECONF0
 449         ori     t0, t0, VPECONF0_VPA
 450         mttc0   t0, CP0_VPECONF0
 451
 452         /* Next VPE */
 453 2:      srl     ta2, ta2, 1
 454         addiu   ta1, ta1, 1
 455         bnez    ta2, 1b
 456          nop
 457
 458         /* Leave VPE configuration state */
 459         mfc0    t1, CP0_MVPCONTROL
 460         xori    t1, t1, MVPCONTROL_VPC
 461         mtc0    t1, CP0_MVPCONTROL
 462         ehb
 463         evpe
 464
 465         /* Check whether this VPE is meant to be running */
 466         li      t0, 1
 467         sll     t0, t0, t9
 468         and     t0, t0, t8
 469         bnez    t0, 2f
 470          nop
 471
 472         /* This VPE should be offline, halt the TC */
 473         li      t0, TCHALT_H
 474         mtc0    t0, CP0_TCHALT
 475         PTR_LA  t0, 1f
 476 1:      jr.hb   t0
 477          nop
 478
 479 2:      .set    pop
 480
 481 #endif /* CONFIG_MIPS_MT_SMP */
 482
 483         /* Return */
 484         jr      ra
 485          nop
 486         END(mips_cps_boot_vpes)
 487
 488 #if defined(CONFIG_MIPS_CPS_PM) && defined(CONFIG_CPU_PM)
 489
 490         /* Calculate a pointer to this CPUs struct mips_static_suspend_state */
 491         .macro  psstate dest
 492         .set    push
 493         .set    noat
 494         lw      $1, TI_CPU(gp)
 495         sll     $1, $1, LONGLOG
 496         PTR_LA  \dest, __per_cpu_offset
 497         addu    $1, $1, \dest
 498         lw      $1, 0($1)
 499         PTR_LA  \dest, cps_cpu_state
 500         addu    \dest, \dest, $1
 501         .set    pop
 502         .endm
 503
 504 LEAF(mips_cps_pm_save)
 505         /* Save CPU state */
 506         SUSPEND_SAVE_REGS
 507         psstate t1
 508         SUSPEND_SAVE_STATIC
 509         jr      v0
 510          nop
 511         END(mips_cps_pm_save)
 512
 513 LEAF(mips_cps_pm_restore)
 514         /* Restore CPU state */
 515         psstate t1
 516         RESUME_RESTORE_STATIC
 517         RESUME_RESTORE_REGS_RETURN
 518         END(mips_cps_pm_restore)
 519
 520 #endif /* CONFIG_MIPS_CPS_PM && CONFIG_CPU_PM */