;;; Mudsync --- Live hackable MUD
;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
;;;
;;; This file is part of Mudsync.
;;;
;;; Mudsync is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or
;;; (at your option) any later version.
;;;
;;; Mudsync is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with Mudsync.  If not, see <http://www.gnu.org/licenses/>.

(define-module (mudsync room)
  #:use-module (mudsync command)
  #:use-module (mudsync gameobj)
  #:use-module (8sync systems actors)
  #:use-module (8sync agenda)
  #:use-module (oop goops)
  #:use-module (srfi srfi-1)
  #:export (<room>
            room-actions
            room-actions*

            <exit>))


;;; Exits
;;; =====

(define-class <exit> ()
  ;; Used for wiring
  (to-symbol #:accessor exit-to-symbol
             #:init-keyword #:to-symbol)
  ;; The actual address we use
  (to-address #:accessor exit-to-address
              #:init-keyword #:address)
  ;; Name of the room (@@: Should this be names?)
  (name #:accessor exit-name
        #:init-keyword #:name)
  (desc #:accessor exit-desc
               #:init-keyword #:desc)

  ;; *Note*: These two methods have an extra layer of indirection, but
  ;;   it's for a good reason.
  (visible-check #:init-value (const #t)
                 #:init-keyword #:visible-check)
  ;; By default all exits can be traversed
  (traverse-check #:init-value (const #t)
                  #:init-keyword #:traverse-check))

(define* (exit-can-traverse? exit actor
                             #:optional (target-actor (actor-id actor)))
  ((slot-ref exit 'traverse-check) exit actor target-actor))

(define* (exit-is-visible? exit actor
                           #:optional (target-actor (actor-id actor)))
  ((slot-ref exit 'traverse-check) exit actor target-actor))



;;; Rooms
;;; =====

(define %room-contain-commands
  (list
   (loose-direct-command "look" 'cmd-look-at)
   (empty-command "look" 'cmd-look-room)
   (loose-direct-command "go" 'cmd-go)))

;; TODO: Subclass from container?
(define-class <room> (<gameobj>)
  ;; A list of <exit>
  (exits #:init-value '()
         #:init-keyword #:exits
         #:getter room-exits)

  (container-commands
   #:init-value %room-contain-commands)

  (message-handler
   #:allocation #:each-subclass
   ;; @@: Can remove this indirection once things settle
   #:init-value (wrap-apply room-action-dispatch)))


(define room-actions
  (build-actions
   ;; desc == description
   (wire-exits! (wrap-apply room-wire-exits!))
   (cmd-go (wrap-apply room-cmd-go))))

(define room-actions*
  (append room-actions gameobj-actions))

(define room-action-dispatch
  (simple-dispatcher room-actions*))


(define (room-wire-exits! room message)
  "Actually hook up the rooms' exit addresses to the rooms they
claim to point to."
  (for-each
   (lambda (exit)
     (define new-exit
       (<-wait room (gameobj-gm room) 'lookup-room
               #:symbol (exit-to-symbol exit)))

     (set! (exit-to-address exit) new-exit))

   (room-exits room)))

(define-mhandler (room-cmd-go room message direct-obj)
  (define exit
    (find
     (lambda (exit)
       (equal? (exit-name exit) direct-obj))
     (pk 'later-exits (room-exits room))))
  (if exit
      (<- room (message-from message) 'tell
          #:text "Yeah you can go there...\n")
      (<- room (message-from message) 'tell
          #:text "I don't know where that is?\n")))