arch/arm/vfp/vfphw.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  *  linux/arch/arm/vfp/vfphw.S
   4  *
   5  *  Copyright (C) 2004 ARM Limited.
   6  *  Written by Deep Blue Solutions Limited.
   7  *
   8  * This code is called from the kernel's undefined instruction trap.
   9  * r9 holds the return address for successful handling.
  10  * lr holds the return address for unrecognised instructions.
  11  * r10 points at the start of the private FP workspace in the thread structure
  12  * sp points to a struct pt_regs (as defined in include/asm/proc/ptrace.h)
  13  */
  14 #include <linux/init.h>
  15 #include <linux/linkage.h>
  16 #include <asm/thread_info.h>
  17 #include <asm/vfpmacros.h>
  18 #include <linux/kern_levels.h>
  19 #include <asm/assembler.h>
  20 #include <asm/asm-offsets.h>
  21
  22         .macro  DBGSTR, str
  23 #ifdef DEBUG
  24         stmfd   sp!, {r0-r3, ip, lr}
  25         ldr     r0, =1f
  26         bl      printk
  27         ldmfd   sp!, {r0-r3, ip, lr}
  28
  29         .pushsection .rodata, "a"
  30 1:      .ascii  KERN_DEBUG "VFP: \str\n"
  31         .byte   0
  32         .previous
  33 #endif
  34         .endm
  35
  36         .macro  DBGSTR1, str, arg
  37 #ifdef DEBUG
  38         stmfd   sp!, {r0-r3, ip, lr}
  39         mov     r1, \arg
  40         ldr     r0, =1f
  41         bl      printk
  42         ldmfd   sp!, {r0-r3, ip, lr}
  43
  44         .pushsection .rodata, "a"
  45 1:      .ascii  KERN_DEBUG "VFP: \str\n"
  46         .byte   0
  47         .previous
  48 #endif
  49         .endm
  50
  51         .macro  DBGSTR3, str, arg1, arg2, arg3
  52 #ifdef DEBUG
  53         stmfd   sp!, {r0-r3, ip, lr}
  54         mov     r3, \arg3
  55         mov     r2, \arg2
  56         mov     r1, \arg1
  57         ldr     r0, =1f
  58         bl      printk
  59         ldmfd   sp!, {r0-r3, ip, lr}
  60
  61         .pushsection .rodata, "a"
  62 1:      .ascii  KERN_DEBUG "VFP: \str\n"
  63         .byte   0
  64         .previous
  65 #endif
  66         .endm
  67
  68
  69 @ VFP hardware support entry point.
  70 @
  71 @  r0  = instruction opcode (32-bit ARM or two 16-bit Thumb)
  72 @  r2  = PC value to resume execution after successful emulation
  73 @  r9  = normal "successful" return address
  74 @  r10 = vfp_state union
  75 @  r11 = CPU number
  76 @  lr  = unrecognised instruction return address
  77 @  IRQs enabled.
  78 ENTRY(vfp_support_entry)
  79         DBGSTR3 "instr %08x pc %08x state %p", r0, r2, r10
  80
  81         VFPFMRX r1, FPEXC               @ Is the VFP enabled?
  82         DBGSTR1 "fpexc %08x", r1
  83         tst     r1, #FPEXC_EN
  84         bne     look_for_VFP_exceptions @ VFP is already enabled
  85
  86         DBGSTR1 "enable %x", r10
  87         ldr     r3, vfp_current_hw_state_address
  88         orr     r1, r1, #FPEXC_EN       @ user FPEXC has the enable bit set
  89         ldr     r4, [r3, r11, lsl #2]   @ vfp_current_hw_state pointer
  90         bic     r5, r1, #FPEXC_EX       @ make sure exceptions are disabled
  91         cmp     r4, r10                 @ this thread owns the hw context?
  92 #ifndef CONFIG_SMP
  93         @ For UP, checking that this thread owns the hw context is
  94         @ sufficient to determine that the hardware state is valid.
  95         beq     vfp_hw_state_valid
  96
  97         @ On UP, we lazily save the VFP context.  As a different
  98         @ thread wants ownership of the VFP hardware, save the old
  99         @ state if there was a previous (valid) owner.
 100
 101         VFPFMXR FPEXC, r5               @ enable VFP, disable any pending
 102                                         @ exceptions, so we can get at the
 103                                         @ rest of it
 104
 105         DBGSTR1 "save old state %p", r4
 106         cmp     r4, #0                  @ if the vfp_current_hw_state is NULL
 107         beq     vfp_reload_hw           @ then the hw state needs reloading
 108         VFPFSTMIA r4, r5                @ save the working registers
 109         VFPFMRX r5, FPSCR               @ current status
 110 #ifndef CONFIG_CPU_FEROCEON
 111         tst     r1, #FPEXC_EX           @ is there additional state to save?
 112         beq     1f
 113         VFPFMRX r6, FPINST              @ FPINST (only if FPEXC.EX is set)
 114         tst     r1, #FPEXC_FP2V         @ is there an FPINST2 to read?
 115         beq     1f
 116         VFPFMRX r8, FPINST2             @ FPINST2 if needed (and present)
 117 1:
 118 #endif
 119         stmia   r4, {r1, r5, r6, r8}    @ save FPEXC, FPSCR, FPINST, FPINST2
 120 vfp_reload_hw:
 121
 122 #else
 123         @ For SMP, if this thread does not own the hw context, then we
 124         @ need to reload it.  No need to save the old state as on SMP,
 125         @ we always save the state when we switch away from a thread.
 126         bne     vfp_reload_hw
 127
 128         @ This thread has ownership of the current hardware context.
 129         @ However, it may have been migrated to another CPU, in which
 130         @ case the saved state is newer than the hardware context.
 131         @ Check this by looking at the CPU number which the state was
 132         @ last loaded onto.
 133         ldr     ip, [r10, #VFP_CPU]
 134         teq     ip, r11
 135         beq     vfp_hw_state_valid
 136
 137 vfp_reload_hw:
 138         @ We're loading this threads state into the VFP hardware. Update
 139         @ the CPU number which contains the most up to date VFP context.
 140         str     r11, [r10, #VFP_CPU]
 141
 142         VFPFMXR FPEXC, r5               @ enable VFP, disable any pending
 143                                         @ exceptions, so we can get at the
 144                                         @ rest of it
 145 #endif
 146
 147         DBGSTR1 "load state %p", r10
 148         str     r10, [r3, r11, lsl #2]  @ update the vfp_current_hw_state pointer
 149                                         @ Load the saved state back into the VFP
 150         VFPFLDMIA r10, r5               @ reload the working registers while
 151                                         @ FPEXC is in a safe state
 152         ldmia   r10, {r1, r5, r6, r8}   @ load FPEXC, FPSCR, FPINST, FPINST2
 153 #ifndef CONFIG_CPU_FEROCEON
 154         tst     r1, #FPEXC_EX           @ is there additional state to restore?
 155         beq     1f
 156         VFPFMXR FPINST, r6              @ restore FPINST (only if FPEXC.EX is set)
 157         tst     r1, #FPEXC_FP2V         @ is there an FPINST2 to write?
 158         beq     1f
 159         VFPFMXR FPINST2, r8             @ FPINST2 if needed (and present)
 160 1:
 161 #endif
 162         VFPFMXR FPSCR, r5               @ restore status
 163
 164 @ The context stored in the VFP hardware is up to date with this thread
 165 vfp_hw_state_valid:
 166         tst     r1, #FPEXC_EX
 167         bne     process_exception       @ might as well handle the pending
 168                                         @ exception before retrying branch
 169                                         @ out before setting an FPEXC that
 170                                         @ stops us reading stuff
 171         VFPFMXR FPEXC, r1               @ Restore FPEXC last
 172         sub     r2, r2, #4              @ Retry current instruction - if Thumb
 173         str     r2, [sp, #S_PC]         @ mode it's two 16-bit instructions,
 174                                         @ else it's one 32-bit instruction, so
 175                                         @ always subtract 4 from the following
 176                                         @ instruction address.
 177         dec_preempt_count_ti r10, r4
 178         ret     r9                      @ we think we have handled things
 179
 180
 181 look_for_VFP_exceptions:
 182         @ Check for synchronous or asynchronous exception
 183         tst     r1, #FPEXC_EX | FPEXC_DEX
 184         bne     process_exception
 185         @ On some implementations of the VFP subarch 1, setting FPSCR.IXE
 186         @ causes all the CDP instructions to be bounced synchronously without
 187         @ setting the FPEXC.EX bit
 188         VFPFMRX r5, FPSCR
 189         tst     r5, #FPSCR_IXE
 190         bne     process_exception
 191
 192         tst     r5, #FPSCR_LENGTH_MASK
 193         beq     skip
 194         orr     r1, r1, #FPEXC_DEX
 195         b       process_exception
 196 skip:
 197
 198         @ Fall into hand on to next handler - appropriate coproc instr
 199         @ not recognised by VFP
 200
 201         DBGSTR  "not VFP"
 202         dec_preempt_count_ti r10, r4
 203         ret     lr
 204
 205 process_exception:
 206         DBGSTR  "bounce"
 207         mov     r2, sp                  @ nothing stacked - regdump is at TOS
 208         mov     lr, r9                  @ setup for a return to the user code.
 209
 210         @ Now call the C code to package up the bounce to the support code
 211         @   r0 holds the trigger instruction
 212         @   r1 holds the FPEXC value
 213         @   r2 pointer to register dump
 214         b       VFP_bounce              @ we have handled this - the support
 215                                         @ code will raise an exception if
 216                                         @ required. If not, the user code will
 217                                         @ retry the faulted instruction
 218 ENDPROC(vfp_support_entry)
 219
 220 ENTRY(vfp_save_state)
 221         @ Save the current VFP state
 222         @ r0 - save location
 223         @ r1 - FPEXC
 224         DBGSTR1 "save VFP state %p", r0
 225         VFPFSTMIA r0, r2                @ save the working registers
 226         VFPFMRX r2, FPSCR               @ current status
 227         tst     r1, #FPEXC_EX           @ is there additional state to save?
 228         beq     1f
 229         VFPFMRX r3, FPINST              @ FPINST (only if FPEXC.EX is set)
 230         tst     r1, #FPEXC_FP2V         @ is there an FPINST2 to read?
 231         beq     1f
 232         VFPFMRX r12, FPINST2            @ FPINST2 if needed (and present)
 233 1:
 234         stmia   r0, {r1, r2, r3, r12}   @ save FPEXC, FPSCR, FPINST, FPINST2
 235         ret     lr
 236 ENDPROC(vfp_save_state)
 237
 238         .align
 239 vfp_current_hw_state_address:
 240         .word   vfp_current_hw_state
 241
 242         .macro  tbl_branch, base, tmp, shift
 243 #ifdef CONFIG_THUMB2_KERNEL
 244         adr     \tmp, 1f
 245         add     \tmp, \tmp, \base, lsl \shift
 246         ret     \tmp
 247 #else
 248         add     pc, pc, \base, lsl \shift
 249         mov     r0, r0
 250 #endif
 251 1:
 252         .endm
 253
 254 ENTRY(vfp_get_float)
 255         tbl_branch r0, r3, #3
 256         .fpu    vfpv2
 257         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 258 1:      vmov    r0, s\dr
 259         ret     lr
 260         .org    1b + 8
 261         .endr
 262         .irp    dr,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 263 1:      vmov    r0, s\dr
 264         ret     lr
 265         .org    1b + 8
 266         .endr
 267 ENDPROC(vfp_get_float)
 268
 269 ENTRY(vfp_put_float)
 270         tbl_branch r1, r3, #3
 271         .fpu    vfpv2
 272         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 273 1:      vmov    s\dr, r0
 274         ret     lr
 275         .org    1b + 8
 276         .endr
 277         .irp    dr,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 278 1:      vmov    s\dr, r0
 279         ret     lr
 280         .org    1b + 8
 281         .endr
 282 ENDPROC(vfp_put_float)
 283
 284 ENTRY(vfp_get_double)
 285         tbl_branch r0, r3, #3
 286         .fpu    vfpv2
 287         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 288 1:      vmov    r0, r1, d\dr
 289         ret     lr
 290         .org    1b + 8
 291         .endr
 292 #ifdef CONFIG_VFPv3
 293         @ d16 - d31 registers
 294         .fpu    vfpv3
 295         .irp    dr,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 296 1:      vmov    r0, r1, d\dr
 297         ret     lr
 298         .org    1b + 8
 299         .endr
 300 #endif
 301
 302         @ virtual register 16 (or 32 if VFPv3) for compare with zero
 303         mov     r0, #0
 304         mov     r1, #0
 305         ret     lr
 306 ENDPROC(vfp_get_double)
 307
 308 ENTRY(vfp_put_double)
 309         tbl_branch r2, r3, #3
 310         .fpu    vfpv2
 311         .irp    dr,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15
 312 1:      vmov    d\dr, r0, r1
 313         ret     lr
 314         .org    1b + 8
 315         .endr
 316 #ifdef CONFIG_VFPv3
 317         .fpu    vfpv3
 318         @ d16 - d31 registers
 319         .irp    dr,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 320 1:      vmov    d\dr, r0, r1
 321         ret     lr
 322         .org    1b + 8
 323         .endr
 324 #endif
 325 ENDPROC(vfp_put_double)