arch/arm/mach-omap1/ams-delta-fiq-handler.S

   1 /*
   2  *  linux/arch/arm/mach-omap1/ams-delta-fiq-handler.S
   3  *
   4  *  Based on  linux/arch/arm/lib/floppydma.S
   5  *  Renamed and modified to work with 2.6 kernel by Matt Callow
   6  *  Copyright (C) 1995, 1996 Russell King
   7  *  Copyright (C) 2004 Pete Trapps
   8  *  Copyright (C) 2006 Matt Callow
   9  *  Copyright (C) 2010 Janusz Krzysztofik
  10  *
  11  * This program is free software; you can redistribute it and/or modify it
  12  * under the terms of the GNU General Public License version 2
  13  * as published by the Free Software Foundation.
  14  */
  15
  16 #include <linux/linkage.h>
  17 #include <linux/platform_data/ams-delta-fiq.h>
  18
  19 #include <asm/assembler.h>
  20 #include <mach/board-ams-delta.h>
  21
  22 #include "ams-delta-fiq.h"
  23 #include "iomap.h"
  24 #include "soc.h"
  25
  26 /*
  27  * GPIO related definitions, copied from arch/arm/plat-omap/gpio.c.
  28  * Unfortunately, those were not placed in a separate header file.
  29  */
  30 #define OMAP1510_GPIO_BASE              0xFFFCE000
  31 #define OMAP1510_GPIO_DATA_INPUT        0x00
  32 #define OMAP1510_GPIO_DATA_OUTPUT       0x04
  33 #define OMAP1510_GPIO_DIR_CONTROL       0x08
  34 #define OMAP1510_GPIO_INT_CONTROL       0x0c
  35 #define OMAP1510_GPIO_INT_MASK          0x10
  36 #define OMAP1510_GPIO_INT_STATUS        0x14
  37 #define OMAP1510_GPIO_PIN_CONTROL       0x18
  38
  39 /* GPIO register bitmasks */
  40 #define KEYBRD_DATA_MASK                (0x1 << AMS_DELTA_GPIO_PIN_KEYBRD_DATA)
  41 #define KEYBRD_CLK_MASK                 (0x1 << AMS_DELTA_GPIO_PIN_KEYBRD_CLK)
  42 #define MODEM_IRQ_MASK                  (0x1 << AMS_DELTA_GPIO_PIN_MODEM_IRQ)
  43 #define HOOK_SWITCH_MASK                (0x1 << AMS_DELTA_GPIO_PIN_HOOK_SWITCH)
  44 #define OTHERS_MASK                     (MODEM_IRQ_MASK | HOOK_SWITCH_MASK)
  45
  46 /* IRQ handler register bitmasks */
  47 #define DEFERRED_FIQ_MASK               OMAP_IRQ_BIT(INT_DEFERRED_FIQ)
  48 #define GPIO_BANK1_MASK                 OMAP_IRQ_BIT(INT_GPIO_BANK1)
  49
  50 /* Driver buffer byte offsets */
  51 #define BUF_MASK                        (FIQ_MASK * 4)
  52 #define BUF_STATE                       (FIQ_STATE * 4)
  53 #define BUF_KEYS_CNT                    (FIQ_KEYS_CNT * 4)
  54 #define BUF_TAIL_OFFSET                 (FIQ_TAIL_OFFSET * 4)
  55 #define BUF_HEAD_OFFSET                 (FIQ_HEAD_OFFSET * 4)
  56 #define BUF_BUF_LEN                     (FIQ_BUF_LEN * 4)
  57 #define BUF_KEY                         (FIQ_KEY * 4)
  58 #define BUF_MISSED_KEYS                 (FIQ_MISSED_KEYS * 4)
  59 #define BUF_BUFFER_START                (FIQ_BUFFER_START * 4)
  60 #define BUF_GPIO_INT_MASK               (FIQ_GPIO_INT_MASK * 4)
  61 #define BUF_KEYS_HICNT                  (FIQ_KEYS_HICNT * 4)
  62 #define BUF_IRQ_PEND                    (FIQ_IRQ_PEND * 4)
  63 #define BUF_SIR_CODE_L1                 (FIQ_SIR_CODE_L1 * 4)
  64 #define BUF_SIR_CODE_L2                 (IRQ_SIR_CODE_L2 * 4)
  65 #define BUF_CNT_INT_00                  (FIQ_CNT_INT_00 * 4)
  66 #define BUF_CNT_INT_KEY                 (FIQ_CNT_INT_KEY * 4)
  67 #define BUF_CNT_INT_MDM                 (FIQ_CNT_INT_MDM * 4)
  68 #define BUF_CNT_INT_03                  (FIQ_CNT_INT_03 * 4)
  69 #define BUF_CNT_INT_HSW                 (FIQ_CNT_INT_HSW * 4)
  70 #define BUF_CNT_INT_05                  (FIQ_CNT_INT_05 * 4)
  71 #define BUF_CNT_INT_06                  (FIQ_CNT_INT_06 * 4)
  72 #define BUF_CNT_INT_07                  (FIQ_CNT_INT_07 * 4)
  73 #define BUF_CNT_INT_08                  (FIQ_CNT_INT_08 * 4)
  74 #define BUF_CNT_INT_09                  (FIQ_CNT_INT_09 * 4)
  75 #define BUF_CNT_INT_10                  (FIQ_CNT_INT_10 * 4)
  76 #define BUF_CNT_INT_11                  (FIQ_CNT_INT_11 * 4)
  77 #define BUF_CNT_INT_12                  (FIQ_CNT_INT_12 * 4)
  78 #define BUF_CNT_INT_13                  (FIQ_CNT_INT_13 * 4)
  79 #define BUF_CNT_INT_14                  (FIQ_CNT_INT_14 * 4)
  80 #define BUF_CNT_INT_15                  (FIQ_CNT_INT_15 * 4)
  81 #define BUF_CIRC_BUFF                   (FIQ_CIRC_BUFF * 4)
  82
  83
  84 /*
  85  * Register usage
  86  * r8  - temporary
  87  * r9  - the driver buffer
  88  * r10 - temporary
  89  * r11 - interrupts mask
  90  * r12 - base pointers
  91  * r13 - interrupts status
  92  */
  93
  94         .text
  95
  96         .global qwerty_fiqin_end
  97
  98 ENTRY(qwerty_fiqin_start)
  99         @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 100         @ FIQ intrrupt handler
 101         ldr r12, omap_ih1_base                  @ set pointer to level1 handler
 102
 103         ldr r11, [r12, #IRQ_MIR_REG_OFFSET]     @ fetch interrupts mask
 104
 105         ldr r13, [r12, #IRQ_ITR_REG_OFFSET]     @ fetch interrupts status
 106         bics r13, r13, r11                      @ clear masked - any left?
 107         beq exit                                @ none - spurious FIQ? exit
 108
 109         ldr r10, [r12, #IRQ_SIR_FIQ_REG_OFFSET] @ get requested interrupt number
 110
 111         mov r8, #2                              @ reset FIQ agreement
 112         str r8, [r12, #IRQ_CONTROL_REG_OFFSET]
 113
 114         cmp r10, #(INT_GPIO_BANK1 - NR_IRQS_LEGACY)     @ is it GPIO interrupt?
 115         beq gpio                                @ yes - process it
 116
 117         mov r8, #1
 118         orr r8, r11, r8, lsl r10                @ mask spurious interrupt
 119         str r8, [r12, #IRQ_MIR_REG_OFFSET]
 120 exit:
 121         subs    pc, lr, #4                      @ return from FIQ
 122         @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
 123
 124
 125         @@@@@@@@@@@@@@@@@@@@@@@@@@@
 126 gpio:   @ GPIO bank interrupt handler
 127         ldr r12, omap1510_gpio_base             @ set base pointer to GPIO bank
 128
 129         ldr r11, [r12, #OMAP1510_GPIO_INT_MASK] @ fetch GPIO interrupts mask
 130 restart:
 131         ldr r13, [r12, #OMAP1510_GPIO_INT_STATUS]       @ fetch status bits
 132         bics r13, r13, r11                      @ clear masked - any left?
 133         beq exit                                @ no - spurious interrupt? exit
 134
 135         orr r11, r11, r13                       @ mask all requested interrupts
 136         str r11, [r12, #OMAP1510_GPIO_INT_MASK]
 137
 138         str r13, [r12, #OMAP1510_GPIO_INT_STATUS] @ ack all requested interrupts
 139
 140         ands r10, r13, #KEYBRD_CLK_MASK         @ extract keyboard status - set?
 141         beq hksw                                @ no - try next source
 142
 143
 144         @@@@@@@@@@@@@@@@@@@@@@
 145         @ Keyboard clock FIQ mode interrupt handler
 146         @ r10 now contains KEYBRD_CLK_MASK, use it
 147         bic r11, r11, r10                               @ unmask it
 148         str r11, [r12, #OMAP1510_GPIO_INT_MASK]
 149
 150         @ Process keyboard data
 151         ldr r8, [r12, #OMAP1510_GPIO_DATA_INPUT]        @ fetch GPIO input
 152
 153         ldr r10, [r9, #BUF_STATE]               @ fetch kbd interface state
 154         cmp r10, #0                             @ are we expecting start bit?
 155         bne data                                @ no - go to data processing
 156
 157         ands r8, r8, #KEYBRD_DATA_MASK          @ check start bit - detected?
 158         beq hksw                                @ no - try next source
 159
 160         @ r8 contains KEYBRD_DATA_MASK, use it
 161         str r8, [r9, #BUF_STATE]                @ enter data processing state
 162         @ r10 already contains 0, reuse it
 163         str r10, [r9, #BUF_KEY]                 @ clear keycode
 164         mov r10, #2                             @ reset input bit mask
 165         str r10, [r9, #BUF_MASK]
 166
 167         @ Mask other GPIO line interrupts till key done
 168         str r11, [r9, #BUF_GPIO_INT_MASK]       @ save mask for later restore
 169         mvn r11, #KEYBRD_CLK_MASK               @ prepare all except kbd mask
 170         str r11, [r12, #OMAP1510_GPIO_INT_MASK] @ store into the mask register
 171
 172         b restart                               @ restart
 173
 174 data:   ldr r10, [r9, #BUF_MASK]                @ fetch current input bit mask
 175
 176         @ r8 still contains GPIO input bits
 177         ands r8, r8, #KEYBRD_DATA_MASK          @ is keyboard data line low?
 178         ldreq r8, [r9, #BUF_KEY]                @ yes - fetch collected so far,
 179         orreq r8, r8, r10                       @ set 1 at current mask position
 180         streq r8, [r9, #BUF_KEY]                @ and save back
 181
 182         mov r10, r10, lsl #1                    @ shift mask left
 183         bics r10, r10, #0x800                   @ have we got all the bits?
 184         strne r10, [r9, #BUF_MASK]              @ not yet - store the mask
 185         bne restart                             @ and restart
 186
 187         @ r10 already contains 0, reuse it
 188         str r10, [r9, #BUF_STATE]               @ reset state to start
 189
 190         @ Key done - restore interrupt mask
 191         ldr r10, [r9, #BUF_GPIO_INT_MASK]       @ fetch saved mask
 192         and r11, r11, r10                       @ unmask all saved as unmasked
 193         str r11, [r12, #OMAP1510_GPIO_INT_MASK] @ restore into the mask register
 194
 195         @ Try appending the keycode to the circular buffer
 196         ldr r10, [r9, #BUF_KEYS_CNT]            @ get saved keystrokes count
 197         ldr r8, [r9, #BUF_BUF_LEN]              @ get buffer size
 198         cmp r10, r8                             @ is buffer full?
 199         beq hksw                                @ yes - key lost, next source
 200
 201         add r10, r10, #1                        @ incremet keystrokes counter
 202         str r10, [r9, #BUF_KEYS_CNT]
 203
 204         ldr r10, [r9, #BUF_TAIL_OFFSET]         @ get buffer tail offset
 205         @ r8 already contains buffer size
 206         cmp r10, r8                             @ end of buffer?
 207         moveq r10, #0                           @ yes - rewind to buffer start
 208
 209         ldr r12, [r9, #BUF_BUFFER_START]        @ get buffer start address
 210         add r12, r12, r10, LSL #2               @ calculate buffer tail address
 211         ldr r8, [r9, #BUF_KEY]                  @ get last keycode
 212         str r8, [r12]                           @ append it to the buffer tail
 213
 214         add r10, r10, #1                        @ increment buffer tail offset
 215         str r10, [r9, #BUF_TAIL_OFFSET]
 216
 217         ldr r10, [r9, #BUF_CNT_INT_KEY]         @ increment interrupts counter
 218         add r10, r10, #1
 219         str r10, [r9, #BUF_CNT_INT_KEY]
 220         @@@@@@@@@@@@@@@@@@@@@@@@
 221
 222
 223 hksw:   @Is hook switch interrupt requested?
 224         tst r13, #HOOK_SWITCH_MASK              @ is hook switch status bit set?
 225         beq mdm                                 @ no - try next source
 226
 227
 228         @@@@@@@@@@@@@@@@@@@@@@@@
 229         @ Hook switch interrupt FIQ mode simple handler
 230
 231         @ Don't toggle active edge, the switch always bounces
 232
 233         @ Increment hook switch interrupt counter
 234         ldr r10, [r9, #BUF_CNT_INT_HSW]
 235         add r10, r10, #1
 236         str r10, [r9, #BUF_CNT_INT_HSW]
 237         @@@@@@@@@@@@@@@@@@@@@@@@
 238
 239
 240 mdm:    @Is it a modem interrupt?
 241         tst r13, #MODEM_IRQ_MASK                @ is modem status bit set?
 242         beq irq                                 @ no - check for next interrupt
 243
 244
 245         @@@@@@@@@@@@@@@@@@@@@@@@
 246         @ Modem FIQ mode interrupt handler stub
 247
 248         @ Increment modem interrupt counter
 249         ldr r10, [r9, #BUF_CNT_INT_MDM]
 250         add r10, r10, #1
 251         str r10, [r9, #BUF_CNT_INT_MDM]
 252         @@@@@@@@@@@@@@@@@@@@@@@@
 253
 254
 255 irq:    @ Place deferred_fiq interrupt request
 256         ldr r12, deferred_fiq_ih_base           @ set pointer to IRQ handler
 257         mov r10, #DEFERRED_FIQ_MASK             @ set deferred_fiq bit
 258         str r10, [r12, #IRQ_ISR_REG_OFFSET]     @ place it in the ISR register
 259
 260         ldr r12, omap1510_gpio_base             @ set pointer back to GPIO bank
 261         b restart                               @ check for next GPIO interrupt
 262         @@@@@@@@@@@@@@@@@@@@@@@@@@@
 263
 264
 265 /*
 266  * Virtual addresses for IO
 267  */
 268 omap_ih1_base:
 269         .word OMAP1_IO_ADDRESS(OMAP_IH1_BASE)
 270 deferred_fiq_ih_base:
 271         .word OMAP1_IO_ADDRESS(DEFERRED_FIQ_IH_BASE)
 272 omap1510_gpio_base:
 273         .word OMAP1_IO_ADDRESS(OMAP1510_GPIO_BASE)
 274 qwerty_fiqin_end:
 275
 276 /*
 277  * Check the size of the FIQ,
 278  * it cannot go beyond 0xffff0200, and is copied to 0xffff001c
 279  */
 280 .if (qwerty_fiqin_end - qwerty_fiqin_start) > (0x200 - 0x1c)
 281         .err
 282 .endif