Add wire cage

[mudsync.git] / worlds / bricabrac.scm

;;; Mudsync --- Live hackable MUD
;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
;;;
;;; This file is part of Mudsync.
;;;
;;; Mudsync is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or
;;; (at your option) any later version.
;;;
;;; Mudsync is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with Mudsync.  If not, see <http://www.gnu.org/licenses/>.

;;; Hotel Bricabrac

(use-modules (mudsync)
             (mudsync parser)
             (8sync actors)
             (8sync agenda)
             (oop goops)
             (ice-9 control)
             (ice-9 format)
             (ice-9 match)
             (rx irregex))


\f
;;; Utilities, useful or otherwise
;;; ==============================

(set! *random-state* (random-state-from-platform))

(define (random-choice lst)
  (list-ref lst (random (length lst))))

;; list of lists, lol.
(define-syntax-rule (lol (list-contents ...) ...)
  (list (list list-contents ...) ...))

\f
;;; Some simple object types.
;;; =========================

(define-class <readable> (<thing>)
  (read-text #:init-value "All it says is: \"Blah blah blah.\""
             #:init-keyword #:read-text)
  (commands
   #:allocation #:each-subclass
   #:init-thunk (build-commands
                 ("read" ((direct-command cmd-read)))))
  (actions #:allocation #:each-subclass
           #:init-thunk (build-actions
                         (cmd-read readable-cmd-read))))

