arch/arm64/kernel/entry-ftrace.S

   1 /*
   2  * arch/arm64/kernel/entry-ftrace.S
   3  *
   4  * Copyright (C) 2013 Linaro Limited
   5  * Author: AKASHI Takahiro <takahiro.akashi@linaro.org>
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  */
  11
  12 #include <linux/linkage.h>
  13 #include <asm/assembler.h>
  14 #include <asm/ftrace.h>
  15 #include <asm/insn.h>
  16
  17 /*
  18  * Gcc with -pg will put the following code in the beginning of each function:
  19  *      mov x0, x30
  20  *      bl _mcount
  21  *      [function's body ...]
  22  * "bl _mcount" may be replaced to "bl ftrace_caller" or NOP if dynamic
  23  * ftrace is enabled.
  24  *
  25  * Please note that x0 as an argument will not be used here because we can
  26  * get lr(x30) of instrumented function at any time by winding up call stack
  27  * as long as the kernel is compiled without -fomit-frame-pointer.
  28  * (or CONFIG_FRAME_POINTER, this is forced on arm64)
  29  *
  30  * stack layout after mcount_enter in _mcount():
  31  *
  32  * current sp/fp =>  0:+-----+
  33  * in _mcount()        | x29 | -> instrumented function's fp
  34  *                     +-----+
  35  *                     | x30 | -> _mcount()'s lr (= instrumented function's pc)
  36  * old sp       => +16:+-----+
  37  * when instrumented   |     |
  38  * function calls      | ... |
  39  * _mcount()           |     |
  40  *                     |     |
  41  * instrumented => +xx:+-----+
  42  * function's fp       | x29 | -> parent's fp
  43  *                     +-----+
  44  *                     | x30 | -> instrumented function's lr (= parent's pc)
  45  *                     +-----+
  46  *                     | ... |
  47  */
  48
  49         .macro mcount_enter
  50         stp     x29, x30, [sp, #-16]!
  51         mov     x29, sp
  52         .endm
  53
  54         .macro mcount_exit
  55         ldp     x29, x30, [sp], #16
  56         ret
  57         .endm
  58
  59         .macro mcount_adjust_addr rd, rn
  60         sub     \rd, \rn, #AARCH64_INSN_SIZE
  61         .endm
  62
  63         /* for instrumented function's parent */
  64         .macro mcount_get_parent_fp reg
  65         ldr     \reg, [x29]
  66         ldr     \reg, [\reg]
  67         .endm
  68
  69         /* for instrumented function */
  70         .macro mcount_get_pc0 reg
  71         mcount_adjust_addr      \reg, x30
  72         .endm
  73
  74         .macro mcount_get_pc reg
  75         ldr     \reg, [x29, #8]
  76         mcount_adjust_addr      \reg, \reg
  77         .endm
  78
  79         .macro mcount_get_lr reg
  80         ldr     \reg, [x29]
  81         ldr     \reg, [\reg, #8]
  82         .endm
  83
  84         .macro mcount_get_lr_addr reg
  85         ldr     \reg, [x29]
  86         add     \reg, \reg, #8
  87         .endm
  88
  89 #ifndef CONFIG_DYNAMIC_FTRACE
  90 /*
  91  * void _mcount(unsigned long return_address)
  92  * @return_address: return address to instrumented function
  93  *
  94  * This function makes calls, if enabled, to:
  95  *     - tracer function to probe instrumented function's entry,
  96  *     - ftrace_graph_caller to set up an exit hook
  97  */
  98 ENTRY(_mcount)
  99         mcount_enter
 100
 101         ldr_l   x2, ftrace_trace_function
 102         adr     x0, ftrace_stub
 103         cmp     x0, x2                  // if (ftrace_trace_function
 104         b.eq    skip_ftrace_call        //     != ftrace_stub) {
 105
 106         mcount_get_pc   x0              //       function's pc
 107         mcount_get_lr   x1              //       function's lr (= parent's pc)
 108         blr     x2                      //   (*ftrace_trace_function)(pc, lr);
 109
 110 skip_ftrace_call:                       // }
 111 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 112         ldr_l   x2, ftrace_graph_return
 113         cmp     x0, x2                  //   if ((ftrace_graph_return
 114         b.ne    ftrace_graph_caller     //        != ftrace_stub)
 115
 116         ldr_l   x2, ftrace_graph_entry  //     || (ftrace_graph_entry
 117         adr_l   x0, ftrace_graph_entry_stub //     != ftrace_graph_entry_stub))
 118         cmp     x0, x2
 119         b.ne    ftrace_graph_caller     //     ftrace_graph_caller();
 120 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
 121         mcount_exit
 122 ENDPROC(_mcount)
 123
 124 #else /* CONFIG_DYNAMIC_FTRACE */
 125 /*
 126  * _mcount() is used to build the kernel with -pg option, but all the branch
 127  * instructions to _mcount() are replaced to NOP initially at kernel start up,
 128  * and later on, NOP to branch to ftrace_caller() when enabled or branch to
 129  * NOP when disabled per-function base.
 130  */
 131 ENTRY(_mcount)
 132         ret
 133 ENDPROC(_mcount)
 134
 135 /*
 136  * void ftrace_caller(unsigned long return_address)
 137  * @return_address: return address to instrumented function
 138  *
 139  * This function is a counterpart of _mcount() in 'static' ftrace, and
 140  * makes calls to:
 141  *     - tracer function to probe instrumented function's entry,
 142  *     - ftrace_graph_caller to set up an exit hook
 143  */
 144 ENTRY(ftrace_caller)
 145         mcount_enter
 146
 147         mcount_get_pc0  x0              //     function's pc
 148         mcount_get_lr   x1              //     function's lr
 149
 150         .global ftrace_call
 151 ftrace_call:                            // tracer(pc, lr);
 152         nop                             // This will be replaced with "bl xxx"
 153                                         // where xxx can be any kind of tracer.
 154
 155 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 156         .global ftrace_graph_call
 157 ftrace_graph_call:                      // ftrace_graph_caller();
 158         nop                             // If enabled, this will be replaced
 159                                         // "b ftrace_graph_caller"
 160 #endif
 161
 162         mcount_exit
 163 ENDPROC(ftrace_caller)
 164 #endif /* CONFIG_DYNAMIC_FTRACE */
 165
 166 ENTRY(ftrace_stub)
 167         ret
 168 ENDPROC(ftrace_stub)
 169
 170 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 171         /* save return value regs*/
 172         .macro save_return_regs
 173         sub sp, sp, #64
 174         stp x0, x1, [sp]
 175         stp x2, x3, [sp, #16]
 176         stp x4, x5, [sp, #32]
 177         stp x6, x7, [sp, #48]
 178         .endm
 179
 180         /* restore return value regs*/
 181         .macro restore_return_regs
 182         ldp x0, x1, [sp]
 183         ldp x2, x3, [sp, #16]
 184         ldp x4, x5, [sp, #32]
 185         ldp x6, x7, [sp, #48]
 186         add sp, sp, #64
 187         .endm
 188
 189 /*
 190  * void ftrace_graph_caller(void)
 191  *
 192  * Called from _mcount() or ftrace_caller() when function_graph tracer is
 193  * selected.
 194  * This function w/ prepare_ftrace_return() fakes link register's value on
 195  * the call stack in order to intercept instrumented function's return path
 196  * and run return_to_handler() later on its exit.
 197  */
 198 ENTRY(ftrace_graph_caller)
 199         mcount_get_lr_addr        x0    //     pointer to function's saved lr
 200         mcount_get_pc             x1    //     function's pc
 201         mcount_get_parent_fp      x2    //     parent's fp
 202         bl      prepare_ftrace_return   // prepare_ftrace_return(&lr, pc, fp)
 203
 204         mcount_exit
 205 ENDPROC(ftrace_graph_caller)
 206
 207 /*
 208  * void return_to_handler(void)
 209  *
 210  * Run ftrace_return_to_handler() before going back to parent.
 211  * @fp is checked against the value passed by ftrace_graph_caller()
 212  * only when HAVE_FUNCTION_GRAPH_FP_TEST is enabled.
 213  */
 214 ENTRY(return_to_handler)
 215         save_return_regs
 216         mov     x0, x29                 //     parent's fp
 217         bl      ftrace_return_to_handler// addr = ftrace_return_to_hander(fp);
 218         mov     x30, x0                 // restore the original return address
 219         restore_return_regs
 220         ret
 221 END(return_to_handler)
 222 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */