mudsync/room.scm

   1 ;;; Mudsync --- Live hackable MUD
   2 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of Mudsync.
   5 ;;;
   6 ;;; Mudsync is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or
   9 ;;; (at your option) any later version.
  10 ;;;
  11 ;;; Mudsync is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;;; General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with Mudsync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (mudsync room)
  20   #:use-module (mudsync command)
  21   #:use-module (mudsync gameobj)
  22   #:use-module (8sync systems actors)
  23   #:use-module (8sync agenda)
  24   #:use-module (oop goops)
  25   #:use-module (srfi srfi-1)
  26   #:export (<room>
  27             room-actions
  28             room-actions*
  29
  30             <exit>))
  31
  32 \f
  33 ;;; Exits
  34 ;;; =====
  35
  36 (define-class <exit> ()
  37   ;; Used for wiring
  38   (to-symbol #:init-keyword #:to-symbol)
  39   ;; The actual address we use
  40   (to-address #:init-keyword #:address)
  41   ;; Name of the room (@@: Should this be names?)
  42   (name #:getter exit-name
  43         #:init-keyword #:name)
  44   (desc #:init-keyword #:desc
  45         #:init-value #f)
  46
  47   ;; *Note*: These two methods have an extra layer of indirection, but
  48   ;;   it's for a good reason.
  49   (visible-check #:init-value (const #t)
  50                  #:init-keyword #:visible-check)
  51   ;; By default all exits can be traversed
  52   (traverse-check #:init-value (const #t)
  53                   #:init-keyword #:traverse-check))
  54
  55 (define* (exit-can-traverse? exit actor
  56                              #:optional (target-actor (actor-id actor)))
  57   ((slot-ref exit 'traverse-check) exit actor target-actor))
  58
  59 (define* (exit-is-visible? exit actor
  60                            #:optional (target-actor (actor-id actor)))
  61   ((slot-ref exit 'traverse-check) exit actor target-actor))
  62
  63
  64 \f
  65 ;;; Rooms
  66 ;;; =====
  67
  68 (define %room-contain-commands
  69   (list
  70    (loose-direct-command "look" 'cmd-look-at)
  71    (empty-command "look" 'cmd-look-room)
  72    (empty-command "go" 'cmd-go-where)
  73    (loose-direct-command "go" 'cmd-go)))
  74
  75 (define room-actions
  76   (build-actions
  77    ;; desc == description
  78    (init (wrap-apply room-init))
  79    (wire-exits! (wrap-apply room-wire-exits!))
  80    (cmd-go (wrap-apply room-cmd-go))
  81    (cmd-go-where (wrap-apply room-cmd-go-where))
  82    (cmd-look-room (wrap-apply room-cmd-look-room))))
  83
  84 (define room-actions*
  85   (append room-actions gameobj-actions))
  86
  87 (define room-action-dispatch
  88   (simple-dispatcher room-actions*))
  89
  90 ;; TODO: Subclass from container?
  91 (define-class <room> (<gameobj>)
  92   ;; A list of <exit>
  93   (exits #:init-value '()
  94          #:init-keyword #:exits
  95          #:getter room-exits)
  96
  97   (container-commands
  98    #:init-value (wrap %room-contain-commands))
  99
 100   (message-handler
 101    #:allocation #:each-subclass
 102    ;; @@: Can remove this indirection once things settle
 103    #:init-value (wrap-apply room-action-dispatch)))
 104
 105 (define (room-init room message)
 106   (room-wire-exits! room))
 107
 108 (define (room-wire-exits! room)
 109   "Actually hook up the rooms' exit addresses to the rooms they
 110 claim to point to."
 111   (for-each
 112    (lambda (exit)
 113      (define new-exit
 114        (message-ref
 115         (<-wait room (gameobj-gm room) 'lookup-special
 116                 #:symbol (slot-ref exit 'to-symbol))
 117         'room-id))
 118
 119      (slot-set! exit 'to-address new-exit))
 120
 121    (room-exits room)))
 122
 123 (define-mhandler (room-cmd-go room message direct-obj)
 124   (define exit
 125     (find
 126      (lambda (exit)
 127        (equal? (exit-name exit) direct-obj))
 128      (room-exits room)))
 129   (cond
 130    (exit
 131     (<-wait room (message-from message) 'set-loc!
 132             #:loc (slot-ref exit 'to-address))
 133     (<- room (message-from message) 'look-room))
 134    (else
 135     (<- room (message-from message) 'tell
 136         #:text "You don't see any way to go there.\n"))))
 137
 138 (define-mhandler (room-cmd-go-where room message)
 139   (<- room (message-from message) 'tell
 140       #:text "Go where?\n"))
 141
 142 (define-mhandler (room-cmd-look-room room message)
 143   (<- room (message-from message) 'look-room))