arch/arm64/kernel/vdso/vdso.lds.S

   1 /*
   2  * GNU linker script for the VDSO library.
   3 *
   4  * Copyright (C) 2012 ARM Limited
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  * This program is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17  *
  18  * Author: Will Deacon <will.deacon@arm.com>
  19  * Heavily based on the vDSO linker scripts for other archs.
  20  */
  21
  22 #include <linux/const.h>
  23 #include <asm/page.h>
  24 #include <asm/vdso.h>
  25
  26 OUTPUT_FORMAT("elf64-littleaarch64", "elf64-bigaarch64", "elf64-littleaarch64")
  27 OUTPUT_ARCH(aarch64)
  28
  29 SECTIONS
  30 {
  31         PROVIDE(_vdso_data = . - PAGE_SIZE);
  32         . = VDSO_LBASE + SIZEOF_HEADERS;
  33
  34         .hash           : { *(.hash) }                  :text
  35         .gnu.hash       : { *(.gnu.hash) }
  36         .dynsym         : { *(.dynsym) }
  37         .dynstr         : { *(.dynstr) }
  38         .gnu.version    : { *(.gnu.version) }
  39         .gnu.version_d  : { *(.gnu.version_d) }
  40         .gnu.version_r  : { *(.gnu.version_r) }
  41
  42         /*
  43          * Discard .note.gnu.property sections which are unused and have
  44          * different alignment requirement from vDSO note sections.
  45          */
  46         /DISCARD/       : {
  47                 *(.note.GNU-stack .note.gnu.property)
  48         }
  49         .note           : { *(.note.*) }                :text   :note
  50
  51         . = ALIGN(16);
  52
  53         .text           : { *(.text*) }                 :text   =0xd503201f
  54         PROVIDE (__etext = .);
  55         PROVIDE (_etext = .);
  56         PROVIDE (etext = .);
  57
  58         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  59         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  60
  61         .dynamic        : { *(.dynamic) }               :text   :dynamic
  62
  63         .rodata         : { *(.rodata*) }               :text
  64
  65         _end = .;
  66         PROVIDE(end = .);
  67
  68         /DISCARD/       : {
  69                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
  70                 *(.bss .sbss .dynbss .dynsbss)
  71         }
  72 }
  73
  74 /*
  75  * We must supply the ELF program headers explicitly to get just one
  76  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  77  */
  78 PHDRS
  79 {
  80         text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
  81         dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
  82         note            PT_NOTE         FLAGS(4);               /* PF_R */
  83         eh_frame_hdr    PT_GNU_EH_FRAME;
  84 }
  85
  86 /*
  87  * This controls what symbols we export from the DSO.
  88  */
  89 VERSION
  90 {
  91         LINUX_2.6.39 {
  92         global:
  93                 __kernel_rt_sigreturn;
  94                 __kernel_gettimeofday;
  95                 __kernel_clock_gettime;
  96                 __kernel_clock_getres;
  97         local: *;
  98         };
  99 }
 100
 101 /*
 102  * Make the sigreturn code visible to the kernel.
 103  */
 104 VDSO_sigtramp           = __kernel_rt_sigreturn;