arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/assembler.h>
  12 #include <asm/unistd.h>
  13 #include <asm/ftrace.h>
  14 #include <asm/unwind.h>
  15
  16 #ifdef CONFIG_NEED_RET_TO_USER
  17 #include <mach/entry-macro.S>
  18 #else
  19         .macro  arch_ret_to_user, tmp1, tmp2
  20         .endm
  21 #endif
  22
  23 #include "entry-header.S"
  24
  25
  26         .align  5
  27 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING))
  28 /*
  29  * This is the fast syscall return path.  We do as little as possible here,
  30  * such as avoiding writing r0 to the stack.  We only use this path if we
  31  * have tracing and context tracking disabled - the overheads from those
  32  * features make this path too inefficient.
  33  */
  34 ret_fast_syscall:
  35 __ret_fast_syscall:
  36  UNWIND(.fnstart        )
  37  UNWIND(.cantunwind     )
  38         disable_irq_notrace                     @ disable interrupts
  39         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  40         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  41         bne     fast_work_pending
  42
  43         /* perform architecture specific actions before user return */
  44         arch_ret_to_user r1, lr
  45
  46         restore_user_regs fast = 1, offset = S_OFF
  47  UNWIND(.fnend          )
  48 ENDPROC(ret_fast_syscall)
  49
  50         /* Ok, we need to do extra processing, enter the slow path. */
  51 fast_work_pending:
  52         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  53         /* fall through to work_pending */
  54 #else
  55 /*
  56  * The "replacement" ret_fast_syscall for when tracing or context tracking
  57  * is enabled.  As we will need to call out to some C functions, we save
  58  * r0 first to avoid needing to save registers around each C function call.
  59  */
  60 ret_fast_syscall:
  61 __ret_fast_syscall:
  62  UNWIND(.fnstart        )
  63  UNWIND(.cantunwind     )
  64         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  65         disable_irq_notrace                     @ disable interrupts
  66         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  67         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  68         beq     no_work_pending
  69  UNWIND(.fnend          )
  70 ENDPROC(ret_fast_syscall)
  71
  72         /* Slower path - fall through to work_pending */
  73 #endif
  74
  75         tst     r1, #_TIF_SYSCALL_WORK
  76         bne     __sys_trace_return_nosave
  77 slow_work_pending:
  78         mov     r0, sp                          @ 'regs'
  79         mov     r2, why                         @ 'syscall'
  80         bl      do_work_pending
  81         cmp     r0, #0
  82         beq     no_work_pending
  83         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
  84         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
  85         b       local_restart                   @ ... and off we go
  86 ENDPROC(ret_fast_syscall)
  87
  88 /*
  89  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  90  * IRQs may be enabled here, so always disable them.  Note that we use the
  91  * "notrace" version to avoid calling into the tracing code unnecessarily.
  92  * do_work_pending() will update this state if necessary.
  93  */
  94 ENTRY(ret_to_user)
  95 ret_slow_syscall:
  96         disable_irq_notrace                     @ disable interrupts
  97 ENTRY(ret_to_user_from_irq)
  98         ldr     r1, [tsk, #TI_FLAGS]
  99         tst     r1, #_TIF_WORK_MASK
 100         bne     slow_work_pending
 101 no_work_pending:
 102         asm_trace_hardirqs_on save = 0
 103
 104         /* perform architecture specific actions before user return */
 105         arch_ret_to_user r1, lr
 106         ct_user_enter save = 0
 107
 108         restore_user_regs fast = 0, offset = 0
 109 ENDPROC(ret_to_user_from_irq)
 110 ENDPROC(ret_to_user)
 111
 112 /*
 113  * This is how we return from a fork.
 114  */
 115 ENTRY(ret_from_fork)
 116         bl      schedule_tail
 117         cmp     r5, #0
 118         movne   r0, r4
 119         badrne  lr, 1f
 120         retne   r5
 121 1:      get_thread_info tsk
 122         b       ret_slow_syscall
 123 ENDPROC(ret_from_fork)
 124
 125         .equ NR_syscalls,0
 126 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
 127 #include "calls.S"
 128
 129 /*
 130  * Ensure that the system call table is equal to __NR_syscalls,
 131  * which is the value the rest of the system sees
 132  */
 133 .ifne NR_syscalls - __NR_syscalls
 134 .error "__NR_syscalls is not equal to the size of the syscall table"
 135 .endif
 136
 137 #undef CALL
 138 #define CALL(x) .long x
 139
 140 /*=============================================================================
 141  * SWI handler
 142  *-----------------------------------------------------------------------------
 143  */
 144
 145         .align  5
 146 ENTRY(vector_swi)
 147 #ifdef CONFIG_CPU_V7M
 148         v7m_exception_entry
 149 #else
 150         sub     sp, sp, #PT_REGS_SIZE
 151         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 152  ARM(   add     r8, sp, #S_PC           )
 153  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 154  THUMB( mov     r8, sp                  )
 155  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 156         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 157         str     lr, [sp, #S_PC]                 @ Save calling PC
 158         str     r8, [sp, #S_PSR]                @ Save CPSR
 159         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 160 #endif
 161         zero_fp
 162         alignment_trap r10, ip, __cr_alignment
 163         enable_irq
 164         ct_user_exit
 165         get_thread_info tsk
 166
 167         /*
 168          * Get the system call number.
 169          */
 170
 171 #if defined(CONFIG_OABI_COMPAT)
 172
 173         /*
 174          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 175          * value to determine if it is an EABI or an old ABI call.
 176          */
 177 #ifdef CONFIG_ARM_THUMB
 178         tst     r8, #PSR_T_BIT
 179         movne   r10, #0                         @ no thumb OABI emulation
 180  USER(  ldreq   r10, [lr, #-4]          )       @ get SWI instruction
 181 #else
 182  USER(  ldr     r10, [lr, #-4]          )       @ get SWI instruction
 183 #endif
 184  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 185
 186 #elif defined(CONFIG_AEABI)
 187
 188         /*
 189          * Pure EABI user space always put syscall number into scno (r7).
 190          */
 191 #elif defined(CONFIG_ARM_THUMB)
 192         /* Legacy ABI only, possibly thumb mode. */
 193         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 194         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 195  USER(  ldreq   scno, [lr, #-4]         )
 196
 197 #else
 198         /* Legacy ABI only. */
 199  USER(  ldr     scno, [lr, #-4]         )       @ get SWI instruction
 200 #endif
 201
 202         uaccess_disable tbl
 203
 204         adr     tbl, sys_call_table             @ load syscall table pointer
 205
 206 #if defined(CONFIG_OABI_COMPAT)
 207         /*
 208          * If the swi argument is zero, this is an EABI call and we do nothing.
 209          *
 210          * If this is an old ABI call, get the syscall number into scno and
 211          * get the old ABI syscall table address.
 212          */
 213         bics    r10, r10, #0xff000000
 214         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 215         ldrne   tbl, =sys_oabi_call_table
 216 #elif !defined(CONFIG_AEABI)
 217         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 218         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 219 #endif
 220
 221 local_restart:
 222         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 223         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 224
 225         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 226         bne     __sys_trace
 227
 228         invoke_syscall tbl, scno, r10, __ret_fast_syscall
 229
 230         add     r1, sp, #S_OFF
 231 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 232         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 233         bcs     arm_syscall
 234         mov     why, #0                         @ no longer a real syscall
 235         b       sys_ni_syscall                  @ not private func
 236
 237 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 238         /*
 239          * We failed to handle a fault trying to access the page
 240          * containing the swi instruction, but we're not really in a
 241          * position to return -EFAULT. Instead, return back to the
 242          * instruction and re-enter the user fault handling path trying
 243          * to page it in. This will likely result in sending SEGV to the
 244          * current task.
 245          */
 246 9001:
 247         sub     lr, lr, #4
 248         str     lr, [sp, #S_PC]
 249         b       ret_fast_syscall
 250 #endif
 251 ENDPROC(vector_swi)
 252
 253         /*
 254          * This is the really slow path.  We're going to be doing
 255          * context switches, and waiting for our parent to respond.
 256          */
 257 __sys_trace:
 258         mov     r1, scno
 259         add     r0, sp, #S_OFF
 260         bl      syscall_trace_enter
 261         mov     scno, r0
 262         invoke_syscall tbl, scno, r10, __sys_trace_return, reload=1
 263         cmp     scno, #-1                       @ skip the syscall?
 264         bne     2b
 265         add     sp, sp, #S_OFF                  @ restore stack
 266
 267 __sys_trace_return_nosave:
 268         enable_irq_notrace
 269         mov     r0, sp
 270         bl      syscall_trace_exit
 271         b       ret_slow_syscall
 272
 273 __sys_trace_return:
 274         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 275         mov     r0, sp
 276         bl      syscall_trace_exit
 277         b       ret_slow_syscall
 278
 279         .align  5
 280 #ifdef CONFIG_ALIGNMENT_TRAP
 281         .type   __cr_alignment, #object
 282 __cr_alignment:
 283         .word   cr_alignment
 284 #endif
 285         .ltorg
 286
 287 /*
 288  * This is the syscall table declaration for native ABI syscalls.
 289  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 290  */
 291 #define ABI(native, compat) native
 292 #ifdef CONFIG_AEABI
 293 #define OBSOLETE(syscall) sys_ni_syscall
 294 #else
 295 #define OBSOLETE(syscall) syscall
 296 #endif
 297
 298         .type   sys_call_table, #object
 299 ENTRY(sys_call_table)
 300 #include "calls.S"
 301 #undef ABI
 302 #undef OBSOLETE
 303
 304 /*============================================================================
 305  * Special system call wrappers
 306  */
 307 @ r0 = syscall number
 308 @ r8 = syscall table
 309 sys_syscall:
 310                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 311                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 312                 cmpne   scno, #NR_syscalls      @ check range
 313 #ifdef CONFIG_CPU_SPECTRE
 314                 movhs   scno, #0
 315                 csdb
 316 #endif
 317                 stmloia sp, {r5, r6}            @ shuffle args
 318                 movlo   r0, r1
 319                 movlo   r1, r2
 320                 movlo   r2, r3
 321                 movlo   r3, r4
 322                 ldrlo   pc, [tbl, scno, lsl #2]
 323                 b       sys_ni_syscall
 324 ENDPROC(sys_syscall)
 325
 326 sys_sigreturn_wrapper:
 327                 add     r0, sp, #S_OFF
 328                 mov     why, #0         @ prevent syscall restart handling
 329                 b       sys_sigreturn
 330 ENDPROC(sys_sigreturn_wrapper)
 331
 332 sys_rt_sigreturn_wrapper:
 333                 add     r0, sp, #S_OFF
 334                 mov     why, #0         @ prevent syscall restart handling
 335                 b       sys_rt_sigreturn
 336 ENDPROC(sys_rt_sigreturn_wrapper)
 337
 338 sys_statfs64_wrapper:
 339                 teq     r1, #88
 340                 moveq   r1, #84
 341                 b       sys_statfs64
 342 ENDPROC(sys_statfs64_wrapper)
 343
 344 sys_fstatfs64_wrapper:
 345                 teq     r1, #88
 346                 moveq   r1, #84
 347                 b       sys_fstatfs64
 348 ENDPROC(sys_fstatfs64_wrapper)
 349
 350 /*
 351  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 352  * offset, we return EINVAL.
 353  */
 354 sys_mmap2:
 355 #if PAGE_SHIFT > 12
 356                 tst     r5, #PGOFF_MASK
 357                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 358                 streq   r5, [sp, #4]
 359                 beq     sys_mmap_pgoff
 360                 mov     r0, #-EINVAL
 361                 ret     lr
 362 #else
 363                 str     r5, [sp, #4]
 364                 b       sys_mmap_pgoff
 365 #endif
 366 ENDPROC(sys_mmap2)
 367
 368 #ifdef CONFIG_OABI_COMPAT
 369
 370 /*
 371  * These are syscalls with argument register differences
 372  */
 373
 374 sys_oabi_pread64:
 375                 stmia   sp, {r3, r4}
 376                 b       sys_pread64
 377 ENDPROC(sys_oabi_pread64)
 378
 379 sys_oabi_pwrite64:
 380                 stmia   sp, {r3, r4}
 381                 b       sys_pwrite64
 382 ENDPROC(sys_oabi_pwrite64)
 383
 384 sys_oabi_truncate64:
 385                 mov     r3, r2
 386                 mov     r2, r1
 387                 b       sys_truncate64
 388 ENDPROC(sys_oabi_truncate64)
 389
 390 sys_oabi_ftruncate64:
 391                 mov     r3, r2
 392                 mov     r2, r1
 393                 b       sys_ftruncate64
 394 ENDPROC(sys_oabi_ftruncate64)
 395
 396 sys_oabi_readahead:
 397                 str     r3, [sp]
 398                 mov     r3, r2
 399                 mov     r2, r1
 400                 b       sys_readahead
 401 ENDPROC(sys_oabi_readahead)
 402
 403 /*
 404  * Let's declare a second syscall table for old ABI binaries
 405  * using the compatibility syscall entries.
 406  */
 407 #define ABI(native, compat) compat
 408 #define OBSOLETE(syscall) syscall
 409
 410         .type   sys_oabi_call_table, #object
 411 ENTRY(sys_oabi_call_table)
 412 #include "calls.S"
 413 #undef ABI
 414 #undef OBSOLETE
 415
 416 #endif
 417