(define (readable-cmd-read actor message)
  (<- (message-from message) 'tell
      #:text (string-append (slot-ref actor 'read-text) "\n")))


\f
;;; Lobby
;;; -----

(define (npc-chat-randomly actor message . _)
  (define text-to-send
    (format #f "~a says: \"~a\"\n"
            (slot-ref actor 'name)
            (random-choice (slot-ref actor 'catchphrases))))
  (<- (message-from message) 'tell
      #:text text-to-send))

(define hotel-owner-grumps
  '("Eight sinks!  Eight sinks!  And I couldn't unwind them..."
    "Don't mind the mess.  I built this place on a dare, you
know?"
    "(*tearfully*) Here, take this parenthesis.  May it serve
you well."
    "I gotta get back to the goblin farm soon..."
    "Oh, but I was going to make a mansion... a great,
beautiful mansion!  Full of ghosts!  Now all I have is this cruddy
mo... hotel.  Oh... If only I had more time!"
    "I told them to paint more of the walls purple.
Why didn't they listen?"
    "Listen to that overhead muzak.  Whoever made that doesn't
know how to compose very well!  Have you heard of the bands 'fmt'
or 'skribe'?  Now *that's* composition!"))

(define-class <chatty-npc> (<gameobj>)
  (catchphrases #:init-value '("Blarga blarga blarga!")
                #:init-keyword #:catchphrases)
  (commands
   #:allocation #:each-subclass
   #:init-thunk (build-commands
                 (("chat" "talk") ((direct-command cmd-chat)))))
  (actions #:allocation #:each-subclass
           #:init-thunk
           (build-actions
            (cmd-chat npc-chat-randomly))))

(define-class <sign-in-form> (<gameobj>)
  (commands
   #:allocation #:each-subclass
   #:init-thunk (build-commands
                 ("sign" ((prep-direct-command cmd-sign-form '("as"))))))
  (actions #:allocation #:each-subclass
           #:init-thunk (build-actions
                         (cmd-sign-form sign-cmd-sign-in))))


(define name-sre
  (sre->irregex '(: alpha (** 1 14 (or alphanum "-" "_")))))

(define forbidden-words
  (append article preposition
          '("and" "or" "but" "admin")))

(define (valid-name? name)
  (and (irregex-match name-sre name)
       (not (member name forbidden-words))))

(define* (sign-cmd-sign-in actor message
                           #:key direct-obj indir-obj preposition)
  (define old-name
    (mbody-val (<-wait (message-from message) 'get-name)))
  (define name indir-obj)
  (if (valid-name? indir-obj)
      (begin
        (<-wait (message-from message) 'set-name! name)
        (<- (slot-ref actor 'loc) 'tell-room
            #:text (format #f "~a signs the form!\n~a is now known as ~a\n"
                           old-name old-name name)))
      (<- (message-from message) 'tell
          #:text "Sorry, that's not a valid name.
Alphanumerics, _ and - only, 2-15 characters, starts with an alphabetic
character.\n")))


(define-class <summoning-bell> (<thing>)
  (summons #:init-keyword #:summons)

  (commands
   #:allocation #:each-subclass
   #:init-thunk (build-commands
                 ("ring" ((direct-command cmd-ring)))))
  (actions #:allocation #:each-subclass
           #:init-thunk (build-actions
                         (cmd-ring summoning-bell-cmd-ring))))

(define* (summoning-bell-cmd-ring bell message . _)
  ;; Call back to actor who invoked this message handler
  ;; and find out their name.  We'll call *their* get-name message
  ;; handler... meanwhile, this procedure suspends until we get
  ;; their response.
  (define who-rang
    (mbody-val (<-wait (message-from message) 'get-name)))

  ;; Now we'll invoke the "tell" message handler on the player
  ;; who rang us, displaying this text on their screen.
  ;; This one just uses <- instead of <-wait, since we don't
  ;; care when it's delivered; we're not following up on it.
  (<- (message-from message) 'tell
      #:text "*ring ring!*  You ring the bell!\n")
  ;; We also want everyone else in the room to "hear" the bell,
  ;; but they get a different message since they aren't the ones
  ;; ringing it.  Notice here's where we make use of the invoker's
  ;; name as extracted and assigned to the who-rang variable.
  ;; Notice how we send this message to our "location", which
  ;; forwards it to the rest of the occupants in the room.
  (<- (gameobj-loc bell) 'tell-room
      #:text
      (format #f "*ring ring!*  ~a rings the bell!\n"
              who-rang)
      #:exclude (message-from message))
  ;; Now we perform the primary task of the bell, which is to summon
  ;; the "clerk" character to the room.  (This is configurable,
  ;; so we dynamically look up their address.)
  (<- (dyn-ref bell (slot-ref bell 'summons)) 'be-summoned
      #:who-summoned (message-from message)))


(define prefect-quotes
  '("I'm a frood who really knows where my towel is!"
    "On no account allow a Vogon to read poetry at you."
    "Time is an illusion, lunchtime doubly so!"
    "How can you have money if none of you produces anything?"
    "On no account allow Arthur to request tea on this ship."))

(define lobby
  (lol
   ('room:lobby
    <room> #f
    #:name "Hotel Lobby"
    #:desc
    '((p "You're in some sort of hotel lobby.  You see a large sign hanging "
         "over the desk that says \"Hotel Bricabrac\".  On the desk is a bell "
         "that says \"'ring bell' for service\".  Terrible music plays from a speaker "
         "somewhere overhead.  "
         "The room is lined with various curio cabinets, filled with all sorts "
         "of kitschy junk.  It looks like whoever decorated this place had great "
         "ambitions, but actually assembled it all in a hurry and used whatever "
         "kind of objects they found lying around.")
      (p "There's a door to the north leading to some kind of hallway."))
    #:exits
    (list (make <exit>
            #:name "north"
            #:to 'room:grand-hallway)))
   ;; NPC: hotel owner
   ('npc:lobby:hotel-owner
    <chatty-npc> 'room:lobby
    #:name "a frumpy fellow"
    #:desc
    '((p "  Whoever this is, they looks totally exhausted.  They're
collapsed into the only comfortable looking chair in the room and you
don't get the sense that they're likely to move any time soon.
  You notice they're wearing a sticker badly adhesed to their clothing
which says \"Hotel Proprietor\", but they look so disorganized that you
think that can't possibly be true... can it?
  Despite their exhaustion, you sense they'd be happy to chat with you,
though the conversation may be a bit one sided."))
    #:goes-by '("frumpy fellow" "fellow"
                "Chris Webber"  ; heh, did you rtfc?  or was it so obvious?
                "hotel proprietor" "proprietor")
    #:catchphrases hotel-owner-grumps)
   ;; Object: Sign
   ('thing:lobby:sign
    <readable> 'room:lobby
    #:name "the Hotel Bricabrac sign"
    #:desc "  It strikes you that there's something funny going on with this sign.
Sure enough, if you look at it hard enough, you can tell that someone
hastily painted over an existing sign and changed the \"M\" to an \"H\".
Classy!"
    #:read-text "  All it says is \"Hotel Bricabrac\" in smudged, hasty text."
    #:goes-by '("sign"
                "bricabrac sign"
                "hotel sign"
                "hotel bricabrac sign"
                "lobby sign"))

   ('thing:lobby:bell
    <summoning-bell> 'room:lobby
    #:name "a shiny brass bell"
    #:goes-by '("shiny brass bell" "shiny bell" "brass bell" "bell")
    #:desc "  A shiny brass bell.  Inscribed on its wooden base is the text
\"ring me for service\".  You probably could \"ring the bell\" if you 
wanted to."
    #:summons 'npc:break-room:desk-clerk)

   ;; Object: curio cabinets
   ('thing:lobby:cabinet
    <gameobj> 'room:lobby
    #:name "a curio cabinet"
    #:goes-by '("curio cabinet" "cabinet" "bricabrac cabinet"
                "cabinet of curiosities")
    #:desc (lambda _
             (format #f "  The curio cabinet is full of all sorts of oddities!
Something catches your eye!
Ooh, ~a!" (random-choice
           '("a creepy porcelain doll"
             "assorted 1950s robots"
             "an exquisite tea set"
             "an antique mustard pot"
             "the pickled head of Elvis"
             "the pickled circuitboard of EVLIS"
             "a scroll of teletype paper holding the software Four Freedoms"
             "a telephone shaped like an orange cartoon cat")))))
   ('thing:lobby:sign-in-form
    <sign-in-form> 'room:lobby
    #:name "sign-in form"
    #:goes-by '("sign-in form" "form" "signin form")
    #:desc "It looks like you could sign this form and set your name.")

   ('thing:lobby:porcelain-doll
    <thing> 'room:lobby
    #:generally-visible #f
    #:name "a creepy porcelain doll"
    #:desc "It strikes you that while the doll is technically well crafted,
it's also the stuff of nightmares."
    #:goes-by '("porcelain doll" "doll"))
   ('thing:lobby:1950s-robots
    <thing> 'room:lobby
    #:generally-visible #f
    #:name "a set of 1950s robots"
    #:desc "There's a whole set of these 1950s style robots.
They seem to be stamped out of tin, and have various decorations of levers
and buttons and springs.  Some of them have wind-up knobs on them."
    #:goes-by '("robot" "robots" "1950s robot" "1950s robots"))
   ('thing:lobby:tea-set
    <thing> 'room:lobby
    #:generally-visible #f
    #:name "a tea set"
    #:desc "A complete tea set.  Some of the cups are chipped.
You can imagine yourself joining a tea party using this set, around a
nice table with some doilies, drinking some Earl Grey tea, hot.  Mmmm."
    #:goes-by '("tea set" "tea"))
   ('thing:lobby:mustard-pot
    <thing> 'room:lobby
    #:generally-visible #f
    #:name "a mustard pot"
    #:desc '((p "It's a mustard pot.  I mean, it's kind of cool, it has a
nice design, and it's an antique, but you can't imagine putting something
like this in a museum.")
             (p "Ha... imagine that... a mustard museum."))
    #:goes-by '("mustard pot" "antique mustard pot" "mustard"))
   ('thing:lobby:head-of-elvis
    <thing> 'room:lobby
    #:generally-visible #f
    #:name "the pickled head of Elvis"
    #:desc '((p "It's a jar full of some briny-looking liquid and...
a free floating head.  The head looks an awful lot like Elvis, and
definitely not the younger Elvis.  The hair even somehow maintains
that signature swoop while suspended in liquid.  But of course it's
not Elvis.")
             (p "Oh, wait, it has a label at the bottom which says:
\"This is really the head of Elvis\".  Well... maybe don't believe
everything you read."))
    #:goes-by '("pickled head of elvis" "pickled head of Elvis"
                "elvis" "Elvis" "head" "pickled head"))
   ('thing:lobby:circuitboard-of-evlis
    <thing> 'room:lobby
    #:generally-visible #f
    #:name "the pickled circuitboard of Evlis"
    #:desc '((p "It's a circuitboard from a Lisp Machine called EVLIS.
This is quite the find, and you bet just about anyone interested in
preserving computer history would love to get their hands on this.")
             (p "Unfortunately, whatever moron did acquire this has
no idea what it means to preserve computers, so here it is floating
in some kind of briny liquid.  It appears to be heavily corroded.
Too bad..."))
    #:goes-by '("pickled circuitboard of evlis" "pickled circuitboard of Evlis"
                "pickled circuitboard of EVLIS"
                "evlis" "Evlis" "EVLIS" "circuitboard" "pickled circuitboard"))
   ('thing:lobby:teletype-scroll
    <thing> 'room:lobby
    #:generally-visible #f
    #:name "a scroll of teletype"
    #:desc '((p "This is a scroll of teletype paper.  It's a bit old
and yellowed but the type is very legible.  It says:")
             (br)
             (i
              (p (strong "== The four essential freedoms =="))
              (p "A program is free software if the program's users have
the four essential freedoms: ")
              (ul (li "The freedom to run the program as you wish, for any purpose (freedom 0).")
                  (li "The freedom to study how the program works, and change it so it does your computing as you wish (freedom 1). Access to the source code is a precondition for this.")
                  (li "The freedom to redistribute copies so you can help your neighbor (freedom 2).")
                  (li "The freedom to distribute copies of your modified versions to others (freedom 3). By doing this you can give the whole community a chance to benefit from your changes. Access to the source code is a precondition for this.")))
             (p "You get this feeling that ambiguities in the
English language surrounding the word 'free' have lead to a lot of terminology debates."))
    #:goes-by '("scroll of teletype" "scroll of teletype paper" "teletype scroll"
                "teletype paper" "scroll" "four freedoms"
                "scroll of teletype paper holding the software Four Freedoms"
                "scroll of teletype paper holding the software four freedoms"))
   ('thing:lobby:orange-cat-phone
    <thing> 'room:lobby
    #:generally-visible #f
    #:name "a telephone shaped like an orange cartoon cat"
    #:desc "It's made out of a cheap plastic, and it's very orange.
It resembles a striped tabby, and it's eyes hold the emotion of
a being both sleepy and smarmy.
You suspect that someone, somewhere made a ton of cash on items holding
this general shape in the 1990s."
    #:goes-by '("orange cartoon cat phone" "orange cartoon cat telephone"
                "orange cat phone" "orange cat telephone"
                "cartoon cat phone" "cartoon cat"
                "cat phone" "cat telephone" "phone" "telephone"))))


\f
;;; Grand hallway
;;; -------------

(define grand-hallway
  (lol
   ('room:grand-hallway
    <room> #f
    #:name "Grand Hallway"
    #:desc "  A majestic red carpet runs down the center of the room.
Busts of serious looking people line the walls, but there's no
clear indication that they have any logical relation to this place.
  In the center is a large statue of a bearded man.  You wonder what
that's all about?
  To the south is the lobby.  A door to the east is labeled \"smoking
room\", while a door to the west is labeled \"playroom\"."
    #:exits
    (list (make <exit>
            #:name "south"
            #:to 'room:lobby)
          (make <exit>
            #:name "west"
            #:to 'room:playroom)
          (make <exit>
            #:name "east"
            #:to 'room:smoking-parlor)))
   ('thing:ignucius-statue
    <gameobj> 'room:grand-hallway
    #:name "a statue"
    #:desc "  The statue is of a serious-looking bearded man with long, flowing hair.
  It has a large physical halo.  Removing it is tempting, but it looks pretty
well fastened."
    #:goes-by '("statue" "st ignucius" "st. ignucius"))))

\f
;;; Playroom
;;; --------

(define playroom
  (lol
   ('room:playroom
    <room> #f
    #:name "The Playroom"
    #:desc "  There are toys scattered everywhere here.  It's really unclear
if this room is intended for children or child-like adults."
    #:exits
    (list (make <exit>
            #:name "east"
            #:to 'room:grand-hallway)))
   ('thing:playroom:cubey
    <thing> 'room:playroom
    #:name "cubey"
    #:takeable #t
    #:desc "  It's a little foam cube with googly eyes on it.  So cute!")
   ('thing:cuddles-plushie
    <thing> 'room:playroom
    #:name "a cuddles plushie"
    #:goes-by '("plushie" "cuddles plushie" "cuddles")
    #:takeable #t
    #:desc "  A warm and fuzzy cuddles plushie!  It's a cuddlefish!")))


\f
;;; Writing room
;;; ------------

\f
;;; Armory???
;;; ---------

;; ... full of NURPH weapons?

\f
;;; Smoking parlor
;;; --------------

(define-class <furniture> (<gameobj>)
  (sit-phrase #:init-keyword #:sit-phrase)
  (sit-phrase-third-person #:init-keyword #:sit-phrase-third-person)
  (sit-name #:init-keyword #:sit-name)

  (commands
   #:allocation #:each-subclass
   #:init-thunk (build-commands
                 ("sit" ((direct-command cmd-sit-furniture)))))
  (actions #:allocation #:each-subclass
           #:init-thunk (build-actions
                         (cmd-sit-furniture furniture-cmd-sit))))

(define* (furniture-cmd-sit actor message #:key direct-obj)
  (define player-name
    (mbody-val (<-wait (message-from message) 'get-name)))
  (<- (message-from message) 'tell
      #:text (format #f "You ~a ~a.\n"
                     (slot-ref actor 'sit-phrase)
                     (slot-ref actor 'sit-name)))
  (<- (slot-ref actor 'loc) 'tell-room
      #:text (format #f "~a ~a on ~a.\n"
                     player-name
                     (slot-ref actor 'sit-phrase-third-person)
                     (slot-ref actor 'sit-name))
      #:exclude (message-from message)))


(define smoking-parlor
  (lol
   ('room:smoking-parlor
    <room> #f
    #:name "Smoking Parlor"
    #:desc
    '((p "This room looks quite posh.  There are huge comfy seats you can sit in
if you like. Strangely, you see a large sign saying \"No Smoking\".  The owners must
have installed this place and then changed their mind later.")
      (p "There's a door to the west leading back to the grand hallway, and
a nondescript steel door to the south, leading apparently outside."))
    #:exits
    (list (make <exit>
            #:name "west"
            #:to 'room:grand-hallway)
          (make <exit>
            #:name "south"
            #:to 'room:break-room)))
   ('thing:smoking-parlor:chair
    <furniture> 'room:smoking-parlor
    #:name "a comfy leather chair"
    #:desc "  That leather chair looks really comfy!"
    #:goes-by '("leather chair" "comfy leather chair" "chair")
    #:sit-phrase "sink into"
    #:sit-phrase-third-person "sinks into"
    #:sit-name "the comfy leather chair")
   ('thing:smoking-parlor:sofa
    <furniture> 'room:smoking-parlor
    #:name "a plush leather sofa"
    #:desc "  That leather chair looks really comfy!"
    #:goes-by '("leather sofa" "plush leather sofa" "sofa"
                "leather couch" "plush leather couch" "couch")
    #:sit-phrase "sprawl out on"
    #:sit-phrase-third-person "sprawls out on into"
    #:sit-name "the plush leather couch")
   ('thing:smoking-parlor:bar-stool
    <furniture> 'room:smoking-parlor
    #:name "a bar stool"
    #:desc "  Conveniently located near the bar!  Not the most comfortable
seat in the room, though."
    #:goes-by '("stool" "bar stool" "seat")
    #:sit-phrase "hop on"
    #:sit-phrase-third-person "hops onto"
    #:sit-name "the bar stool")
   ('npc:ford-prefect
    <chatty-npc> 'room:smoking-parlor
    #:name "Ford Prefect"
    #:desc "Just some guy, you know?"
    #:goes-by '("Ford Prefect" "ford prefect"
                "frood" "prefect" "ford")
    #:catchphrases prefect-quotes)

   ('thing:smoking-parlor:no-smoking-sign
    <thing> 'room:smoking-parlor
    #:generally-visible #f
    #:name "No Smoking Sign"
    #:desc "This sign says \"No Smoking\" in big, red letters.
It has some bits of bubble gum stuck to it... yuck."
    #:goes-by '("no smoking sign" "sign"))

   ;; TODO: Cigar dispenser
   ))

\f

;;; Breakroom
;;; ---------

(define-class <desk-clerk> (<thing>)
  ;; The desk clerk has three states:
  ;;  - on-duty: Arrived, and waiting for instructions (and losing patience
  ;;    gradually)
  ;;  - slacking: In the break room, probably smoking a cigarette
  ;;    or checking text messages
  (state #:init-value 'slacking)
  (commands #:allocation #:each-subclass
            #:init-thunk
            (build-commands
             (("talk" "chat") ((direct-command cmd-chat)))
             ("ask" ((direct-command cmd-ask-incomplete)
                     (prep-direct-command cmd-ask-about)))
             ("dismiss" ((direct-command cmd-dismiss)))))
  (patience #:init-value 0)
  (actions #:allocation #:each-subclass
           #:init-thunk (build-actions
                         (init clerk-act-init)
                         (cmd-chat clerk-cmd-chat)
                         (cmd-ask-incomplete clerk-cmd-ask-incomplete)
                         (cmd-ask-about clerk-cmd-ask)
                         (cmd-dismiss clerk-cmd-dismiss)
                         (update-loop clerk-act-update-loop)
                         (be-summoned clerk-act-be-summoned))))

(define (clerk-act-init clerk message . _)
  ;; call the gameobj main init method
  (gameobj-act-init clerk message)
  ;; start our main loop
  (<- (actor-id clerk) 'update-loop))

(define clerk-help-topics
  '(("changing name" .
     "Changing your name is easy!  We have a clipboard here at the desk
where you can make yourself known to other participants in the hotel
if you sign it.  Try 'sign form as <your-name>', replacing
<your-name>, obviously!")
    ("common commands" .
     "Here are some useful commands you might like to try: chat,
go, take, drop, say...")
    ("hotel" .
     "We hope you enjoy your stay at Hotel Bricabrac.  As you may see,
our hotel emphasizes interesting experiences over rest and lodging.
The origins of the hotel are... unclear... and it has recently come
under new... 'management'.  But at Hotel Bricabrac we believe these
aspects make the hotel into a fun and unique experience!  Please,
feel free to walk around and explore.")))


(define clerk-knows-about
  "'ask clerk about changing name', 'ask clerk about common commands', and 'ask clerk about the hotel'")

(define clerk-general-helpful-line
  (string-append
   "The clerk says, \"If you need help with anything, feel free to ask me about it.
For example, 'ask clerk about changing name'. You can ask me about the following:
" clerk-knows-about ".\"\n"))

(define clerk-slacking-complaints
  '("The pay here is absolutely lousy."
    "The owner here has no idea what they're doing."
    "Some times you just gotta step away, you know?"
    "You as exhausted as I am?"
    "Yeah well, this is just temporary.  I'm studying to be a high
energy particle physicist.  But ya gotta pay the bills, especially
with tuition at where it is..."))

(define* (clerk-cmd-chat clerk message #:key direct-obj)
  (match (slot-ref clerk 'state)
    ('on-duty
     (<- (message-from message) 'tell
         #:text clerk-general-helpful-line))
    ('slacking
     (<- (message-from message) 'tell
         #:text
         (string-append
          "The clerk says, \""
          (random-choice clerk-slacking-complaints)
          "\"\n")))))

(define (clerk-cmd-ask-incomplete clerk message . _)
  (<- (message-from message) 'tell
      #:text "The clerk says, \"Ask about what?\"\n"))

(define clerk-doesnt-know-text
  "The clerk apologizes and says she doesn't know about that topic.\n")

(define* (clerk-cmd-ask clerk message #:key indir-obj
                        #:allow-other-keys)
  (match (slot-ref clerk 'state)
    ('on-duty
     (match (assoc (pk 'indir indir-obj) clerk-help-topics)
       ((_ . info)
           (<- (message-from message) 'tell
               #:text
               (string-append "The clerk clears her throat and says:\n  \""
                              info
                              "\"\n")))
       (#f
        (<- (message-from message) 'tell
            #:text clerk-doesnt-know-text))))
    ('slacking
     (<- (message-from message) 'tell
         #:text "The clerk says, \"Sorry, I'm on my break.\"\n"))))

(define* (clerk-act-be-summoned clerk message #:key who-summoned)
  (match (slot-ref clerk 'state)
    ('on-duty
     (<- who-summoned 'tell
         #:text
         "The clerk tells you as politely as she can that she's already here,
so there's no need to ring the bell.\n"))
    ('slacking
     (<- (gameobj-loc clerk) 'tell-room
         #:text
         "The clerk's ears perk up, she stamps out a cigarette, and she
runs out of the room!\n")
     (gameobj-set-loc! clerk (dyn-ref clerk 'room:lobby))
     (slot-set! clerk 'patience 8)
     (slot-set! clerk 'state 'on-duty)
     (<- (gameobj-loc clerk) 'tell-room
         #:text
         (string-append
          "  Suddenly, a uniformed woman rushes into the room!  She's wearing a
badge that says \"Desk Clerk\".
  \"Hello, yes,\" she says between breaths, \"welcome to Hotel Bricabrac!
We look forward to your stay.  If you'd like help getting acclimated,
feel free to ask me.  For example, 'ask clerk about changing name'.
You can ask me about the following:
" clerk-knows-about ".\"\n")))))

(define* (clerk-cmd-dismiss clerk message . _)
  (define player-name
    (mbody-val (<-wait (message-from message) 'get-name)))
  (match (slot-ref clerk 'state)
    ('on-duty
     (<- (gameobj-loc clerk) 'tell-room
         #:text
         (format #f "\"Thanks ~a!\" says the clerk. \"I have somewhere I need to be.\"
The clerk leaves the room in a hurry.\n"
                 player-name)
         #:exclude (actor-id clerk))
     (gameobj-set-loc! clerk (dyn-ref clerk 'room:break-room))
     (slot-set! clerk 'state 'slacking)
     (<- (gameobj-loc clerk) 'tell-room
         #:text clerk-return-to-slacking-text
         #:exclude (actor-id clerk)))
    ('slacking
     (<- (message-from message) 'tell
         #:text "The clerk sternly asks you to not be so dismissive.\n"))))

(define clerk-slacking-texts
  '("The clerk takes a long drag on her cigarette.\n"
    "The clerk scrolls through text messages on her phone.\n"
    "The clerk coughs a few times.\n"
    "The clerk checks her watch and justifies a few more minutes outside.\n"
    "The clerk fumbles around for a lighter.\n"
    "The clerk sighs deeply and exhaustedly.\n"
    "The clerk fumbles around for a cigarette.\n"))

(define clerk-working-impatience-texts
  '("The clerk hums something, but you're not sure what it is."
    "The clerk attempts to change the overhead music, but the dial seems broken."
    "The clerk clicks around on the desk computer."
    "The clerk scribbles an equation on a memo pad, then crosses it out."
    "The clerk mutters something about the proprietor having no idea how to run a hotel."
    "The clerk thumbs through a printout of some physics paper."))

(define clerk-slack-excuse-text
  "The desk clerk excuses herself, but says you are welcome to ring the bell
if you need further help.")

(define clerk-return-to-slacking-text
  "The desk clerk enters and slams the door behind her.\n")


(define (clerk-act-update-loop clerk message)
  (define (tell-room text)
    (<- (gameobj-loc clerk) 'tell-room
        #:text text
        #:exclude (actor-id clerk)))
  (define (loop-if-not-destructed)
    (if (not (slot-ref clerk 'destructed))
        ;; This iterates by "recursing" on itself by calling itself
        ;; (as the message handler) again.  It used to be that we had to do
        ;; this, because there was a bug where a loop which yielded like this
        ;; would keep growing the stack due to some parameter goofiness.
        ;; That's no longer true, but there's an added advantage to this
        ;; route: it's much more live hackable.  If we change the definition
        ;; of this method, the character will act differently on the next
        ;; "tick" of the loop.
        (<- (actor-id clerk) 'update-loop)))
  (match (slot-ref clerk 'state)
    ('slacking
     (tell-room (random-choice clerk-slacking-texts))
     (8sleep (+ (random 20) 15))
     (loop-if-not-destructed))
    ('on-duty
     (if (> (slot-ref clerk 'patience) 0)
         ;; Keep working but lose patience gradually
         (begin
           (tell-room (random-choice clerk-working-impatience-texts))
           (slot-set! clerk 'patience (- (slot-ref clerk 'patience)
                                         (+ (random 2) 1)))
           (8sleep (+ (random 60) 40))
           (loop-if-not-destructed))
         ;; Back to slacking
         (begin
           (tell-room clerk-slack-excuse-text)
           ;; back bto the break room
           (gameobj-set-loc! clerk (pk 'break-room (dyn-ref clerk 'room:break-room)))
           (tell-room clerk-return-to-slacking-text)
           ;; annnnnd back to slacking
           (slot-set! clerk 'state 'slacking)
           (8sleep (+ (random 30) 15))
           (loop-if-not-destructed))))))


(define break-room
  (lol
   ('room:break-room
    <room> #f
    #:name "Employee Break Room"
    #:desc "  This is less a room and more of an outdoor wire cage.  You get
a bit of a view of the brick exterior of the building, and a crisp wind blows,
whistling, through the openings of the fenced area.  Partly smoked cigarettes
and various other debris cover the floor.
  Through the wires you can see... well... hm.  It looks oddly like
the scenery tapers off nothingness.  But that can't be right, can it?"
    #:exits
    (list (make <exit>
            #:name "north"
            #:to 'room:smoking-parlor))
    )
   ('npc:break-room:desk-clerk
    <desk-clerk> 'room:break-room
    #:name "the hotel desk clerk"
    #:desc "  The hotel clerk is wearing a neatly pressed uniform bearing the
hotel insignia.  She appears to be rather exhausted."
    #:goes-by '("hotel desk clerk" "clerk" "desk clerk"))
   ('thing:break-room:void
    <thing> 'room:break-room
    #:generally-visible #f
    #:name "The Void"
    #:desc "As you stare into the void, the void stares back into you."
    #:goes-by '("void" "abyss" "nothingness" "scenery"))
   ('thing:break-room:fence
    <thing> 'room:break-room
    #:generally-visible #f
    #:name "break room cage"
    #:desc "It's a mostly-cubical wire mesh surrounding the break area.
You can see through the gaps, but they're too small to put more than a
couple of fingers through.  There appears to be some wear and tear to
the paint, but the wires themselves seem to be unusually sturdy."
    #:goes-by '("fence" "cage" "wire cage"))))


\f
;;; Ennpie's Sea Lounge
;;; -------------------

\f
;;; Computer room
;;; -------------

\f
;;; Game
;;; ----

(define (game-spec)
  (append lobby grand-hallway smoking-parlor
          playroom break-room))

;; TODO: Provide command line args
(define (run-game . args)
  (run-demo (game-spec) 'room:lobby #:repl-server #t))