mudsync/player.scm

   1 ;;; Mudsync --- Live hackable MUD
   2 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of Mudsync.
   5 ;;;
   6 ;;; Mudsync is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or
   9 ;;; (at your option) any later version.
  10 ;;;
  11 ;;; Mudsync is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ;;; General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with Mudsync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (mudsync player)
  20   #:use-module (mudsync command)
  21   #:use-module (mudsync gameobj)
  22   #:use-module (mudsync game-master)
  23   #:use-module (mudsync parser)
  24   #:use-module (8sync actors)
  25   #:use-module (8sync agenda)
  26   #:use-module (8sync rmeta-slot)
  27   #:use-module (ice-9 control)
  28   #:use-module (ice-9 format)
  29   #:use-module (ice-9 match)
  30   #:use-module (oop goops)
  31   #:use-module (srfi srfi-1)
  32   #:use-module (srfi srfi-9)
  33   #:export (<player>))
  34
  35 ;;; Players
  36 ;;; =======
  37
  38 (define-class <player> (<gameobj>)
  39   (username #:init-keyword #:username
  40             #:getter player-username)
  41
  42   (self-commands #:allocation #:each-subclass
  43                  #:init-thunk
  44                  (build-commands
  45                   (("inventory" "inv" "i") ((empty-command cmd-inventory)))
  46                   ("help" ((empty-command cmd-help)))))
  47
  48   (actions #:allocation #:each-subclass
  49            #:init-thunk
  50            (build-actions
  51             (init player-init)
  52             (handle-input player-handle-input)
  53             (tell player-tell)
  54             (disconnect-self-destruct player-disconnect-self-destruct)
  55             (cmd-inventory player-cmd-inventory)
  56             (cmd-help player-cmd-help))))
  57
  58
  59 ;;; player message handlers
  60
  61 (define (player-init player message)
  62   ;; Look around the room we're in
  63   (<- (gameobj-loc player) 'look-room))
  64
  65
  66 (define* (player-handle-input player message #:key input)
  67   (define split-input (split-verb-and-rest input))
  68   (define input-verb (car split-input))
  69   (define input-rest (cdr split-input))
  70
  71   (define command-candidates
  72     (player-gather-command-handlers player input-verb))
  73
  74   (define winner
  75     (find-command-winner command-candidates input-rest))
  76
  77   (match winner
  78     ((cmd-action winner-id message-args)
  79      (apply <- winner-id cmd-action message-args))
  80     (#f
  81      (<- (gameobj-gm player) 'write-home
  82          #:text "Sorry, I didn't understand that? (type \"help\" for common commands)\n"))))
  83
  84 (define* (player-tell player message #:key text)
  85   (<- (gameobj-gm player) 'write-home
  86       #:text text))
  87
  88 (define (player-disconnect-self-destruct player message)
  89   "Action routine for being told to disconnect and self destruct."
  90   (define loc (gameobj-loc player))
  91   (when loc
  92     (<- loc 'tell-room
  93         #:exclude (actor-id player)
  94         #:text (format #f "~a disappears in a puff of entropy!\n"
  95                        (slot-ref player 'name))))
  96   (gameobj-self-destruct player))
  97
  98 (define (player-cmd-inventory player message)
  99   "Display the inventory for the player"
 100   (define inv-names
 101     (map
 102      (lambda (inv-item)
 103        (mbody-val (<-wait inv-item 'get-name)))
 104      (gameobj-occupants player)))
 105   (define text-to-show
 106     (if (eq? inv-names '())
 107         "You aren't carrying anything.\n"
 108         `((p "You are carrying:")
 109           (ul ,(map (lambda (item-name)
 110                       `(li ,item-name))
 111                     inv-names)))))
 112   (<- (actor-id player) 'tell #:text text-to-show))
 113
 114 (define (player-cmd-help player message)
 115   (<- (actor-id player) 'tell
 116       #:text '((strong "** Mudsync Help **")(br)
 117                (p "You're playing Mudsync, a multiplayer text-adventure. "
 118                   "Type different commands to interact with your surroundings "
 119                   "and other players.")
 120                (p "Some common commands:"
 121                   (ul (li (strong "say <message>") " -- "
 122                           "Chat with other players in the same room. "
 123                           "(Also aliased to the " (b "\"") " character.)")
 124                       (li (strong "look") " -- "
 125                           "Look around the room you're in.")
 126                       (li (strong "look [at] <object>") " -- "
 127                           "Examine a particular object.")
 128                       (li (strong "go <exit>") " -- "
 129                           "Move to another room in <exit> direction.")))
 130                (p "Different objects can be interacted with in different ways. "
 131                   "For example, if there's a bell in the same room as you, "
 132                   "you might try typing " (em "ring bell")
 133                   " and see what happens."))))
 134
 135
 136 ;;; Command handling
 137 ;;; ================
 138
 139 ;; @@: Hard to know whether this should be in player.scm or here...
 140 ;; @@: This could be more efficient as a stream...!?
 141 (define (player-gather-command-handlers player verb)
 142   (define player-loc
 143     (let ((result (gameobj-loc player)))
 144       (if result
 145           result
 146           (throw 'player-has-no-location
 147                  "Player ~a has no location!  How'd that happen?\n"
 148                  #:player-id (actor-id player)))))
 149
 150   ;; Ask the room for its commands
 151   (define room-commands
 152     ;; TODO: Map room id and sort
 153     (mbody-receive (_ #:key commands)
 154         (<-wait player-loc 'get-container-commands
 155                 #:verb verb)
 156       commands))
 157
 158   ;; All the co-occupants of the room (not including ourself)
 159   (define co-occupants
 160     (remove
 161      (lambda (x) (equal? x (actor-id player)))
 162      (mbody-val (<-wait player-loc 'get-occupants))))
 163
 164   ;; @@: There's a race condition here if someone leaves the room
 165   ;;   during this, heh...
 166   ;;   I'm not sure it can be solved, but "lag" on the race can be
 167   ;;   reduced maybe?
 168
 169   ;; Get all the co-occupants' commands
 170   (define co-occupant-commands
 171     (fold
 172      (lambda (co-occupant prev)
 173        (mbody-receive (_ #:key commands goes-by)
 174            (<-wait co-occupant 'get-commands
 175                    #:verb verb)
 176          (append
 177           (map (lambda (command)
 178                  (list command goes-by co-occupant))
 179                commands)
 180           prev)))
 181      '()
 182      co-occupants))
 183
 184   ;; Append our own command handlers
 185   (define our-commands
 186     (class-rmeta-ref (class-of player) 'self-commands verb
 187                      #:dflt '()))
 188
 189   ;; Append our inventory's relevant command handlers
 190   (define inv-items
 191     (gameobj-occupants player))
 192   (define inv-item-commands
 193     (fold
 194      (lambda (inv-item prev)
 195        (mbody-receive (_ #:key commands goes-by)
 196            (<-wait inv-item 'get-contained-commands
 197                    #:verb verb)
 198          (append
 199           (map (lambda (command)
 200                  (list command goes-by inv-item))
 201                commands)
 202           prev)))
 203      '()
 204      inv-items))
 205
 206   ;; Now return a big ol sorted list of ((actor-id . command))
 207   (append
 208    (sort-commands-append-actor room-commands
 209                                player-loc '()) ; room doesn't go by anything
 210    (sort-commands-multi-actors co-occupant-commands)
 211    (sort-commands-append-actor our-commands
 212                                (actor-id player) '()) ; nor does player
 213    (sort-commands-multi-actors inv-item-commands)))
 214
 215 (define (sort-commands-append-actor commands actor-id goes-by)
 216   (sort-commands-multi-actors
 217    (map (lambda (command) (list command goes-by actor-id)) commands)))
 218
 219 (define (sort-commands-multi-actors actors-and-commands)
 220   (sort
 221    actors-and-commands
 222    (lambda (x y)
 223      (> (command-priority (car x))
 224         (command-priority (car y))))))
 225
 226
 227 (define (find-command-winner sorted-candidates line)
 228   "Find a command winner from a sorted list of candidates"
 229   ;; A cache of results from matchers we've already seen
 230   ;; TODO: fill in this cache.  This is a *critical* optimization!
 231   (define matcher-cache '())
 232   (call/ec
 233    (lambda (return)
 234      (for-each
 235       (match-lambda
 236         ((command actor-goes-by actor-id)
 237          (let* ((matcher (command-matcher command))
 238                 (matched (matcher line)))
 239            (if (and matched
 240                     ;; Great, it matched, but does it also pass
 241                     ;; should-handle?
 242                     (apply (command-should-handle command)
 243                            actor-goes-by
 244                            matched))  ; matched is kwargs if truthy
 245                (return (list (command-action command)
 246                              actor-id matched))
 247                #f))))
 248       sorted-candidates)
 249      #f)))