arch/arm64/mm/proc.S

   1 /*
   2  * Based on arch/arm/mm/proc.S
   3  *
   4  * Copyright (C) 2001 Deep Blue Solutions Ltd.
   5  * Copyright (C) 2012 ARM Ltd.
   6  * Author: Catalin Marinas <catalin.marinas@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23 #include <asm/assembler.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/hwcap.h>
  26 #include <asm/pgtable.h>
  27 #include <asm/pgtable-hwdef.h>
  28 #include <asm/cpufeature.h>
  29 #include <asm/alternative.h>
  30
  31 #ifdef CONFIG_ARM64_64K_PAGES
  32 #define TCR_TG_FLAGS    TCR_TG0_64K | TCR_TG1_64K
  33 #elif defined(CONFIG_ARM64_16K_PAGES)
  34 #define TCR_TG_FLAGS    TCR_TG0_16K | TCR_TG1_16K
  35 #else /* CONFIG_ARM64_4K_PAGES */
  36 #define TCR_TG_FLAGS    TCR_TG0_4K | TCR_TG1_4K
  37 #endif
  38
  39 #define TCR_SMP_FLAGS   TCR_SHARED
  40
  41 /* PTWs cacheable, inner/outer WBWA */
  42 #define TCR_CACHE_FLAGS TCR_IRGN_WBWA | TCR_ORGN_WBWA
  43
  44 #define MAIR(attr, mt)  ((attr) << ((mt) * 8))
  45
  46 /*
  47  *      cpu_do_idle()
  48  *
  49  *      Idle the processor (wait for interrupt).
  50  */
  51 ENTRY(cpu_do_idle)
  52         dsb     sy                              // WFI may enter a low-power mode
  53         wfi
  54         ret
  55 ENDPROC(cpu_do_idle)
  56
  57 #ifdef CONFIG_CPU_PM
  58 /**
  59  * cpu_do_suspend - save CPU registers context
  60  *
  61  * x0: virtual address of context pointer
  62  */
  63 ENTRY(cpu_do_suspend)
  64         mrs     x2, tpidr_el0
  65         mrs     x3, tpidrro_el0
  66         mrs     x4, contextidr_el1
  67         mrs     x5, osdlr_el1
  68         mrs     x6, cpacr_el1
  69         mrs     x7, tcr_el1
  70         mrs     x8, vbar_el1
  71         mrs     x9, mdscr_el1
  72         mrs     x10, oslsr_el1
  73         mrs     x11, sctlr_el1
  74         stp     x2, x3, [x0]
  75         stp     x4, x5, [x0, #16]
  76         stp     x6, x7, [x0, #32]
  77         stp     x8, x9, [x0, #48]
  78         stp     x10, x11, [x0, #64]
  79         ret
  80 ENDPROC(cpu_do_suspend)
  81
  82 /**
  83  * cpu_do_resume - restore CPU register context
  84  *
  85  * x0: Address of context pointer
  86  */
  87         .pushsection ".idmap.text", "awx"
  88 ENTRY(cpu_do_resume)
  89         ldp     x2, x3, [x0]
  90         ldp     x4, x5, [x0, #16]
  91         ldp     x6, x8, [x0, #32]
  92         ldp     x9, x10, [x0, #48]
  93         ldp     x11, x12, [x0, #64]
  94         msr     tpidr_el0, x2
  95         msr     tpidrro_el0, x3
  96         msr     contextidr_el1, x4
  97         msr     cpacr_el1, x6
  98
  99         /* Don't change t0sz here, mask those bits when restoring */
 100         mrs     x7, tcr_el1
 101         bfi     x8, x7, TCR_T0SZ_OFFSET, TCR_TxSZ_WIDTH
 102
 103         msr     tcr_el1, x8
 104         msr     vbar_el1, x9
 105
 106         /*
 107          * __cpu_setup() cleared MDSCR_EL1.MDE and friends, before unmasking
 108          * debug exceptions. By restoring MDSCR_EL1 here, we may take a debug
 109          * exception. Mask them until local_dbg_restore() in cpu_suspend()
 110          * resets them.
 111          */
 112         disable_dbg
 113         msr     mdscr_el1, x10
 114
 115         msr     sctlr_el1, x12
 116         /*
 117          * Restore oslsr_el1 by writing oslar_el1
 118          */
 119         msr     osdlr_el1, x5
 120         ubfx    x11, x11, #1, #1
 121         msr     oslar_el1, x11
 122         reset_pmuserenr_el0 x0                  // Disable PMU access from EL0
 123         isb
 124         ret
 125 ENDPROC(cpu_do_resume)
 126         .popsection
 127 #endif
 128
 129 /*
 130  *      cpu_do_switch_mm(pgd_phys, tsk)
 131  *
 132  *      Set the translation table base pointer to be pgd_phys.
 133  *
 134  *      - pgd_phys - physical address of new TTB
 135  */
 136 ENTRY(cpu_do_switch_mm)
 137         mrs     x2, ttbr1_el1
 138         mmid    x1, x1                          // get mm->context.id
 139         bfi     x2, x1, #48, #16                // set the ASID
 140         msr     ttbr1_el1, x2                   // in TTBR1 (since TCR.A1 is set)
 141         isb
 142         msr     ttbr0_el1, x0                   // now update TTBR0
 143         isb
 144         b       post_ttbr_update_workaround     // Back to C code...
 145 ENDPROC(cpu_do_switch_mm)
 146
 147         .pushsection ".idmap.text", "awx"
 148
 149 .macro  __idmap_cpu_set_reserved_ttbr1, tmp1, tmp2
 150         adrp    \tmp1, empty_zero_page
 151         msr     ttbr1_el1, \tmp1
 152         isb
 153         tlbi    vmalle1
 154         dsb     nsh
 155         isb
 156 .endm
 157
 158 /*
 159  * void idmap_cpu_replace_ttbr1(phys_addr_t new_pgd)
 160  *
 161  * This is the low-level counterpart to cpu_replace_ttbr1, and should not be
 162  * called by anything else. It can only be executed from a TTBR0 mapping.
 163  */
 164 ENTRY(idmap_cpu_replace_ttbr1)
 165         mrs     x2, daif
 166         msr     daifset, #0xf
 167
 168         __idmap_cpu_set_reserved_ttbr1 x1, x3
 169
 170         msr     ttbr1_el1, x0
 171         isb
 172
 173         msr     daif, x2
 174
 175         ret
 176 ENDPROC(idmap_cpu_replace_ttbr1)
 177         .popsection
 178
 179 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 180         .pushsection ".idmap.text", "awx"
 181
 182         .macro  __idmap_kpti_get_pgtable_ent, type
 183         dc      cvac, cur_\()\type\()p          // Ensure any existing dirty
 184         dmb     sy                              // lines are written back before
 185         ldr     \type, [cur_\()\type\()p]       // loading the entry
 186         tbz     \type, #0, skip_\()\type        // Skip invalid and
 187         tbnz    \type, #11, skip_\()\type       // non-global entries
 188         .endm
 189
 190         .macro __idmap_kpti_put_pgtable_ent_ng, type
 191         orr     \type, \type, #PTE_NG           // Same bit for blocks and pages
 192         str     \type, [cur_\()\type\()p]       // Update the entry and ensure
 193         dmb     sy                              // that it is visible to all
 194         dc      civac, cur_\()\type\()p         // CPUs.
 195         .endm
 196
 197 /*
 198  * void __kpti_install_ng_mappings(int cpu, int num_cpus, phys_addr_t swapper)
 199  *
 200  * Called exactly once from stop_machine context by each CPU found during boot.
 201  */
 202 __idmap_kpti_flag:
 203         .long   1
 204 ENTRY(idmap_kpti_install_ng_mappings)
 205         cpu             .req    w0
 206         num_cpus        .req    w1
 207         swapper_pa      .req    x2
 208         swapper_ttb     .req    x3
 209         flag_ptr        .req    x4
 210         cur_pgdp        .req    x5
 211         end_pgdp        .req    x6
 212         pgd             .req    x7
 213         cur_pudp        .req    x8
 214         end_pudp        .req    x9
 215         pud             .req    x10
 216         cur_pmdp        .req    x11
 217         end_pmdp        .req    x12
 218         pmd             .req    x13
 219         cur_ptep        .req    x14
 220         end_ptep        .req    x15
 221         pte             .req    x16
 222
 223         mrs     swapper_ttb, ttbr1_el1
 224         adr     flag_ptr, __idmap_kpti_flag
 225
 226         cbnz    cpu, __idmap_kpti_secondary
 227
 228         /* We're the boot CPU. Wait for the others to catch up */
 229         sevl
 230 1:      wfe
 231         ldaxr   w18, [flag_ptr]
 232         eor     w18, w18, num_cpus
 233         cbnz    w18, 1b
 234
 235         /* We need to walk swapper, so turn off the MMU. */
 236         mrs     x18, sctlr_el1
 237         bic     x18, x18, #SCTLR_ELx_M
 238         msr     sctlr_el1, x18
 239         isb
 240
 241         /* Everybody is enjoying the idmap, so we can rewrite swapper. */
 242         /* PGD */
 243         mov     cur_pgdp, swapper_pa
 244         add     end_pgdp, cur_pgdp, #(PTRS_PER_PGD * 8)
 245 do_pgd: __idmap_kpti_get_pgtable_ent    pgd
 246         tbnz    pgd, #1, walk_puds
 247 next_pgd:
 248         __idmap_kpti_put_pgtable_ent_ng pgd
 249 skip_pgd:
 250         add     cur_pgdp, cur_pgdp, #8
 251         cmp     cur_pgdp, end_pgdp
 252         b.ne    do_pgd
 253
 254         /* Publish the updated tables and nuke all the TLBs */
 255         dsb     sy
 256         tlbi    vmalle1is
 257         dsb     ish
 258         isb
 259
 260         /* We're done: fire up the MMU again */
 261         mrs     x18, sctlr_el1
 262         orr     x18, x18, #SCTLR_ELx_M
 263         msr     sctlr_el1, x18
 264         isb
 265
 266         /*
 267          * Invalidate the local I-cache so that any instructions fetched
 268          * speculatively from the PoC are discarded, since they may have
 269          * been dynamically patched at the PoU.
 270          */
 271         ic      iallu
 272         dsb     nsh
 273         isb
 274
 275         /* Set the flag to zero to indicate that we're all done */
 276         str     wzr, [flag_ptr]
 277         ret
 278
 279         /* PUD */
 280 walk_puds:
 281         .if CONFIG_PGTABLE_LEVELS > 3
 282         pte_to_phys     cur_pudp, pgd
 283         add     end_pudp, cur_pudp, #(PTRS_PER_PUD * 8)
 284 do_pud: __idmap_kpti_get_pgtable_ent    pud
 285         tbnz    pud, #1, walk_pmds
 286 next_pud:
 287         __idmap_kpti_put_pgtable_ent_ng pud
 288 skip_pud:
 289         add     cur_pudp, cur_pudp, 8
 290         cmp     cur_pudp, end_pudp
 291         b.ne    do_pud
 292         b       next_pgd
 293         .else /* CONFIG_PGTABLE_LEVELS <= 3 */
 294         mov     pud, pgd
 295         b       walk_pmds
 296 next_pud:
 297         b       next_pgd
 298         .endif
 299
 300         /* PMD */
 301 walk_pmds:
 302         .if CONFIG_PGTABLE_LEVELS > 2
 303         pte_to_phys     cur_pmdp, pud
 304         add     end_pmdp, cur_pmdp, #(PTRS_PER_PMD * 8)
 305 do_pmd: __idmap_kpti_get_pgtable_ent    pmd
 306         tbnz    pmd, #1, walk_ptes
 307 next_pmd:
 308         __idmap_kpti_put_pgtable_ent_ng pmd
 309 skip_pmd:
 310         add     cur_pmdp, cur_pmdp, #8
 311         cmp     cur_pmdp, end_pmdp
 312         b.ne    do_pmd
 313         b       next_pud
 314         .else /* CONFIG_PGTABLE_LEVELS <= 2 */
 315         mov     pmd, pud
 316         b       walk_ptes
 317 next_pmd:
 318         b       next_pud
 319         .endif
 320
 321         /* PTE */
 322 walk_ptes:
 323         pte_to_phys     cur_ptep, pmd
 324         add     end_ptep, cur_ptep, #(PTRS_PER_PTE * 8)
 325 do_pte: __idmap_kpti_get_pgtable_ent    pte
 326         __idmap_kpti_put_pgtable_ent_ng pte
 327 skip_pte:
 328         add     cur_ptep, cur_ptep, #8
 329         cmp     cur_ptep, end_ptep
 330         b.ne    do_pte
 331         b       next_pmd
 332
 333         /* Secondary CPUs end up here */
 334 __idmap_kpti_secondary:
 335         /* Uninstall swapper before surgery begins */
 336         __idmap_cpu_set_reserved_ttbr1 x18, x17
 337
 338         /* Increment the flag to let the boot CPU we're ready */
 339 1:      ldxr    w18, [flag_ptr]
 340         add     w18, w18, #1
 341         stxr    w17, w18, [flag_ptr]
 342         cbnz    w17, 1b
 343
 344         /* Wait for the boot CPU to finish messing around with swapper */
 345         sevl
 346 1:      wfe
 347         ldxr    w18, [flag_ptr]
 348         cbnz    w18, 1b
 349
 350         /* All done, act like nothing happened */
 351         msr     ttbr1_el1, swapper_ttb
 352         isb
 353         ret
 354
 355         .unreq  cpu
 356         .unreq  num_cpus
 357         .unreq  swapper_pa
 358         .unreq  swapper_ttb
 359         .unreq  flag_ptr
 360         .unreq  cur_pgdp
 361         .unreq  end_pgdp
 362         .unreq  pgd
 363         .unreq  cur_pudp
 364         .unreq  end_pudp
 365         .unreq  pud
 366         .unreq  cur_pmdp
 367         .unreq  end_pmdp
 368         .unreq  pmd
 369         .unreq  cur_ptep
 370         .unreq  end_ptep
 371         .unreq  pte
 372 ENDPROC(idmap_kpti_install_ng_mappings)
 373         .popsection
 374 #endif
 375
 376 /*
 377  *      __cpu_setup
 378  *
 379  *      Initialise the processor for turning the MMU on.  Return in x0 the
 380  *      value of the SCTLR_EL1 register.
 381  */
 382         .pushsection ".idmap.text", "awx"
 383 ENTRY(__cpu_setup)
 384         tlbi    vmalle1                         // Invalidate local TLB
 385         dsb     nsh
 386
 387         mov     x0, #3 << 20
 388         msr     cpacr_el1, x0                   // Enable FP/ASIMD
 389         mov     x0, #1 << 12                    // Reset mdscr_el1 and disable
 390         msr     mdscr_el1, x0                   // access to the DCC from EL0
 391         isb                                     // Unmask debug exceptions now,
 392         enable_dbg                              // since this is per-cpu
 393         reset_pmuserenr_el0 x0                  // Disable PMU access from EL0
 394         /*
 395          * Memory region attributes for LPAE:
 396          *
 397          *   n = AttrIndx[2:0]
 398          *                      n       MAIR
 399          *   DEVICE_nGnRnE      000     00000000
 400          *   DEVICE_nGnRE       001     00000100
 401          *   DEVICE_GRE         010     00001100
 402          *   NORMAL_NC          011     01000100
 403          *   NORMAL             100     11111111
 404          *   NORMAL_WT          101     10111011
 405          */
 406         ldr     x5, =MAIR(0x00, MT_DEVICE_nGnRnE) | \
 407                      MAIR(0x04, MT_DEVICE_nGnRE) | \
 408                      MAIR(0x0c, MT_DEVICE_GRE) | \
 409                      MAIR(0x44, MT_NORMAL_NC) | \
 410                      MAIR(0xff, MT_NORMAL) | \
 411                      MAIR(0xbb, MT_NORMAL_WT)
 412         msr     mair_el1, x5
 413         /*
 414          * Prepare SCTLR
 415          */
 416         mov_q   x0, SCTLR_EL1_SET
 417         /*
 418          * Set/prepare TCR and TTBR. We use 512GB (39-bit) address range for
 419          * both user and kernel.
 420          */
 421         ldr     x10, =TCR_TxSZ(VA_BITS) | TCR_CACHE_FLAGS | TCR_SMP_FLAGS | \
 422                         TCR_TG_FLAGS | TCR_ASID16 | TCR_TBI0 | TCR_A1
 423         tcr_set_idmap_t0sz      x10, x9
 424
 425         /*
 426          * Read the PARange bits from ID_AA64MMFR0_EL1 and set the IPS bits in
 427          * TCR_EL1.
 428          */
 429         mrs     x9, ID_AA64MMFR0_EL1
 430         bfi     x10, x9, #32, #3
 431 #ifdef CONFIG_ARM64_HW_AFDBM
 432         /*
 433          * Hardware update of the Access and Dirty bits.
 434          */
 435         mrs     x9, ID_AA64MMFR1_EL1
 436         and     x9, x9, #0xf
 437         cbz     x9, 2f
 438         cmp     x9, #2
 439         b.lt    1f
 440 #ifdef CONFIG_ARM64_ERRATUM_1024718
 441         /* Disable hardware DBM on Cortex-A55 all versions */
 442         cpu_midr_match MIDR_CORTEX_A55, MIDR_CPU_VAR_REV(0, 0), MIDR_CPU_VAR_REV(0xf, 0xf), x1, x2, x3, x4
 443         cbnz    x1, 1f
 444 #endif
 445         orr     x10, x10, #TCR_HD               // hardware Dirty flag update
 446 1:      orr     x10, x10, #TCR_HA               // hardware Access flag update
 447 2:
 448 #endif  /* CONFIG_ARM64_HW_AFDBM */
 449         msr     tcr_el1, x10
 450         ret                                     // return to head.S
 451 ENDPROC(__cpu_setup)