arch/arm64/kernel/entry.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * Low-level exception handling code
   4  *
   5  * Copyright (C) 2012 ARM Ltd.
   6  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   7  *              Will Deacon <will.deacon@arm.com>
   8  */
   9
  10 #include <linux/arm-smccc.h>
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13
  14 #include <asm/alternative.h>
  15 #include <asm/assembler.h>
  16 #include <asm/asm-offsets.h>
  17 #include <asm/asm_pointer_auth.h>
  18 #include <asm/bug.h>
  19 #include <asm/cpufeature.h>
  20 #include <asm/errno.h>
  21 #include <asm/esr.h>
  22 #include <asm/irq.h>
  23 #include <asm/memory.h>
  24 #include <asm/mmu.h>
  25 #include <asm/processor.h>
  26 #include <asm/ptrace.h>
  27 #include <asm/scs.h>
  28 #include <asm/thread_info.h>
  29 #include <asm/asm-uaccess.h>
  30 #include <asm/unistd.h>
  31
  32         .macro  clear_gp_regs
  33         .irp    n,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29
  34         mov     x\n, xzr
  35         .endr
  36         .endm
  37
  38         .macro kernel_ventry, el:req, ht:req, regsize:req, label:req
  39         .align 7
  40 .Lventry_start\@:
  41         .if     \el == 0
  42         /*
  43          * This must be the first instruction of the EL0 vector entries. It is
  44          * skipped by the trampoline vectors, to trigger the cleanup.
  45          */
  46         b       .Lskip_tramp_vectors_cleanup\@
  47         .if     \regsize == 64
  48         mrs     x30, tpidrro_el0
  49         msr     tpidrro_el0, xzr
  50         .else
  51         mov     x30, xzr
  52         .endif
  53 .Lskip_tramp_vectors_cleanup\@:
  54         .endif
  55
  56         sub     sp, sp, #PT_REGS_SIZE
  57 #ifdef CONFIG_VMAP_STACK
  58         /*
  59          * Test whether the SP has overflowed, without corrupting a GPR.
  60          * Task and IRQ stacks are aligned so that SP & (1 << THREAD_SHIFT)
  61          * should always be zero.
  62          */
  63         add     sp, sp, x0                      // sp' = sp + x0
  64         sub     x0, sp, x0                      // x0' = sp' - x0 = (sp + x0) - x0 = sp
  65         tbnz    x0, #THREAD_SHIFT, 0f
  66         sub     x0, sp, x0                      // x0'' = sp' - x0' = (sp + x0) - sp = x0
  67         sub     sp, sp, x0                      // sp'' = sp' - x0 = (sp + x0) - x0 = sp
  68         b       el\el\ht\()_\regsize\()_\label
  69
  70 0:
  71         /*
  72          * Either we've just detected an overflow, or we've taken an exception
  73          * while on the overflow stack. Either way, we won't return to
  74          * userspace, and can clobber EL0 registers to free up GPRs.
  75          */
  76
  77         /* Stash the original SP (minus PT_REGS_SIZE) in tpidr_el0. */
  78         msr     tpidr_el0, x0
  79
  80         /* Recover the original x0 value and stash it in tpidrro_el0 */
  81         sub     x0, sp, x0
  82         msr     tpidrro_el0, x0
  83
  84         /* Switch to the overflow stack */
  85         adr_this_cpu sp, overflow_stack + OVERFLOW_STACK_SIZE, x0
  86
  87         /*
  88          * Check whether we were already on the overflow stack. This may happen
  89          * after panic() re-enables interrupts.
  90          */
  91         mrs     x0, tpidr_el0                   // sp of interrupted context
  92         sub     x0, sp, x0                      // delta with top of overflow stack
  93         tst     x0, #~(OVERFLOW_STACK_SIZE - 1) // within range?
  94         b.ne    __bad_stack                     // no? -> bad stack pointer
  95
  96         /* We were already on the overflow stack. Restore sp/x0 and carry on. */
  97         sub     sp, sp, x0
  98         mrs     x0, tpidrro_el0
  99 #endif
 100         b       el\el\ht\()_\regsize\()_\label
 101 .org .Lventry_start\@ + 128     // Did we overflow the ventry slot?
 102         .endm
 103
 104         .macro tramp_alias, dst, sym, tmp
 105         mov_q   \dst, TRAMP_VALIAS
 106         adr_l   \tmp, \sym
 107         add     \dst, \dst, \tmp
 108         adr_l   \tmp, .entry.tramp.text
 109         sub     \dst, \dst, \tmp
 110         .endm
 111
 112         /*
 113          * This macro corrupts x0-x3. It is the caller's duty  to save/restore
 114          * them if required.
 115          */
 116         .macro  apply_ssbd, state, tmp1, tmp2
 117 alternative_cb  ARM64_ALWAYS_SYSTEM, spectre_v4_patch_fw_mitigation_enable
 118         b       .L__asm_ssbd_skip\@             // Patched to NOP
 119 alternative_cb_end
 120         ldr_this_cpu    \tmp2, arm64_ssbd_callback_required, \tmp1
 121         cbz     \tmp2,  .L__asm_ssbd_skip\@
 122         ldr     \tmp2, [tsk, #TSK_TI_FLAGS]
 123         tbnz    \tmp2, #TIF_SSBD, .L__asm_ssbd_skip\@
 124         mov     w0, #ARM_SMCCC_ARCH_WORKAROUND_2
 125         mov     w1, #\state
 126 alternative_cb  ARM64_ALWAYS_SYSTEM, smccc_patch_fw_mitigation_conduit
 127         nop                                     // Patched to SMC/HVC #0
 128 alternative_cb_end
 129 .L__asm_ssbd_skip\@:
 130         .endm
 131
 132         /* Check for MTE asynchronous tag check faults */
 133         .macro check_mte_async_tcf, tmp, ti_flags, thread_sctlr
 134 #ifdef CONFIG_ARM64_MTE
 135         .arch_extension lse
 136 alternative_if_not ARM64_MTE
 137         b       1f
 138 alternative_else_nop_endif
 139         /*
 140          * Asynchronous tag check faults are only possible in ASYNC (2) or
 141          * ASYM (3) modes. In each of these modes bit 1 of SCTLR_EL1.TCF0 is
 142          * set, so skip the check if it is unset.
 143          */
 144         tbz     \thread_sctlr, #(SCTLR_EL1_TCF0_SHIFT + 1), 1f
 145         mrs_s   \tmp, SYS_TFSRE0_EL1
 146         tbz     \tmp, #SYS_TFSR_EL1_TF0_SHIFT, 1f
 147         /* Asynchronous TCF occurred for TTBR0 access, set the TI flag */
 148         mov     \tmp, #_TIF_MTE_ASYNC_FAULT
 149         add     \ti_flags, tsk, #TSK_TI_FLAGS
 150         stset   \tmp, [\ti_flags]
 151 1:
 152 #endif
 153         .endm
 154
 155         /* Clear the MTE asynchronous tag check faults */
 156         .macro clear_mte_async_tcf thread_sctlr
 157 #ifdef CONFIG_ARM64_MTE
 158 alternative_if ARM64_MTE
 159         /* See comment in check_mte_async_tcf above. */
 160         tbz     \thread_sctlr, #(SCTLR_EL1_TCF0_SHIFT + 1), 1f
 161         dsb     ish
 162         msr_s   SYS_TFSRE0_EL1, xzr
 163 1:
 164 alternative_else_nop_endif
 165 #endif
 166         .endm
 167
 168         .macro mte_set_gcr, mte_ctrl, tmp
 169 #ifdef CONFIG_ARM64_MTE
 170         ubfx    \tmp, \mte_ctrl, #MTE_CTRL_GCR_USER_EXCL_SHIFT, #16
 171         orr     \tmp, \tmp, #SYS_GCR_EL1_RRND
 172         msr_s   SYS_GCR_EL1, \tmp
 173 #endif
 174         .endm
 175
 176         .macro mte_set_kernel_gcr, tmp, tmp2
 177 #ifdef CONFIG_KASAN_HW_TAGS
 178 alternative_cb  ARM64_ALWAYS_SYSTEM, kasan_hw_tags_enable
 179         b       1f
 180 alternative_cb_end
 181         mov     \tmp, KERNEL_GCR_EL1
 182         msr_s   SYS_GCR_EL1, \tmp
 183 1:
 184 #endif
 185         .endm
 186
 187         .macro mte_set_user_gcr, tsk, tmp, tmp2
 188 #ifdef CONFIG_KASAN_HW_TAGS
 189 alternative_cb  ARM64_ALWAYS_SYSTEM, kasan_hw_tags_enable
 190         b       1f
 191 alternative_cb_end
 192         ldr     \tmp, [\tsk, #THREAD_MTE_CTRL]
 193
 194         mte_set_gcr \tmp, \tmp2
 195 1:
 196 #endif
 197         .endm
 198
 199         .macro  kernel_entry, el, regsize = 64
 200         .if     \regsize == 32
 201         mov     w0, w0                          // zero upper 32 bits of x0
 202         .endif
 203         stp     x0, x1, [sp, #16 * 0]
 204         stp     x2, x3, [sp, #16 * 1]
 205         stp     x4, x5, [sp, #16 * 2]
 206         stp     x6, x7, [sp, #16 * 3]
 207         stp     x8, x9, [sp, #16 * 4]
 208         stp     x10, x11, [sp, #16 * 5]
 209         stp     x12, x13, [sp, #16 * 6]
 210         stp     x14, x15, [sp, #16 * 7]
 211         stp     x16, x17, [sp, #16 * 8]
 212         stp     x18, x19, [sp, #16 * 9]
 213         stp     x20, x21, [sp, #16 * 10]
 214         stp     x22, x23, [sp, #16 * 11]
 215         stp     x24, x25, [sp, #16 * 12]
 216         stp     x26, x27, [sp, #16 * 13]
 217         stp     x28, x29, [sp, #16 * 14]
 218
 219         .if     \el == 0
 220         clear_gp_regs
 221         mrs     x21, sp_el0
 222         ldr_this_cpu    tsk, __entry_task, x20
 223         msr     sp_el0, tsk
 224
 225         /*
 226          * Ensure MDSCR_EL1.SS is clear, since we can unmask debug exceptions
 227          * when scheduling.
 228          */
 229         ldr     x19, [tsk, #TSK_TI_FLAGS]
 230         disable_step_tsk x19, x20
 231
 232         /* Check for asynchronous tag check faults in user space */
 233         ldr     x0, [tsk, THREAD_SCTLR_USER]
 234         check_mte_async_tcf x22, x23, x0
 235
 236 #ifdef CONFIG_ARM64_PTR_AUTH
 237 alternative_if ARM64_HAS_ADDRESS_AUTH
 238         /*
 239          * Enable IA for in-kernel PAC if the task had it disabled. Although
 240          * this could be implemented with an unconditional MRS which would avoid
 241          * a load, this was measured to be slower on Cortex-A75 and Cortex-A76.
 242          *
 243          * Install the kernel IA key only if IA was enabled in the task. If IA
 244          * was disabled on kernel exit then we would have left the kernel IA
 245          * installed so there is no need to install it again.
 246          */
 247         tbz     x0, SCTLR_ELx_ENIA_SHIFT, 1f
 248         __ptrauth_keys_install_kernel_nosync tsk, x20, x22, x23
 249         b       2f
 250 1:
 251         mrs     x0, sctlr_el1
 252         orr     x0, x0, SCTLR_ELx_ENIA
 253         msr     sctlr_el1, x0
 254 2:
 255 alternative_else_nop_endif
 256 #endif
 257
 258         apply_ssbd 1, x22, x23
 259
 260         mte_set_kernel_gcr x22, x23
 261
 262         /*
 263          * Any non-self-synchronizing system register updates required for
 264          * kernel entry should be placed before this point.
 265          */
 266 alternative_if ARM64_MTE
 267         isb
 268         b       1f
 269 alternative_else_nop_endif
 270 alternative_if ARM64_HAS_ADDRESS_AUTH
 271         isb
 272 alternative_else_nop_endif
 273 1:
 274
 275         scs_load_current
 276         .else
 277         add     x21, sp, #PT_REGS_SIZE
 278         get_current_task tsk
 279         .endif /* \el == 0 */
 280         mrs     x22, elr_el1
 281         mrs     x23, spsr_el1
 282         stp     lr, x21, [sp, #S_LR]
 283
 284         /*
 285          * For exceptions from EL0, create a final frame record.
 286          * For exceptions from EL1, create a synthetic frame record so the
 287          * interrupted code shows up in the backtrace.
 288          */
 289         .if \el == 0
 290         stp     xzr, xzr, [sp, #S_STACKFRAME]
 291         .else
 292         stp     x29, x22, [sp, #S_STACKFRAME]
 293         .endif
 294         add     x29, sp, #S_STACKFRAME
 295
 296 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 297 alternative_if_not ARM64_HAS_PAN
 298         bl      __swpan_entry_el\el
 299 alternative_else_nop_endif
 300 #endif
 301
 302         stp     x22, x23, [sp, #S_PC]
 303
 304         /* Not in a syscall by default (el0_svc overwrites for real syscall) */
 305         .if     \el == 0
 306         mov     w21, #NO_SYSCALL
 307         str     w21, [sp, #S_SYSCALLNO]
 308         .endif
 309
 310 #ifdef CONFIG_ARM64_PSEUDO_NMI
 311         /* Save pmr */
 312 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 313         mrs_s   x20, SYS_ICC_PMR_EL1
 314         str     x20, [sp, #S_PMR_SAVE]
 315         mov     x20, #GIC_PRIO_IRQON | GIC_PRIO_PSR_I_SET
 316         msr_s   SYS_ICC_PMR_EL1, x20
 317 alternative_else_nop_endif
 318 #endif
 319
 320         /*
 321          * Registers that may be useful after this macro is invoked:
 322          *
 323          * x20 - ICC_PMR_EL1
 324          * x21 - aborted SP
 325          * x22 - aborted PC
 326          * x23 - aborted PSTATE
 327         */
 328         .endm
 329
 330         .macro  kernel_exit, el
 331         .if     \el != 0
 332         disable_daif
 333         .endif
 334
 335 #ifdef CONFIG_ARM64_PSEUDO_NMI
 336         /* Restore pmr */
 337 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 338         ldr     x20, [sp, #S_PMR_SAVE]
 339         msr_s   SYS_ICC_PMR_EL1, x20
 340         mrs_s   x21, SYS_ICC_CTLR_EL1
 341         tbz     x21, #6, .L__skip_pmr_sync\@    // Check for ICC_CTLR_EL1.PMHE
 342         dsb     sy                              // Ensure priority change is seen by redistributor
 343 .L__skip_pmr_sync\@:
 344 alternative_else_nop_endif
 345 #endif
 346
 347         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 348
 349 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 350 alternative_if_not ARM64_HAS_PAN
 351         bl      __swpan_exit_el\el
 352 alternative_else_nop_endif
 353 #endif
 354
 355         .if     \el == 0
 356         ldr     x23, [sp, #S_SP]                // load return stack pointer
 357         msr     sp_el0, x23
 358         tst     x22, #PSR_MODE32_BIT            // native task?
 359         b.eq    3f
 360
 361 #ifdef CONFIG_ARM64_ERRATUM_845719
 362 alternative_if ARM64_WORKAROUND_845719
 363 #ifdef CONFIG_PID_IN_CONTEXTIDR
 364         mrs     x29, contextidr_el1
 365         msr     contextidr_el1, x29
 366 #else
 367         msr contextidr_el1, xzr
 368 #endif
 369 alternative_else_nop_endif
 370 #endif
 371 3:
 372         scs_save tsk
 373
 374         /* Ignore asynchronous tag check faults in the uaccess routines */
 375         ldr     x0, [tsk, THREAD_SCTLR_USER]
 376         clear_mte_async_tcf x0
 377
 378 #ifdef CONFIG_ARM64_PTR_AUTH
 379 alternative_if ARM64_HAS_ADDRESS_AUTH
 380         /*
 381          * IA was enabled for in-kernel PAC. Disable it now if needed, or
 382          * alternatively install the user's IA. All other per-task keys and
 383          * SCTLR bits were updated on task switch.
 384          *
 385          * No kernel C function calls after this.
 386          */
 387         tbz     x0, SCTLR_ELx_ENIA_SHIFT, 1f
 388         __ptrauth_keys_install_user tsk, x0, x1, x2
 389         b       2f
 390 1:
 391         mrs     x0, sctlr_el1
 392         bic     x0, x0, SCTLR_ELx_ENIA
 393         msr     sctlr_el1, x0
 394 2:
 395 alternative_else_nop_endif
 396 #endif
 397
 398         mte_set_user_gcr tsk, x0, x1
 399
 400         apply_ssbd 0, x0, x1
 401         .endif
 402
 403         msr     elr_el1, x21                    // set up the return data
 404         msr     spsr_el1, x22
 405         ldp     x0, x1, [sp, #16 * 0]
 406         ldp     x2, x3, [sp, #16 * 1]
 407         ldp     x4, x5, [sp, #16 * 2]
 408         ldp     x6, x7, [sp, #16 * 3]
 409         ldp     x8, x9, [sp, #16 * 4]
 410         ldp     x10, x11, [sp, #16 * 5]
 411         ldp     x12, x13, [sp, #16 * 6]
 412         ldp     x14, x15, [sp, #16 * 7]
 413         ldp     x16, x17, [sp, #16 * 8]
 414         ldp     x18, x19, [sp, #16 * 9]
 415         ldp     x20, x21, [sp, #16 * 10]
 416         ldp     x22, x23, [sp, #16 * 11]
 417         ldp     x24, x25, [sp, #16 * 12]
 418         ldp     x26, x27, [sp, #16 * 13]
 419         ldp     x28, x29, [sp, #16 * 14]
 420
 421         .if     \el == 0
 422 alternative_if ARM64_WORKAROUND_SPECULATIVE_UNPRIV_LOAD
 423         tlbi    vale1, xzr
 424         dsb     nsh
 425 alternative_else_nop_endif
 426 alternative_if_not ARM64_UNMAP_KERNEL_AT_EL0
 427         ldr     lr, [sp, #S_LR]
 428         add     sp, sp, #PT_REGS_SIZE           // restore sp
 429         eret
 430 alternative_else_nop_endif
 431 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 432         bne     4f
 433         msr     far_el1, x29
 434         tramp_alias     x30, tramp_exit_native, x29
 435         br      x30
 436 4:
 437         tramp_alias     x30, tramp_exit_compat, x29
 438         br      x30
 439 #endif
 440         .else
 441         ldr     lr, [sp, #S_LR]
 442         add     sp, sp, #PT_REGS_SIZE           // restore sp
 443
 444         /* Ensure any device/NC reads complete */
 445         alternative_insn nop, "dmb sy", ARM64_WORKAROUND_1508412
 446
 447         eret
 448         .endif
 449         sb
 450         .endm
 451
 452 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 453         /*
 454          * Set the TTBR0 PAN bit in SPSR. When the exception is taken from
 455          * EL0, there is no need to check the state of TTBR0_EL1 since
 456          * accesses are always enabled.
 457          * Note that the meaning of this bit differs from the ARMv8.1 PAN
 458          * feature as all TTBR0_EL1 accesses are disabled, not just those to
 459          * user mappings.
 460          */
 461 SYM_CODE_START_LOCAL(__swpan_entry_el1)
 462         mrs     x21, ttbr0_el1
 463         tst     x21, #TTBR_ASID_MASK            // Check for the reserved ASID
 464         orr     x23, x23, #PSR_PAN_BIT          // Set the emulated PAN in the saved SPSR
 465         b.eq    1f                              // TTBR0 access already disabled
 466         and     x23, x23, #~PSR_PAN_BIT         // Clear the emulated PAN in the saved SPSR
 467 SYM_INNER_LABEL(__swpan_entry_el0, SYM_L_LOCAL)
 468         __uaccess_ttbr0_disable x21
 469 1:      ret
 470 SYM_CODE_END(__swpan_entry_el1)
 471
 472         /*
 473          * Restore access to TTBR0_EL1. If returning to EL0, no need for SPSR
 474          * PAN bit checking.
 475          */
 476 SYM_CODE_START_LOCAL(__swpan_exit_el1)
 477         tbnz    x22, #22, 1f                    // Skip re-enabling TTBR0 access if the PSR_PAN_BIT is set
 478         __uaccess_ttbr0_enable x0, x1
 479 1:      and     x22, x22, #~PSR_PAN_BIT         // ARMv8.0 CPUs do not understand this bit
 480         ret
 481 SYM_CODE_END(__swpan_exit_el1)
 482
 483 SYM_CODE_START_LOCAL(__swpan_exit_el0)
 484         __uaccess_ttbr0_enable x0, x1
 485         /*
 486          * Enable errata workarounds only if returning to user. The only
 487          * workaround currently required for TTBR0_EL1 changes are for the
 488          * Cavium erratum 27456 (broadcast TLBI instructions may cause I-cache
 489          * corruption).
 490          */
 491         b       post_ttbr_update_workaround
 492 SYM_CODE_END(__swpan_exit_el0)
 493 #endif
 494
 495 /* GPRs used by entry code */
 496 tsk     .req    x28             // current thread_info
 497
 498         .text
 499
 500 /*
 501  * Exception vectors.
 502  */
 503         .pushsection ".entry.text", "ax"
 504
 505         .align  11
 506 SYM_CODE_START(vectors)
 507         kernel_ventry   1, t, 64, sync          // Synchronous EL1t
 508         kernel_ventry   1, t, 64, irq           // IRQ EL1t
 509         kernel_ventry   1, t, 64, fiq           // FIQ EL1t
 510         kernel_ventry   1, t, 64, error         // Error EL1t
 511
 512         kernel_ventry   1, h, 64, sync          // Synchronous EL1h
 513         kernel_ventry   1, h, 64, irq           // IRQ EL1h
 514         kernel_ventry   1, h, 64, fiq           // FIQ EL1h
 515         kernel_ventry   1, h, 64, error         // Error EL1h
 516
 517         kernel_ventry   0, t, 64, sync          // Synchronous 64-bit EL0
 518         kernel_ventry   0, t, 64, irq           // IRQ 64-bit EL0
 519         kernel_ventry   0, t, 64, fiq           // FIQ 64-bit EL0
 520         kernel_ventry   0, t, 64, error         // Error 64-bit EL0
 521
 522         kernel_ventry   0, t, 32, sync          // Synchronous 32-bit EL0
 523         kernel_ventry   0, t, 32, irq           // IRQ 32-bit EL0
 524         kernel_ventry   0, t, 32, fiq           // FIQ 32-bit EL0
 525         kernel_ventry   0, t, 32, error         // Error 32-bit EL0
 526 SYM_CODE_END(vectors)
 527
 528 #ifdef CONFIG_VMAP_STACK
 529 SYM_CODE_START_LOCAL(__bad_stack)
 530         /*
 531          * We detected an overflow in kernel_ventry, which switched to the
 532          * overflow stack. Stash the exception regs, and head to our overflow
 533          * handler.
 534          */
 535
 536         /* Restore the original x0 value */
 537         mrs     x0, tpidrro_el0
 538
 539         /*
 540          * Store the original GPRs to the new stack. The orginal SP (minus
 541          * PT_REGS_SIZE) was stashed in tpidr_el0 by kernel_ventry.
 542          */
 543         sub     sp, sp, #PT_REGS_SIZE
 544         kernel_entry 1
 545         mrs     x0, tpidr_el0
 546         add     x0, x0, #PT_REGS_SIZE
 547         str     x0, [sp, #S_SP]
 548
 549         /* Stash the regs for handle_bad_stack */
 550         mov     x0, sp
 551
 552         /* Time to die */
 553         bl      handle_bad_stack
 554         ASM_BUG()
 555 SYM_CODE_END(__bad_stack)
 556 #endif /* CONFIG_VMAP_STACK */
 557
 558
 559         .macro entry_handler el:req, ht:req, regsize:req, label:req
 560 SYM_CODE_START_LOCAL(el\el\ht\()_\regsize\()_\label)
 561         kernel_entry \el, \regsize
 562         mov     x0, sp
 563         bl      el\el\ht\()_\regsize\()_\label\()_handler
 564         .if \el == 0
 565         b       ret_to_user
 566         .else
 567         b       ret_to_kernel
 568         .endif
 569 SYM_CODE_END(el\el\ht\()_\regsize\()_\label)
 570         .endm
 571
 572 /*
 573  * Early exception handlers
 574  */
 575         entry_handler   1, t, 64, sync
 576         entry_handler   1, t, 64, irq
 577         entry_handler   1, t, 64, fiq
 578         entry_handler   1, t, 64, error
 579
 580         entry_handler   1, h, 64, sync
 581         entry_handler   1, h, 64, irq
 582         entry_handler   1, h, 64, fiq
 583         entry_handler   1, h, 64, error
 584
 585         entry_handler   0, t, 64, sync
 586         entry_handler   0, t, 64, irq
 587         entry_handler   0, t, 64, fiq
 588         entry_handler   0, t, 64, error
 589
 590         entry_handler   0, t, 32, sync
 591         entry_handler   0, t, 32, irq
 592         entry_handler   0, t, 32, fiq
 593         entry_handler   0, t, 32, error
 594
 595 SYM_CODE_START_LOCAL(ret_to_kernel)
 596         kernel_exit 1
 597 SYM_CODE_END(ret_to_kernel)
 598
 599 SYM_CODE_START_LOCAL(ret_to_user)
 600         ldr     x19, [tsk, #TSK_TI_FLAGS]       // re-check for single-step
 601         enable_step_tsk x19, x2
 602 #ifdef CONFIG_GCC_PLUGIN_STACKLEAK
 603         bl      stackleak_erase_on_task_stack
 604 #endif
 605         kernel_exit 0
 606 SYM_CODE_END(ret_to_user)
 607
 608         .popsection                             // .entry.text
 609
 610         // Move from tramp_pg_dir to swapper_pg_dir
 611         .macro tramp_map_kernel, tmp
 612         mrs     \tmp, ttbr1_el1
 613         add     \tmp, \tmp, #TRAMP_SWAPPER_OFFSET
 614         bic     \tmp, \tmp, #USER_ASID_FLAG
 615         msr     ttbr1_el1, \tmp
 616 #ifdef CONFIG_QCOM_FALKOR_ERRATUM_1003
 617 alternative_if ARM64_WORKAROUND_QCOM_FALKOR_E1003
 618         /* ASID already in \tmp[63:48] */
 619         movk    \tmp, #:abs_g2_nc:(TRAMP_VALIAS >> 12)
 620         movk    \tmp, #:abs_g1_nc:(TRAMP_VALIAS >> 12)
 621         /* 2MB boundary containing the vectors, so we nobble the walk cache */
 622         movk    \tmp, #:abs_g0_nc:((TRAMP_VALIAS & ~(SZ_2M - 1)) >> 12)
 623         isb
 624         tlbi    vae1, \tmp
 625         dsb     nsh
 626 alternative_else_nop_endif
 627 #endif /* CONFIG_QCOM_FALKOR_ERRATUM_1003 */
 628         .endm
 629
 630         // Move from swapper_pg_dir to tramp_pg_dir
 631         .macro tramp_unmap_kernel, tmp
 632         mrs     \tmp, ttbr1_el1
 633         sub     \tmp, \tmp, #TRAMP_SWAPPER_OFFSET
 634         orr     \tmp, \tmp, #USER_ASID_FLAG
 635         msr     ttbr1_el1, \tmp
 636         /*
 637          * We avoid running the post_ttbr_update_workaround here because
 638          * it's only needed by Cavium ThunderX, which requires KPTI to be
 639          * disabled.
 640          */
 641         .endm
 642
 643         .macro          tramp_data_read_var     dst, var
 644 #ifdef CONFIG_RELOCATABLE
 645         ldr             \dst, .L__tramp_data_\var
 646         .ifndef         .L__tramp_data_\var
 647         .pushsection    ".entry.tramp.rodata", "a", %progbits
 648         .align          3
 649 .L__tramp_data_\var:
 650         .quad           \var
 651         .popsection
 652         .endif
 653 #else
 654         /*
 655          * As !RELOCATABLE implies !RANDOMIZE_BASE the address is always a
 656          * compile time constant (and hence not secret and not worth hiding).
 657          *
 658          * As statically allocated kernel code and data always live in the top
 659          * 47 bits of the address space we can sign-extend bit 47 and avoid an
 660          * instruction to load the upper 16 bits (which must be 0xFFFF).
 661          */
 662         movz            \dst, :abs_g2_s:\var
 663         movk            \dst, :abs_g1_nc:\var
 664         movk            \dst, :abs_g0_nc:\var
 665 #endif
 666         .endm
 667
 668 #define BHB_MITIGATION_NONE     0
 669 #define BHB_MITIGATION_LOOP     1
 670 #define BHB_MITIGATION_FW       2
 671 #define BHB_MITIGATION_INSN     3
 672
 673         .macro tramp_ventry, vector_start, regsize, kpti, bhb
 674         .align  7
 675 1:
 676         .if     \regsize == 64
 677         msr     tpidrro_el0, x30        // Restored in kernel_ventry
 678         .endif
 679
 680         .if     \bhb == BHB_MITIGATION_LOOP
 681         /*
 682          * This sequence must appear before the first indirect branch. i.e. the
 683          * ret out of tramp_ventry. It appears here because x30 is free.
 684          */
 685         __mitigate_spectre_bhb_loop     x30
 686         .endif // \bhb == BHB_MITIGATION_LOOP
 687
 688         .if     \bhb == BHB_MITIGATION_INSN
 689         clearbhb
 690         isb
 691         .endif // \bhb == BHB_MITIGATION_INSN
 692
 693         .if     \kpti == 1
 694         /*
 695          * Defend against branch aliasing attacks by pushing a dummy
 696          * entry onto the return stack and using a RET instruction to
 697          * enter the full-fat kernel vectors.
 698          */
 699         bl      2f
 700         b       .
 701 2:
 702         tramp_map_kernel        x30
 703 alternative_insn isb, nop, ARM64_WORKAROUND_QCOM_FALKOR_E1003
 704         tramp_data_read_var     x30, vectors
 705 alternative_if_not ARM64_WORKAROUND_CAVIUM_TX2_219_PRFM
 706         prfm    plil1strm, [x30, #(1b - \vector_start)]
 707 alternative_else_nop_endif
 708
 709         msr     vbar_el1, x30
 710         isb
 711         .else
 712         adr_l   x30, vectors
 713         .endif // \kpti == 1
 714
 715         .if     \bhb == BHB_MITIGATION_FW
 716         /*
 717          * The firmware sequence must appear before the first indirect branch.
 718          * i.e. the ret out of tramp_ventry. But it also needs the stack to be
 719          * mapped to save/restore the registers the SMC clobbers.
 720          */
 721         __mitigate_spectre_bhb_fw
 722         .endif // \bhb == BHB_MITIGATION_FW
 723
 724         add     x30, x30, #(1b - \vector_start + 4)
 725         ret
 726 .org 1b + 128   // Did we overflow the ventry slot?
 727         .endm
 728
 729         .macro tramp_exit, regsize = 64
 730         tramp_data_read_var     x30, this_cpu_vector
 731         get_this_cpu_offset x29
 732         ldr     x30, [x30, x29]
 733
 734         msr     vbar_el1, x30
 735         ldr     lr, [sp, #S_LR]
 736         tramp_unmap_kernel      x29
 737         .if     \regsize == 64
 738         mrs     x29, far_el1
 739         .endif
 740         add     sp, sp, #PT_REGS_SIZE           // restore sp
 741         eret
 742         sb
 743         .endm
 744
 745         .macro  generate_tramp_vector,  kpti, bhb
 746 .Lvector_start\@:
 747         .space  0x400
 748
 749         .rept   4
 750         tramp_ventry    .Lvector_start\@, 64, \kpti, \bhb
 751         .endr
 752         .rept   4
 753         tramp_ventry    .Lvector_start\@, 32, \kpti, \bhb
 754         .endr
 755         .endm
 756
 757 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 758 /*
 759  * Exception vectors trampoline.
 760  * The order must match __bp_harden_el1_vectors and the
 761  * arm64_bp_harden_el1_vectors enum.
 762  */
 763         .pushsection ".entry.tramp.text", "ax"
 764         .align  11
 765 SYM_CODE_START_NOALIGN(tramp_vectors)
 766 #ifdef CONFIG_MITIGATE_SPECTRE_BRANCH_HISTORY
 767         generate_tramp_vector   kpti=1, bhb=BHB_MITIGATION_LOOP
 768         generate_tramp_vector   kpti=1, bhb=BHB_MITIGATION_FW
 769         generate_tramp_vector   kpti=1, bhb=BHB_MITIGATION_INSN
 770 #endif /* CONFIG_MITIGATE_SPECTRE_BRANCH_HISTORY */
 771         generate_tramp_vector   kpti=1, bhb=BHB_MITIGATION_NONE
 772 SYM_CODE_END(tramp_vectors)
 773
 774 SYM_CODE_START(tramp_exit_native)
 775         tramp_exit
 776 SYM_CODE_END(tramp_exit_native)
 777
 778 SYM_CODE_START(tramp_exit_compat)
 779         tramp_exit      32
 780 SYM_CODE_END(tramp_exit_compat)
 781         .popsection                             // .entry.tramp.text
 782 #endif /* CONFIG_UNMAP_KERNEL_AT_EL0 */
 783
 784 /*
 785  * Exception vectors for spectre mitigations on entry from EL1 when
 786  * kpti is not in use.
 787  */
 788         .macro generate_el1_vector, bhb
 789 .Lvector_start\@:
 790         kernel_ventry   1, t, 64, sync          // Synchronous EL1t
 791         kernel_ventry   1, t, 64, irq           // IRQ EL1t
 792         kernel_ventry   1, t, 64, fiq           // FIQ EL1h
 793         kernel_ventry   1, t, 64, error         // Error EL1t
 794
 795         kernel_ventry   1, h, 64, sync          // Synchronous EL1h
 796         kernel_ventry   1, h, 64, irq           // IRQ EL1h
 797         kernel_ventry   1, h, 64, fiq           // FIQ EL1h
 798         kernel_ventry   1, h, 64, error         // Error EL1h
 799
 800         .rept   4
 801         tramp_ventry    .Lvector_start\@, 64, 0, \bhb
 802         .endr
 803         .rept 4
 804         tramp_ventry    .Lvector_start\@, 32, 0, \bhb
 805         .endr
 806         .endm
 807
 808 /* The order must match tramp_vecs and the arm64_bp_harden_el1_vectors enum. */
 809         .pushsection ".entry.text", "ax"
 810         .align  11
 811 SYM_CODE_START(__bp_harden_el1_vectors)
 812 #ifdef CONFIG_MITIGATE_SPECTRE_BRANCH_HISTORY
 813         generate_el1_vector     bhb=BHB_MITIGATION_LOOP
 814         generate_el1_vector     bhb=BHB_MITIGATION_FW
 815         generate_el1_vector     bhb=BHB_MITIGATION_INSN
 816 #endif /* CONFIG_MITIGATE_SPECTRE_BRANCH_HISTORY */
 817 SYM_CODE_END(__bp_harden_el1_vectors)
 818         .popsection
 819
 820
 821 /*
 822  * Register switch for AArch64. The callee-saved registers need to be saved
 823  * and restored. On entry:
 824  *   x0 = previous task_struct (must be preserved across the switch)
 825  *   x1 = next task_struct
 826  * Previous and next are guaranteed not to be the same.
 827  *
 828  */
 829 SYM_FUNC_START(cpu_switch_to)
 830         mov     x10, #THREAD_CPU_CONTEXT
 831         add     x8, x0, x10
 832         mov     x9, sp
 833         stp     x19, x20, [x8], #16             // store callee-saved registers
 834         stp     x21, x22, [x8], #16
 835         stp     x23, x24, [x8], #16
 836         stp     x25, x26, [x8], #16
 837         stp     x27, x28, [x8], #16
 838         stp     x29, x9, [x8], #16
 839         str     lr, [x8]
 840         add     x8, x1, x10
 841         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 842         ldp     x21, x22, [x8], #16
 843         ldp     x23, x24, [x8], #16
 844         ldp     x25, x26, [x8], #16
 845         ldp     x27, x28, [x8], #16
 846         ldp     x29, x9, [x8], #16
 847         ldr     lr, [x8]
 848         mov     sp, x9
 849         msr     sp_el0, x1
 850         ptrauth_keys_install_kernel x1, x8, x9, x10
 851         scs_save x0
 852         scs_load_current
 853         ret
 854 SYM_FUNC_END(cpu_switch_to)
 855 NOKPROBE(cpu_switch_to)
 856
 857 /*
 858  * This is how we return from a fork.
 859  */
 860 SYM_CODE_START(ret_from_fork)
 861         bl      schedule_tail
 862         cbz     x19, 1f                         // not a kernel thread
 863         mov     x0, x20
 864         blr     x19
 865 1:      get_current_task tsk
 866         mov     x0, sp
 867         bl      asm_exit_to_user_mode
 868         b       ret_to_user
 869 SYM_CODE_END(ret_from_fork)
 870 NOKPROBE(ret_from_fork)
 871
 872 /*
 873  * void call_on_irq_stack(struct pt_regs *regs,
 874  *                        void (*func)(struct pt_regs *));
 875  *
 876  * Calls func(regs) using this CPU's irq stack and shadow irq stack.
 877  */
 878 SYM_FUNC_START(call_on_irq_stack)
 879 #ifdef CONFIG_SHADOW_CALL_STACK
 880         get_current_task x16
 881         scs_save x16
 882         ldr_this_cpu scs_sp, irq_shadow_call_stack_ptr, x17
 883 #endif
 884
 885         /* Create a frame record to save our LR and SP (implicit in FP) */
 886         stp     x29, x30, [sp, #-16]!
 887         mov     x29, sp
 888
 889         ldr_this_cpu x16, irq_stack_ptr, x17
 890
 891         /* Move to the new stack and call the function there */
 892         add     sp, x16, #IRQ_STACK_SIZE
 893         blr     x1
 894
 895         /*
 896          * Restore the SP from the FP, and restore the FP and LR from the frame
 897          * record.
 898          */
 899         mov     sp, x29
 900         ldp     x29, x30, [sp], #16
 901         scs_load_current
 902         ret
 903 SYM_FUNC_END(call_on_irq_stack)
 904 NOKPROBE(call_on_irq_stack)
 905
 906 #ifdef CONFIG_ARM_SDE_INTERFACE
 907
 908 #include <asm/sdei.h>
 909 #include <uapi/linux/arm_sdei.h>
 910
 911 .macro sdei_handler_exit exit_mode
 912         /* On success, this call never returns... */
 913         cmp     \exit_mode, #SDEI_EXIT_SMC
 914         b.ne    99f
 915         smc     #0
 916         b       .
 917 99:     hvc     #0
 918         b       .
 919 .endm
 920
 921 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 922 /*
 923  * The regular SDEI entry point may have been unmapped along with the rest of
 924  * the kernel. This trampoline restores the kernel mapping to make the x1 memory
 925  * argument accessible.
 926  *
 927  * This clobbers x4, __sdei_handler() will restore this from firmware's
 928  * copy.
 929  */
 930 .pushsection ".entry.tramp.text", "ax"
 931 SYM_CODE_START(__sdei_asm_entry_trampoline)
 932         mrs     x4, ttbr1_el1
 933         tbz     x4, #USER_ASID_BIT, 1f
 934
 935         tramp_map_kernel tmp=x4
 936         isb
 937         mov     x4, xzr
 938
 939         /*
 940          * Remember whether to unmap the kernel on exit.
 941          */
 942 1:      str     x4, [x1, #(SDEI_EVENT_INTREGS + S_SDEI_TTBR1)]
 943         tramp_data_read_var     x4, __sdei_asm_handler
 944         br      x4
 945 SYM_CODE_END(__sdei_asm_entry_trampoline)
 946 NOKPROBE(__sdei_asm_entry_trampoline)
 947
 948 /*
 949  * Make the exit call and restore the original ttbr1_el1
 950  *
 951  * x0 & x1: setup for the exit API call
 952  * x2: exit_mode
 953  * x4: struct sdei_registered_event argument from registration time.
 954  */
 955 SYM_CODE_START(__sdei_asm_exit_trampoline)
 956         ldr     x4, [x4, #(SDEI_EVENT_INTREGS + S_SDEI_TTBR1)]
 957         cbnz    x4, 1f
 958
 959         tramp_unmap_kernel      tmp=x4
 960
 961 1:      sdei_handler_exit exit_mode=x2
 962 SYM_CODE_END(__sdei_asm_exit_trampoline)
 963 NOKPROBE(__sdei_asm_exit_trampoline)
 964 .popsection             // .entry.tramp.text
 965 #endif /* CONFIG_UNMAP_KERNEL_AT_EL0 */
 966
 967 /*
 968  * Software Delegated Exception entry point.
 969  *
 970  * x0: Event number
 971  * x1: struct sdei_registered_event argument from registration time.
 972  * x2: interrupted PC
 973  * x3: interrupted PSTATE
 974  * x4: maybe clobbered by the trampoline
 975  *
 976  * Firmware has preserved x0->x17 for us, we must save/restore the rest to
 977  * follow SMC-CC. We save (or retrieve) all the registers as the handler may
 978  * want them.
 979  */
 980 SYM_CODE_START(__sdei_asm_handler)
 981         stp     x2, x3, [x1, #SDEI_EVENT_INTREGS + S_PC]
 982         stp     x4, x5, [x1, #SDEI_EVENT_INTREGS + 16 * 2]
 983         stp     x6, x7, [x1, #SDEI_EVENT_INTREGS + 16 * 3]
 984         stp     x8, x9, [x1, #SDEI_EVENT_INTREGS + 16 * 4]
 985         stp     x10, x11, [x1, #SDEI_EVENT_INTREGS + 16 * 5]
 986         stp     x12, x13, [x1, #SDEI_EVENT_INTREGS + 16 * 6]
 987         stp     x14, x15, [x1, #SDEI_EVENT_INTREGS + 16 * 7]
 988         stp     x16, x17, [x1, #SDEI_EVENT_INTREGS + 16 * 8]
 989         stp     x18, x19, [x1, #SDEI_EVENT_INTREGS + 16 * 9]
 990         stp     x20, x21, [x1, #SDEI_EVENT_INTREGS + 16 * 10]
 991         stp     x22, x23, [x1, #SDEI_EVENT_INTREGS + 16 * 11]
 992         stp     x24, x25, [x1, #SDEI_EVENT_INTREGS + 16 * 12]
 993         stp     x26, x27, [x1, #SDEI_EVENT_INTREGS + 16 * 13]
 994         stp     x28, x29, [x1, #SDEI_EVENT_INTREGS + 16 * 14]
 995         mov     x4, sp
 996         stp     lr, x4, [x1, #SDEI_EVENT_INTREGS + S_LR]
 997
 998         mov     x19, x1
 999
1000         /* Store the registered-event for crash_smp_send_stop() */
1001         ldrb    w4, [x19, #SDEI_EVENT_PRIORITY]
1002         cbnz    w4, 1f
1003         adr_this_cpu dst=x5, sym=sdei_active_normal_event, tmp=x6
1004         b       2f
1005 1:      adr_this_cpu dst=x5, sym=sdei_active_critical_event, tmp=x6
1006 2:      str     x19, [x5]
1007
1008 #ifdef CONFIG_VMAP_STACK
1009         /*
1010          * entry.S may have been using sp as a scratch register, find whether
1011          * this is a normal or critical event and switch to the appropriate
1012          * stack for this CPU.
1013          */
1014         cbnz    w4, 1f
1015         ldr_this_cpu dst=x5, sym=sdei_stack_normal_ptr, tmp=x6
1016         b       2f
1017 1:      ldr_this_cpu dst=x5, sym=sdei_stack_critical_ptr, tmp=x6
1018 2:      mov     x6, #SDEI_STACK_SIZE
1019         add     x5, x5, x6
1020         mov     sp, x5
1021 #endif
1022
1023 #ifdef CONFIG_SHADOW_CALL_STACK
1024         /* Use a separate shadow call stack for normal and critical events */
1025         cbnz    w4, 3f
1026         ldr_this_cpu dst=scs_sp, sym=sdei_shadow_call_stack_normal_ptr, tmp=x6
1027         b       4f
1028 3:      ldr_this_cpu dst=scs_sp, sym=sdei_shadow_call_stack_critical_ptr, tmp=x6
1029 4:
1030 #endif
1031
1032         /*
1033          * We may have interrupted userspace, or a guest, or exit-from or
1034          * return-to either of these. We can't trust sp_el0, restore it.
1035          */
1036         mrs     x28, sp_el0
1037         ldr_this_cpu    dst=x0, sym=__entry_task, tmp=x1
1038         msr     sp_el0, x0
1039
1040         /* If we interrupted the kernel point to the previous stack/frame. */
1041         and     x0, x3, #0xc
1042         mrs     x1, CurrentEL
1043         cmp     x0, x1
1044         csel    x29, x29, xzr, eq       // fp, or zero
1045         csel    x4, x2, xzr, eq         // elr, or zero
1046
1047         stp     x29, x4, [sp, #-16]!
1048         mov     x29, sp
1049
1050         add     x0, x19, #SDEI_EVENT_INTREGS
1051         mov     x1, x19
1052         bl      __sdei_handler
1053
1054         msr     sp_el0, x28
1055         /* restore regs >x17 that we clobbered */
1056         mov     x4, x19         // keep x4 for __sdei_asm_exit_trampoline
1057         ldp     x28, x29, [x4, #SDEI_EVENT_INTREGS + 16 * 14]
1058         ldp     x18, x19, [x4, #SDEI_EVENT_INTREGS + 16 * 9]
1059         ldp     lr, x1, [x4, #SDEI_EVENT_INTREGS + S_LR]
1060         mov     sp, x1
1061
1062         mov     x1, x0                  // address to complete_and_resume
1063         /* x0 = (x0 <= SDEI_EV_FAILED) ?
1064          * EVENT_COMPLETE:EVENT_COMPLETE_AND_RESUME
1065          */
1066         cmp     x0, #SDEI_EV_FAILED
1067         mov_q   x2, SDEI_1_0_FN_SDEI_EVENT_COMPLETE
1068         mov_q   x3, SDEI_1_0_FN_SDEI_EVENT_COMPLETE_AND_RESUME
1069         csel    x0, x2, x3, ls
1070
1071         ldr_l   x2, sdei_exit_mode
1072
1073         /* Clear the registered-event seen by crash_smp_send_stop() */
1074         ldrb    w3, [x4, #SDEI_EVENT_PRIORITY]
1075         cbnz    w3, 1f
1076         adr_this_cpu dst=x5, sym=sdei_active_normal_event, tmp=x6
1077         b       2f
1078 1:      adr_this_cpu dst=x5, sym=sdei_active_critical_event, tmp=x6
1079 2:      str     xzr, [x5]
1080
1081 alternative_if_not ARM64_UNMAP_KERNEL_AT_EL0
1082         sdei_handler_exit exit_mode=x2
1083 alternative_else_nop_endif
1084
1085 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
1086         tramp_alias     dst=x5, sym=__sdei_asm_exit_trampoline, tmp=x3
1087         br      x5
1088 #endif
1089 SYM_CODE_END(__sdei_asm_handler)
1090 NOKPROBE(__sdei_asm_handler)
1091
1092 SYM_CODE_START(__sdei_handler_abort)
1093         mov_q   x0, SDEI_1_0_FN_SDEI_EVENT_COMPLETE_AND_RESUME
1094         adr     x1, 1f
1095         ldr_l   x2, sdei_exit_mode
1096         sdei_handler_exit exit_mode=x2
1097         // exit the handler and jump to the next instruction.
1098         // Exit will stomp x0-x17, PSTATE, ELR_ELx, and SPSR_ELx.
1099 1:      ret
1100 SYM_CODE_END(__sdei_handler_abort)
1101 NOKPROBE(__sdei_handler_abort)
1102 #endif /* CONFIG_ARM_SDE_INTERFACE */