arch/arm64/mm/proc.S

   1 /*
   2  * Based on arch/arm/mm/proc.S
   3  *
   4  * Copyright (C) 2001 Deep Blue Solutions Ltd.
   5  * Copyright (C) 2012 ARM Ltd.
   6  * Author: Catalin Marinas <catalin.marinas@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23 #include <asm/assembler.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/hwcap.h>
  26 #include <asm/pgtable.h>
  27 #include <asm/pgtable-hwdef.h>
  28 #include <asm/cpufeature.h>
  29 #include <asm/alternative.h>
  30
  31 #ifdef CONFIG_ARM64_64K_PAGES
  32 #define TCR_TG_FLAGS    TCR_TG0_64K | TCR_TG1_64K
  33 #elif defined(CONFIG_ARM64_16K_PAGES)
  34 #define TCR_TG_FLAGS    TCR_TG0_16K | TCR_TG1_16K
  35 #else /* CONFIG_ARM64_4K_PAGES */
  36 #define TCR_TG_FLAGS    TCR_TG0_4K | TCR_TG1_4K
  37 #endif
  38
  39 #ifdef CONFIG_RANDOMIZE_BASE
  40 #define TCR_KASLR_FLAGS TCR_NFD1
  41 #else
  42 #define TCR_KASLR_FLAGS 0
  43 #endif
  44
  45 #define TCR_SMP_FLAGS   TCR_SHARED
  46
  47 /* PTWs cacheable, inner/outer WBWA */
  48 #define TCR_CACHE_FLAGS TCR_IRGN_WBWA | TCR_ORGN_WBWA
  49
  50 #define MAIR(attr, mt)  ((attr) << ((mt) * 8))
  51
  52 /*
  53  *      cpu_do_idle()
  54  *
  55  *      Idle the processor (wait for interrupt).
  56  */
  57 ENTRY(cpu_do_idle)
  58         dsb     sy                              // WFI may enter a low-power mode
  59         wfi
  60         ret
  61 ENDPROC(cpu_do_idle)
  62
  63 #ifdef CONFIG_CPU_PM
  64 /**
  65  * cpu_do_suspend - save CPU registers context
  66  *
  67  * x0: virtual address of context pointer
  68  */
  69 ENTRY(cpu_do_suspend)
  70         mrs     x2, tpidr_el0
  71         mrs     x3, tpidrro_el0
  72         mrs     x4, contextidr_el1
  73         mrs     x5, osdlr_el1
  74         mrs     x6, cpacr_el1
  75         mrs     x7, tcr_el1
  76         mrs     x8, vbar_el1
  77         mrs     x9, mdscr_el1
  78         mrs     x10, oslsr_el1
  79         mrs     x11, sctlr_el1
  80 alternative_if_not ARM64_HAS_VIRT_HOST_EXTN
  81         mrs     x12, tpidr_el1
  82 alternative_else
  83         mrs     x12, tpidr_el2
  84 alternative_endif
  85         mrs     x13, sp_el0
  86         stp     x2, x3, [x0]
  87         stp     x4, x5, [x0, #16]
  88         stp     x6, x7, [x0, #32]
  89         stp     x8, x9, [x0, #48]
  90         stp     x10, x11, [x0, #64]
  91         stp     x12, x13, [x0, #80]
  92         ret
  93 ENDPROC(cpu_do_suspend)
  94
  95 /**
  96  * cpu_do_resume - restore CPU register context
  97  *
  98  * x0: Address of context pointer
  99  */
 100         .pushsection ".idmap.text", "awx"
 101 ENTRY(cpu_do_resume)
 102         ldp     x2, x3, [x0]
 103         ldp     x4, x5, [x0, #16]
 104         ldp     x6, x8, [x0, #32]
 105         ldp     x9, x10, [x0, #48]
 106         ldp     x11, x12, [x0, #64]
 107         ldp     x13, x14, [x0, #80]
 108         msr     tpidr_el0, x2
 109         msr     tpidrro_el0, x3
 110         msr     contextidr_el1, x4
 111         msr     cpacr_el1, x6
 112
 113         /* Don't change t0sz here, mask those bits when restoring */
 114         mrs     x7, tcr_el1
 115         bfi     x8, x7, TCR_T0SZ_OFFSET, TCR_TxSZ_WIDTH
 116
 117         msr     tcr_el1, x8
 118         msr     vbar_el1, x9
 119
 120         /*
 121          * __cpu_setup() cleared MDSCR_EL1.MDE and friends, before unmasking
 122          * debug exceptions. By restoring MDSCR_EL1 here, we may take a debug
 123          * exception. Mask them until local_daif_restore() in cpu_suspend()
 124          * resets them.
 125          */
 126         disable_daif
 127         msr     mdscr_el1, x10
 128
 129         msr     sctlr_el1, x12
 130 alternative_if_not ARM64_HAS_VIRT_HOST_EXTN
 131         msr     tpidr_el1, x13
 132 alternative_else
 133         msr     tpidr_el2, x13
 134 alternative_endif
 135         msr     sp_el0, x14
 136         /*
 137          * Restore oslsr_el1 by writing oslar_el1
 138          */
 139         msr     osdlr_el1, x5
 140         ubfx    x11, x11, #1, #1
 141         msr     oslar_el1, x11
 142         reset_pmuserenr_el0 x0                  // Disable PMU access from EL0
 143
 144 alternative_if ARM64_HAS_RAS_EXTN
 145         msr_s   SYS_DISR_EL1, xzr
 146 alternative_else_nop_endif
 147
 148         isb
 149         ret
 150 ENDPROC(cpu_do_resume)
 151         .popsection
 152 #endif
 153
 154 /*
 155  *      cpu_do_switch_mm(pgd_phys, tsk)
 156  *
 157  *      Set the translation table base pointer to be pgd_phys.
 158  *
 159  *      - pgd_phys - physical address of new TTB
 160  */
 161 ENTRY(cpu_do_switch_mm)
 162         mrs     x2, ttbr1_el1
 163         mmid    x1, x1                          // get mm->context.id
 164         phys_to_ttbr x3, x0
 165 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 166         bfi     x3, x1, #48, #16                // set the ASID field in TTBR0
 167 #endif
 168         bfi     x2, x1, #48, #16                // set the ASID
 169         msr     ttbr1_el1, x2                   // in TTBR1 (since TCR.A1 is set)
 170         isb
 171         msr     ttbr0_el1, x3                   // now update TTBR0
 172         isb
 173         b       post_ttbr_update_workaround     // Back to C code...
 174 ENDPROC(cpu_do_switch_mm)
 175
 176         .pushsection ".idmap.text", "awx"
 177
 178 .macro  __idmap_cpu_set_reserved_ttbr1, tmp1, tmp2
 179         adrp    \tmp1, empty_zero_page
 180         phys_to_ttbr \tmp2, \tmp1
 181         msr     ttbr1_el1, \tmp2
 182         isb
 183         tlbi    vmalle1
 184         dsb     nsh
 185         isb
 186 .endm
 187
 188 /*
 189  * void idmap_cpu_replace_ttbr1(phys_addr_t new_pgd)
 190  *
 191  * This is the low-level counterpart to cpu_replace_ttbr1, and should not be
 192  * called by anything else. It can only be executed from a TTBR0 mapping.
 193  */
 194 ENTRY(idmap_cpu_replace_ttbr1)
 195         save_and_disable_daif flags=x2
 196
 197         __idmap_cpu_set_reserved_ttbr1 x1, x3
 198
 199         phys_to_ttbr x3, x0
 200         msr     ttbr1_el1, x3
 201         isb
 202
 203         restore_daif x2
 204
 205         ret
 206 ENDPROC(idmap_cpu_replace_ttbr1)
 207         .popsection
 208
 209 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 210         .pushsection ".idmap.text", "awx"
 211
 212         .macro  __idmap_kpti_get_pgtable_ent, type
 213         dc      cvac, cur_\()\type\()p          // Ensure any existing dirty
 214         dmb     sy                              // lines are written back before
 215         ldr     \type, [cur_\()\type\()p]       // loading the entry
 216         tbz     \type, #0, skip_\()\type        // Skip invalid and
 217         tbnz    \type, #11, skip_\()\type       // non-global entries
 218         .endm
 219
 220         .macro __idmap_kpti_put_pgtable_ent_ng, type
 221         orr     \type, \type, #PTE_NG           // Same bit for blocks and pages
 222         str     \type, [cur_\()\type\()p]       // Update the entry and ensure
 223         dmb     sy                              // that it is visible to all
 224         dc      civac, cur_\()\type\()p         // CPUs.
 225         .endm
 226
 227 /*
 228  * void __kpti_install_ng_mappings(int cpu, int num_cpus, phys_addr_t swapper)
 229  *
 230  * Called exactly once from stop_machine context by each CPU found during boot.
 231  */
 232 __idmap_kpti_flag:
 233         .long   1
 234 ENTRY(idmap_kpti_install_ng_mappings)
 235         cpu             .req    w0
 236         num_cpus        .req    w1
 237         swapper_pa      .req    x2
 238         swapper_ttb     .req    x3
 239         flag_ptr        .req    x4
 240         cur_pgdp        .req    x5
 241         end_pgdp        .req    x6
 242         pgd             .req    x7
 243         cur_pudp        .req    x8
 244         end_pudp        .req    x9
 245         pud             .req    x10
 246         cur_pmdp        .req    x11
 247         end_pmdp        .req    x12
 248         pmd             .req    x13
 249         cur_ptep        .req    x14
 250         end_ptep        .req    x15
 251         pte             .req    x16
 252
 253         mrs     swapper_ttb, ttbr1_el1
 254         adr     flag_ptr, __idmap_kpti_flag
 255
 256         cbnz    cpu, __idmap_kpti_secondary
 257
 258         /* We're the boot CPU. Wait for the others to catch up */
 259         sevl
 260 1:      wfe
 261         ldaxr   w18, [flag_ptr]
 262         eor     w18, w18, num_cpus
 263         cbnz    w18, 1b
 264
 265         /* We need to walk swapper, so turn off the MMU. */
 266         pre_disable_mmu_workaround
 267         mrs     x18, sctlr_el1
 268         bic     x18, x18, #SCTLR_ELx_M
 269         msr     sctlr_el1, x18
 270         isb
 271
 272         /* Everybody is enjoying the idmap, so we can rewrite swapper. */
 273         /* PGD */
 274         mov     cur_pgdp, swapper_pa
 275         add     end_pgdp, cur_pgdp, #(PTRS_PER_PGD * 8)
 276 do_pgd: __idmap_kpti_get_pgtable_ent    pgd
 277         tbnz    pgd, #1, walk_puds
 278 next_pgd:
 279         __idmap_kpti_put_pgtable_ent_ng pgd
 280 skip_pgd:
 281         add     cur_pgdp, cur_pgdp, #8
 282         cmp     cur_pgdp, end_pgdp
 283         b.ne    do_pgd
 284
 285         /* Publish the updated tables and nuke all the TLBs */
 286         dsb     sy
 287         tlbi    vmalle1is
 288         dsb     ish
 289         isb
 290
 291         /* We're done: fire up the MMU again */
 292         mrs     x18, sctlr_el1
 293         orr     x18, x18, #SCTLR_ELx_M
 294         msr     sctlr_el1, x18
 295         isb
 296
 297         /*
 298          * Invalidate the local I-cache so that any instructions fetched
 299          * speculatively from the PoC are discarded, since they may have
 300          * been dynamically patched at the PoU.
 301          */
 302         ic      iallu
 303         dsb     nsh
 304         isb
 305
 306         /* Set the flag to zero to indicate that we're all done */
 307         str     wzr, [flag_ptr]
 308         ret
 309
 310         /* PUD */
 311 walk_puds:
 312         .if CONFIG_PGTABLE_LEVELS > 3
 313         pte_to_phys     cur_pudp, pgd
 314         add     end_pudp, cur_pudp, #(PTRS_PER_PUD * 8)
 315 do_pud: __idmap_kpti_get_pgtable_ent    pud
 316         tbnz    pud, #1, walk_pmds
 317 next_pud:
 318         __idmap_kpti_put_pgtable_ent_ng pud
 319 skip_pud:
 320         add     cur_pudp, cur_pudp, 8
 321         cmp     cur_pudp, end_pudp
 322         b.ne    do_pud
 323         b       next_pgd
 324         .else /* CONFIG_PGTABLE_LEVELS <= 3 */
 325         mov     pud, pgd
 326         b       walk_pmds
 327 next_pud:
 328         b       next_pgd
 329         .endif
 330
 331         /* PMD */
 332 walk_pmds:
 333         .if CONFIG_PGTABLE_LEVELS > 2
 334         pte_to_phys     cur_pmdp, pud
 335         add     end_pmdp, cur_pmdp, #(PTRS_PER_PMD * 8)
 336 do_pmd: __idmap_kpti_get_pgtable_ent    pmd
 337         tbnz    pmd, #1, walk_ptes
 338 next_pmd:
 339         __idmap_kpti_put_pgtable_ent_ng pmd
 340 skip_pmd:
 341         add     cur_pmdp, cur_pmdp, #8
 342         cmp     cur_pmdp, end_pmdp
 343         b.ne    do_pmd
 344         b       next_pud
 345         .else /* CONFIG_PGTABLE_LEVELS <= 2 */
 346         mov     pmd, pud
 347         b       walk_ptes
 348 next_pmd:
 349         b       next_pud
 350         .endif
 351
 352         /* PTE */
 353 walk_ptes:
 354         pte_to_phys     cur_ptep, pmd
 355         add     end_ptep, cur_ptep, #(PTRS_PER_PTE * 8)
 356 do_pte: __idmap_kpti_get_pgtable_ent    pte
 357         __idmap_kpti_put_pgtable_ent_ng pte
 358 skip_pte:
 359         add     cur_ptep, cur_ptep, #8
 360         cmp     cur_ptep, end_ptep
 361         b.ne    do_pte
 362         b       next_pmd
 363
 364         /* Secondary CPUs end up here */
 365 __idmap_kpti_secondary:
 366         /* Uninstall swapper before surgery begins */
 367         __idmap_cpu_set_reserved_ttbr1 x18, x17
 368
 369         /* Increment the flag to let the boot CPU we're ready */
 370 1:      ldxr    w18, [flag_ptr]
 371         add     w18, w18, #1
 372         stxr    w17, w18, [flag_ptr]
 373         cbnz    w17, 1b
 374
 375         /* Wait for the boot CPU to finish messing around with swapper */
 376         sevl
 377 1:      wfe
 378         ldxr    w18, [flag_ptr]
 379         cbnz    w18, 1b
 380
 381         /* All done, act like nothing happened */
 382         msr     ttbr1_el1, swapper_ttb
 383         isb
 384         ret
 385
 386         .unreq  cpu
 387         .unreq  num_cpus
 388         .unreq  swapper_pa
 389         .unreq  swapper_ttb
 390         .unreq  flag_ptr
 391         .unreq  cur_pgdp
 392         .unreq  end_pgdp
 393         .unreq  pgd
 394         .unreq  cur_pudp
 395         .unreq  end_pudp
 396         .unreq  pud
 397         .unreq  cur_pmdp
 398         .unreq  end_pmdp
 399         .unreq  pmd
 400         .unreq  cur_ptep
 401         .unreq  end_ptep
 402         .unreq  pte
 403 ENDPROC(idmap_kpti_install_ng_mappings)
 404         .popsection
 405 #endif
 406
 407 /*
 408  *      __cpu_setup
 409  *
 410  *      Initialise the processor for turning the MMU on.  Return in x0 the
 411  *      value of the SCTLR_EL1 register.
 412  */
 413         .pushsection ".idmap.text", "awx"
 414 ENTRY(__cpu_setup)
 415         tlbi    vmalle1                         // Invalidate local TLB
 416         dsb     nsh
 417
 418         mov     x0, #3 << 20
 419         msr     cpacr_el1, x0                   // Enable FP/ASIMD
 420         mov     x0, #1 << 12                    // Reset mdscr_el1 and disable
 421         msr     mdscr_el1, x0                   // access to the DCC from EL0
 422         isb                                     // Unmask debug exceptions now,
 423         enable_dbg                              // since this is per-cpu
 424         reset_pmuserenr_el0 x0                  // Disable PMU access from EL0
 425         /*
 426          * Memory region attributes for LPAE:
 427          *
 428          *   n = AttrIndx[2:0]
 429          *                      n       MAIR
 430          *   DEVICE_nGnRnE      000     00000000
 431          *   DEVICE_nGnRE       001     00000100
 432          *   DEVICE_GRE         010     00001100
 433          *   NORMAL_NC          011     01000100
 434          *   NORMAL             100     11111111
 435          *   NORMAL_WT          101     10111011
 436          */
 437         ldr     x5, =MAIR(0x00, MT_DEVICE_nGnRnE) | \
 438                      MAIR(0x04, MT_DEVICE_nGnRE) | \
 439                      MAIR(0x0c, MT_DEVICE_GRE) | \
 440                      MAIR(0x44, MT_NORMAL_NC) | \
 441                      MAIR(0xff, MT_NORMAL) | \
 442                      MAIR(0xbb, MT_NORMAL_WT)
 443         msr     mair_el1, x5
 444         /*
 445          * Prepare SCTLR
 446          */
 447         mov_q   x0, SCTLR_EL1_SET
 448         /*
 449          * Set/prepare TCR and TTBR. We use 512GB (39-bit) address range for
 450          * both user and kernel.
 451          */
 452         ldr     x10, =TCR_TxSZ(VA_BITS) | TCR_CACHE_FLAGS | TCR_SMP_FLAGS | \
 453                         TCR_TG_FLAGS | TCR_KASLR_FLAGS | TCR_ASID16 | \
 454                         TCR_TBI0 | TCR_A1
 455         tcr_set_idmap_t0sz      x10, x9
 456
 457         /*
 458          * Set the IPS bits in TCR_EL1.
 459          */
 460         tcr_compute_pa_size x10, #TCR_IPS_SHIFT, x5, x6
 461 #ifdef CONFIG_ARM64_HW_AFDBM
 462         /*
 463          * Enable hardware update of the Access Flags bit.
 464          * Hardware dirty bit management is enabled later,
 465          * via capabilities.
 466          */
 467         mrs     x9, ID_AA64MMFR1_EL1
 468         and     x9, x9, #0xf
 469         cbz     x9, 1f
 470         orr     x10, x10, #TCR_HA               // hardware Access flag update
 471 1:
 472 #endif  /* CONFIG_ARM64_HW_AFDBM */
 473         msr     tcr_el1, x10
 474         ret                                     // return to head.S
 475 ENDPROC(__cpu_setup)