srt2vtt

   1 #!/usr/bin/guile --no-auto-compile
   2 -*- scheme -*-
   3 !#
   4
   5 ;;; srt2vtt --- SRT to WebVTT converter
   6 ;;; Copyright © 2015 David Thompson <davet@gnu.org>
   7 ;;;
   8 ;;; srt2vtt is free software; you can redistribute it and/or modify it
   9 ;;; under the terms of the GNU General Public License as published by
  10 ;;; the Free Software Foundation; either version 3 of the License, or
  11 ;;; (at your option) any later version.
  12 ;;;
  13 ;;; srt2vtt is distributed in the hope that it will be useful, but
  14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;;; General Public License for more details.
  17 ;;;
  18 ;;; You should have received a copy of the GNU General Public License
  19 ;;; along with srt2vtt.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22 ;;
  23 ;; Convert SRT formatted subtitles to WebVTT format.
  24 ;;
  25 ;;; Code:
  26
  27 (use-modules (ice-9 format)
  28              (ice-9 match)
  29              (ice-9 rdelim)
  30              (ice-9 regex)
  31              (srfi srfi-1)
  32              (srfi srfi-9)
  33              (srfi srfi-11)
  34              (srfi srfi-26)
  35              (srfi srfi-37))
  36
  37 (define-record-type <subtitle>
  38   (make-subtitle id start end text)
  39   subtitle?
  40   (id subtitle-id)
  41   (start subtitle-start)
  42   (end subtitle-end)
  43   (text subtitle-text))
  44
  45 (define parse-time
  46   (let ((regexp (make-regexp "([0-9]+):([0-9]+):([0-9]+),([0-9]+)")))
  47     (lambda (s)
  48       "Parse the SubRip formatted timestamp in the string S into a 4
  49 element list.  Valid input looks like '00:00:03.417'."
  50       (let ((match (regexp-exec regexp s)))
  51         (map (cut match:substring match <>) '(1 2 3 4))))))
  52
  53 (define parse-time-span
  54   (let ((regexp (make-regexp "([0-9:,]+) --> ([0-9:,]+)")))
  55     (lambda (s)
  56       "Parse the SubRip formatted time span in the string S and return
  57 two values: the start time and the end time.  Valid input looks like
  58 '00:00:03.417 --> 00:00:04.936'."
  59       (let ((match (regexp-exec regexp s)))
  60         (values (parse-time (match:substring match 1))
  61                 (parse-time (match:substring match 2)))))))
  62
  63 (define (read-sub-rip port)
  64   "Read a SubRip formatted subtitle from PORT."
  65   (let-values (((id) (string->number (read-line port)))
  66                ((start end) (parse-time-span (read-line port)))
  67                ((lines) (let loop ((lines '()))
  68                           (let ((line (read-line port)))
  69                             (if (string-null? line)
  70                                 lines
  71                                 (loop (cons line lines)))))))
  72     (make-subtitle id start end lines)))
  73
  74 (define (read-sub-rips port)
  75   "Read all SubRip formatted subtitles from PORT."
  76   (reverse
  77    (let loop ((subs '()))
  78      (if (eof-object? (peek-char port))
  79          subs
  80          (loop (cons (read-sub-rip port) subs))))))
  81
  82 (define (write-time time port)
  83   "Write TIME as a WebVTT formatted timestamp to PORT."
  84   (match time
  85    ((h m s ms)
  86     (format port "~a:~a:~a.~a" h m s ms))))
  87
  88 (define (write-web-vtt subtitle port)
  89   "Write SUBTITLE as a WebVTT formatted subtitle to PORT."
  90   (match subtitle
  91     (($ <subtitle> id start end text)
  92      (format port "~a~%" id)
  93      (write-time start port)
  94      (display " --> " port)
  95      (write-time end port)
  96      (newline port)
  97      (format port "~a~%" (string-join text "\n"))
  98      (newline port))))
  99
 100 (define (write-web-vtts subtitles port)
 101   "Write all SUBTITLES as WebVTT formatted subtitles to PORT."
 102   (format port "WEBVTT~%~%")
 103   (for-each (cut write-web-vtt <> port) subtitles))
 104
 105 (define (convert input-port output-port)
 106   "Read the SubRip formatted subtitles from INPUT-PORT and write the
 107 WebVTT equivalents to OUTPUT-PORT."
 108   (write-web-vtts (read-sub-rips input-port) output-port))
 109
 110 (define (show-help-and-exit)
 111   (format #t "Usage: srt2vtt [OPTIONS]
 112 Convert SubRip formatted subtitles to WebVTT format.~%")
 113   (display "
 114   -h, --help             display this help and exit")
 115   (display "
 116   -v, --version          display version and exit")
 117   (display "
 118   -i, --input=FILE-NAME  read input from FILE-NAME")
 119   (display "
 120   -o, --output=FILE-NAME write output to FILE-NAME")
 121   (newline)
 122   (exit 0))
 123
 124 (define (show-version-and-exit)
 125   (format #t "srt2vtt 0.1~%")
 126   (exit 0))
 127
 128 (define (show-usage-and-exit)
 129   (format #t "Try `srt2vtt --help' for more information.~%")
 130   (exit 1))
 131
 132 (define (show-wrong-args-and-exit)
 133   (format #t "Invalid arguments~%")
 134   (show-usage-and-exit))
 135
 136 (define %default-args
 137   `((input . ,(current-input-port))
 138     (output . ,(current-output-port))))
 139
 140 (define %options
 141   (list (option '(#\h "help") #f #f
 142                 (lambda (opt name arg args)
 143                   (show-help-and-exit)))
 144         (option '(#\v "version") #f #f
 145                 (lambda (opt name arg args)
 146                   (show-version-and-exit)))
 147         (option '(#\i "input") #t #f
 148                 (lambda (opt name arg args)
 149                   (alist-cons 'input arg args)))
 150         (option '(#\o "output") #t #f
 151                 (lambda (opt name arg args)
 152                   (alist-cons 'output arg args)))))
 153
 154 (define (make-call-with-port-or-file file-proc)
 155   "Create a new procedure that accepts two arguments: a port or file,
 156 and a procedure.  When the returned procedure is called with a port as
 157 the first argument, the second argument is simply applied with that
 158 port.  If the first argument is a string, the second argument is
 159 applied with the port corresponding to the file name contained in the
 160 string as opened by FILE-PROC."
 161   (lambda (port-or-file proc)
 162     (if (port? port-or-file)
 163         (proc port-or-file)
 164         (file-proc port-or-file proc))))
 165
 166 (define call-with-port-or-input-file
 167   (make-call-with-port-or-file call-with-input-file))
 168
 169 (define call-with-port-or-output-file
 170   (make-call-with-port-or-file call-with-output-file))
 171
 172 (define (parse-opts args)
 173   "Parse the list of ARGS and return a list of option/value pairs.
 174 When an option isn't specified in ARGS, it defaults to the value in
 175 '%default-args'."
 176   (args-fold args
 177              %options
 178              (lambda (opt name arg args)
 179                (error "Unrecognized option '~a'" name))
 180              (lambda (arg args)
 181                (error "Extraneous argument '~a'" arg))
 182              %default-args))
 183
 184 (define (main args)
 185   "srt2vtt entry point."
 186   (let ((opts (parse-opts args)))
 187     (call-with-port-or-input-file (assoc-ref opts 'input)
 188       (lambda (input-port)
 189         (call-with-port-or-output-file (assoc-ref opts 'output)
 190           (lambda (output-port)
 191             (convert input-port output-port)))))))
 192
 193 (match (command-line)
 194   ((arg0 args ...)
 195    (main args)))