arch/arm/kernel/entry-common.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  *  linux/arch/arm/kernel/entry-common.S
   4  *
   5  *  Copyright (C) 2000 Russell King
   6  */
   7
   8 #include <asm/assembler.h>
   9 #include <asm/unistd.h>
  10 #include <asm/ftrace.h>
  11 #include <asm/unwind.h>
  12 #include <asm/memory.h>
  13 #ifdef CONFIG_AEABI
  14 #include <asm/unistd-oabi.h>
  15 #endif
  16
  17         .equ    NR_syscalls, __NR_syscalls
  18
  19         .macro  arch_ret_to_user, tmp
  20 #ifdef CONFIG_ARCH_IOP32X
  21         mrc     p15, 0, \tmp, c15, c1, 0
  22         tst     \tmp, #(1 << 6)
  23         bicne   \tmp, \tmp, #(1 << 6)
  24         mcrne   p15, 0, \tmp, c15, c1, 0        @ Disable cp6 access
  25 #endif
  26         .endm
  27
  28 #include "entry-header.S"
  29
  30 saved_psr       .req    r8
  31 #if defined(CONFIG_TRACE_IRQFLAGS) || defined(CONFIG_CONTEXT_TRACKING_USER)
  32 saved_pc        .req    r9
  33 #define TRACE(x...) x
  34 #else
  35 saved_pc        .req    lr
  36 #define TRACE(x...)
  37 #endif
  38
  39         .section .entry.text,"ax",%progbits
  40         .align  5
  41 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING_USER) || \
  42         IS_ENABLED(CONFIG_DEBUG_RSEQ))
  43 /*
  44  * This is the fast syscall return path.  We do as little as possible here,
  45  * such as avoiding writing r0 to the stack.  We only use this path if we
  46  * have tracing, context tracking and rseq debug disabled - the overheads
  47  * from those features make this path too inefficient.
  48  */
  49 ret_fast_syscall:
  50 __ret_fast_syscall:
  51  UNWIND(.fnstart        )
  52  UNWIND(.cantunwind     )
  53         disable_irq_notrace                     @ disable interrupts
  54         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  55         movs    r1, r1, lsl #16
  56         bne     fast_work_pending
  57
  58
  59         /* perform architecture specific actions before user return */
  60         arch_ret_to_user r1
  61
  62         restore_user_regs fast = 1, offset = S_OFF
  63  UNWIND(.fnend          )
  64 ENDPROC(ret_fast_syscall)
  65
  66         /* Ok, we need to do extra processing, enter the slow path. */
  67 fast_work_pending:
  68         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  69         /* fall through to work_pending */
  70 #else
  71 /*
  72  * The "replacement" ret_fast_syscall for when tracing, context tracking,
  73  * or rseq debug is enabled.  As we will need to call out to some C functions,
  74  * we save r0 first to avoid needing to save registers around each C function
  75  * call.
  76  */
  77 ret_fast_syscall:
  78 __ret_fast_syscall:
  79  UNWIND(.fnstart        )
  80  UNWIND(.cantunwind     )
  81         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  82 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
  83         /* do_rseq_syscall needs interrupts enabled. */
  84         mov     r0, sp                          @ 'regs'
  85         bl      do_rseq_syscall
  86 #endif
  87         disable_irq_notrace                     @ disable interrupts
  88         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  89         movs    r1, r1, lsl #16
  90         beq     no_work_pending
  91  UNWIND(.fnend          )
  92 ENDPROC(ret_fast_syscall)
  93
  94         /* Slower path - fall through to work_pending */
  95 #endif
  96
  97         tst     r1, #_TIF_SYSCALL_WORK
  98         bne     __sys_trace_return_nosave
  99 slow_work_pending:
 100         mov     r0, sp                          @ 'regs'
 101         mov     r2, why                         @ 'syscall'
 102         bl      do_work_pending
 103         cmp     r0, #0
 104         beq     no_work_pending
 105         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
 106         str     scno, [tsk, #TI_ABI_SYSCALL]    @ make sure tracers see update
 107         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
 108         b       local_restart                   @ ... and off we go
 109 ENDPROC(ret_fast_syscall)
 110
 111 /*
 112  * "slow" syscall return path.  "why" tells us if this was a real syscall.
 113  * IRQs may be enabled here, so always disable them.  Note that we use the
 114  * "notrace" version to avoid calling into the tracing code unnecessarily.
 115  * do_work_pending() will update this state if necessary.
 116  */
 117 ENTRY(ret_to_user)
 118 ret_slow_syscall:
 119 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
 120         /* do_rseq_syscall needs interrupts enabled. */
 121         enable_irq_notrace                      @ enable interrupts
 122         mov     r0, sp                          @ 'regs'
 123         bl      do_rseq_syscall
 124 #endif
 125         disable_irq_notrace                     @ disable interrupts
 126 ENTRY(ret_to_user_from_irq)
 127         ldr     r1, [tsk, #TI_FLAGS]
 128         movs    r1, r1, lsl #16
 129         bne     slow_work_pending
 130 no_work_pending:
 131         asm_trace_hardirqs_on save = 0
 132
 133         /* perform architecture specific actions before user return */
 134         arch_ret_to_user r1
 135         ct_user_enter save = 0
 136
 137         restore_user_regs fast = 0, offset = 0
 138 ENDPROC(ret_to_user_from_irq)
 139 ENDPROC(ret_to_user)
 140
 141 /*
 142  * This is how we return from a fork.
 143  */
 144 ENTRY(ret_from_fork)
 145         bl      schedule_tail
 146         cmp     r5, #0
 147         movne   r0, r4
 148         badrne  lr, 1f
 149         retne   r5
 150 1:      get_thread_info tsk
 151         b       ret_slow_syscall
 152 ENDPROC(ret_from_fork)
 153
 154 /*=============================================================================
 155  * SWI handler
 156  *-----------------------------------------------------------------------------
 157  */
 158
 159         .align  5
 160 #ifdef CONFIG_HARDEN_BRANCH_HISTORY
 161 ENTRY(vector_bhb_loop8_swi)
 162         sub     sp, sp, #PT_REGS_SIZE
 163         stmia   sp, {r0 - r12}
 164         mov     r8, #8
 165 1:      b       2f
 166 2:      subs    r8, r8, #1
 167         bne     1b
 168         dsb     nsh
 169         isb
 170         b       3f
 171 ENDPROC(vector_bhb_loop8_swi)
 172
 173         .align  5
 174 ENTRY(vector_bhb_bpiall_swi)
 175         sub     sp, sp, #PT_REGS_SIZE
 176         stmia   sp, {r0 - r12}
 177         mcr     p15, 0, r8, c7, c5, 6   @ BPIALL
 178         isb
 179         b       3f
 180 ENDPROC(vector_bhb_bpiall_swi)
 181 #endif
 182         .align  5
 183 ENTRY(vector_swi)
 184 #ifdef CONFIG_CPU_V7M
 185         v7m_exception_entry
 186 #else
 187         sub     sp, sp, #PT_REGS_SIZE
 188         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 189 3:
 190  ARM(   add     r8, sp, #S_PC           )
 191  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 192  THUMB( mov     r8, sp                  )
 193  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 194         mrs     saved_psr, spsr                 @ called from non-FIQ mode, so ok.
 195  TRACE( mov     saved_pc, lr            )
 196         str     saved_pc, [sp, #S_PC]           @ Save calling PC
 197         str     saved_psr, [sp, #S_PSR]         @ Save CPSR
 198         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 199 #endif
 200         reload_current r10, ip
 201         zero_fp
 202         alignment_trap r10, ip, cr_alignment
 203         asm_trace_hardirqs_on save=0
 204         enable_irq_notrace
 205         ct_user_exit save=0
 206
 207         /*
 208          * Get the system call number.
 209          */
 210
 211 #if defined(CONFIG_OABI_COMPAT)
 212
 213         /*
 214          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 215          * value to determine if it is an EABI or an old ABI call.
 216          */
 217 #ifdef CONFIG_ARM_THUMB
 218         tst     saved_psr, #PSR_T_BIT
 219         movne   r10, #0                         @ no thumb OABI emulation
 220  USER(  ldreq   r10, [saved_pc, #-4]    )       @ get SWI instruction
 221 #else
 222  USER(  ldr     r10, [saved_pc, #-4]    )       @ get SWI instruction
 223 #endif
 224  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 225
 226 #elif defined(CONFIG_AEABI)
 227
 228         /*
 229          * Pure EABI user space always put syscall number into scno (r7).
 230          */
 231 #elif defined(CONFIG_ARM_THUMB)
 232         /* Legacy ABI only, possibly thumb mode. */
 233         tst     saved_psr, #PSR_T_BIT           @ this is SPSR from save_user_regs
 234         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 235  USER(  ldreq   scno, [saved_pc, #-4]   )
 236
 237 #else
 238         /* Legacy ABI only. */
 239  USER(  ldr     scno, [saved_pc, #-4]   )       @ get SWI instruction
 240 #endif
 241
 242         /* saved_psr and saved_pc are now dead */
 243
 244         uaccess_disable tbl
 245         get_thread_info tsk
 246
 247         adr     tbl, sys_call_table             @ load syscall table pointer
 248
 249 #if defined(CONFIG_OABI_COMPAT)
 250         /*
 251          * If the swi argument is zero, this is an EABI call and we do nothing.
 252          *
 253          * If this is an old ABI call, get the syscall number into scno and
 254          * get the old ABI syscall table address.
 255          */
 256         bics    r10, r10, #0xff000000
 257         strne   r10, [tsk, #TI_ABI_SYSCALL]
 258         streq   scno, [tsk, #TI_ABI_SYSCALL]
 259         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 260         ldrne   tbl, =sys_oabi_call_table
 261 #elif !defined(CONFIG_AEABI)
 262         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 263         str     scno, [tsk, #TI_ABI_SYSCALL]
 264         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 265 #else
 266         str     scno, [tsk, #TI_ABI_SYSCALL]
 267 #endif
 268         /*
 269          * Reload the registers that may have been corrupted on entry to
 270          * the syscall assembly (by tracing or context tracking.)
 271          */
 272  TRACE( ldmia   sp, {r0 - r3}           )
 273
 274 local_restart:
 275         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 276         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 277
 278         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 279         bne     __sys_trace
 280
 281         invoke_syscall tbl, scno, r10, __ret_fast_syscall
 282
 283         add     r1, sp, #S_OFF
 284 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 285         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 286         bcs     arm_syscall
 287         mov     why, #0                         @ no longer a real syscall
 288         b       sys_ni_syscall                  @ not private func
 289
 290 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 291         /*
 292          * We failed to handle a fault trying to access the page
 293          * containing the swi instruction, but we're not really in a
 294          * position to return -EFAULT. Instead, return back to the
 295          * instruction and re-enter the user fault handling path trying
 296          * to page it in. This will likely result in sending SEGV to the
 297          * current task.
 298          */
 299 9001:
 300         sub     lr, saved_pc, #4
 301         str     lr, [sp, #S_PC]
 302         get_thread_info tsk
 303         b       ret_fast_syscall
 304 #endif
 305 ENDPROC(vector_swi)
 306         .ltorg
 307
 308         /*
 309          * This is the really slow path.  We're going to be doing
 310          * context switches, and waiting for our parent to respond.
 311          */
 312 __sys_trace:
 313         add     r0, sp, #S_OFF
 314         bl      syscall_trace_enter
 315         mov     scno, r0
 316         invoke_syscall tbl, scno, r10, __sys_trace_return, reload=1
 317         cmp     scno, #-1                       @ skip the syscall?
 318         bne     2b
 319         add     sp, sp, #S_OFF                  @ restore stack
 320
 321 __sys_trace_return_nosave:
 322         enable_irq_notrace
 323         mov     r0, sp
 324         bl      syscall_trace_exit
 325         b       ret_slow_syscall
 326
 327 __sys_trace_return:
 328         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 329         mov     r0, sp
 330         bl      syscall_trace_exit
 331         b       ret_slow_syscall
 332
 333         .macro  syscall_table_start, sym
 334         .equ    __sys_nr, 0
 335         .type   \sym, #object
 336 ENTRY(\sym)
 337         .endm
 338
 339         .macro  syscall, nr, func
 340         .ifgt   __sys_nr - \nr
 341         .error  "Duplicated/unorded system call entry"
 342         .endif
 343         .rept   \nr - __sys_nr
 344         .long   sys_ni_syscall
 345         .endr
 346         .long   \func
 347         .equ    __sys_nr, \nr + 1
 348         .endm
 349
 350         .macro  syscall_table_end, sym
 351         .ifgt   __sys_nr - __NR_syscalls
 352         .error  "System call table too big"
 353         .endif
 354         .rept   __NR_syscalls - __sys_nr
 355         .long   sys_ni_syscall
 356         .endr
 357         .size   \sym, . - \sym
 358         .endm
 359
 360 #define __SYSCALL_WITH_COMPAT(nr, native, compat)       __SYSCALL(nr, native)
 361 #define __SYSCALL(nr, func) syscall nr, func
 362
 363 /*
 364  * This is the syscall table declaration for native ABI syscalls.
 365  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 366  */
 367         syscall_table_start sys_call_table
 368 #ifdef CONFIG_AEABI
 369 #include <calls-eabi.S>
 370 #else
 371 #include <calls-oabi.S>
 372 #endif
 373         syscall_table_end sys_call_table
 374
 375 /*============================================================================
 376  * Special system call wrappers
 377  */
 378 @ r0 = syscall number
 379 @ r8 = syscall table
 380 sys_syscall:
 381                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 382                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 383                 cmpne   scno, #NR_syscalls      @ check range
 384 #ifdef CONFIG_CPU_SPECTRE
 385                 movhs   scno, #0
 386                 csdb
 387 #endif
 388                 stmialo sp, {r5, r6}            @ shuffle args
 389                 movlo   r0, r1
 390                 movlo   r1, r2
 391                 movlo   r2, r3
 392                 movlo   r3, r4
 393                 ldrlo   pc, [tbl, scno, lsl #2]
 394                 b       sys_ni_syscall
 395 ENDPROC(sys_syscall)
 396
 397 sys_sigreturn_wrapper:
 398                 add     r0, sp, #S_OFF
 399                 mov     why, #0         @ prevent syscall restart handling
 400                 b       sys_sigreturn
 401 ENDPROC(sys_sigreturn_wrapper)
 402
 403 sys_rt_sigreturn_wrapper:
 404                 add     r0, sp, #S_OFF
 405                 mov     why, #0         @ prevent syscall restart handling
 406                 b       sys_rt_sigreturn
 407 ENDPROC(sys_rt_sigreturn_wrapper)
 408
 409 sys_statfs64_wrapper:
 410                 teq     r1, #88
 411                 moveq   r1, #84
 412                 b       sys_statfs64
 413 ENDPROC(sys_statfs64_wrapper)
 414
 415 sys_fstatfs64_wrapper:
 416                 teq     r1, #88
 417                 moveq   r1, #84
 418                 b       sys_fstatfs64
 419 ENDPROC(sys_fstatfs64_wrapper)
 420
 421 /*
 422  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 423  * offset, we return EINVAL.
 424  */
 425 sys_mmap2:
 426                 str     r5, [sp, #4]
 427                 b       sys_mmap_pgoff
 428 ENDPROC(sys_mmap2)
 429
 430 #ifdef CONFIG_OABI_COMPAT
 431
 432 /*
 433  * These are syscalls with argument register differences
 434  */
 435
 436 sys_oabi_pread64:
 437                 stmia   sp, {r3, r4}
 438                 b       sys_pread64
 439 ENDPROC(sys_oabi_pread64)
 440
 441 sys_oabi_pwrite64:
 442                 stmia   sp, {r3, r4}
 443                 b       sys_pwrite64
 444 ENDPROC(sys_oabi_pwrite64)
 445
 446 sys_oabi_truncate64:
 447                 mov     r3, r2
 448                 mov     r2, r1
 449                 b       sys_truncate64
 450 ENDPROC(sys_oabi_truncate64)
 451
 452 sys_oabi_ftruncate64:
 453                 mov     r3, r2
 454                 mov     r2, r1
 455                 b       sys_ftruncate64
 456 ENDPROC(sys_oabi_ftruncate64)
 457
 458 sys_oabi_readahead:
 459                 str     r3, [sp]
 460                 mov     r3, r2
 461                 mov     r2, r1
 462                 b       sys_readahead
 463 ENDPROC(sys_oabi_readahead)
 464
 465 /*
 466  * Let's declare a second syscall table for old ABI binaries
 467  * using the compatibility syscall entries.
 468  */
 469         syscall_table_start sys_oabi_call_table
 470 #undef __SYSCALL_WITH_COMPAT
 471 #define __SYSCALL_WITH_COMPAT(nr, native, compat)       __SYSCALL(nr, compat)
 472 #include <calls-oabi.S>
 473         syscall_table_end sys_oabi_call_table
 474
 475 #endif
 476