mudsync/room.scm

   1 ;;; Mudsync --- Live hackable MUD
   2 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of Mudsync.
   5 ;;;
   6 ;;; Mudsync is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or
   9 ;;; (at your option) any later version.
  10 ;;;
  11 ;;; Mudsync is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;;; General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with Mudsync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (mudsync room)
  20   #:use-module (mudsync command)
  21   #:use-module (mudsync gameobj)
  22   #:use-module (8sync systems actors)
  23   #:use-module (8sync agenda)
  24   #:use-module (oop goops)
  25   #:use-module (srfi srfi-1)
  26   #:use-module (ice-9 control)
  27   #:export (<room>
  28             room-actions
  29             room-actions*
  30
  31             <exit>))
  32
  33 \f
  34 ;;; Exits
  35 ;;; =====
  36
  37 (define-class <exit> ()
  38   ;; Used for wiring
  39   (to-symbol #:init-keyword #:to-symbol)
  40   ;; The actual address we use
  41   (to-address #:init-keyword #:address)
  42   ;; Name of the room (@@: Should this be names?)
  43   (name #:getter exit-name
  44         #:init-keyword #:name)
  45   (desc #:init-keyword #:desc
  46         #:init-value #f)
  47
  48   ;; *Note*: These two methods have an extra layer of indirection, but
  49   ;;   it's for a good reason.
  50   (visible-check #:init-value (const #t)
  51                  #:init-keyword #:visible-check)
  52   ;; By default all exits can be traversed
  53   (traverse-check #:init-value (const #t)
  54                   #:init-keyword #:traverse-check))
  55
  56 (define* (exit-can-traverse? exit actor
  57                              #:optional (target-actor (actor-id actor)))
  58   ((slot-ref exit 'traverse-check) exit actor target-actor))
  59
  60 (define* (exit-is-visible? exit actor
  61                            #:optional (target-actor (actor-id actor)))
  62   ((slot-ref exit 'traverse-check) exit actor target-actor))
  63
  64
  65 \f
  66 ;;; Rooms
  67 ;;; =====
  68
  69 (define %room-contain-commands
  70   (list
  71    (loose-direct-command "look" 'cmd-look-at)
  72    (empty-command "look" 'cmd-look-room)
  73    (empty-command "go" 'cmd-go-where)
  74    (loose-direct-command "go" 'cmd-go)
  75    (greedy-command "say" 'cmd-say)
  76    (greedy-command "emote" 'cmd-emote)))
  77
  78 (define room-actions
  79   (build-actions
  80    ;; desc == description
  81    (init (wrap-apply room-init))
  82    (wire-exits! (wrap-apply room-wire-exits!))
  83    (cmd-go (wrap-apply room-cmd-go))
  84    (cmd-go-where (wrap-apply room-cmd-go-where))
  85    (announce-entrance (wrap-apply room-announce-entrance))
  86    (look-room (wrap-apply room-look-room))
  87    (tell-room (wrap-apply room-act-tell-room))
  88    ;; in this case the command is the same version as the normal
  89    ;; look-room version
  90    (cmd-look-room (wrap-apply room-look-room))
  91    (cmd-look-at (wrap-apply room-look-at))
  92    (cmd-say (wrap-apply room-cmd-say))
  93    (cmd-emote (wrap-apply room-cmd-emote))))
  94
  95 (define room-actions*
  96   (append room-actions gameobj-actions))
  97
  98 (define room-action-dispatch
  99   (simple-dispatcher room-actions*))
 100
 101 ;; TODO: Subclass from container?
 102 (define-class <room> (<gameobj>)
 103   ;; A list of <exit>
 104   (exits #:init-value '()
 105          #:init-keyword #:exits
 106          #:getter room-exits)
 107
 108   (container-commands
 109    #:init-value (wrap %room-contain-commands))
 110
 111   (message-handler
 112    #:allocation #:each-subclass
 113    ;; @@: Can remove this indirection once things settle
 114    #:init-value (wrap-apply room-action-dispatch)))
 115
 116 (define (room-init room message)
 117   (room-wire-exits! room))
 118
 119 (define (room-wire-exits! room)
 120   "Actually hook up the rooms' exit addresses to the rooms they
 121 claim to point to."
 122   (for-each
 123    (lambda (exit)
 124      (define new-exit
 125        (message-ref
 126         (<-wait room (gameobj-gm room) 'lookup-special
 127                 #:symbol (slot-ref exit 'to-symbol))
 128         'room-id))
 129
 130      (slot-set! exit 'to-address new-exit))
 131
 132    (room-exits room)))
 133
 134 (define-mhandler (room-cmd-go room message direct-obj)
 135   (define exit
 136     (find
 137      (lambda (exit)
 138        (equal? (exit-name exit) direct-obj))
 139      (room-exits room)))
 140   (define to-address (if exit
 141                          (slot-ref exit 'to-address)
 142                          #f))
 143   (define player-name
 144     (message-ref (<-wait room (message-from message)
 145                          'get-name) 'val))
 146   (cond
 147    (exit
 148     ;; Set the player's new location
 149     (<-wait room (message-from message) 'set-loc!
 150             #:loc to-address)
 151     ;; Tell everyone else the person walked away
 152     (room-tell-room
 153      room
 154      (format #f "~a wanders ~a.\n"
 155              player-name direct-obj))
 156     (<- room to-address 'announce-entrance
 157         #:who-entered (message-from message))
 158     ;; Have the new room update the player to the new location
 159     (<- room (slot-ref exit 'to-address) 'look-room
 160         #:to-id (message-from message)))
 161    (else
 162     (<- room (message-from message) 'tell
 163         #:text "You don't see any way to go there.\n"))))
 164
 165 (define-mhandler (room-cmd-go-where room message)
 166   (<- room (message-from message) 'tell
 167       #:text "Go where?\n"))
 168
 169 ;;; look commands
 170
 171 (define (list-words-as-string words)
 172   "A little utility for listing a bunch of words in an English-style list"
 173   ;; TODO: This could be made faster by traversing the O(n)
 174   ;;   list once, not twice
 175   (let ((word-length (length words)))
 176     (cond
 177      ((eqv? word-length 0) "")
 178      ((eqv? word-length 1) (car words))
 179      (else
 180       ;; TODO: and this is NOT efficient
 181       (string-append
 182        (string-join
 183         (drop-right words 1)
 184         ", ")
 185        " and "
 186        (last words))))))
 187
 188 (define (room-player-looks-around room player-id)
 189   "Handle looking around the room"
 190   ;; Get the room text
 191   (define room-text
 192     (format #f "**~a**\n~a\n"
 193             (slot-ref room 'name)
 194             (slot-ref room 'desc)))
 195
 196   ;; Get a list of other things the player would see in the room
 197   (define occupant-names-all
 198     (map
 199      (lambda (occupant)
 200        (message-ref
 201         (<-wait room occupant 'visible-name
 202                 #:whos-looking player-id)
 203         'text))
 204      (remove
 205       (lambda (x) (equal? x player-id))
 206       (hash-map->list (lambda (x _) x)
 207                       (slot-ref room 'occupants)))))
 208
 209   ;; Strip out the #f responses (these aren't listed because they lack a name
 210   ;; or they aren't "obviously visible" to the player)
 211   (define occupant-names-filtered
 212     (filter identity occupant-names-all))
 213
 214   (define occupant-names-string
 215     (if (eq? occupant-names-filtered '())
 216         #f
 217         (format #f "You see here: ~a.\n"
 218                 (list-words-as-string occupant-names-filtered))))
 219
 220   (define final-text
 221     (if occupant-names-string
 222         (string-append room-text occupant-names-string)
 223         room-text))
 224
 225   (<- room player-id 'tell
 226       #:text final-text))
 227
 228
 229 (define-mhandler (room-look-room room message)
 230   "Command: Player asks to look around the room"
 231   (room-player-looks-around
 232    room
 233    ;; Either send it to the #:to-id of the message, or to the
 234    ;; sender of the message
 235    (message-ref message 'to-id
 236                 (message-from message))))
 237
 238 (define (room-find-thing-called room called-this)
 239   "Find something called CALLED-THIS in the room, if any."
 240   (call/ec
 241    (lambda (return)
 242      (for-each
 243       (lambda (occupant)
 244         (define goes-by
 245           (message-ref (<-wait room occupant 'goes-by)
 246                        'goes-by #f))
 247         (if (member called-this goes-by)
 248             (return occupant)))
 249       (hash-map->list (lambda (key val) key)
 250                       (slot-ref room 'occupants)))
 251      #f)))
 252
 253 (define %formless-desc
 254   "You don't see anything special.")
 255
 256 (define-mhandler (room-look-at room message direct-obj)
 257   "Look at a specific object in the room."
 258   (define matching-object
 259     (room-find-thing-called room direct-obj))
 260
 261   (cond
 262    (matching-object
 263     (let ((obj-desc
 264            (message-ref
 265             (<-wait room matching-object 'get-desc
 266                     #:whos-looking (message-from message))
 267             'val)))
 268       (if obj-desc
 269           (<- room (message-from message) 'tell
 270               #:text (string-append obj-desc "\n"))
 271           (<- room (message-from message) 'tell
 272               #:text (string-append %formless-desc "\n")))))
 273    (else
 274     (<- room (message-from message) 'tell
 275         #:text "You don't see that here, so you can't look at it.\n"))))
 276
 277
 278 (define* (room-tell-room room text #:key exclude wait)
 279   (define who-to-tell (gameobj-occupants room #:exclude exclude))
 280   (for-each
 281    (lambda (tell-me)
 282      ;; @@: Does anything really care?
 283      (define deliver-method
 284        (if wait
 285            <-wait
 286            <-))
 287      (deliver-method room tell-me 'tell
 288                      #:text text))
 289    who-to-tell))
 290
 291 (define-mhandler (room-act-tell-room room message text)
 292   "Tell the room some messages."
 293   (define exclude (message-ref message 'exclude #f))
 294   (define wait-delivery (message-ref message 'wait #f))
 295   (room-tell-room room text
 296                   #:exclude exclude
 297                   #:wait wait-delivery))
 298
 299 (define-mhandler (room-cmd-say room message phrase)
 300   "Command: Say something to room participants."
 301   (define player-name
 302     (message-ref (<-wait room (message-from message)
 303                          'get-name) 'val))
 304   (define message-to-send
 305     (format #f "~a says: ~a\n" player-name phrase))
 306   (room-tell-room room message-to-send))
 307
 308 (define-mhandler (room-cmd-emote room message phrase)
 309   "Command: Say something to room participants."
 310   (define player-name
 311     (message-ref (<-wait room (message-from message)
 312                          'get-name) 'val))
 313   (define message-to-send
 314     (format #f "* ~a ~a\n" player-name phrase))
 315   (room-tell-room room message-to-send))
 316
 317 (define-mhandler (room-announce-entrance room message who-entered)
 318   (define player-name
 319     (message-ref (<-wait room who-entered 'get-name)
 320                  'val))
 321   (define message-to-send
 322     (format #f "~a enters the room.\n" player-name))
 323   (room-tell-room room message-to-send
 324                   #:exclude who-entered))