arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/memory.h>
  31 #include <asm/thread_info.h>
  32 #include <asm/asm-uaccess.h>
  33 #include <asm/unistd.h>
  34
  35 /*
  36  * Context tracking subsystem.  Used to instrument transitions
  37  * between user and kernel mode.
  38  */
  39         .macro ct_user_exit, syscall = 0
  40 #ifdef CONFIG_CONTEXT_TRACKING
  41         bl      context_tracking_user_exit
  42         .if \syscall == 1
  43         /*
  44          * Save/restore needed during syscalls.  Restore syscall arguments from
  45          * the values already saved on stack during kernel_entry.
  46          */
  47         ldp     x0, x1, [sp]
  48         ldp     x2, x3, [sp, #S_X2]
  49         ldp     x4, x5, [sp, #S_X4]
  50         ldp     x6, x7, [sp, #S_X6]
  51         .endif
  52 #endif
  53         .endm
  54
  55         .macro ct_user_enter
  56 #ifdef CONFIG_CONTEXT_TRACKING
  57         bl      context_tracking_user_enter
  58 #endif
  59         .endm
  60
  61 /*
  62  * Bad Abort numbers
  63  *-----------------
  64  */
  65 #define BAD_SYNC        0
  66 #define BAD_IRQ         1
  67 #define BAD_FIQ         2
  68 #define BAD_ERROR       3
  69
  70         .macro  kernel_entry, el, regsize = 64
  71         sub     sp, sp, #S_FRAME_SIZE
  72         .if     \regsize == 32
  73         mov     w0, w0                          // zero upper 32 bits of x0
  74         .endif
  75         stp     x0, x1, [sp, #16 * 0]
  76         stp     x2, x3, [sp, #16 * 1]
  77         stp     x4, x5, [sp, #16 * 2]
  78         stp     x6, x7, [sp, #16 * 3]
  79         stp     x8, x9, [sp, #16 * 4]
  80         stp     x10, x11, [sp, #16 * 5]
  81         stp     x12, x13, [sp, #16 * 6]
  82         stp     x14, x15, [sp, #16 * 7]
  83         stp     x16, x17, [sp, #16 * 8]
  84         stp     x18, x19, [sp, #16 * 9]
  85         stp     x20, x21, [sp, #16 * 10]
  86         stp     x22, x23, [sp, #16 * 11]
  87         stp     x24, x25, [sp, #16 * 12]
  88         stp     x26, x27, [sp, #16 * 13]
  89         stp     x28, x29, [sp, #16 * 14]
  90
  91         .if     \el == 0
  92         mrs     x21, sp_el0
  93         get_thread_info tsk                     // Ensure MDSCR_EL1.SS is clear,
  94         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
  95         disable_step_tsk x19, x20               // exceptions when scheduling.
  96         .else
  97         add     x21, sp, #S_FRAME_SIZE
  98         get_thread_info tsk
  99         /* Save the task's original addr_limit and set USER_DS (TASK_SIZE_64) */
 100         ldr     x20, [tsk, #TI_ADDR_LIMIT]
 101         str     x20, [sp, #S_ORIG_ADDR_LIMIT]
 102         mov     x20, #TASK_SIZE_64
 103         str     x20, [tsk, #TI_ADDR_LIMIT]
 104         .endif /* \el == 0 */
 105         mrs     x22, elr_el1
 106         mrs     x23, spsr_el1
 107         stp     lr, x21, [sp, #S_LR]
 108         stp     x22, x23, [sp, #S_PC]
 109
 110         /*
 111          * Set syscallno to -1 by default (overridden later if real syscall).
 112          */
 113         .if     \el == 0
 114         mvn     x21, xzr
 115         str     x21, [sp, #S_SYSCALLNO]
 116         .endif
 117
 118         /*
 119          * Registers that may be useful after this macro is invoked:
 120          *
 121          * x21 - aborted SP
 122          * x22 - aborted PC
 123          * x23 - aborted PSTATE
 124         */
 125         .endm
 126
 127         .macro  kernel_exit, el
 128         .if     \el != 0
 129         /* Restore the task's original addr_limit. */
 130         ldr     x20, [sp, #S_ORIG_ADDR_LIMIT]
 131         str     x20, [tsk, #TI_ADDR_LIMIT]
 132         .endif
 133
 134         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 135         .if     \el == 0
 136         ct_user_enter
 137         ldr     x23, [sp, #S_SP]                // load return stack pointer
 138         msr     sp_el0, x23
 139 #ifdef CONFIG_ARM64_ERRATUM_845719
 140 alternative_if_not ARM64_WORKAROUND_845719
 141         nop
 142         nop
 143 #ifdef CONFIG_PID_IN_CONTEXTIDR
 144         nop
 145 #endif
 146 alternative_else
 147         tbz     x22, #4, 1f
 148 #ifdef CONFIG_PID_IN_CONTEXTIDR
 149         mrs     x29, contextidr_el1
 150         msr     contextidr_el1, x29
 151 #else
 152         msr contextidr_el1, xzr
 153 #endif
 154 1:
 155 alternative_endif
 156 #endif
 157         .endif
 158         msr     elr_el1, x21                    // set up the return data
 159         msr     spsr_el1, x22
 160         ldp     x0, x1, [sp, #16 * 0]
 161         ldp     x2, x3, [sp, #16 * 1]
 162         ldp     x4, x5, [sp, #16 * 2]
 163         ldp     x6, x7, [sp, #16 * 3]
 164         ldp     x8, x9, [sp, #16 * 4]
 165         ldp     x10, x11, [sp, #16 * 5]
 166         ldp     x12, x13, [sp, #16 * 6]
 167         ldp     x14, x15, [sp, #16 * 7]
 168         ldp     x16, x17, [sp, #16 * 8]
 169         ldp     x18, x19, [sp, #16 * 9]
 170         ldp     x20, x21, [sp, #16 * 10]
 171         ldp     x22, x23, [sp, #16 * 11]
 172         ldp     x24, x25, [sp, #16 * 12]
 173         ldp     x26, x27, [sp, #16 * 13]
 174         ldp     x28, x29, [sp, #16 * 14]
 175         ldr     lr, [sp, #S_LR]
 176         add     sp, sp, #S_FRAME_SIZE           // restore sp
 177         eret                                    // return to kernel
 178         .endm
 179
 180         .macro  get_thread_info, rd
 181         mov     \rd, sp
 182         and     \rd, \rd, #~(THREAD_SIZE - 1)   // top of stack
 183         .endm
 184
 185 /*
 186  * These are the registers used in the syscall handler, and allow us to
 187  * have in theory up to 7 arguments to a function - x0 to x6.
 188  *
 189  * x7 is reserved for the system call number in 32-bit mode.
 190  */
 191 sc_nr   .req    x25             // number of system calls
 192 scno    .req    x26             // syscall number
 193 stbl    .req    x27             // syscall table pointer
 194 tsk     .req    x28             // current thread_info
 195
 196 /*
 197  * Interrupt handling.
 198  */
 199         .macro  irq_handler
 200         adrp    x1, handle_arch_irq
 201         ldr     x1, [x1, #:lo12:handle_arch_irq]
 202         mov     x0, sp
 203         blr     x1
 204         .endm
 205
 206         .text
 207
 208 /*
 209  * Exception vectors.
 210  */
 211
 212         .align  11
 213 ENTRY(vectors)
 214         ventry  el1_sync_invalid                // Synchronous EL1t
 215         ventry  el1_irq_invalid                 // IRQ EL1t
 216         ventry  el1_fiq_invalid                 // FIQ EL1t
 217         ventry  el1_error_invalid               // Error EL1t
 218
 219         ventry  el1_sync                        // Synchronous EL1h
 220         ventry  el1_irq                         // IRQ EL1h
 221         ventry  el1_fiq_invalid                 // FIQ EL1h
 222         ventry  el1_error_invalid               // Error EL1h
 223
 224         ventry  el0_sync                        // Synchronous 64-bit EL0
 225         ventry  el0_irq                         // IRQ 64-bit EL0
 226         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 227         ventry  el0_error_invalid               // Error 64-bit EL0
 228
 229 #ifdef CONFIG_COMPAT
 230         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 231         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 232         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 233         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 234 #else
 235         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 236         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 237         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 238         ventry  el0_error_invalid               // Error 32-bit EL0
 239 #endif
 240 END(vectors)
 241
 242 /*
 243  * Invalid mode handlers
 244  */
 245         .macro  inv_entry, el, reason, regsize = 64
 246         kernel_entry \el, \regsize
 247         mov     x0, sp
 248         mov     x1, #\reason
 249         mrs     x2, esr_el1
 250         b       bad_mode
 251         .endm
 252
 253 el0_sync_invalid:
 254         inv_entry 0, BAD_SYNC
 255 ENDPROC(el0_sync_invalid)
 256
 257 el0_irq_invalid:
 258         inv_entry 0, BAD_IRQ
 259 ENDPROC(el0_irq_invalid)
 260
 261 el0_fiq_invalid:
 262         inv_entry 0, BAD_FIQ
 263 ENDPROC(el0_fiq_invalid)
 264
 265 el0_error_invalid:
 266         inv_entry 0, BAD_ERROR
 267 ENDPROC(el0_error_invalid)
 268
 269 #ifdef CONFIG_COMPAT
 270 el0_fiq_invalid_compat:
 271         inv_entry 0, BAD_FIQ, 32
 272 ENDPROC(el0_fiq_invalid_compat)
 273
 274 el0_error_invalid_compat:
 275         inv_entry 0, BAD_ERROR, 32
 276 ENDPROC(el0_error_invalid_compat)
 277 #endif
 278
 279 el1_sync_invalid:
 280         inv_entry 1, BAD_SYNC
 281 ENDPROC(el1_sync_invalid)
 282
 283 el1_irq_invalid:
 284         inv_entry 1, BAD_IRQ
 285 ENDPROC(el1_irq_invalid)
 286
 287 el1_fiq_invalid:
 288         inv_entry 1, BAD_FIQ
 289 ENDPROC(el1_fiq_invalid)
 290
 291 el1_error_invalid:
 292         inv_entry 1, BAD_ERROR
 293 ENDPROC(el1_error_invalid)
 294
 295 /*
 296  * EL1 mode handlers.
 297  */
 298         .align  6
 299 el1_sync:
 300         kernel_entry 1
 301         mrs     x1, esr_el1                     // read the syndrome register
 302         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 303         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 304         b.eq    el1_da
 305         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 306         b.eq    el1_undef
 307         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 308         b.eq    el1_sp_pc
 309         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 310         b.eq    el1_sp_pc
 311         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 312         b.eq    el1_undef
 313         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 314         b.ge    el1_dbg
 315         b       el1_inv
 316 el1_da:
 317         /*
 318          * Data abort handling
 319          */
 320         mrs     x3, far_el1
 321         enable_dbg
 322         // re-enable interrupts if they were enabled in the aborted context
 323         tbnz    x23, #7, 1f                     // PSR_I_BIT
 324         enable_irq
 325 1:
 326         clear_address_tag x0, x3
 327         mov     x2, sp                          // struct pt_regs
 328         bl      do_mem_abort
 329
 330         // disable interrupts before pulling preserved data off the stack
 331         disable_irq
 332         kernel_exit 1
 333 el1_sp_pc:
 334         /*
 335          * Stack or PC alignment exception handling
 336          */
 337         mrs     x0, far_el1
 338         enable_dbg
 339         mov     x2, sp
 340         b       do_sp_pc_abort
 341 el1_undef:
 342         /*
 343          * Undefined instruction
 344          */
 345         enable_dbg
 346         mov     x0, sp
 347         b       do_undefinstr
 348 el1_dbg:
 349         /*
 350          * Debug exception handling
 351          */
 352         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 353         cinc    x24, x24, eq                    // set bit '0'
 354         tbz     x24, #0, el1_inv                // EL1 only
 355         mrs     x0, far_el1
 356         mov     x2, sp                          // struct pt_regs
 357         bl      do_debug_exception
 358         kernel_exit 1
 359 el1_inv:
 360         // TODO: add support for undefined instructions in kernel mode
 361         enable_dbg
 362         mov     x0, sp
 363         mov     x2, x1
 364         mov     x1, #BAD_SYNC
 365         b       bad_mode
 366 ENDPROC(el1_sync)
 367
 368         .align  6
 369 el1_irq:
 370         kernel_entry 1
 371         enable_dbg
 372 #ifdef CONFIG_TRACE_IRQFLAGS
 373         bl      trace_hardirqs_off
 374 #endif
 375
 376         irq_handler
 377
 378 #ifdef CONFIG_PREEMPT
 379         get_thread_info tsk
 380         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 381         cbnz    w24, 1f                         // preempt count != 0
 382         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 383         tbz     x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 384         bl      el1_preempt
 385 1:
 386 #endif
 387 #ifdef CONFIG_TRACE_IRQFLAGS
 388         bl      trace_hardirqs_on
 389 #endif
 390         kernel_exit 1
 391 ENDPROC(el1_irq)
 392
 393 #ifdef CONFIG_PREEMPT
 394 el1_preempt:
 395         mov     x24, lr
 396 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 397         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 398         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 399         ret     x24
 400 #endif
 401
 402 /*
 403  * EL0 mode handlers.
 404  */
 405         .align  6
 406 el0_sync:
 407         kernel_entry 0
 408         mrs     x25, esr_el1                    // read the syndrome register
 409         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 410         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 411         b.eq    el0_svc
 412         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 413         b.eq    el0_da
 414         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 415         b.eq    el0_ia
 416         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 417         b.eq    el0_fpsimd_acc
 418         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 419         b.eq    el0_fpsimd_exc
 420         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 421         b.eq    el0_undef
 422         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 423         b.eq    el0_sp_pc
 424         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 425         b.eq    el0_sp_pc
 426         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 427         b.eq    el0_undef
 428         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 429         b.ge    el0_dbg
 430         b       el0_inv
 431
 432 #ifdef CONFIG_COMPAT
 433         .align  6
 434 el0_sync_compat:
 435         kernel_entry 0, 32
 436         mrs     x25, esr_el1                    // read the syndrome register
 437         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 438         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 439         b.eq    el0_svc_compat
 440         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 441         b.eq    el0_da
 442         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 443         b.eq    el0_ia
 444         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 445         b.eq    el0_fpsimd_acc
 446         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 447         b.eq    el0_fpsimd_exc
 448         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 449         b.eq    el0_sp_pc
 450         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 451         b.eq    el0_undef
 452         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 453         b.eq    el0_undef
 454         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 455         b.eq    el0_undef
 456         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 457         b.eq    el0_undef
 458         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 459         b.eq    el0_undef
 460         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 461         b.eq    el0_undef
 462         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 463         b.ge    el0_dbg
 464         b       el0_inv
 465 el0_svc_compat:
 466         /*
 467          * AArch32 syscall handling
 468          */
 469         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 470         uxtw    scno, w7                        // syscall number in w7 (r7)
 471         mov     sc_nr, #__NR_compat_syscalls
 472         b       el0_svc_naked
 473
 474         .align  6
 475 el0_irq_compat:
 476         kernel_entry 0, 32
 477         b       el0_irq_naked
 478 #endif
 479
 480 el0_da:
 481         /*
 482          * Data abort handling
 483          */
 484         mrs     x26, far_el1
 485         // enable interrupts before calling the main handler
 486         enable_dbg_and_irq
 487         ct_user_exit
 488         clear_address_tag x0, x26
 489         mov     x1, x25
 490         mov     x2, sp
 491         bl      do_mem_abort
 492         b       ret_to_user
 493 el0_ia:
 494         /*
 495          * Instruction abort handling
 496          */
 497         mrs     x26, far_el1
 498         // enable interrupts before calling the main handler
 499         enable_dbg_and_irq
 500         ct_user_exit
 501         mov     x0, x26
 502         orr     x1, x25, #1 << 24               // use reserved ISS bit for instruction aborts
 503         mov     x2, sp
 504         bl      do_mem_abort
 505         b       ret_to_user
 506 el0_fpsimd_acc:
 507         /*
 508          * Floating Point or Advanced SIMD access
 509          */
 510         enable_dbg
 511         ct_user_exit
 512         mov     x0, x25
 513         mov     x1, sp
 514         bl      do_fpsimd_acc
 515         b       ret_to_user
 516 el0_fpsimd_exc:
 517         /*
 518          * Floating Point or Advanced SIMD exception
 519          */
 520         enable_dbg
 521         ct_user_exit
 522         mov     x0, x25
 523         mov     x1, sp
 524         bl      do_fpsimd_exc
 525         b       ret_to_user
 526 el0_sp_pc:
 527         /*
 528          * Stack or PC alignment exception handling
 529          */
 530         mrs     x26, far_el1
 531         // enable interrupts before calling the main handler
 532         enable_dbg_and_irq
 533         ct_user_exit
 534         mov     x0, x26
 535         mov     x1, x25
 536         mov     x2, sp
 537         bl      do_sp_pc_abort
 538         b       ret_to_user
 539 el0_undef:
 540         /*
 541          * Undefined instruction
 542          */
 543         // enable interrupts before calling the main handler
 544         enable_dbg_and_irq
 545         ct_user_exit
 546         mov     x0, sp
 547         bl      do_undefinstr
 548         b       ret_to_user
 549 el0_dbg:
 550         /*
 551          * Debug exception handling
 552          */
 553         tbnz    x24, #0, el0_inv                // EL0 only
 554         mrs     x0, far_el1
 555         mov     x1, x25
 556         mov     x2, sp
 557         bl      do_debug_exception
 558         enable_dbg
 559         ct_user_exit
 560         b       ret_to_user
 561 el0_inv:
 562         enable_dbg
 563         ct_user_exit
 564         mov     x0, sp
 565         mov     x1, #BAD_SYNC
 566         mov     x2, x25
 567         bl      bad_el0_sync
 568         b       ret_to_user
 569 ENDPROC(el0_sync)
 570
 571         .align  6
 572 el0_irq:
 573         kernel_entry 0
 574 el0_irq_naked:
 575         enable_dbg
 576 #ifdef CONFIG_TRACE_IRQFLAGS
 577         bl      trace_hardirqs_off
 578 #endif
 579
 580         ct_user_exit
 581         irq_handler
 582
 583 #ifdef CONFIG_TRACE_IRQFLAGS
 584         bl      trace_hardirqs_on
 585 #endif
 586         b       ret_to_user
 587 ENDPROC(el0_irq)
 588
 589 /*
 590  * Register switch for AArch64. The callee-saved registers need to be saved
 591  * and restored. On entry:
 592  *   x0 = previous task_struct (must be preserved across the switch)
 593  *   x1 = next task_struct
 594  * Previous and next are guaranteed not to be the same.
 595  *
 596  */
 597 ENTRY(cpu_switch_to)
 598         mov     x10, #THREAD_CPU_CONTEXT
 599         add     x8, x0, x10
 600         mov     x9, sp
 601         stp     x19, x20, [x8], #16             // store callee-saved registers
 602         stp     x21, x22, [x8], #16
 603         stp     x23, x24, [x8], #16
 604         stp     x25, x26, [x8], #16
 605         stp     x27, x28, [x8], #16
 606         stp     x29, x9, [x8], #16
 607         str     lr, [x8]
 608         add     x8, x1, x10
 609         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 610         ldp     x21, x22, [x8], #16
 611         ldp     x23, x24, [x8], #16
 612         ldp     x25, x26, [x8], #16
 613         ldp     x27, x28, [x8], #16
 614         ldp     x29, x9, [x8], #16
 615         ldr     lr, [x8]
 616         mov     sp, x9
 617         ret
 618 ENDPROC(cpu_switch_to)
 619
 620 /*
 621  * This is the fast syscall return path.  We do as little as possible here,
 622  * and this includes saving x0 back into the kernel stack.
 623  */
 624 ret_fast_syscall:
 625         disable_irq                             // disable interrupts
 626         str     x0, [sp, #S_X0]                 // returned x0
 627         ldr     x1, [tsk, #TI_FLAGS]            // re-check for syscall tracing
 628         and     x2, x1, #_TIF_SYSCALL_WORK
 629         cbnz    x2, ret_fast_syscall_trace
 630         and     x2, x1, #_TIF_WORK_MASK
 631         cbnz    x2, work_pending
 632         enable_step_tsk x1, x2
 633         kernel_exit 0
 634 ret_fast_syscall_trace:
 635         enable_irq                              // enable interrupts
 636         b       __sys_trace_return_skipped      // we already saved x0
 637
 638 /*
 639  * Ok, we need to do extra processing, enter the slow path.
 640  */
 641 work_pending:
 642         tbnz    x1, #TIF_NEED_RESCHED, work_resched
 643         /* TIF_SIGPENDING, TIF_NOTIFY_RESUME or TIF_FOREIGN_FPSTATE case */
 644         ldr     x2, [sp, #S_PSTATE]
 645         mov     x0, sp                          // 'regs'
 646         tst     x2, #PSR_MODE_MASK              // user mode regs?
 647         b.ne    no_work_pending                 // returning to kernel
 648         enable_irq                              // enable interrupts for do_notify_resume()
 649         bl      do_notify_resume
 650         b       ret_to_user
 651 work_resched:
 652 #ifdef CONFIG_TRACE_IRQFLAGS
 653         bl      trace_hardirqs_off              // the IRQs are off here, inform the tracing code
 654 #endif
 655         bl      schedule
 656
 657 /*
 658  * "slow" syscall return path.
 659  */
 660 ret_to_user:
 661         disable_irq                             // disable interrupts
 662         ldr     x1, [tsk, #TI_FLAGS]
 663         and     x2, x1, #_TIF_WORK_MASK
 664         cbnz    x2, work_pending
 665         enable_step_tsk x1, x2
 666 no_work_pending:
 667         kernel_exit 0
 668 ENDPROC(ret_to_user)
 669
 670 /*
 671  * This is how we return from a fork.
 672  */
 673 ENTRY(ret_from_fork)
 674         bl      schedule_tail
 675         cbz     x19, 1f                         // not a kernel thread
 676         mov     x0, x20
 677         blr     x19
 678 1:      get_thread_info tsk
 679         b       ret_to_user
 680 ENDPROC(ret_from_fork)
 681
 682 /*
 683  * SVC handler.
 684  */
 685         .align  6
 686 el0_svc:
 687         adrp    stbl, sys_call_table            // load syscall table pointer
 688         uxtw    scno, w8                        // syscall number in w8
 689         mov     sc_nr, #__NR_syscalls
 690 el0_svc_naked:                                  // compat entry point
 691         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 692         enable_dbg_and_irq
 693         ct_user_exit 1
 694
 695         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 696         tst     x16, #_TIF_SYSCALL_WORK
 697         b.ne    __sys_trace
 698         cmp     scno, sc_nr                     // check upper syscall limit
 699         b.hs    ni_sys
 700         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 701         blr     x16                             // call sys_* routine
 702         b       ret_fast_syscall
 703 ni_sys:
 704         mov     x0, sp
 705         bl      do_ni_syscall
 706         b       ret_fast_syscall
 707 ENDPROC(el0_svc)
 708
 709         /*
 710          * This is the really slow path.  We're going to be doing context
 711          * switches, and waiting for our parent to respond.
 712          */
 713 __sys_trace:
 714         mov     w0, #-1                         // set default errno for
 715         cmp     scno, x0                        // user-issued syscall(-1)
 716         b.ne    1f
 717         mov     x0, #-ENOSYS
 718         str     x0, [sp, #S_X0]
 719 1:      mov     x0, sp
 720         bl      syscall_trace_enter
 721         cmp     w0, #-1                         // skip the syscall?
 722         b.eq    __sys_trace_return_skipped
 723         uxtw    scno, w0                        // syscall number (possibly new)
 724         mov     x1, sp                          // pointer to regs
 725         cmp     scno, sc_nr                     // check upper syscall limit
 726         b.hs    __ni_sys_trace
 727         ldp     x0, x1, [sp]                    // restore the syscall args
 728         ldp     x2, x3, [sp, #S_X2]
 729         ldp     x4, x5, [sp, #S_X4]
 730         ldp     x6, x7, [sp, #S_X6]
 731         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 732         blr     x16                             // call sys_* routine
 733
 734 __sys_trace_return:
 735         str     x0, [sp, #S_X0]                 // save returned x0
 736 __sys_trace_return_skipped:
 737         mov     x0, sp
 738         bl      syscall_trace_exit
 739         b       ret_to_user
 740
 741 __ni_sys_trace:
 742         mov     x0, sp
 743         bl      do_ni_syscall
 744         b       __sys_trace_return
 745
 746 /*
 747  * Special system call wrappers.
 748  */
 749 ENTRY(sys_rt_sigreturn_wrapper)
 750         mov     x0, sp
 751         b       sys_rt_sigreturn
 752 ENDPROC(sys_rt_sigreturn_wrapper)