arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/assembler.h>
  12 #include <asm/unistd.h>
  13 #include <asm/ftrace.h>
  14 #include <asm/unwind.h>
  15
  16 #ifdef CONFIG_NEED_RET_TO_USER
  17 #include <mach/entry-macro.S>
  18 #else
  19         .macro  arch_ret_to_user, tmp1, tmp2
  20         .endm
  21 #endif
  22
  23 #include "entry-header.S"
  24
  25
  26         .align  5
  27 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING))
  28 /*
  29  * This is the fast syscall return path.  We do as little as possible here,
  30  * such as avoiding writing r0 to the stack.  We only use this path if we
  31  * have tracing and context tracking disabled - the overheads from those
  32  * features make this path too inefficient.
  33  */
  34 ret_fast_syscall:
  35 __ret_fast_syscall:
  36  UNWIND(.fnstart        )
  37  UNWIND(.cantunwind     )
  38         disable_irq_notrace                     @ disable interrupts
  39         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  40         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  41         bne     fast_work_pending
  42
  43         /* perform architecture specific actions before user return */
  44         arch_ret_to_user r1, lr
  45
  46         restore_user_regs fast = 1, offset = S_OFF
  47  UNWIND(.fnend          )
  48 ENDPROC(ret_fast_syscall)
  49
  50         /* Ok, we need to do extra processing, enter the slow path. */
  51 fast_work_pending:
  52         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  53         /* fall through to work_pending */
  54 #else
  55 /*
  56  * The "replacement" ret_fast_syscall for when tracing or context tracking
  57  * is enabled.  As we will need to call out to some C functions, we save
  58  * r0 first to avoid needing to save registers around each C function call.
  59  */
  60 ret_fast_syscall:
  61 __ret_fast_syscall:
  62  UNWIND(.fnstart        )
  63  UNWIND(.cantunwind     )
  64         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  65         disable_irq_notrace                     @ disable interrupts
  66         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  67         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  68         beq     no_work_pending
  69  UNWIND(.fnend          )
  70 ENDPROC(ret_fast_syscall)
  71
  72         /* Slower path - fall through to work_pending */
  73 #endif
  74
  75         tst     r1, #_TIF_SYSCALL_WORK
  76         bne     __sys_trace_return_nosave
  77 slow_work_pending:
  78         mov     r0, sp                          @ 'regs'
  79         mov     r2, why                         @ 'syscall'
  80         bl      do_work_pending
  81         cmp     r0, #0
  82         beq     no_work_pending
  83         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
  84         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
  85         b       local_restart                   @ ... and off we go
  86 ENDPROC(ret_fast_syscall)
  87
  88 /*
  89  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  90  * IRQs may be enabled here, so always disable them.  Note that we use the
  91  * "notrace" version to avoid calling into the tracing code unnecessarily.
  92  * do_work_pending() will update this state if necessary.
  93  */
  94 ENTRY(ret_to_user)
  95 ret_slow_syscall:
  96         disable_irq_notrace                     @ disable interrupts
  97 ENTRY(ret_to_user_from_irq)
  98         ldr     r1, [tsk, #TI_FLAGS]
  99         tst     r1, #_TIF_WORK_MASK
 100         bne     slow_work_pending
 101 no_work_pending:
 102         asm_trace_hardirqs_on save = 0
 103
 104         /* perform architecture specific actions before user return */
 105         arch_ret_to_user r1, lr
 106         ct_user_enter save = 0
 107
 108         restore_user_regs fast = 0, offset = 0
 109 ENDPROC(ret_to_user_from_irq)
 110 ENDPROC(ret_to_user)
 111
 112 /*
 113  * This is how we return from a fork.
 114  */
 115 ENTRY(ret_from_fork)
 116         bl      schedule_tail
 117         cmp     r5, #0
 118         movne   r0, r4
 119         badrne  lr, 1f
 120         retne   r5
 121 1:      get_thread_info tsk
 122         b       ret_slow_syscall
 123 ENDPROC(ret_from_fork)
 124
 125         .equ NR_syscalls,0
 126 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
 127 #include "calls.S"
 128
 129 /*
 130  * Ensure that the system call table is equal to __NR_syscalls,
 131  * which is the value the rest of the system sees
 132  */
 133 .ifne NR_syscalls - __NR_syscalls
 134 .error "__NR_syscalls is not equal to the size of the syscall table"
 135 .endif
 136
 137 #undef CALL
 138 #define CALL(x) .long x
 139
 140 /*=============================================================================
 141  * SWI handler
 142  *-----------------------------------------------------------------------------
 143  */
 144
 145         .align  5
 146 #ifdef CONFIG_HARDEN_BRANCH_HISTORY
 147 ENTRY(vector_bhb_loop8_swi)
 148         sub     sp, sp, #PT_REGS_SIZE
 149         stmia   sp, {r0 - r12}
 150         mov     r8, #8
 151 1:      b       2f
 152 2:      subs    r8, r8, #1
 153         bne     1b
 154         dsb
 155         isb
 156         b       3f
 157 ENDPROC(vector_bhb_loop8_swi)
 158
 159         .align  5
 160 ENTRY(vector_bhb_bpiall_swi)
 161         sub     sp, sp, #PT_REGS_SIZE
 162         stmia   sp, {r0 - r12}
 163         mcr     p15, 0, r8, c7, c5, 6   @ BPIALL
 164         isb
 165         b       3f
 166 ENDPROC(vector_bhb_bpiall_swi)
 167 #endif
 168         .align  5
 169 ENTRY(vector_swi)
 170 #ifdef CONFIG_CPU_V7M
 171         v7m_exception_entry
 172 #else
 173         sub     sp, sp, #PT_REGS_SIZE
 174         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 175 3:
 176  ARM(   add     r8, sp, #S_PC           )
 177  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 178  THUMB( mov     r8, sp                  )
 179  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 180         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 181         str     lr, [sp, #S_PC]                 @ Save calling PC
 182         str     r8, [sp, #S_PSR]                @ Save CPSR
 183         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 184 #endif
 185         zero_fp
 186         alignment_trap r10, ip, __cr_alignment
 187         enable_irq
 188         ct_user_exit
 189         get_thread_info tsk
 190
 191         /*
 192          * Get the system call number.
 193          */
 194
 195 #if defined(CONFIG_OABI_COMPAT)
 196
 197         /*
 198          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 199          * value to determine if it is an EABI or an old ABI call.
 200          */
 201 #ifdef CONFIG_ARM_THUMB
 202         tst     r8, #PSR_T_BIT
 203         movne   r10, #0                         @ no thumb OABI emulation
 204  USER(  ldreq   r10, [lr, #-4]          )       @ get SWI instruction
 205 #else
 206  USER(  ldr     r10, [lr, #-4]          )       @ get SWI instruction
 207 #endif
 208  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 209
 210 #elif defined(CONFIG_AEABI)
 211
 212         /*
 213          * Pure EABI user space always put syscall number into scno (r7).
 214          */
 215 #elif defined(CONFIG_ARM_THUMB)
 216         /* Legacy ABI only, possibly thumb mode. */
 217         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 218         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 219  USER(  ldreq   scno, [lr, #-4]         )
 220
 221 #else
 222         /* Legacy ABI only. */
 223  USER(  ldr     scno, [lr, #-4]         )       @ get SWI instruction
 224 #endif
 225
 226         uaccess_disable tbl
 227
 228         adr     tbl, sys_call_table             @ load syscall table pointer
 229
 230 #if defined(CONFIG_OABI_COMPAT)
 231         /*
 232          * If the swi argument is zero, this is an EABI call and we do nothing.
 233          *
 234          * If this is an old ABI call, get the syscall number into scno and
 235          * get the old ABI syscall table address.
 236          */
 237         bics    r10, r10, #0xff000000
 238         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 239         ldrne   tbl, =sys_oabi_call_table
 240 #elif !defined(CONFIG_AEABI)
 241         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 242         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 243 #endif
 244
 245 local_restart:
 246         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 247         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 248
 249         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 250         bne     __sys_trace
 251
 252         invoke_syscall tbl, scno, r10, __ret_fast_syscall
 253
 254         add     r1, sp, #S_OFF
 255 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 256         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 257         bcs     arm_syscall
 258         mov     why, #0                         @ no longer a real syscall
 259         b       sys_ni_syscall                  @ not private func
 260
 261 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 262         /*
 263          * We failed to handle a fault trying to access the page
 264          * containing the swi instruction, but we're not really in a
 265          * position to return -EFAULT. Instead, return back to the
 266          * instruction and re-enter the user fault handling path trying
 267          * to page it in. This will likely result in sending SEGV to the
 268          * current task.
 269          */
 270 9001:
 271         sub     lr, lr, #4
 272         str     lr, [sp, #S_PC]
 273         b       ret_fast_syscall
 274 #endif
 275 ENDPROC(vector_swi)
 276
 277         /*
 278          * This is the really slow path.  We're going to be doing
 279          * context switches, and waiting for our parent to respond.
 280          */
 281 __sys_trace:
 282         mov     r1, scno
 283         add     r0, sp, #S_OFF
 284         bl      syscall_trace_enter
 285         mov     scno, r0
 286         invoke_syscall tbl, scno, r10, __sys_trace_return, reload=1
 287         cmp     scno, #-1                       @ skip the syscall?
 288         bne     2b
 289         add     sp, sp, #S_OFF                  @ restore stack
 290
 291 __sys_trace_return_nosave:
 292         enable_irq_notrace
 293         mov     r0, sp
 294         bl      syscall_trace_exit
 295         b       ret_slow_syscall
 296
 297 __sys_trace_return:
 298         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 299         mov     r0, sp
 300         bl      syscall_trace_exit
 301         b       ret_slow_syscall
 302
 303         .align  5
 304 #ifdef CONFIG_ALIGNMENT_TRAP
 305         .type   __cr_alignment, #object
 306 __cr_alignment:
 307         .word   cr_alignment
 308 #endif
 309         .ltorg
 310
 311 /*
 312  * This is the syscall table declaration for native ABI syscalls.
 313  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 314  */
 315 #define ABI(native, compat) native
 316 #ifdef CONFIG_AEABI
 317 #define OBSOLETE(syscall) sys_ni_syscall
 318 #else
 319 #define OBSOLETE(syscall) syscall
 320 #endif
 321
 322         .type   sys_call_table, #object
 323 ENTRY(sys_call_table)
 324 #include "calls.S"
 325 #undef ABI
 326 #undef OBSOLETE
 327
 328 /*============================================================================
 329  * Special system call wrappers
 330  */
 331 @ r0 = syscall number
 332 @ r8 = syscall table
 333 sys_syscall:
 334                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 335                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 336                 cmpne   scno, #NR_syscalls      @ check range
 337 #ifdef CONFIG_CPU_SPECTRE
 338                 movhs   scno, #0
 339                 csdb
 340 #endif
 341                 stmloia sp, {r5, r6}            @ shuffle args
 342                 movlo   r0, r1
 343                 movlo   r1, r2
 344                 movlo   r2, r3
 345                 movlo   r3, r4
 346                 ldrlo   pc, [tbl, scno, lsl #2]
 347                 b       sys_ni_syscall
 348 ENDPROC(sys_syscall)
 349
 350 sys_sigreturn_wrapper:
 351                 add     r0, sp, #S_OFF
 352                 mov     why, #0         @ prevent syscall restart handling
 353                 b       sys_sigreturn
 354 ENDPROC(sys_sigreturn_wrapper)
 355
 356 sys_rt_sigreturn_wrapper:
 357                 add     r0, sp, #S_OFF
 358                 mov     why, #0         @ prevent syscall restart handling
 359                 b       sys_rt_sigreturn
 360 ENDPROC(sys_rt_sigreturn_wrapper)
 361
 362 sys_statfs64_wrapper:
 363                 teq     r1, #88
 364                 moveq   r1, #84
 365                 b       sys_statfs64
 366 ENDPROC(sys_statfs64_wrapper)
 367
 368 sys_fstatfs64_wrapper:
 369                 teq     r1, #88
 370                 moveq   r1, #84
 371                 b       sys_fstatfs64
 372 ENDPROC(sys_fstatfs64_wrapper)
 373
 374 /*
 375  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 376  * offset, we return EINVAL.
 377  */
 378 sys_mmap2:
 379 #if PAGE_SHIFT > 12
 380                 tst     r5, #PGOFF_MASK
 381                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 382                 streq   r5, [sp, #4]
 383                 beq     sys_mmap_pgoff
 384                 mov     r0, #-EINVAL
 385                 ret     lr
 386 #else
 387                 str     r5, [sp, #4]
 388                 b       sys_mmap_pgoff
 389 #endif
 390 ENDPROC(sys_mmap2)
 391
 392 #ifdef CONFIG_OABI_COMPAT
 393
 394 /*
 395  * These are syscalls with argument register differences
 396  */
 397
 398 sys_oabi_pread64:
 399                 stmia   sp, {r3, r4}
 400                 b       sys_pread64
 401 ENDPROC(sys_oabi_pread64)
 402
 403 sys_oabi_pwrite64:
 404                 stmia   sp, {r3, r4}
 405                 b       sys_pwrite64
 406 ENDPROC(sys_oabi_pwrite64)
 407
 408 sys_oabi_truncate64:
 409                 mov     r3, r2
 410                 mov     r2, r1
 411                 b       sys_truncate64
 412 ENDPROC(sys_oabi_truncate64)
 413
 414 sys_oabi_ftruncate64:
 415                 mov     r3, r2
 416                 mov     r2, r1
 417                 b       sys_ftruncate64
 418 ENDPROC(sys_oabi_ftruncate64)
 419
 420 sys_oabi_readahead:
 421                 str     r3, [sp]
 422                 mov     r3, r2
 423                 mov     r2, r1
 424                 b       sys_readahead
 425 ENDPROC(sys_oabi_readahead)
 426
 427 /*
 428  * Let's declare a second syscall table for old ABI binaries
 429  * using the compatibility syscall entries.
 430  */
 431 #define ABI(native, compat) compat
 432 #define OBSOLETE(syscall) syscall
 433
 434         .type   sys_oabi_call_table, #object
 435 ENTRY(sys_oabi_call_table)
 436 #include "calls.S"
 437 #undef ABI
 438 #undef OBSOLETE
 439
 440 #endif
 441