mudsync/thing.scm

   1 ;;; Mudsync --- Live hackable MUD
   2 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of Mudsync.
   5 ;;;
   6 ;;; Mudsync is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or
   9 ;;; (at your option) any later version.
  10 ;;;
  11 ;;; Mudsync is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;;; General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with Mudsync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;;; Common "things" and stuff you can do with things.
  20
  21 (define-module (mudsync thing)
  22   #:use-module (mudsync command)
  23   #:use-module (mudsync gameobj)
  24   #:use-module (8sync systems actors)
  25   #:use-module (8sync agenda)
  26   #:use-module (oop goops)
  27   #:use-module (ice-9 match)
  28   #:use-module (ice-9 format)
  29   #:export (<thing>
  30             thing-commands
  31             thing-commands*
  32             thing-contained-commands
  33             thing-contained-commands*
  34             thing-actions
  35             thing-actions*))
  36
  37 (define thing-commands
  38   (list
  39    (direct-command "take" 'cmd-take)))
  40
  41 ;; Doesn't inherit anything (gameobj has no commands)
  42 ;; so it's an alias.
  43 (define thing-commands* thing-commands)
  44
  45 (define thing-contained-commands
  46   (list
  47    (direct-command "drop" 'cmd-drop)))
  48
  49 ;; Doesn't inherit anything (gameobj has no contained-commands)
  50 ;; so it's an alias.
  51 (define thing-contained-commands* thing-contained-commands)
  52
  53 (define thing-actions
  54   (build-actions
  55    (cmd-take (wrap-apply thing-cmd-take))
  56    (cmd-drop (wrap-apply thing-cmd-drop))))
  57
  58 (define thing-actions*
  59   (append thing-actions
  60           gameobj-actions))
  61
  62 (define thing-dispatcher
  63   (simple-dispatcher thing-actions*))
  64
  65 (define-class <thing> (<gameobj>)
  66   ;; Can be a boolean or a procedure accepting two arguments
  67   ;; (thing-actor whos-acting)
  68   (takeable #:init-value #f
  69             #:init-keyword #:takeable)
  70   ;; Can be a boolean or a procedure accepting two arguments
  71   ;; (thing-actor whos-dropping)
  72   (dropable #:init-value #t
  73             #:init-keyword #:dropable)
  74   (commands
  75    #:init-value (wrap thing-commands))
  76   (contained-commands
  77    #:init-value (wrap thing-contained-commands))
  78   (message-handler
  79    #:init-value
  80    (wrap-apply thing-dispatcher)))
  81
  82 (define* (thing-cmd-take thing message #:key direct-obj)
  83   (define player (message-from message))
  84   (define player-name
  85     (msg-val (<-wait thing player 'get-name)))
  86   (define player-loc
  87     (msg-val (<-wait thing player 'get-loc)))
  88   (define thing-name (slot-ref thing 'name))
  89   (define should-take
  90     (slot-ref-maybe-runcheck thing 'takeable player))
  91   (if should-take
  92       ;; Set the location to whoever's picking us up
  93       (begin
  94         (gameobj-set-loc! thing player)
  95         (<- thing player 'tell
  96             #:text (format #f "You pick up ~a.\n"
  97                            thing-name))
  98         (<- thing player-loc 'tell-room
  99             #:text (format #f "~a picks up ~a.\n"
 100                            player-name
 101                            thing-name)
 102             #:exclude player))
 103       (<- thing player 'tell
 104           #:text (format #f "It doesn't seem like you can pick up ~a.\n"
 105                          thing-name))))
 106
 107 (define* (thing-cmd-drop thing message #:key direct-obj)
 108   (define player (message-from message))
 109   (define player-name
 110     (msg-val (<-wait thing player 'get-name)))
 111   (define player-loc
 112     (msg-val (<-wait thing player 'get-loc)))
 113   (define thing-name (slot-ref thing 'name))
 114   (define should-drop
 115     (slot-ref-maybe-runcheck thing 'dropable player))
 116   (if player-loc
 117       ;; Set the location to whoever's picking us up's location
 118       (begin
 119         (gameobj-set-loc! thing player-loc)
 120         (<- thing player 'tell
 121             #:text (format #f "You drop ~a.\n"
 122                            thing-name))
 123         (<- thing player-loc 'tell-room
 124             #:text (format #f "~a drops ~a.\n"
 125                            player-name
 126                            thing-name)
 127             #:exclude player))
 128       (<- thing player 'tell
 129           #:text (format #f "It doesn't seem like you can drop ~a.\n"
 130                          thing-name))))